exiftool_vendored 10.31.0 → 10.40.0

data/bin/Image-ExifTool-10.40/lib/Image/ExifTool/Apple.pm

@@ -0,0 +1,153 @@
+#------------------------------------------------------------------------------
+# File:         Apple.pm
+#
+# Description:  Apple EXIF maker notes tags
+#
+# Revisions:    2013-09-13 - P. Harvey Created
+#
+# References:   1) http://www.photoinvestigator.co/blog/the-mystery-of-maker-apple-metadata/
+#------------------------------------------------------------------------------
+
+package Image::ExifTool::Apple;
+
+use strict;
+use vars qw($VERSION);
+use Image::ExifTool::Exif;
+use Image::ExifTool::PLIST;
+
+$VERSION = '1.03';
+
+# Apple iPhone metadata (ref PH)
+%Image::ExifTool::Apple::Main = (
+    WRITE_PROC => \&Image::ExifTool::Exif::WriteExif,
+    CHECK_PROC => \&Image::ExifTool::Exif::CheckExif,
+    WRITABLE => 1,
+    GROUPS => { 0 => 'MakerNotes', 2 => 'Image' },
+    NOTES => 'Tags extracted from the maker notes of iPhone images.',
+    # 0x0001 - int32s: seen 0,1,2,3,4
+    # 0x0002 - binary plist with a single data object of size 512 bytes (iPhone5s)
+    0x0003 => {
+        Name => 'RunTime', # (includes time plugged in, but not when suspended, ref 1)
+        SubDirectory => { TagTable => 'Image::ExifTool::Apple::RunTime' },
+    },
+    # 0x0004 - int32s: normally 1, but 0 for low-light images
+    # 0x0005 - int32s: seen values 113-247, and 100 for blank images
+    # 0x0006 - int32s: seen values 27-258, and 20 for blank images
+    # 0x0007 - int32s: seen 1
+    0x0008 => { #1
+        Name => 'AccelerationVector',
+        Groups => { 2 => 'Camera' },
+        Writable => 'rational64s',
+        Count => 3,
+        # Note: the directions are contrary to the Apple documentation (which have the
+        # signs of all axes reversed -- apparently the Apple geeks aren't very good
+        # with basic physics, and don't understand the concept of acceleration.  See
+        # http://nscookbook.com/2013/03/ios-programming-recipe-19-using-core-motion-to-access-gyro-and-accelerometer/
+        # for one of the few correct descriptions of this).  Note that this leads to
+        # a left-handed coordinate system for acceleration.
+        Notes => q{
+            XYZ coordinates of the acceleration vector in units of g.  As viewed from
+            the front of the phone, positive X is toward the left side, positive Y is
+            toward the bottom, and positive Z points into the face of the phone
+        },
+    },
+    # 0x0009 - int32s: seen 19,275,531,4371
+    0x000a => {
+        Name => 'HDRImageType',
+        Writable => 'int32s',
+        PrintConv => {
+            # 2 => ? (iPad mini 2)
+            3 => 'HDR Image',
+            4 => 'Original Image',
+        },
+    },
+    0x000b => {
+        Name => 'BurstUUID',
+        Writable => 'string',
+        Notes => 'unique ID for all images in a burst',
+    },
+    # 0x000c - rational64s[2]: eg) "0.1640625 0.19921875"
+    # 0x000d - int32s: 0,1,6,20,40
+    # 0x000e - int32s: 0,1,4,12 (Orienation? 0=landscape? 4=portrait? ref 1)
+    # 0x000f - int32s: 2,3
+    # 0x0010 - int32s: 1
+    # 0x0011 - string[37]: some type of UID, eg. "FFCBAC24-E547-4BBC-AF47-38B1A3D845E3\0" (iPhone 6s, iOS 6.1)
+    # 0x0014 - int32s: 1,2,3,4,5 (iPhone 6s, iOS 6.1)
+    0x0015 => {
+        Name => 'ImageUniqueID',
+        Writable => 'string',
+    },
+);
+
+# PLIST-format CMTime structure (ref PH)
+# (CMTime ref https://developer.apple.com/library/ios/documentation/CoreMedia/Reference/CMTime/Reference/reference.html)
+%Image::ExifTool::Apple::RunTime = (
+    PROCESS_PROC => \&Image::ExifTool::PLIST::ProcessBinaryPLIST,
+    GROUPS => { 0 => 'MakerNotes', 2 => 'Image' },
+    NOTES => q{
+        This PLIST-format information contains the elements of a CMTime structure
+        representing the amount of time the phone has been running since the last
+        boot, not including standby time.
+    },
+    timescale => { Name => 'RunTimeScale' }, # (seen 1000000000 --> ns)
+    epoch     => { Name => 'RunTimeEpoch' }, # (seen 0)
+    value     => { Name => 'RunTimeValue' }, # (should divide by RunTimeScale to get seconds)
+    flags => {
+        Name => 'RunTimeFlags',
+        PrintConv => { BITMASK => {
+            0 => 'Valid',
+            1 => 'Has been rounded',
+            2 => 'Positive infinity',
+            3 => 'Negative infinity',
+            4 => 'Indefinite',
+        }},
+    },
+);
+
+# Apple composite tags
+%Image::ExifTool::Apple::Composite = (
+    GROUPS => { 2 => 'Camera' },
+    RunTimeSincePowerUp => {
+        Require => {
+            0 => 'Apple:RunTimeValue',
+            1 => 'Apple:RunTimeScale',
+        },
+        ValueConv => '$val[1] ? $val[0] / $val[1] : undef',
+        PrintConv => 'ConvertDuration($val)',
+    },
+);
+
+# add our composite tags
+Image::ExifTool::AddCompositeTags('Image::ExifTool::Apple');
+
+
+1;  # end
+
+__END__
+
+=head1 NAME
+
+Image::ExifTool::Apple - Apple EXIF maker notes tags
+
+=head1 SYNOPSIS
+
+This module is loaded automatically by Image::ExifTool when required.
+
+=head1 DESCRIPTION
+
+This module contains definitions required by Image::ExifTool to interpret
+Apple maker notes in EXIF information.
+
+=head1 AUTHOR
+
+Copyright 2003-2017, Phil Harvey (phil at owl.phy.queensu.ca)
+
+This library is free software; you can redistribute it and/or modify it
+under the same terms as Perl itself.
+
+=head1 SEE ALSO
+
+L<Image::ExifTool::TagNames/Apple Tags>,
+L<Image::ExifTool(3pm)|Image::ExifTool>
+
+=cut

data/bin/Image-ExifTool-10.40/lib/Image/ExifTool/Audible.pm

@@ -0,0 +1,317 @@
+#------------------------------------------------------------------------------
+# File:         Audible.pm
+#
+# Description:  Read metadata from Audible audio books
+#
+# Revisions:    2015/04/05 - P. Harvey Created
+#
+# References:   1) https://github.com/jteeuwen/audible
+#               2) https://code.google.com/p/pyaudibletags/
+#               3) http://wiki.multimedia.cx/index.php?title=Audible_Audio
+#------------------------------------------------------------------------------
+
+package Image::ExifTool::Audible;
+
+use strict;
+use vars qw($VERSION);
+use Image::ExifTool qw(:DataAccess :Utils);
+
+$VERSION = '1.02';
+
+sub ProcessAudible_meta($$$);
+sub ProcessAudible_cvrx($$$);
+
+%Image::ExifTool::Audible::Main = (
+    GROUPS => { 2 => 'Audio' },
+    NOTES => q{
+        ExifTool will extract any information found in the metadata dictionary of
+        Audible .AA files, even if not listed in the table below.
+    },
+    # tags found in the metadata dictionary (chunk 2)
+    pubdate    => { Name => 'PublishDate', Groups => { 2 => 'Time' } },
+    pub_date_start => { Name => 'PublishDateStart', Groups => { 2 => 'Time' } },
+    author     => { Name => 'Author',      Groups => { 2 => 'Author' } },
+    copyright  => { Name => 'Copyright',   Groups => { 2 => 'Author' } },
+    # also seen (ref PH):
+    # product_id, parent_id, title, provider, narrator, price, description,
+    # long_description, short_title, is_aggregation, title_id, codec, HeaderSeed,
+    # EncryptedBlocks, HeaderKey, license_list, CPUType, license_count, <12 hex digits>,
+    # parent_short_title, parent_title, aggregation_id, short_description, user_alias
+
+    # information extracted from other chunks
+    _chapter_count => { Name => 'ChapterCount' },       # from chunk 6
+    _cover_art => { # from chunk 11
+        Name => 'CoverArt',
+        Groups => { 2 => 'Preview' },
+        Binary => 1,
+    },
+);
+
+# 'tags' atoms observed in Audible .m4b audio books (ref PH)
+%Image::ExifTool::Audible::tags = (
+    GROUPS => { 0 => 'QuickTime', 2 => 'Audio' },
+    NOTES => 'Information found in "tags" atom of Audible M4B audio books.',
+    meta => {
+        Name => 'Audible_meta',
+        SubDirectory => { TagTable => 'Image::ExifTool::Audible::meta' },
+    },
+    cvrx => {
+        Name => 'Audible_cvrx',
+        SubDirectory => { TagTable => 'Image::ExifTool::Audible::cvrx' },
+    },
+    tseg => {
+        Name => 'Audible_tseg',
+        SubDirectory => { TagTable => 'Image::ExifTool::Audible::tseg' },
+    },
+);
+
+# 'meta' information observed in Audible .m4b audio books (ref PH)
+%Image::ExifTool::Audible::meta = (
+    PROCESS_PROC => \&ProcessAudible_meta,
+    GROUPS => { 0 => 'QuickTime', 2 => 'Audio' },
+    NOTES => 'Information found in Audible M4B "meta" atom.',
+    Album       => 'Album',
+    ALBUMARTIST => { Name => 'AlbumArtist', Groups => { 2 => 'Author' } },
+    Artist      => { Name => 'Artist',      Groups => { 2 => 'Author' } },
+    Comment     => 'Comment',
+    Genre       => 'Genre',
+    itunesmediatype => { Name => 'iTunesMediaType', Description => 'iTunes Media Type' },
+    SUBTITLE    => 'Subtitle',
+    Title       => 'Title',
+    TOOL        => 'CreatorTool',
+    Year        => { Name => 'Year', Groups => { 2 => 'Time' } },
+    track       => 'ChapterName', # (found in 'meta' of 'tseg' atom)
+);
+
+# 'cvrx' information observed in Audible .m4b audio books (ref PH)
+%Image::ExifTool::Audible::cvrx = (
+    PROCESS_PROC => \&ProcessAudible_cvrx,
+    GROUPS => { 0 => 'QuickTime', 2 => 'Audio' },
+    NOTES => 'Audible cover art information in M4B audio books.',
+    VARS => { NO_ID => 1 },
+    CoverArtType => 'CoverArtType',
+    CoverArt     => {
+        Name => 'CoverArt',
+        Groups => { 2 => 'Preview' },
+        Binary => 1,
+    },
+);
+
+# 'tseg' information observed in Audible .m4b audio books (ref PH)
+%Image::ExifTool::Audible::tseg = (
+    GROUPS => { 0 => 'QuickTime', 2 => 'Audio' },
+    tshd => {
+        Name => 'ChapterNumber',
+        Format => 'int32u',
+        ValueConv => '$val + 1',    # start counting from 1
+    },
+    meta => {
+        Name => 'Audible_meta2',
+        SubDirectory => { TagTable => 'Image::ExifTool::Audible::meta' },
+    },
+);
+
+#------------------------------------------------------------------------------
+# Process Audible 'meta' tags from M4B files (ref PH)
+# Inputs: 0) ExifTool object ref, 1) dirInfo ref, 2) tag table ref
+# Returns: 1 on success
+sub ProcessAudible_meta($$$)
+{
+    my ($et, $dirInfo, $tagTablePtr) = @_;
+    my $dataPt = $$dirInfo{DataPt};
+    my $dataPos = $$dirInfo{DataPos};
+    my $dirLen = length $$dataPt;
+    return 0 if $dirLen < 4;
+    my $num = Get32u($dataPt, 0);
+    $et->VerboseDir('Audible_meta', $num);
+    my $pos = 4;
+    my $index;
+    for ($index=0; $index<$num; ++$index) {
+        last if $pos + 3 > $dirLen;
+        my $unk = Get8u($dataPt, $pos);             # ? (0x80 or 0x00)
+        last unless $unk eq 0x80 or $unk eq 0x00;
+        my $len = Get16u($dataPt, $pos + 1);        # tag length
+        $pos += 3;
+        last if $pos + $len + 6 > $dirLen or not $len;
+        my $tag = substr($$dataPt, $pos, $len);     # tag ID
+        my $ver = Get16u($dataPt, $pos + $len);     # version?
+        last unless $ver eq 0x0001;
+        my $size = Get32u($dataPt, $pos + $len + 2);# data size
+        $pos += $len + 6;
+        last if $pos + $size > $dirLen;
+        my $val = $et->Decode(substr($$dataPt, $pos, $size), 'UTF8');
+        unless ($$tagTablePtr{$tag}) {
+            my $name = Image::ExifTool::MakeTagName(($tag =~ /[a-z]/) ? $tag : lc($tag));
+            AddTagToTable($tagTablePtr, $tag, { Name => $name });
+        }
+        $et->HandleTag($tagTablePtr, $tag, $val,
+            DataPt  => $dataPt,
+            DataPos => $dataPos,
+            Start   => $pos,
+            Size    => $size,
+            Index   => $index,
+        );
+        $pos += $size;
+    }
+    return 1;
+}
+
+#------------------------------------------------------------------------------
+# Process Audible 'cvrx' cover art atom from M4B files (ref PH)
+# Inputs: 0) ExifTool object ref, 1) dirInfo ref, 2) tag table ref
+# Returns: 1 on success
+sub ProcessAudible_cvrx($$$)
+{
+    my ($et, $dirInfo, $tagTablePtr) = @_;
+    my $dataPt = $$dirInfo{DataPt};
+    my $dataPos = $$dirInfo{DataPos};
+    my $dirLen = length $$dataPt;
+    return 0 if 0x0a > $dirLen;
+    my $len = Get16u($dataPt, 0x08);
+    return 0 if 0x0a + $len + 6 > $dirLen;
+    my $size = Get32u($dataPt, 0x0a + $len + 2);
+    return 0 if 0x0a + $len + 6 + $size > $dirLen;
+    $et->VerboseDir('Audible_cvrx', undef, $dirLen);
+    $et->HandleTag($tagTablePtr, 'CoverArtType', undef,
+        DataPt  => $dataPt,
+        DataPos => $dataPos,
+        Start   => 0x0a,
+        Size    => $len,
+    );
+    $et->HandleTag($tagTablePtr, 'CoverArt', undef,
+        DataPt  => $dataPt,
+        DataPos => $dataPos,
+        Start   => 0x0a + $len + 6,
+        Size    => $size,
+    );
+    return 1;
+}
+
+#------------------------------------------------------------------------------
+# Read information from an Audible .AA file
+# Inputs: 0) ExifTool ref, 1) dirInfo ref
+# Returns: 1 on success, 0 if this wasn't a valid AA file
+sub ProcessAA($$)
+{
+    my ($et, $dirInfo) = @_;
+    my $raf = $$dirInfo{RAF};
+    my ($buff, $toc, $entry, $i);
+
+    # check magic number
+    return 0 unless $raf->Read($buff, 16) == 16 and $buff=~/^.{4}\x57\x90\x75\x36/s;
+    # check file size
+    if (defined $$et{VALUE}{FileSize}) {
+        # first 4 bytes of the file should be the filesize
+        unpack('N', $buff) == $$et{VALUE}{FileSize} or return 0;
+    }
+    $et->SetFileType();
+    SetByteOrder('MM');
+    my $bytes = 12 * Get32u(\$buff, 8); # table of contents size in bytes
+    $bytes > 0xc00 and $et->Warn('Invalid TOC'), return 1;
+    # read the table of contents
+    $raf->Read($toc, $bytes) == $bytes or $et->Warn('Truncated TOC'), return 1;
+    my $tagTablePtr = GetTagTable('Image::ExifTool::Audible::Main');
+    # parse table of contents (in $toc)
+    for ($entry=0; $entry<$bytes; $entry+=12) {
+        my $type = Get32u(\$toc, $entry);
+        next unless $type == 2 or $type == 6 or $type == 11;
+        my $offset = Get32u(\$toc, $entry + 4);
+        my $length = Get32u(\$toc, $entry + 8) or next;
+        $raf->Seek($offset, 0) or $et->Warn("Chunk $type seek error"), last;
+        if ($type == 6) {   # offset table
+            next if $length < 4 or $raf->Read($buff, 4) != 4; # only read the chapter count
+            $et->HandleTag($tagTablePtr, '_chapter_count', Get32u(\$buff, 0));
+            next;
+        }
+        # read the chunk
+        $length > 100000000 and $et->Warn("Chunk $type too big"), next;
+        $raf->Read($buff, $length) == $length or $et->Warn("Chunk $type read error"), last;
+        if ($type == 11) {  # cover art
+            next if $length < 8;
+            my $len = Get32u(\$buff, 0);
+            my $off = Get32u(\$buff, 4);
+            next if $off < $offset + 8 or $off - $offset + $len > $length;
+            $et->HandleTag($tagTablePtr, '_cover_art', substr($buff, $off-$offset, $len));
+            next;
+        }
+        # parse metadata dictionary (in $buff)
+        $length < 4 and $et->Warn('Bad dictionary'), next;
+        my $num = Get32u(\$buff, 0);
+        $num > 0x200 and $et->Warn('Bad dictionary count'), next;
+        my $pos = 4;    # dictionary starts immediately after count
+        require Image::ExifTool::HTML;  # (for UnescapeHTML)
+        $et->VerboseDir('Audible Metadata', $num);
+        for ($i=0; $i<$num; ++$i) {
+            my $tagPos = $pos + 9;                  # position of tag string
+            $tagPos > $length and $et->Warn('Truncated dictionary'), last;
+            # (1 unknown byte ignored at start of each dictionary entry)
+            my $tagLen = Get32u(\$buff, $pos + 1);  # tag string length
+            my $valLen = Get32u(\$buff, $pos + 5);  # value string length
+            my $valPos = $tagPos + $tagLen;         # position of value string
+            my $nxtPos = $valPos + $valLen;         # position of next entry
+            $nxtPos > $length and $et->Warn('Bad dictionary entry'), last;
+            my $tag = substr($buff, $tagPos, $tagLen);
+            my $val = substr($buff, $valPos, $valLen);
+            unless ($$tagTablePtr{$tag}) {
+                my $name = Image::ExifTool::MakeTagName($tag);
+                $name =~ s/_(.)/\U$1/g; # change from underscore-separated to mixed case
+                AddTagToTable($tagTablePtr, $tag, { Name => $name });
+            }
+            # unescape HTML character references and convert from UTF-8
+            $val = $et->Decode(Image::ExifTool::HTML::UnescapeHTML($val), 'UTF8');
+            $et->HandleTag($tagTablePtr, $tag, $val,
+                DataPos => $offset,
+                DataPt  => \$buff,
+                Start   => $valPos,
+                Size    => $valLen,
+                Index   => $i,
+            );
+            $pos = $nxtPos; # step to next dictionary entry
+        }
+    }
+    return 1;
+}
+
+1;  # end
+
+__END__
+
+=head1 NAME
+
+Image::ExifTool::Audible - Read meta information from Audible audio books
+
+=head1 SYNOPSIS
+
+This module is used by Image::ExifTool
+
+=head1 DESCRIPTION
+
+This module contains definitions required by Image::ExifTool to read meta
+information from Audible audio books.
+
+=head1 AUTHOR
+
+Copyright 2003-2017, Phil Harvey (phil at owl.phy.queensu.ca)
+
+This library is free software; you can redistribute it and/or modify it
+under the same terms as Perl itself.
+
+=head1 REFERENCES
+
+=over 4
+
+=item L<https://github.com/jteeuwen/audible>
+
+=item L<https://code.google.com/p/pyaudibletags/>
+
+=item L<http://wiki.multimedia.cx/index.php?title=Audible_Audio>
+
+=back
+
+=head1 SEE ALSO
+
+L<Image::ExifTool::TagNames/Audible Tags>,
+L<Image::ExifTool(3pm)|Image::ExifTool>
+
+=cut
+