romdev-mcp 0.1.1

package/src/platforms/c64/lib/cc65-src/extra/soft80mono.s

@@ -0,0 +1,74 @@
+;
+; Groepaz/Hitmen, 19.10.2015
+;
+; import/overload stubs for the monochrome soft80 implementation
+;
+; - optimized for size, almost 1k smaller footprint than the full color version
+; - textcolor() sets one common text color for the whole screen
+;
+        .include "../soft80.inc"
+
+        ; soft80mono_cgetc.s
+        .import soft80mono_cgetc
+        .export _cgetc := soft80mono_cgetc              ; cgetc.s
+
+        ; soft80mono_color.s
+        .import soft80mono_textcolor
+        .import soft80mono_bgcolor
+        .export _textcolor := soft80mono_textcolor      ; color.s
+        .export _bgcolor := soft80mono_bgcolor          ; color.s
+
+        ; soft80mono_cpeekc.s
+        .import soft80_cpeekc
+        .export _cpeekc := soft80_cpeekc                ; cpeekc.s
+
+        ; soft80mono_cpeekcolor.s
+        .import soft80mono_cpeekcolor
+        .export _cpeekcolor := soft80mono_cpeekcolor    ; cpeekcolor.s
+
+        ; soft80mono_cpeekrevers.s
+        .import soft80_cpeekrevers
+        .export _cpeekrevers := soft80_cpeekrevers      ; cpeekrevers.s
+
+        ; soft80mono_cpeeks.s
+        .import soft80_cpeeks
+        .export _cpeeks := soft80_cpeeks                ; cpeeks.s
+
+        ; soft80mono_cputc.s
+        .import soft80mono_cputc
+        .import soft80mono_cputcxy
+        .import soft80mono_cputdirect
+        .import soft80mono_putchar
+        .import soft80mono_newline
+        .import soft80mono_plot
+        .export _cputc := soft80mono_cputc              ; cputc.s
+        .export _cputcxy := soft80mono_cputcxy          ; cputc.s
+        .export cputdirect := soft80mono_cputdirect     ; cputc.s
+        .export putchar := soft80mono_putchar           ; cputc.s
+        .export newline := soft80mono_newline           ; cputc.s
+        .export plot := soft80mono_plot                 ; cputc.s
+
+        ; soft80mono_kclrscr.s
+        .import soft80mono_kclrscr
+        .export _clrscr := soft80mono_kclrscr           ; clrscr.s
+
+        ; soft80mono_kplot.s
+        .import soft80mono_kplot
+        .export PLOT := soft80mono_kplot                ; kplot.s
+
+        ; soft80_kscreen.s
+        .import soft80_screensize
+        .export screensize := soft80_screensize         ; _scrsize.s
+        ; FIXME: use _scrsize.s/remove soft80_scrsize.s
+        ;.export SCREEN := soft80_screensize             ; kernal func (kernal.s)
+
+        ; VIC sprite data for the mouse pointer
+        .export         mcb_spritememory  := soft80_spriteblock
+        .export         mcb_spritepointer := (soft80_vram + $03F8)
+
+        ; Chars used by chline () and cvline ()
+        .exportzp       chlinechar = CH_HLINE
+        .exportzp       cvlinechar = CH_VLINE
+
+        .import         return1
+        .export         _doesclrscrafterexit := return1

package/src/platforms/c64/lib/cc65-src/extra/tgimousedata.s

@@ -0,0 +1,21 @@
+; C64 sprite addresses for the TGI mouse pointer
+;
+; 2017-01-13, Greg King
+
+; In order to provide a visible mouse pointer during TGI's graphics mode,
+; the object file "c64-tgimousedata.o" must be linked explicitly into
+; a program file.  Example:
+;
+; cl65 -t c64 -o program-file main-code.c subroutines.s c64-tgimousedata.o
+;
+; Note:  Currently, a program cannot have default
+; pointers for both text and graphic modes.
+
+; The TGI graphics mode uses VIC-II's 16K bank number three.
+;
+; Address of the TGI bitmap's color RAM
+
+COLORMAP        :=      $D000
+
+        .export         mcb_spritepointer := COLORMAP + $03F8
+        .export         mcb_spritememory  := COLORMAP + $0400

package/src/platforms/c64/lib/cc65-src/get_ostype.s

@@ -0,0 +1,43 @@
+;
+; Stefan Haubenthal, Jul 10 2003
+;
+; C64DTV detection by
+; Marco van den Heuvel, 2010-01-28
+;
+; unsigned char get_ostype(void)
+;
+; $AA US
+; $64 PET-64
+; $43 SX-64
+; $03 EU_NEW
+; $00 EU_OLD
+; $FF C64DTV
+;
+
+        .export         _get_ostype
+
+.proc   _get_ostype
+
+        ldx     #0            ; Clear high byte
+
+        ldy     #1
+        sty     $d03f
+        ldy     $d040
+        cpy     $d000
+        bne     @c64dtv
+        inc     $d000
+        cpy     $d040
+        beq     @c64dtv
+
+; Normal C64
+
+        lda     $ff80
+        rts
+
+; C64 DTV
+
+@c64dtv:
+        stx     $d03f
+        lda     #$ff
+        rts
+.endproc

package/src/platforms/c64/lib/cc65-src/get_tv.s

@@ -0,0 +1,20 @@
+;
+; Ullrich von Bassewitz, 2002-12-03
+;
+; unsigned char get_tv (void);
+; /* Return the video mode the machine is using */
+;
+
+        .include        "c64.inc"
+        .include        "get_tv.inc"
+
+;--------------------------------------------------------------------------
+; _get_tv
+
+.proc   _get_tv
+
+        lda     PALFLAG
+        ldx     #0
+        rts
+
+.endproc

package/src/platforms/c64/lib/cc65-src/gettime.s

@@ -0,0 +1,83 @@
+;
+; Stefan Haubenthal, 27.7.2009
+; Oliver Schmidt, 14.8.2018
+;
+; int __fastcall__ clock_gettime (clockid_t clk_id, struct timespec *tp);
+;
+
+        .include        "time.inc"
+        .include        "c64.inc"
+
+        .importzp       sreg, tmp1, tmp2
+        .import         pushax, pusheax, tosmul0ax, steaxspidx, incsp1, return0
+        .import         TM, load_tenth
+
+
+;----------------------------------------------------------------------------
+.code
+
+.proc   _clock_gettime
+
+        jsr     pushax
+        jsr     pushax
+
+        lda     CIA1_TODHR
+        sed
+        tax                     ; Save PM flag
+        and     #%01111111
+        cmp     #$12            ; 12 AM/PM
+        bcc     @L1
+        sbc     #$12
+@L1:    inx                     ; Get PM flag
+        bpl     @L2
+        clc
+        adc     #$12
+@L2:    cld
+        jsr     BCD2dec
+        sta     TM + tm::tm_hour
+        lda     CIA1_TODMIN
+        jsr     BCD2dec
+        sta     TM + tm::tm_min
+        lda     CIA1_TODSEC
+        jsr     BCD2dec
+        sta     TM + tm::tm_sec
+        lda     #<TM
+        ldx     #>TM
+        jsr     _mktime
+
+        ldy     #timespec::tv_sec
+        jsr     steaxspidx      ; Pops address pushed by 2. pushax
+
+        jsr     load_tenth
+        jsr     pusheax
+        lda     CIA1_TOD10
+        ldx     #>$0000
+        jsr     tosmul0ax
+
+        ldy     #timespec::tv_nsec
+        jsr     steaxspidx      ; Pops address pushed by 1. pushax
+
+        jsr     incsp1
+        jmp     return0
+
+.endproc
+
+;----------------------------------------------------------------------------
+; dec = (((BCD>>4)*10) + (BCD&0xf))
+
+.proc   BCD2dec
+
+        tax
+        and     #%00001111
+        sta     tmp1
+        txa
+        and     #%11110000      ; *16
+        lsr                     ; *8
+        sta     tmp2
+        lsr
+        lsr                     ; *2
+        adc     tmp2            ; = *10
+        adc     tmp1
+        rts
+
+.endproc

package/src/platforms/c64/lib/cc65-src/irq.s

@@ -0,0 +1,49 @@
+;
+; IRQ handling (C64 version)
+;
+
+        .export         initirq, doneirq
+        .import         callirq
+
+        .include        "c64.inc"
+
+; ------------------------------------------------------------------------
+
+.segment        "ONCE"
+
+initirq:
+        lda     IRQVec
+        ldx     IRQVec+1
+        sta     IRQInd+1
+        stx     IRQInd+2
+        lda     #<IRQStub
+        ldx     #>IRQStub
+        jmp     setvec
+
+; ------------------------------------------------------------------------
+
+.code
+
+doneirq:
+        lda     IRQInd+1
+        ldx     IRQInd+2
+setvec: sei
+        sta     IRQVec
+        stx     IRQVec+1
+        cli
+        rts
+
+; ------------------------------------------------------------------------
+
+.segment        "LOWCODE"
+
+IRQStub:
+        cld                             ; Just to be sure
+        jsr     callirq                 ; Call the functions
+        jmp     IRQInd                  ; Jump to the saved IRQ vector
+
+; ------------------------------------------------------------------------
+
+.data
+
+IRQInd: jmp     $0000

package/src/platforms/c64/lib/cc65-src/joy/c64-hitjoy.s

@@ -0,0 +1,218 @@
+;
+; DXS/HIT-4 Player joystick driver for the C64
+;
+; Groepaz/Hitmen, 2002-12-23
+; obviously based on Ullrichs driver :)
+;
+
+        .include "zeropage.inc"
+
+        .include "joy-kernel.inc"
+        .include "joy-error.inc"
+        .include "c64.inc"
+
+        .macpack generic
+        .macpack module
+
+
+; ------------------------------------------------------------------------
+; Header. Includes jump table
+
+        module_header   _c64_hitjoy_joy
+
+; Driver signature
+
+        .byte   $6A, $6F, $79   ; "joy"
+        .byte   JOY_API_VERSION ; Driver API version number
+
+; Library reference
+
+        .addr   $0000
+
+; Jump table.
+
+        .addr   INSTALL
+        .addr   UNINSTALL
+        .addr   COUNT
+        .addr   READ
+
+; ------------------------------------------------------------------------
+; Constants
+
+JOY_COUNT       = 4             ; Number of joysticks we support
+
+; ------------------------------------------------------------------------
+; Data. Written in the IRQ, read by the READ routine
+
+.bss
+
+temp3:  .byte 0
+temp4:  .byte 0
+
+.code
+
+; ------------------------------------------------------------------------
+; INSTALL routine. Is called after the driver is loaded into memory. If
+; possible, check if the hardware is present and determine the amount of
+; memory available.
+; Must return an JOY_ERR_xx code in a/x.
+;
+
+INSTALL:
+        lda     #JOY_ERR_OK
+        .assert JOY_ERR_OK = 0, error
+        tax
+
+;       rts             ; Run into UNINSTALL instead
+
+; ------------------------------------------------------------------------
+; UNINSTALL routine. Is called before the driver is removed from memory.
+; Can do cleanup or whatever. Must not return anything.
+;
+
+UNINSTALL:
+        rts
+
+; ------------------------------------------------------------------------
+; COUNT: Return the total number of available joysticks in a/x.
+;
+
+COUNT:  lda     #<JOY_COUNT
+        ldx     #>JOY_COUNT
+        rts
+
+; ------------------------------------------------------------------------
+; READ: Read a particular joystick passed in A.
+;
+
+readadapter:
+
+        sei
+
+        ; cia 2 setup
+        ldy     #$00            ; port b direction
+        sty     $dd03           ; => input
+
+        sty     $dd05           ; cia2 timer a highbyte
+        sty     $dc05           ; cia1 timer a highbyte
+        iny
+        sty     $dd04           ; cia2 timer a lowbyte
+        sty     $dc04           ; cia1 timer a lowbyte
+
+        lda     #%00010001
+        sta     $dd0e           ; control register a
+                                ; timer: start
+                                ;        continuous
+                                ;        forced load
+                                ; serial port: input
+
+        ; cia 1 setup
+        lda     #%01010001
+        sta     $dc0e           ; control register a
+                                ; timer: start
+                                ;        continuous
+                                ;        forced load
+                                ; serial port: output
+
+        ; read directions 3
+        lda     $dd01           ;read cia 2 port b
+        and     #$0f
+        sta     temp3
+
+        ; read button 3
+        lda     $dd02           ;cia 2 port a
+        and     #%11111011      ;data direction
+        sta     $dd02           ;=> bit 2 input
+
+        lda     $dd00           ;read cia 2 p.A
+        and     #%00000100      ;check bit 2
+        asl     a
+        asl     a
+        ora     temp3
+        sta     temp3
+
+        ; read directions 4
+        lda     $dd01           ;read cia 2 port b
+        lsr     a
+        lsr     a
+        lsr     a
+        lsr     a
+        sta     temp4
+
+        ; read button 4
+        ldx     #$ff            ;serial data register
+        stx     $dc0c           ;=> writing $ff causes
+                                ;cia to output some
+                                ;count signals at cnt1
+
+        ldx     $dd0c           ;read cia 2 serial in
+        beq     fire            ;button press if zero
+
+        lda     temp4
+        ora     #%00010000
+        sta     temp4
+
+fire:
+        ; FIXME: to be really 100% correct this should restore the correct timer
+        ;        values for the respective machine (PAL: $4025, NTSC: $4295)
+        ;        however, this should hardly be a problem in a real world program
+
+        lda     #$41
+        sta     $dc05
+        lda     #0
+        sta     $dc04
+
+        cli
+        rts
+
+READ:
+        pha
+        jsr readadapter
+        pla
+
+        tax            ; Joystick number into X
+        bne joy2
+
+; Read joystick 1
+
+joy1:   lda #$7F
+        sei
+        sta CIA1_PRA
+        lda CIA1_PRB
+        cli
+        and #$1F
+        eor #$1F
+        rts
+
+; Read joystick 2
+
+joy2:   dex
+        bne joy3
+
+        ; ldx   #0
+        lda     #$E0
+        ldy     #$FF
+        sei
+        sta     CIA1_DDRA
+        lda     CIA1_PRA
+        sty     CIA1_DDRA
+        cli
+        and     #$1F
+        eor     #$1F
+        rts
+
+        ; Read joystick 3
+
+joy3:   dex
+        bne     joy4
+
+        lda     temp3
+        eor     #$1F
+        rts
+
+        ; Read joystick 4
+
+joy4:   lda     temp4
+        eor     #$1F
+        ldx     #0
+        rts

package/src/platforms/c64/lib/cc65-src/joy/c64-numpad.s

@@ -0,0 +1,155 @@
+;
+; Joystick driver using C128 number pad in 64 mode.
+; May be used multiple times when linked to the statically application.
+;
+; Stefan Haubenthal, 2004-01-26
+; Based on Ullrich von Bassewitz, 2002-12-20
+;
+
+        .include        "zeropage.inc"
+
+        .include        "joy-kernel.inc"
+        .include        "joy-error.inc"
+        .include        "c64.inc"
+
+        .macpack        generic
+        .macpack        module
+
+
+; ------------------------------------------------------------------------
+; Header. Includes jump table
+
+        module_header   _c64_numpad_joy
+
+; Driver signature
+
+        .byte   $6A, $6F, $79           ; "joy"
+        .byte   JOY_API_VERSION         ; Driver API version number
+
+; Library reference
+
+        .addr   $0000
+
+; Jump table.
+
+        .addr   INSTALL
+        .addr   UNINSTALL
+        .addr   COUNT
+        .addr   READ
+
+; ------------------------------------------------------------------------
+; Constants
+
+JOY_COUNT       = 1             ; Number of joysticks we support
+
+
+; ------------------------------------------------------------------------
+; Data.
+
+.rodata
+
+; <U>p      '8' key
+; <D>own    '2' key
+; <L>eft    '4' key
+; <R>ight   '6' key
+; <B>utton  '5' or ENTER key
+
+masktable:
+        ; Input:  LDRBU
+        ; Output: BRLDU
+        .byte %00000000         ; $00
+        .byte %00000001         ; $01
+        .byte %00010000         ; $02
+        .byte %00010001         ; $03
+        .byte %00001000         ; $04
+        .byte %00001001         ; $05
+        .byte %00011000         ; $06
+        .byte %00011001         ; $07
+        .byte %00000010         ; $08
+        .byte %00000011         ; $09
+        .byte %00010010         ; $0A
+        .byte %00010011         ; $0B
+        .byte %00001010         ; $0C
+        .byte %00001011         ; $0D
+        .byte %00011010         ; $0E
+        .byte %00011011         ; $0F
+        .byte %00000100         ; $10
+        .byte %00000101         ; $11
+        .byte %00010100         ; $12
+        .byte %00010101         ; $13
+        .byte %00001100         ; $14
+        .byte %00001101         ; $15
+        .byte %00011100         ; $16
+        .byte %00011101         ; $17
+        .byte %00000110         ; $18
+        .byte %00000111         ; $19
+        .byte %00010110         ; $1A
+        .byte %00010111         ; $1B
+        .byte %00001110         ; $1C
+        .byte %00001111         ; $1D
+        .byte %00011110         ; $1E
+        .byte %00011111         ; $1F
+
+.code
+
+; ------------------------------------------------------------------------
+; INSTALL routine. Is called after the driver is loaded into memory. If
+; possible, check if the hardware is present and determine the amount of
+; memory available.
+; Must return an JOY_ERR_xx code in a/x.
+;
+
+INSTALL:
+        lda     #JOY_ERR_OK             ; Assume we have a "joystick"
+        .assert JOY_ERR_OK = 0, error
+        tax                             ; Set high byte
+        ldy     VIC_CLK_128             ; Test for a C128
+        cpy     #$FF
+        bne     @C128                   ; Jump if we have one
+        lda     #JOY_ERR_NO_DEVICE      ; No C128 -> no numpad
+@C128:
+
+;       rts                     ; Run into UNINSTALL instead
+
+; ------------------------------------------------------------------------
+; UNINSTALL routine. Is called before the driver is removed from memory.
+; Can do cleanup or whatever. Must not return anything.
+;
+
+UNINSTALL:
+        rts
+
+
+; ------------------------------------------------------------------------
+; COUNT: Return the total number of available joysticks in a/x.
+;
+
+COUNT:  lda     #JOY_COUNT
+        ldx     #0
+        rts
+
+; ------------------------------------------------------------------------
+; READ: Read a particular joystick passed in A.
+;
+
+READ:   tax                     ; Clear high byte
+        lda     #$FD            ; For ENTER and '6'
+        ldy     #$FE            ; For '8', '5', '2', '4'
+        sei
+        sta     VIC_KBD_128
+        lda     CIA1_PRB
+        and     #%00110000
+        eor     #%00110000
+        lsr                     ; Map ENTER ...
+        lsr                     ; ... onto '5'
+        sty     VIC_KBD_128
+        eor     CIA1_PRB
+        iny
+        sty     VIC_KBD_128     ; Reset to $FF
+        cli
+        and     #%00111110
+        eor     #%00111110
+        lsr
+        tay
+        lda     masktable,y     ; Convert LDRBU to BRLDU
+        rts