romdev-mcp 0.1.1

package/src/platforms/c64/lib/c64_registers.h

@@ -0,0 +1,108 @@
+/* ── C64 hardware register names ───────────────────────────────────
+ * Standard cc65 / ca65 symbolic names for VIC-II + SID + CIA1/2 +
+ * 6510 I/O ports. Works in both C (`(*(volatile uint8_t*)VIC_BORDER)`)
+ * and ca65 asm (`lda #$00 / sta VIC_BORDER`).
+ *
+ * Address constants follow cc65 cbm.h conventions where possible.
+ */
+#ifndef C64_REGISTERS_H
+#define C64_REGISTERS_H
+
+/* ── 6510 internal I/O ports ($00-$01) ──────────────────────────── */
+#define CPU_PORT_DIR    0x0000  /* data direction */
+#define CPU_PORT        0x0001  /* LORAM/HIRAM/CHAREN/cassette */
+#define CPU_PORT_LORAM  0x01    /* 1 = BASIC ROM visible */
+#define CPU_PORT_HIRAM  0x02    /* 1 = KERNAL ROM visible */
+#define CPU_PORT_CHAREN 0x04    /* 0 = char ROM at $D000, 1 = I/O */
+
+/* ── VIC-II ($D000-$D02E) ───────────────────────────────────────── */
+#define VIC_BASE        0xD000
+#define VIC_SPRITE_X(N) (0xD000 + (N) * 2)
+#define VIC_SPRITE_Y(N) (0xD001 + (N) * 2)
+#define VIC_SPRITES_X8  0xD010   /* sprite X high bits */
+#define VIC_CTRL1       0xD011   /* Y-scroll, 24/25 rows, on, mode bits */
+#define VIC_RASTER      0xD012
+#define VIC_LPEN_X      0xD013
+#define VIC_LPEN_Y      0xD014
+#define VIC_SPR_ENA     0xD015
+#define VIC_CTRL2       0xD016   /* X-scroll, 38/40 cols, multicolor */
+#define VIC_SPR_Y_EXP   0xD017
+#define VIC_MEMORY      0xD018   /* screen base + char base */
+#define VIC_IRQ         0xD019
+#define VIC_IRQ_ENA     0xD01A
+#define VIC_SPR_BG_PRI  0xD01B
+#define VIC_SPR_MCOLOR  0xD01C
+#define VIC_SPR_X_EXP   0xD01D
+#define VIC_SPR_SPR_COL 0xD01E
+#define VIC_SPR_BG_COL  0xD01F
+#define VIC_BORDER      0xD020
+#define VIC_BG0         0xD021
+#define VIC_BG1         0xD022
+#define VIC_BG2         0xD023
+#define VIC_BG3         0xD024
+#define VIC_SPR_MC0     0xD025
+#define VIC_SPR_MC1     0xD026
+#define VIC_SPR_COL(N)  (0xD027 + (N))
+
+/* ── SID ($D400-$D41C) ──────────────────────────────────────────── */
+#define SID_BASE         0xD400
+#define SID_VOICE(N)     (0xD400 + (N) * 7)
+#define SID_FREQ_LO(N)   (0xD400 + (N) * 7 + 0)
+#define SID_FREQ_HI(N)   (0xD400 + (N) * 7 + 1)
+#define SID_PW_LO(N)     (0xD400 + (N) * 7 + 2)
+#define SID_PW_HI(N)     (0xD400 + (N) * 7 + 3)
+#define SID_CTRL(N)      (0xD400 + (N) * 7 + 4)
+#define SID_AD(N)        (0xD400 + (N) * 7 + 5)
+#define SID_SR(N)        (0xD400 + (N) * 7 + 6)
+#define SID_FILTER_LO    0xD415
+#define SID_FILTER_HI    0xD416
+#define SID_RES_FILT     0xD417
+#define SID_VOL_MODE     0xD418
+
+/* SID waveform control bits */
+#define SID_GATE         0x01
+#define SID_SYNC         0x02
+#define SID_RING         0x04
+#define SID_TEST         0x08
+#define SID_TRIANGLE     0x10
+#define SID_SAWTOOTH     0x20
+#define SID_PULSE        0x40
+#define SID_NOISE        0x80
+
+/* ── CIA1 ($DC00-$DC0F) — keyboard / joystick / timers ──────────── */
+#define CIA1_PRA         0xDC00  /* port A (keyboard col / joystick 2) */
+#define CIA1_PRB         0xDC01  /* port B (keyboard row / joystick 1) */
+#define CIA1_DDRA        0xDC02
+#define CIA1_DDRB        0xDC03
+
+/* ── CIA2 ($DD00-$DD0F) — VIC bank select + serial bus ──────────── */
+#define CIA2_PRA         0xDD00  /* bits 0-1 = VIC bank (inverted) */
+#define CIA2_PRB         0xDD01
+#define CIA2_DDRA        0xDD02
+#define CIA2_DDRB        0xDD03
+
+/* ── Color RAM ──────────────────────────────────────────────────── */
+#define COLOR_RAM        0xD800  /* 1 KB, low nibble only */
+
+/* ── Default screen / char locations (VIC bank 0) ───────────────── */
+#define SCREEN_RAM       0x0400  /* 40×25 = 1000 bytes */
+
+/* ── Standard color codes (matches BASIC's PEEK/POKE values) ────── */
+#define COLOR_BLACK      0
+#define COLOR_WHITE      1
+#define COLOR_RED        2
+#define COLOR_CYAN       3
+#define COLOR_PURPLE     4
+#define COLOR_GREEN      5
+#define COLOR_BLUE       6
+#define COLOR_YELLOW     7
+#define COLOR_ORANGE     8
+#define COLOR_BROWN      9
+#define COLOR_LIGHT_RED  10
+#define COLOR_DARK_GRAY  11
+#define COLOR_MED_GRAY   12
+#define COLOR_LIGHT_GREEN 13
+#define COLOR_LIGHT_BLUE 14
+#define COLOR_LIGHT_GRAY 15
+
+#endif /* C64_REGISTERS_H */

package/src/platforms/c64/lib/cc65-src/_scrsize.s

@@ -0,0 +1,12 @@
+;
+; Ullrich von Bassewitz, 26.10.2000
+;
+; Screen size variables
+;
+
+        .export         screensize
+        .import         SCREEN
+
+screensize      = SCREEN
+
+

package/src/platforms/c64/lib/cc65-src/acc_c128_speed.s

@@ -0,0 +1,5 @@
+;
+; Marco van den Heuvel, 2018-04-23
+;
+
+.include "../c128/acc_c128_speed.s"

package/src/platforms/c64/lib/cc65-src/acc_c64dtv_speed.s

@@ -0,0 +1,64 @@
+;
+; Marco van den Heuvel, 2018-04-14
+;
+
+; unsigned char __fastcall__ set_c64dtv_speed (unsigned char speed);
+;
+;/* Set the speed of the C64DTV, using SPEED_SLOW will switch to
+; * slow mode, SPEED_2X or SPEED_FAST will switch to fast mode.
+; *
+; * Note that any value higher or equal to SPEED_2X will switch to fast mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, to my knowledge the switching should not fail.
+; *
+; * This function does not check for the presence of the C64DTV,
+; * make sure you use 'detect_c64dtv();' before using.
+; */
+
+; unsigned char get_c64dtv_speed (void);
+;
+;/* Get the speed of the C64DTV.
+; *
+; * Possible return values:
+; * SPEED_1X    : slow mode
+; * SPEED_2X    : fast mode
+; *
+; * This function does not check for the presence of the C64DTV,
+; * make sure you use 'detect_c64dtv();' before using.
+; */
+
+        .export         _set_c64dtv_speed
+        .export         _get_c64dtv_speed
+
+        .include        "accelerator.inc"
+
+_set_c64dtv_speed:
+        cmp     #SPEED_2X
+        bcs     high_speed
+low_speed:
+        ldx     #C64DTV_Slow
+set_speed:
+        .byte   $32,$99               ; SAC #$99   set accumulator to reg 9 (cpu control)
+        txa                           ; (re)set skip and burst bits
+        .byte   $32,$00               ; SAC #$00   set accumulator back to reg 0
+        jmp     _get_c64dtv_speed
+
+high_speed:
+        ldx     #C64DTV_Fast
+        bne     set_speed
+
+
+_get_c64dtv_speed:
+        .byte   $32,$99               ; SAC #$99   set accumulator to reg 9 (cpu control)
+        tax
+        .byte   $32,$00               ; SAC #$00   set accumulator back to reg 0
+        txa
+        and     #C64DTV_Fast
+        bne     in_fast_mode
+        lda     #$00
+        .byte   $2C
+in_fast_mode:
+        lda     #$01
+        ldx     #$00
+        rts

package/src/platforms/c64/lib/cc65-src/acc_c65_speed.s

@@ -0,0 +1,69 @@
+;
+; Marco van den Heuvel, 2018-04-27
+;
+
+; unsigned char __fastcall__ set_c65_speed (unsigned char speed);
+;
+;/* Set the speed of the C65 CPU, using SPEED_SLOW will switch to
+; * 1 Mhz mode, SPEED_3X or SPEED_FAST will switch to 3.5 Mhz (fast) mode.
+; *
+; * Note that any value higher or equal to SPEED_3X will switch to fast mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, to my knowledge the switching should not fail.
+; *
+; * This function does not check for the presence of a C65/C64DX in C64 mode,
+; * make sure you use 'detect_c65();' before using.
+; */
+
+; unsigned char get_c65_speed (void);
+;
+;/* Get the speed of the C65 CPU.
+; *
+; * Possible return values:
+; * SPEED_SLOW  : 1 Mhz mode
+; * SPEED_3X    : 3.5 Mhz mode
+; *
+; * This function does not check for the presence of a C65/C64DX in C64 mode,
+; * make sure you use 'detect_c65();' before using.
+; */
+
+        .export         _set_c65_speed
+        .export         _get_c65_speed
+
+        .include        "accelerator.inc"
+
+_set_c65_speed:
+        tay
+        jsr     activate_new_vic_mode
+        cpy     #SPEED_3X
+        bcs     high_speed
+low_speed:
+        and     #$BF
+store_speed:
+        sta     C65_VICIII_CTRL_B
+        lda     C65_VICIII_CTRL_B
+        jmp     return_c65_speed
+
+high_speed:
+        ora     #$40
+        bne     store_speed
+
+_get_c65_speed:
+        jsr     activate_new_vic_mode
+return_c65_speed:
+        sta     C65_VICIII_KEY
+        and     #$40
+        beq     speed_is_slow              ; when this branch is taken then register A is already set to SPEED_SLOW
+        lda     #SPEED_3X
+speed_is_slow:
+        ldx     #$00
+        rts
+
+activate_new_vic_mode:
+        lda     #C65_VICIII_UNLOCK_1
+        sta     C65_VICIII_KEY
+        lda     #C65_VICIII_UNLOCK_2
+        sta     C65_VICIII_KEY
+        lda     C65_VICIII_CTRL_B
+        rts

package/src/platforms/c64/lib/cc65-src/acc_chameleon_speed.s

@@ -0,0 +1,100 @@
+;
+; Marco van den Heuvel, 2018-04-25
+;
+
+; unsigned char __fastcall__ set_chameleon_speed (unsigned char speed);
+;
+;/* Set the speed of the Chameleon cartridge, the following inputs
+; * are accepted:
+; * SPEED_SLOW : 1 Mhz mode
+; * SPEED_1X   : 1 Mhz mode
+; * SPEED_2X   : 2 Mhz mode
+; * SPEED_3X   : 3 Mhz mode
+; * SPEED_4X   : 4 Mhz mode
+; * SPEED_5X   : 5 Mhz mode
+; * SPEED_6X   : 6 Mhz mode
+; * SPEED_FAST : Maximum speed mode
+; *
+; * Note that any value higher or equal to SPEED_7X will switch to maximum
+; * speed mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, to my knowledge the switching should not fail.
+; *
+; * This function does not check for the presence of the Chameleon cartridge,
+; * make sure you use 'detect_chameleon();' before using.
+; */
+
+; unsigned char get_chameleon_speed (void);
+;
+;/* Get the speed of the Chameleon cartridge.
+; *
+; * Possible return values:
+; * SPEED_SLOW  : Slow mode
+; * SPEED_2X    : 2Mhz mode
+; * SPEED_3X    : 3Mhz mode
+; * SPEED_4X    : 4Mhz mode
+; * SPEED_5X    : 5Mhz mode
+; * SPEED_6X    : 6Mhz mode
+; * SPEED_FAST  : Maximum speed mode
+; *
+; * This function does not check for the presence of the Chameleon cartridge,
+; * make sure you use 'detect_chameleon();' before using.
+; */
+
+        .export         _set_chameleon_speed
+        .export         _get_chameleon_speed
+
+        .include        "accelerator.inc"
+
+_set_chameleon_speed:
+        cmp     #SPEED_7X
+        bcs     maximum_speed
+        cmp     #SPEED_1X
+        beq     low_speed
+        ora     #$80
+set_speed:
+        jsr     activate_regs
+        sta     CHAMELEON_CFGTUR
+        jmp     return_speed
+
+low_speed:
+        lda     #CHAMELEON_CFGTUR_LIMIT_1MHZ
+        bne     set_speed
+
+maximum_speed:
+        lda     #CHAMELEON_CFGTUR_LIMIT_NONE
+        bne     set_speed
+
+_get_chameleon_speed:
+        jsr     activate_regs
+return_speed:
+        ldx     #$00
+        lda     CHAMELEON_CFGTUR
+        tay
+        and     #%10000000
+        beq     return_value
+        tya
+        and     #%00001000
+        bne     is_slow_mode
+        tya
+        and     #%00000111
+        beq     is_max_mode
+return_value:
+        ldy     #CHAMELEON_DISABLE_REGS
+        sty     CHAMELEON_CFGENA
+        rts
+
+is_slow_mode:
+        txa
+        bne     return_value
+
+is_max_mode:
+        lda     #SPEED_FAST
+        bne     return_value
+
+activate_regs:
+        ldy     #CHAMELEON_ENABLE_REGS
+        sty     CHAMELEON_CFGENA
+        rts
+

package/src/platforms/c64/lib/cc65-src/acc_detect_c128.s

@@ -0,0 +1,33 @@
+;
+; 2018-04-20, Marco van den Heuvel
+; 2018-04-26, Greg King
+;
+
+; unsigned char detect_c128 (void);
+;
+;/* Check for the presence of a C128 in C64 mode.
+; *
+; * Possible return values:
+; * 0x00  : C128 in C64 mode not present
+; * 0x01  : C128 in C64 mode present
+; */
+
+        .export         _detect_c128
+
+        .include        "accelerator.inc"
+
+_detect_c128:
+        ldx     #>$0001
+        lda     #<$0001
+
+; Make sure the CPU is an 8502.
+        .byte   $3A     ; NOP on 8502, DEA on 65(S)C(E)02, 4510, and 65816
+        beq     detect_end
+
+; Make sure a C128 VIC-IIe is present.
+        ldy     C128_VICIIE_CLK
+        cpy     #$FF
+        bne     detect_end
+        txa             ; return zero when not VIC-IIe
+detect_end:
+        rts

package/src/platforms/c64/lib/cc65-src/acc_detect_c64dtv.s

@@ -0,0 +1,44 @@
+;
+; Marco van den Heuvel, 2018-04-14
+;
+
+; unsigned char detect_c64dtv (void);
+;
+;/* Check for the presence of the C64DTV.
+; *
+; * Possible return values:
+; * 0x00  : C64DTV not present
+; * 0x01  : C64DTV present
+; */
+
+        .export         _detect_c64dtv
+
+        .include        "accelerator.inc"
+
+_detect_c64dtv:
+        ldy     C64DTV_Extended_Regs
+        lda     #$00
+        ldx     $D000
+
+; Make sure the CPU is a 6510
+        .byte   $1A                   ; NOP on 8502, INA on 65(S)C(E)02, 4510 and 65816
+        bne     not_found
+        lda     #$01
+        sta     C64DTV_Extended_Regs
+
+; Check if $D000 is mirrored at $D040
+        cpx     $D040
+        bne     found
+        inc     $D000
+        cpx     $D040
+        bne     not_found
+found:
+        lda     #$01
+        .byte   $2C
+not_found:
+        lda     #$00
+        stx     $D000
+        ldx     #$00
+        sty     C64DTV_Extended_Regs
+        rts
+

package/src/platforms/c64/lib/cc65-src/acc_detect_c65.s

@@ -0,0 +1,55 @@
+;
+; Marco van den Heuvel, 2018-04-27
+;
+
+; unsigned char detect_c65 (void);
+;
+;/* Check for the presence of a C65/C64DX in C64 mode.
+; *
+; * Possible return values:
+; * 0x00  : C65/C64DX in C64 mode not present
+; * 0x01  : C65/C64DX in C64 mode present
+; */
+
+        .export         _detect_c65
+
+        .include        "accelerator.inc"
+
+_detect_c65:
+        ldy     $D000
+
+; Make sure the CPU is not a 65816
+        clc
+        .byte   $E2,$01                ; NOP #$01 on 6510 and 65(S)C02, LDA $(01,S),Y on 65CE02 and 4510, SEP #$01 on 65816
+        lda     #$00
+        tax
+        bcs     not_found              ; carry will be set on 65816
+
+; Make sure the CPU is not a 6510
+        .byte   $1A                    ; NOP on 6510, INA on 65(S)C(E)02
+        beq     not_found
+        txa
+
+; Make sure the CPU is a 65CE02/4510
+        .byte   $A3,$A3                ; NOP NOP on 65(S)C02, LDZ #$A3 on 65CE02 and 4510
+        .byte   $6B                    ; NOP on 65(S)C02, TZA on 65CE02 and 4510
+        cmp     #$A3
+        bne     not_found
+
+; Switch to VICIII mode and check if $D040 is a mirror of $D000
+        ldy     #C65_VICIII_UNLOCK_1
+        sty     C65_VICIII_KEY
+        ldy     #C65_VICIII_UNLOCK_2
+        sty     C65_VICIII_KEY
+        cpy     $D040
+        bne     found
+        inc     $D000
+        cpy     $D040
+        bne     not_found
+
+found:
+        lda     #$01
+not_found:
+        sty     $D000
+        sta     C65_VICIII_KEY
+        rts

package/src/platforms/c64/lib/cc65-src/acc_detect_chameleon.s

@@ -0,0 +1,39 @@
+;
+; Marco van den Heuvel, 2018-04-25
+;
+
+; unsigned char detect_chameleon (void);
+;
+;/* Check for the presence of the Chameleon cartridge.
+; *
+; * Possible return values:
+; * 0x00  : Chameleon cartridge not present
+; * 0x01  : Chameleon cartridge present
+; */
+
+        .export         _detect_chameleon
+
+        .include        "accelerator.inc"
+
+_detect_chameleon:
+        lda     #$00
+        tax
+
+; Make sure the CPU is a 6510
+        .byte   $1A                   ; NOP on 6510, INA on 65(S)C(E)02, 4510 and 65816
+        bne     not_found
+
+        ldy     CHAMELEON_CFGENA
+        lda     #CHAMELEON_ENABLE_REGS
+        sta     CHAMELEON_CFGENA
+        lda     CHAMELEON_CFGENA
+        sty     CHAMELEON_CFGENA
+        cmp     #$FF
+        beq     not_found
+found:
+        lda     #$01
+        .byte   $24
+not_found:
+        txa
+        rts
+

package/src/platforms/c64/lib/cc65-src/acc_detect_scpu.s

@@ -0,0 +1,34 @@
+;
+; Marco van den Heuvel, 2018-04-08
+;
+
+; unsigned char detect_scpu (void);
+;
+;/* Check for the presence of the SuperCPU cartridge.
+; *
+; * Possible return values:
+; * 0x00  : SuperCPU cartridge not present
+; * 0x01  : SuperCPU cartridge present
+; */
+
+        .export         _detect_scpu
+
+        .include        "accelerator.inc"
+_detect_scpu:
+        ldx     #$00
+        txa
+
+; Make sure the current CPU is a 65816
+        clc
+        .byte   $E2,$01                ; NOP #$01 on 6510 and 65(S)C02, LDA $(01,S),Y on 65CE02 and 4510, SEP #$01 on 65816
+        bcc     not_found              ; carry will be set on 65816
+
+; 65816 has been detected, make sure it's the SuperCPU cartridge
+
+        lda     SuperCPU_Detect
+        asl
+        bcs     not_found
+found:
+        lda     #$01
+not_found:
+        rts

package/src/platforms/c64/lib/cc65-src/acc_detect_turbomaster.s

@@ -0,0 +1,45 @@
+;
+; Marco van den Heuvel, 2018-04-30
+;
+
+; unsigned char detect_turbomaster (void);
+;
+;/* Check for the presence of a Turbo Master cartridge.
+; *
+; * Possible return values:
+; * 0x00  : TurboMaster cartridge not present
+; * 0x01  : TurboMaster cartridge present
+; */
+
+        .export         _detect_turbomaster
+
+        .include        "accelerator.inc"
+
+_detect_turbomaster:
+        lda     #$00
+        tax
+
+; Make sure the current CPU is not a 6510
+        .byte   $1A                    ; NOP on 8502, INA on 65(S)C(E)02, 4510 and 65816
+        beq     not_found
+
+; Make sure the current CPU is not a 65816
+        clc
+        .byte   $E2,$01                ; NOP #$01 on 65(S)C02, LDA $(01,S),Y on 65CE02 and 4510, SEP #$01 on 65816
+        bcs     not_found              ; carry will be set on 65816
+
+; Make sure the current CPU is not a 65CE02/4510
+        .byte   $A3,$A3                ; NOP NOP on 65(S)C02 and LDZ #$00 on 65CE02 and 4510
+        .byte   $6B                    ; NOP on 65(S)C02 and TZA on 65CE02 and 4510
+        cmp     #$A3
+        beq     not_found
+
+; Check for turbo master basic replacement
+        ldy     TURBOMASTER_DETECT
+        cpy     #$A2
+        beq     found
+not_found:
+        txa
+found:
+        rts
+

package/src/platforms/c64/lib/cc65-src/acc_scpu_speed.s

@@ -0,0 +1,59 @@
+;
+; Marco van den Heuvel, 2018-04-09
+;
+
+; unsigned char __fastcall__ set_scpu_speed (unsigned char speed);
+;
+;/* Set the speed of the SuperCPU cartridge, using SPEED_SLOW will switch to
+; * 1 Mhz mode, SPEED_20X or SPEED_FAST will switch to 20 Mhz mode.
+; *
+; * Note that any value lower than SPEED_20X will switch to 1 Mhz mode, and
+; * any value higher or equal to SPEED_20X will switch to 20 Mhz mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, if this is not the speed that was requested
+; * then possibly the hardware speed switch prevented any software speed
+; * switching.
+; *
+; * This function does not check for the presence of the SuperCPU cartridge,
+; * make sure you use 'detect_scpu();' before using.
+; */
+
+; unsigned char get_scpu_speed (void);
+;
+;/* Get the speed of the SuperCPU cartridge.
+; *
+; * Possible return values:
+; * SPEED_1X    :  1 Mhz mode
+; * SPEED_20X   : 20 Mhz mode
+; *
+; * This function does not check for the presence of the SuperCPU cartridge,
+; * make sure you use 'detect_scpu();' before using.
+; */
+
+        .export         _set_scpu_speed
+        .export         _get_scpu_speed
+
+        .include        "accelerator.inc"
+
+_set_scpu_speed:
+        cmp     #SPEED_20X
+        bcs     high_speed
+low_speed:
+        sta     SuperCPU_Slow
+        jmp     _get_scpu_speed
+
+high_speed:
+        sta     SuperCPU_Fast
+
+_get_scpu_speed:
+        ldx     #$00
+        lda     SuperCPU_Speed_Mode
+        asl
+        asl
+        bcc     is_fast_speed
+        lda     #SPEED_1X
+        rts
+is_fast_speed:
+        lda     #SPEED_20X
+        rts