romdev-mcp 0.1.1

package/src/platforms/atari7800/lib/cc65-src/cputc.s

@@ -0,0 +1,139 @@
+;
+; Mark Keates, Christian Groessler, Piotr Fusik, Karri Kaksonen
+;
+; void cputcxy (unsigned char x, unsigned char y, char c);
+; void cputc (char c);
+;
+; Important note: The implementation of cputs() relies on the cputc() function
+; not clobbering ptr1. Beware when rewriting or changing this function!
+
+        .export         _cputc
+        .import         gotox, gotoy, pusha0
+        .import         pushax
+        .import         _screen
+        .import         txtcolor
+
+        .include        "atari7800.inc"
+        .include        "extzp.inc"
+
+        .code
+
+;---------------------------------------------------------------------------
+; 8x16 routine
+
+umula0:
+        ldy     #8                 ; Number of bits
+        lda     #0
+        lsr     ptr7800            ; Get first bit into carry
+@L0:    bcc     @L1
+
+        clc
+        adc     ptrtmp
+        tax
+        lda     ptrtmp+1           ; hi byte of left op
+        clc
+        adc     ptr7800+1
+        sta     ptr7800+1
+        txa
+
+@L1:    ror     ptr7800+1
+        ror     a
+        ror     ptr7800
+        dey
+        bne     @L0
+        tax
+        lda     ptr7800            ; Load the result
+        rts
+
+;-----------------------------------------------------------------------------
+; Put a character on screen
+;
+; The code will handle newlines that wrap to start of screen
+;
+        .proc   _cputc
+
+        cmp     #$0A            ; LF
+        bne     @L4
+@L1:    lda     CURS_Y          ; newline
+        cmp     #(screenrows-1)
+        bne     @L2
+        lda     #0
+        beq     @L3
+@L2:    clc
+        adc     #1
+@L3:    jsr     gotoy
+        lda     #0
+        jmp     gotox
+
+@L4:
+        cmp     #$20            ; ' '
+        bne     @L5
+        lda     #$00
+        jmp     @L10
+@L5:
+        cmp     #$3F            ; '?'
+        bne     @L6
+        lda     #$02
+        jmp     @L9
+@L6:
+        cmp     #$7C            ; '|'
+        bne     @L7
+        lda     #$06
+        jmp     @L9
+@L7:
+        cmp     #$41            ; >= 'A'
+        bcc     @L8
+        and     #$5F            ; make upper case
+        sec
+        sbc     #($41 - 17)
+        jmp     @L9
+@L8:
+        sec                     ; >= '*'
+        sbc     #($2A - 1)
+@L9:
+        clc
+        adc     txtcolor
+@L10:
+        asl
+        pha
+
+        lda     #0
+        sta     ptr7800+1
+        sta     ptrtmp+1
+        lda     CURS_Y          ; Find position on screen buffer
+        sta     ptr7800
+        lda     #charsperline
+        sta     ptrtmp
+        jsr     umula0
+        clc
+        adc     CURS_X
+        bcc     @L11
+        inx
+@L11:   clc
+        adc     #<(_screen)
+        sta     ptr7800
+        bcc     @L12
+        inx
+@L12:   txa
+        clc
+        adc     #>(_screen)
+        sta     ptr7800+1
+
+        pla                     ; Print character on screen
+        ldy     #0
+        sta     (ptr7800),y
+
+        lda     CURS_X          ; Increment cursor
+        cmp     #(charsperline-1)
+        beq     @L1
+        clc
+        adc     #1
+        jmp     gotox
+
+        .endproc
+
+;-------------------------------------------------------------------------------
+; force the init constructor to be imported
+
+                .import initconio
+conio_init      = initconio

package/src/platforms/atari7800/lib/cc65-src/crt0.s

@@ -0,0 +1,71 @@
+        .export     _zonecounter
+        .export     __STARTUP__ : absolute = 1
+        .export     _exit
+        .import     __ROM_START__
+        .import     __RAM3_START__, __RAM3_SIZE__
+        .import     initlib, donelib
+        .import     zerobss, copydata
+        .import     IRQStub
+        .import     push0, _main
+        .include    "atari7800.inc"
+        .include    "zeropage.inc"
+
+INPTCTRL        =       $01
+
+        .segment "STARTUP"
+start:
+        ; Startup sequence recommended by Atari.
+        ; See the 7800 standards document.
+        sei                     ; Initialize 6502
+        cld
+        lda     #$07            ; Lock machine in 7800 mode
+        sta     INPTCTRL
+        lda     #$7f            ; DMA off
+        sta     CTRL
+        ldx     #0              ; OFFSET must always be 0
+        stx     OFFSET
+        stx     INPTCTRL        ; Make sure joysticks don't freeze
+        dex                     ; Stack pointer = $ff
+        txs
+
+        ; Set up parameter stack
+        lda     #<(__RAM3_START__ + __RAM3_SIZE__)
+        sta     c_sp
+        lda     #>(__RAM3_START__ + __RAM3_SIZE__)
+        sta     c_sp+1
+
+        jsr     copydata
+        jsr     zerobss
+        jsr     initlib
+
+        ; Call main program (pass empty command line)
+        jsr     push0           ; argc
+        jsr     push0           ; argv
+        ldy     #4              ; Argument size
+        jsr     _main
+
+_exit:
+        jsr     donelib
+        jmp     start
+
+NMIHandler:
+        inc     _zonecounter
+        jmp     IRQStub
+
+IRQHandler:
+        rti
+
+        .segment "DATA"
+_zonecounter:
+        .byte   0
+
+        .segment "ENCRYPTION"
+        .res    126, $ff        ; Reserved for encryption
+Lfff8:  .byte   $ff             ; Region verification (always $ff)
+Lfff9:  .byte   $f7             ; Use last 4096 bytes only for encryption
+;;;Lfff9:  .byte   <(((__ROM_START__/4096)<<4) | 7)
+
+        .segment "VECTORS"
+        .word   NMIHandler
+        .word   start
+        .word   IRQHandler

package/src/platforms/atari7800/lib/cc65-src/ctype.s

@@ -0,0 +1,5 @@
+; Character specification table.
+;
+; uses the "common" definition
+
+        .include "ctype_common.inc"

package/src/platforms/atari7800/lib/cc65-src/exehdr.s

@@ -0,0 +1,46 @@
+;
+; Karri Kaksonen, 2022
+;
+; This header contains data for emulators
+;
+        .export         __EXEHDR__: absolute = 1
+        .import         __CARTSIZE__
+; ------------------------------------------------------------------------
+; EXE header
+    .segment "EXEHDR"
+    .byte   3   ; version
+    .byte   'A','T','A','R','I','7','8','0','0',' ',' ',' ',' ',' ',' ',' '
+    .byte   'G','a','m','e',' ','n','a','m','e',0,0,0,0,0,0,0
+    .byte   0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
+    .byte   0,0,>__CARTSIZE__,0 ; Set the cart size in the cfg file
+    ;    bit  0 - pokey at 4000
+    ;    bit  1 - supergame bank switched
+    ;    bit  2 - supergame ram at $4000
+    ;    bit  3 - rom at $4000
+    ;    bit  4 - bank 6 at $4000
+    ;    bit  5 - supergame banked ram
+    ;    bit  6 - pokey at $450
+    ;    bit  7 - mirror ram at $4000
+    ;    bit  8 - activision banking
+    ;    bit  9 - absolute banking
+    ;    bit 10 - pokey at $440
+    ;    bit 11 - ym2151 at $461/462
+    ;    bit 12 - souper
+    ;    bit 13-15 - Special
+    ;   0 = Normal cart
+    .byte   0,0             ; 0 = Normal cart
+    .byte   1               ; 1 = Joystick, 2 = lightgun
+    .byte   0               ; No joystick 2
+    .byte   0               ; bit0 = 0:NTSC,1:PAL bit1 = 0:component,1:composite
+    .byte   0  ; Save data peripheral - 1 byte (version 2)
+    ;    0 = None / unknown (default)
+    ;    1 = High Score Cart (HSC)
+    ;    2 = SaveKey
+
+    .byte   0               ; 63   Expansion module
+    ;    0 = No expansion module (default on all currently released games)
+    ;    1 = Expansion module required
+    .byte   0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
+    .byte   0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
+    .byte   0,0,0,0,0,0,0,0
+    .byte   'A','C','T','U','A','L',' ','C','A','R','T',' ','D','A','T','A',' ','S','T','A','R','T','S',' ','H','E','R','E'

package/src/platforms/atari7800/lib/cc65-src/extra/mono.s

@@ -0,0 +1,28 @@
+;
+; Groepaz/Hitmen, 19.10.2015
+;
+; import/overload stubs for the monochrome conio implementation
+;
+
+        ; mono_conio.s
+        .import _mono_screen
+        .export _screen := _mono_screen
+
+        ; mono_clrscr.s
+        .import _mono_clrscr
+        .export _clrscr := _mono_clrscr
+
+        ; mono_cputc.s
+        .import _mono_cputc
+        .export _cputc := _mono_cputc
+
+        ; mono_font.s
+        .import _mono_font
+        .export _font := _mono_font
+
+        ; mono_setcursor.s
+        .import mono_gotoxy
+        .export gotoxy := mono_gotoxy
+        .import _mono_gotoxy
+        .export _gotoxy := _mono_gotoxy
+

package/src/platforms/atari7800/lib/cc65-src/extzp.inc

@@ -0,0 +1,15 @@
+;
+; extzp.inc for the Atari 7800
+;
+; Karri Kaksonen, 2022-04-05
+;
+; Assembler include file that imports the runtime zero page locations used
+; by the atari7800 runtime, ready for usage in asm code.
+;
+
+        .global         ptr7800: zp
+        .global         ptrtmp: zp
+        .global         cursorzone: zp
+        .global         CURS_X: zp
+        .global         CURS_Y: zp
+

package/src/platforms/atari7800/lib/cc65-src/extzp.s

@@ -0,0 +1,15 @@
+;
+; Karri Kaksonen, 2022-04-05
+;
+; zeropage locations for exclusive use by the library
+;
+
+        .include "extzp.inc"
+
+        .segment "EXTZP" : zeropage
+
+ptr7800:        .res 2
+ptrtmp:         .res 2
+cursorzone:     .res 2
+CURS_X:         .res 1
+CURS_Y:         .res 1

package/src/platforms/atari7800/lib/cc65-src/get_tv.s

@@ -0,0 +1,65 @@
+;
+; Karri Kaksonen, 2022-03-25
+;
+; unsigned char get_tv (void)
+;
+    .include    "atari7800.inc"
+    .include    "get_tv.inc"
+    .export     _get_tv
+    .export     _paldetected
+
+.segment    "DATA"
+
+_paldetected:
+    .byte   $FF
+
+; ---------------------------------------------------------------
+; unsigned char get_tv (void)
+; ---------------------------------------------------------------
+
+.segment    "CODE"
+
+.proc   _get_tv: near
+
+.segment    "CODE"
+
+    ldx     #$00
+    lda     #$FF
+    cmp     _paldetected
+    bne     L8
+L1: lda     MSTAT
+    and     #$80
+    bne     L1
+L2: lda     MSTAT
+    and     #$80
+    beq     L2
+L3: lda     MSTAT
+    and     #$80
+    bne     L3
+    lda     #$00
+    sta     M0001
+    jmp     L5
+L4: sta     MWSYNC
+    sta     MWSYNC
+    dec     M0001
+L5: lda     MSTAT
+    and     #$80
+    beq     L4
+    lda     M0001
+    cmp     #$78
+    bcc     L6
+    lda     #TV::NTSC
+    jmp     L7
+L6: lda     #TV::PAL
+L7: sta     _paldetected
+    ldx     #$00
+L8: lda     _paldetected
+    rts
+
+.segment    "BSS"
+
+M0001:
+    .res    1,$00
+
+.endproc
+

package/src/platforms/atari7800/lib/cc65-src/irq.s

@@ -0,0 +1,36 @@
+;
+; IRQ handling (Atari 7800 version)
+;
+
+        .export         initirq, doneirq, IRQStub
+
+        .import         __INTERRUPTOR_COUNT__, callirq
+
+        .include        "atari7800.inc"
+
+        .code
+; ------------------------------------------------------------------------
+
+initirq:
+doneirq:
+        rts
+
+; ------------------------------------------------------------------------
+
+IRQStub:
+        cld                             ; Just to be sure
+        pha
+        lda     #<(__INTERRUPTOR_COUNT__ * 2)
+        beq     @L1
+        txa
+        pha
+        tya
+        pha
+        jsr     callirq                 ; Call the functions
+        pla
+        tay
+        pla
+        tax
+@L1:    pla
+        rti
+

package/src/platforms/atari7800/lib/cc65-src/joy/atari7800-stdjoy.s

@@ -0,0 +1,197 @@
+;
+; Standard joystick driver for the Atari 7800.
+; This version tries to use 7800 and 2600 joysticks.
+; But assumes that both joysticks are of same type.
+;
+; Modified by Karri Kaksonen, 2022-03-31
+; Ullrich von Bassewitz, 2002-12-20
+; Using code from Steve Schmidtke
+;
+
+        .include        "zeropage.inc"
+
+        .include        "joy-kernel.inc"
+        .include        "joy-error.inc"
+        .include        "atari7800.inc"
+
+        .macpack        generic
+        .macpack        module
+
+
+; ------------------------------------------------------------------------
+; Header. Includes jump table
+
+        module_header   _atari7800_stdjoy_joy
+
+; Driver signature
+
+        .byte   $6A, $6F, $79           ; "joy"
+        .byte   JOY_API_VERSION         ; Driver API version number
+
+; Library reference
+
+        .addr   $0000
+
+; Jump table.
+
+        .addr   INSTALL
+        .addr   UNINSTALL
+        .addr   COUNT
+        .addr   READ
+
+; ------------------------------------------------------------------------
+; Constants
+
+JOY_COUNT       = 2             ; Number of joysticks we support
+
+.code
+
+; ------------------------------------------------------------------------
+; INSTALL routine. Is called after the driver is loaded into memory. If
+; possible, check if the hardware is present and determine the amount of
+; memory available.
+; Must return an JOY_ERR_xx code in a/x.
+;
+
+PB2 = $04 ; Joystick 0
+PB4 = $10 ; Joystick 1
+
+INSTALL:
+        ; Assume 7800 2-button controller, can change
+        ; to 2600 1-button later
+        lda #(PB2 | PB4)
+        ; enable 2-button 7800 controllers on both ports
+        ; by setting PB2 and PB4 to output
+        sta CTLSWB
+        ; enable 2-button 7800 controllers by setting
+        ; the outputs to 0; (INPT4 and INPT5) high
+        ldy #$00
+        sty SWCHB
+
+reset:
+        lda #JOY_ERR_OK
+        .assert JOY_ERR_OK = 0, error
+        tax
+;       rts                     ; Run into UNINSTALL instead
+
+; ------------------------------------------------------------------------
+; UNINSTALL routine. Is called before the driver is removed from memory.
+; Can do cleanup or whatever. Must not return anything.
+;
+
+UNINSTALL:
+        rts
+
+
+; ------------------------------------------------------------------------
+; COUNT: Return the total number of available joysticks in a/x.
+;
+
+COUNT:
+        lda     #<JOY_COUNT
+        ldx     #>JOY_COUNT
+        rts
+
+; ------------------------------------------------------------------------
+; READ: Read a particular joystick passed in A for 2 fire buttons.
+
+readdualbuttons0:
+    ldy #0      ; ........
+    bit INPT0   ; Check for right button
+    bpl L1
+    ldy #2      ; ......2.
+L1: bit INPT1   ; Check for left button
+    bpl L2
+    iny         ; ......21
+L2: tya
+    rts
+
+readdualbuttons1:
+    ldy #0      ; ........
+    bit INPT2   ; Check for right button
+    bpl L1
+    ldy #2      ; ......2.
+L3: bit INPT3   ; Check for left button
+    bpl L2
+    iny         ; ......21
+L4: tya
+    rts
+
+readbuttons:
+    ; Y has joystick of interest 0/1
+    ; return value:
+    ;  $00: no button,
+    ;  $01: left/B button,
+    ;  $02: right/A button,
+    ;  $03: both buttons
+    ; preserves X
+    tya
+    beq readbuttons0
+readbuttons1:
+    ; Joystick 1 processing
+    ; Start by checking for single button 2600 joystick
+    bit INPT5
+    bpl singlebtn1detected
+    jmp readdualbuttons1
+singlebtn1detected:
+    ; Single button joystick detected but could be dual
+    jsr readdualbuttons1
+    bne L5      ; It was a dual button press
+    ; It was a single button press
+    bit INPT5
+    bmi L5
+    iny         ; .......1
+    lda #PB4    ; Joystick 1 is a single button unit
+    clc
+    adc SWCHB
+    sta SWCHB   ; Cut power from the dual button circuit
+L5: tya         ; ......21
+    rts
+
+readbuttons0:
+    ; Joystick 0 processing
+    ; Start by checking for single button 2600 joystick
+    bit INPT4
+    bpl singlebtn0detected
+    jmp readdualbuttons0
+singlebtn0detected:
+    ; Single button joystick detected but could be dual
+    jsr readdualbuttons0
+    bne L6      ; It was a dual button press
+    ; It was a single button press
+    bit INPT4
+    bmi L6
+    iny         ; .......1
+    lda #PB2    ; Joystick 0 is a single button unit
+    clc
+    adc SWCHB
+    sta SWCHB   ; Cut power from the dual button circuit
+L6: tya         ; ......21
+    rts
+
+READ:
+    tay         ; Store joystick 0/1 in Y
+    beq L8
+    lda SWCHA   ; Read directions of joystick 1
+    rol         ; ...RLDU.
+    rol         ; ..RLDU..
+    rol         ; .RLDU... - joystick 1
+    jmp L9
+L8: lda SWCHA   ; Read directions of joystick 0
+    ror         ; .RLDU... - joystick 0
+L9: tax
+    jsr readbuttons ; A = ......21, X = .RLDU...
+    ror             ; A = .......2 1
+    tay             ; Y = .......2
+    txa             ; A = .RLDU...
+    ror             ; A = 1.RLDU..
+    tax             ; X = 1.RLDU..
+    tya             ; A = .......2
+    ror             ; A = ........ 2
+    txa             ; A = 1.RLDU..
+    rol             ; A = .RLDU..2 1
+    rol             ; A = RLDU..21
+    eor #$F0        ; The direction buttons were inversed
+    and #$F3
+    rts
+

package/src/platforms/atari7800/lib/cc65-src/joy_stat_stddrv.s

@@ -0,0 +1,14 @@
+;
+; Address of the static standard joystick driver
+;
+; Oliver Schmidt, 2012-11-01
+;
+; const void joy_static_stddrv[];
+;
+
+        .export _joy_static_stddrv
+        .import _atari7800_stdjoy_joy
+
+.rodata
+
+_joy_static_stddrv := _atari7800_stdjoy_joy

package/src/platforms/atari7800/lib/cc65-src/libref.s

@@ -0,0 +1,8 @@
+;
+; Oliver Schmidt, 2013-05-31
+;
+
+        .export         joy_libref
+        .import         _exit
+
+joy_libref      := _exit

package/src/platforms/atari7800/lib/cc65-src/mono_clrscr.s

@@ -0,0 +1,27 @@
+
+        .include        "atari7800.inc"
+
+        .export _mono_clrscr
+
+        .import _mono_screen
+        .import pushax, ___bzero
+        .include "extzp.inc"
+
+        .code
+
+        .proc _mono_clrscr
+
+        lda     #<_mono_screen
+        ldx     #>_mono_screen
+        jsr     pushax
+        ldx     #>(mono_charsperline * screenrows)
+        lda     #<(mono_charsperline * screenrows)
+        jmp     ___bzero
+
+        .endproc
+
+;-------------------------------------------------------------------------------
+; force the init constructor to be imported
+
+                .import mono_initconio
+conio_init      = mono_initconio