romdev-mcp 0.1.1

package/src/platforms/c64/lib/cc65-src/acc_turbomaster_speed.s

@@ -0,0 +1,56 @@
+;
+; Marco van den Heuvel, 2018-04-30
+;
+
+; unsigned char __fastcall__ set_turbomaster_speed (unsigned char speed);
+;
+;/* Set the speed of the Turbo Master cartridge, using SPEED_SLOW will switch to
+; * 1 Mhz mode, SPEED_4X or SPEED_FAST will switch to 4 Mhz mode.
+; *
+; * Note that any value higher or equal to SPEED_4X will switch to 4 Mhz mode,
+; * any value lower than SPEED_4X will switch to 1 Mhz mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, if the speed is different it might indicate
+; * that the hardware switch has locked the speed.
+; *
+; * This function does not check for the presence of a Turbo Master cartridge,
+; * make sure you use 'detect_turbomaster();' before using.
+; */
+
+; unsigned char get_turbomaster_speed (void);
+;
+;/* Get the speed of the Turbo Master cartridge.
+; *
+; * Possible return values:
+; * SPEED_SLOW  : 1 Mhz mode
+; * SPEED_4X    : 4 Mhz mode
+; *
+; * This function does not check for the presence of a Turbo Master cartridge,
+; * make sure you use 'detect_turbomaster();' before using.
+; */
+
+        .export         _set_turbomaster_speed
+        .export         _get_turbomaster_speed
+
+        .include        "accelerator.inc"
+
+_set_turbomaster_speed:
+        tay
+        lda     TURBOMASTER_SPEED_REG
+        asl
+        cpy     #SPEED_4X
+        ror
+store_speed:
+        sta     TURBOMASTER_SPEED_REG
+
+_get_turbomaster_speed:
+        ldx     #$00
+        lda     TURBOMASTER_SPEED_REG
+        and     #$80
+        beq     is_slow_speed
+is_high_speed:
+        lda     #SPEED_4X
+is_slow_speed:
+        rts
+

package/src/platforms/c64/lib/cc65-src/bordercolor.s

@@ -0,0 +1,17 @@
+;
+; Ullrich von Bassewitz, 06.08.1998
+;
+; unsigned char __fastcall__ bordercolor (unsigned char color);
+;
+
+
+        .export         _bordercolor
+
+        .include        "c64.inc"
+
+_bordercolor:
+        ldx     VIC_BORDERCOLOR ; get old value
+        sta     VIC_BORDERCOLOR ; set new value
+        txa
+        rts
+

package/src/platforms/c64/lib/cc65-src/break.s

@@ -0,0 +1,108 @@
+;
+; Ullrich von Bassewitz, 27.09.1998
+;
+; void __fastcall__ set_brk (unsigned Addr);
+; void reset_brk (void);
+;
+
+        .export         _set_brk, _reset_brk
+        .destructor     _reset_brk
+        .export         _brk_a, _brk_x, _brk_y, _brk_sr, _brk_pc
+
+        .include        "c64.inc"
+
+
+.bss
+_brk_a:         .res    1
+_brk_x:         .res    1
+_brk_y:         .res    1
+_brk_sr:        .res    1
+_brk_pc:        .res    2
+
+oldvec:         .res    2               ; Old vector
+
+
+.data
+uservec:        jmp     $FFFF           ; Patched at runtime
+
+
+.code
+
+; Set the break vector
+.proc   _set_brk
+
+        sta     uservec+1
+        stx     uservec+2       ; Set the user vector
+
+        lda     oldvec
+        ora     oldvec+1        ; Did we save the vector already?
+        bne     L1              ; Jump if we installed the handler already
+
+        lda     BRKVec
+        sta     oldvec
+        lda     BRKVec+1
+        sta     oldvec+1        ; Save the old vector
+
+L1:     lda     #<brk_handler   ; Set the break vector to our routine
+        ldx     #>brk_handler
+        sta     BRKVec
+        stx     BRKVec+1
+        rts
+
+.endproc
+
+
+; Reset the break vector
+.proc   _reset_brk
+
+        lda     oldvec
+        ldx     oldvec+1
+        beq     @L9             ; Jump if vector not installed
+        sta     BRKVec
+        stx     BRKVec+1
+        lda     #$00
+        sta     oldvec          ; Clear the old vector
+        stx     oldvec+1
+@L9:    rts
+
+.endproc
+
+
+
+; Break handler, called if a break occurs
+
+.proc   brk_handler
+
+        pla
+        sta     _brk_y
+        pla
+        sta     _brk_x
+        pla
+        sta     _brk_a
+        pla
+        and     #$EF            ; Clear break bit
+        sta     _brk_sr
+        pla                     ; PC low
+        sec
+        sbc     #2              ; Point to start of brk
+        sta     _brk_pc
+        pla                     ; PC high
+        sbc     #0
+        sta     _brk_pc+1
+
+        jsr     uservec         ; Call the user's routine
+
+        lda     _brk_pc+1
+        pha
+        lda     _brk_pc
+        pha
+        lda     _brk_sr
+        pha
+        ldx     _brk_x
+        ldy     _brk_y
+        lda     _brk_a
+        rti                     ; Jump back...
+
+.endproc
+
+

package/src/platforms/c64/lib/cc65-src/cgetc.s

@@ -0,0 +1,62 @@
+;
+; Ullrich von Bassewitz, 06.08.1998
+;
+; char cgetc (void);
+;
+
+        .export         _cgetc
+        .import         cursor
+
+        .include        "cbm_kernal.inc"
+        .include        "c64.inc"
+
+_cgetc: lda     KEY_COUNT       ; Get number of characters
+        bne     L3              ; Jump if there are already chars waiting
+
+; Switch on the cursor if needed
+
+        lda     CURS_FLAG
+        pha
+        lda     cursor
+        jsr     setcursor
+L1:     lda     KEY_COUNT
+        beq     L1
+        ldx     #0
+        pla
+        bne     L2
+        inx
+L2:     txa
+        jsr     setcursor
+
+L3:     jsr     KBDREAD         ; Read char and return in A
+        ldx     #0
+        rts
+
+
+; Switch the cursor on or off
+
+.proc   setcursor
+
+        tax                     ; On or off?
+        bne     seton           ; Go set it on
+        lda     CURS_FLAG       ; Is the cursor currently off?
+        bne     crs9            ; Jump if yes
+        lda     #1
+        sta     CURS_FLAG       ; Mark it as off
+        lda     CURS_STATE      ; Cursor currently displayed?
+        beq     crs8            ; Jump if no
+        ldy     CURS_X          ; Get the character column
+        lda     (SCREEN_PTR),y  ; Get character
+        eor     #$80
+        sta     (SCREEN_PTR),y  ; Store character back
+        lda     CURS_COLOR
+        sta     (CRAM_PTR),y    ; Store color back
+crs8:   lda     #0
+        sta     CURS_STATE      ; Cursor not displayed
+crs9:   rts
+
+seton:  lda     #0
+        sta     CURS_FLAG
+        rts
+
+.endproc

package/src/platforms/c64/lib/cc65-src/clrscr.s

@@ -0,0 +1,11 @@
+;
+; Ullrich von Bassewitz, 06.08.1998
+;
+; void clrscr (void);
+;
+
+        .export         _clrscr
+
+        .include        "cbm_kernal.inc"
+
+_clrscr = CLRSCR

package/src/platforms/c64/lib/cc65-src/color.s

@@ -0,0 +1,24 @@
+;
+; Ullrich von Bassewitz, 06.08.1998
+;
+; unsigned char __fastcall__ textcolor (unsigned char color);
+; unsigned char __fastcall__ bgcolor (unsigned char color);
+;
+
+
+        .export         _textcolor, _bgcolor
+
+        .include        "c64.inc"
+
+_textcolor:
+        ldx     CHARCOLOR       ; get old value
+        sta     CHARCOLOR       ; set new value
+        txa
+        rts
+
+
+_bgcolor:
+        ldx     VIC_BG_COLOR0   ; get old value
+        sta     VIC_BG_COLOR0   ; set new value
+        txa
+        rts

package/src/platforms/c64/lib/cc65-src/conio.s

@@ -0,0 +1,10 @@
+;
+; Ullrich von Bassewitz, 06.08.1998
+;
+; Low level stuff for screen output/console input
+;
+
+        .exportzp       CURS_X, CURS_Y
+
+        .include        "c64.inc"
+

package/src/platforms/c64/lib/cc65-src/cputc.s

@@ -0,0 +1,105 @@
+;
+; Ullrich von Bassewitz, 1998-08-06, 2009-09-26
+;
+; void __fastcall__ cputcxy (unsigned char x, unsigned char y, char c);
+; void __fastcall__ cputc (char c);
+;
+; Important note: The implementation of cputs() relies on the cputc() function
+; not clobbering ptr1. Beware when rewriting or changing this function!
+
+        .export         _cputcxy, _cputc, cputdirect, putchar
+        .export         newline, plot
+        .import         gotoxy
+        .import         PLOT
+
+        .include        "c64.inc"
+
+
+_cputcxy:
+        pha                     ; Save C
+        jsr     gotoxy          ; Set cursor, drop x and y
+        pla                     ; Restore C
+
+; Plot a character - also used as internal function
+
+_cputc: cmp     #$0A            ; CR?
+        bne     L1
+        lda     #0
+        sta     CURS_X
+        beq     plot            ; Recalculate pointers
+
+L1:     cmp     #$0D            ; LF?
+        beq     newline         ; Recalculate pointers
+
+; Printable char of some sort
+
+        cmp     #' '
+        bcc     cputdirect      ; Other control char
+        tay
+        bmi     L10
+        cmp     #$60
+        bcc     L2
+        and     #$DF
+        bne     cputdirect      ; Branch always
+L2:     and     #$3F
+
+cputdirect:
+        jsr     putchar         ; Write the character to the screen
+
+; Advance cursor position
+
+advance:
+        iny
+        cpy     #XSIZE
+        bne     L3
+        jsr     newline         ; new line
+        ldy     #0              ; + cr
+L3:     sty     CURS_X
+        rts
+
+newline:
+        clc
+        lda     #XSIZE
+        adc     SCREEN_PTR
+        sta     SCREEN_PTR
+        bcc     L4
+        inc     SCREEN_PTR+1
+        clc
+L4:     lda     #XSIZE
+        adc     CRAM_PTR
+        sta     CRAM_PTR
+        bcc     L5
+        inc     CRAM_PTR+1
+L5:     inc     CURS_Y
+        rts
+
+; Handle character if high bit set
+
+L10:    and     #$7F
+        cmp     #$7F            ; PI?
+        bne     L11
+        lda     #$5E            ; Load screen code for PI
+L11:    ora     #$40
+        bne     cputdirect
+
+
+
+; Set cursor position, calculate RAM pointers.
+
+plot:   ldy     CURS_X
+        ldx     CURS_Y
+        clc
+        jmp     PLOT            ; Set the new cursor
+
+
+
+; Write one character to the screen without doing anything else, return X
+; position in Y
+
+putchar:
+        ora     RVS             ; Set revers bit
+        ldy     CURS_X
+        sta     (SCREEN_PTR),y  ; Set char
+        lda     CHARCOLOR
+        sta     (CRAM_PTR),y    ; Set color
+        rts

package/src/platforms/c64/lib/cc65-src/crt0.s

@@ -0,0 +1,117 @@
+;
+; Startup code for cc65 (C64 version)
+;
+
+        .export         _exit
+        .export         __STARTUP__ : absolute = 1      ; Mark as startup
+
+        .import         initlib, donelib
+        .import         zerobss, callmain
+        .import         BSOUT
+        .import         __MAIN_START__, __MAIN_SIZE__   ; Linker generated
+        .import         __STACKSIZE__                   ; from configure file
+
+        .include        "zeropage.inc"
+        .include        "c64.inc"
+
+
+; ------------------------------------------------------------------------
+; Startup code
+
+.segment        "STARTUP"
+
+Start:
+
+; Switch off the BASIC ROM.
+
+        lda     $01
+        sta     mmusave         ; Save the memory configuration
+        and     #$F8
+        ora     #$06            ; Enable Kernal+I/O, disable BASIC
+        sta     $01
+
+        tsx
+        stx     spsave          ; Save the system stack ptr
+
+; Save space by putting some of the start-up code in the ONCE segment,
+; which can be re-used by the BSS segment, the heap and the C stack.
+
+        jsr     init
+
+; Clear the BSS data.
+
+        jsr     zerobss
+
+; Push the command-line arguments; and, call main().
+
+        jsr     callmain
+
+; Back from main() [this is also the exit() entry]. Run the module destructors.
+
+_exit:  pha                     ; Save the return code on stack
+        jsr     donelib
+
+; Copy back the zero-page stuff.
+
+        ldx     #zpspace-1
+L2:     lda     zpsave,x
+        sta     c_sp,x
+        dex
+        bpl     L2
+
+; Place the program return code into BASIC's status variable.
+
+        pla
+        sta     STATUS
+
+; Restore the system stuff.
+
+        ldx     spsave
+        txs                     ; Restore stack pointer
+        ldx     mmusave
+        stx     $01             ; Restore memory configuration
+
+; Back to BASIC.
+
+        rts
+
+
+; ------------------------------------------------------------------------
+
+.segment        "ONCE"
+
+init:
+
+; Save the zero-page locations that we need.
+
+        ldx     #zpspace-1
+L1:     lda     c_sp,x
+        sta     zpsave,x
+        dex
+        bpl     L1
+
+; Set up the stack.
+
+        lda     #<(__MAIN_START__ + __MAIN_SIZE__)
+        ldx     #>(__MAIN_START__ + __MAIN_SIZE__)
+        sta     c_sp
+        stx     c_sp+1          ; Set argument stack ptr
+
+; Switch to the second charset.
+
+        lda     #14
+        jsr     BSOUT
+
+; Call the module constructors.
+
+        jmp     initlib
+
+
+; ------------------------------------------------------------------------
+; Data
+
+.segment        "INIT"
+
+mmusave:.res    1
+spsave: .res    1
+zpsave: .res    zpspace

package/src/platforms/c64/lib/cc65-src/devnum.s

@@ -0,0 +1,7 @@
+;
+; Oliver Schmidt, 2010-02-14
+;
+
+        .include        "c64.inc"
+
+        .exportzp       devnum := DEVNUM