romdev-mcp 0.1.1

package/src/platforms/gba/lib/libgba/gba_cart.ld

@@ -0,0 +1,319 @@
+/* Linker Script Original v1.3 by Jeff Frohwein     */
+/*  v1.0 - Original release                         */
+/*  v1.1 - Added proper .data section support       */
+/*  v1.2 - Added support for c++ & iwram overlays   */
+/*       - Major contributions by Jason Wilkins.    */
+/*  v1.3 - .ewram section now can be used when      */
+/*         compiling for MULTIBOOT mode. This fixes */
+/*         malloc() in DevKitAdvance which depends  */
+/*         on __eheap_start instead of end to define*/
+/*         the starting location of heap space.     */
+/*         External global variable __gba_iwram_heap*/
+/*         support added to allow labels end, _end, */
+/*         & __end__ to point to end of iwram or    */
+/*         the end of ewram.                        */
+/*	Additions by WinterMute				*/
+/* v1.4 -	.sbss section added for unitialised	*/
+/*		    data in ewram 			*/
+/* v1.5 -	padding section added to stop EZF 	*/
+/*		    stripping important data		*/
+
+/* This file is released into the public domain		*/
+/* for commercial or non-commercial use with no		*/
+/* restrictions placed upon it.				*/
+
+/* NOTE!!!: This linker script defines the RAM &  */
+/*   ROM start addresses. In order for it to work */
+/*   properly, remove -Ttext and -Tbss linker     */
+/*   options from your makefile if they are       */
+/*   present.                                     */
+
+/* You can use the following to view section      */
+/* addresses in your .elf file:                   */
+/*   objdump -h file.elf                          */
+/* Please note that empty sections may incorrectly*/
+/* list the lma address as the vma address for    */
+/* some versions of objdump.                      */
+
+OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
+OUTPUT_ARCH(arm)
+ENTRY(_start)
+/* SEARCH_DIR(/bin/arm); */
+
+/* The linker script function "var1 += var2;" sometimes    */
+/* reports incorrect values in the *.map file but the      */
+/* actual value it calculates is usually, if not always,   */
+/* correct. If you leave out the ". = ALIGN(4);" at the    */
+/* end of each section then the return value of SIZEOF()   */
+/* is sometimes incorrect and "var1 += var2;" appears to   */
+/* not work as well. "var1 += var2" style functions are    */
+/* avoided below as a result.                              */
+
+MEMORY {
+
+	rom	: ORIGIN = 0x08000000, LENGTH = 32M
+	iwram	: ORIGIN = 0x03000000, LENGTH = 32K
+	ewram	: ORIGIN = 0x02000000, LENGTH = 256K
+}
+
+__text_start	=	ORIGIN(rom);
+__eheap_end	=	ORIGIN(ewram) + LENGTH(ewram);
+__iwram_start	=	ORIGIN(iwram);
+__iwram_top	=	ORIGIN(iwram) + LENGTH(iwram);;
+__sp_irq	=	__iwram_top - 0x060;
+__sp_usr	=	__sp_irq - 0x0a0;
+__irq_flags	=	0x03007ff8;
+
+SECTIONS
+{
+	. = __text_start;
+	.crt0 :
+	{
+		KEEP (*(.crt0))
+		. = ALIGN(4);
+	} >rom =0xff
+
+
+	.init :
+	{
+		KEEP (*(SORT_NONE(.init)))
+	} >rom
+
+	.plt :
+	{
+		*(.plt)
+		. = ALIGN(4);   /* REQUIRED. LD is flaky without it. */
+	} >rom
+
+	.text  :   /* ALIGN (4): */
+	{
+		*(EXCLUDE_FILE (*.iwram*) .text*)
+		*(.gnu.linkonce.t.*)
+		KEEP (*(.text.*personality*))
+		/* .gnu.warning sections are handled specially by elf32.em.  */
+		*(.gnu.warning)
+		*(.glue_7t) *(.glue_7) *(.vfp11_veneer)
+		. = ALIGN(4);  /* REQUIRED. LD is flaky without it. */
+	} >rom = 0xff
+
+	__text_end = .;
+	.fini           :
+	{
+		KEEP (*(.fini))
+		. = ALIGN(4);  /* REQUIRED. LD is flaky without it. */
+	} >rom =0
+
+	.rodata :
+	{
+		*(.rodata)
+		*all.rodata*(*)
+		*(.roda)
+		*(.rodata.*)
+		*(.gnu.linkonce.r*)
+		SORT(CONSTRUCTORS)
+		. = ALIGN(4);   /* REQUIRED. LD is flaky without it. */
+	} >rom = 0xff
+	.ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >rom
+	__exidx_start = .;
+	.ARM.exidx   : { *(.ARM.exidx* .gnu.linkonce.armexidx.*) } >rom
+	__exidx_end = .;
+
+	.ctors :
+	{
+		/*	gcc uses crtbegin.o to find the start of the constructors, so
+			we make sure it is first.  Because this is a wildcard, it
+			doesn't matter if the user does not actually link against
+			crtbegin.o; the linker won't look for a file to match a
+			wildcard.  The wildcard also means that it doesn't matter which
+			directory crtbegin.o is in.  */
+		KEEP (*crtbegin.o(.ctors))
+		KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
+		KEEP (*(SORT(.ctors.*)))
+		KEEP (*(.ctors))
+		. = ALIGN(4);   /* REQUIRED. LD is flaky without it. */
+	} >rom = 0
+
+	.dtors :
+	{
+		KEEP (*crtbegin.o(.dtors))
+		KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
+		KEEP (*(SORT(.dtors.*)))
+		KEEP (*(.dtors))
+		. = ALIGN(4);   /* REQUIRED. LD is flaky without it. */
+	} >rom = 0
+
+
+	.eh_frame :
+	{
+		KEEP (*(.eh_frame))
+		. = ALIGN(4);   /* REQUIRED. LD is flaky without it. */
+	} >rom = 0
+
+	.gcc_except_table :
+	{
+		*(.gcc_except_table)
+		. = ALIGN(4);   /* REQUIRED. LD is flaky without it. */
+	} >rom = 0
+
+	__iwram_lma = .;
+
+	.iwram __iwram_start : AT (__iwram_lma)
+	{
+		__iwram_start__ = ABSOLUTE(.) ;
+		*(.iwram)
+		*iwram.*(.text* .data*)
+		. = ALIGN(4);   /* REQUIRED. LD is flaky without it. */
+		__iwram_end__ = ABSOLUTE(.) ;
+	} >iwram = 0xff
+
+	__data_lma = __iwram_lma + SIZEOF(.iwram) ;
+
+	.bss ALIGN(4) (NOLOAD) :
+	{
+		__bss_start = ABSOLUTE(.);
+		__bss_start__ = ABSOLUTE(.);
+		*(.dynbss)
+		*(.gnu.linkonce.b*)
+		*(.bss*)
+		*(COMMON)
+		. = ALIGN(4);    /* REQUIRED. LD is flaky without it. */
+		__bss_end__ = ABSOLUTE(.);
+
+	} AT>iwram
+
+	.data ALIGN(4) : AT (__data_lma)
+	{
+		__data_start__ = ABSOLUTE(.);
+		*(.data*)
+		*(.gnu.linkonce.d*)
+		CONSTRUCTORS
+		. = ALIGN(4);
+	} >iwram = 0xff
+
+	__preinit_lma = __data_lma + SIZEOF(.data);
+
+	.preinit_array ALIGN(4)    : AT (__preinit_lma)
+	{
+		__preinit_array_start = ABSOLUTE(.);
+		KEEP (*(.preinit_array))
+		__preinit_array_end = ABSOLUTE(.);
+	} >iwram
+
+	__init_lma = __preinit_lma + SIZEOF(.preinit_array);
+
+	.init_array  ALIGN(4)   : AT (__init_lma)
+	{
+		__init_array_start = ABSOLUTE(.);
+		KEEP (*(SORT(.init_array.*)))
+		KEEP (*(.init_array))
+		__init_array_end = ABSOLUTE(.);
+	} >iwram
+
+	__fini_lma = __init_lma + SIZEOF(.init_array);
+
+	.fini_array  ALIGN(4)   : AT (__fini_lma)
+	{
+		__fini_array_start = ABSOLUTE(.);
+		KEEP (*(SORT(.fini_array.*)))
+		KEEP (*(.fini_array))
+  		__fini_array_end = ABSOLUTE(.);
+	} >iwram
+
+	__jcr_lma = __fini_lma + SIZEOF(.fini_array);
+	.jcr        ALIGN(4)    : AT (__jcr_lma) { KEEP (*(.jcr)) } >iwram
+
+	__data_end__  =  ABSOLUTE(.);
+	__iwram_overlay_lma = __jcr_lma + SIZEOF(.jcr);
+
+	__iwram_overlay_start = . ;
+
+	OVERLAY ALIGN(4) : NOCROSSREFS AT (__iwram_overlay_lma)
+	{
+		.iwram0 { *(.iwram0) . = ALIGN(4);}
+		.iwram1 { *(.iwram1) . = ALIGN(4);}
+		.iwram2 { *(.iwram2) . = ALIGN(4);}
+		.iwram3 { *(.iwram3) . = ALIGN(4);}
+		.iwram4 { *(.iwram4) . = ALIGN(4);}
+		.iwram5 { *(.iwram5) . = ALIGN(4);}
+		.iwram6 { *(.iwram6) . = ALIGN(4);}
+		.iwram7 { *(.iwram7) . = ALIGN(4);}
+		.iwram8 { *(.iwram8) . = ALIGN(4);}
+		.iwram9 { *(.iwram9) . = ALIGN(4);}
+	}>iwram = 0xff
+
+	__iwram_overlay_end = . ;
+	__ewram_lma = __iwram_overlay_lma + SIZEOF(.iwram0) + SIZEOF(.iwram1) + SIZEOF(.iwram2) +
+		SIZEOF(.iwram3) + SIZEOF(.iwram4) + SIZEOF(.iwram5) + SIZEOF(.iwram6) +
+		SIZEOF(.iwram7) + SIZEOF(.iwram8) + SIZEOF(.iwram9) ;
+
+	__iheap_start = . ;
+
+	__ewram_start = ORIGIN(ewram);
+	.ewram __ewram_start : AT (__ewram_lma)
+	{
+		*(.ewram*)
+		. = ALIGN(4);  /* REQUIRED. LD is flaky without it. */
+		__ewram_end = ABSOLUTE(.);
+	}>ewram = 0xff
+
+	__pad_lma = __ewram_lma + SIZEOF(.ewram);
+
+	.sbss ALIGN(4)(NOLOAD):
+ 	{
+		__sbss_start__ = ABSOLUTE(.);
+ 		*(.sbss*)
+ 		. = ALIGN(4);
+		__sbss_end__  = ABSOLUTE(.);
+		__end__ = ABSOLUTE(.);
+		__eheap_start = ABSOLUTE(.);
+ 	} AT>ewram
+
+	/* EZF Advance strips trailing 0xff bytes, add a pad section so nothing important is removed */
+	.pad ALIGN(4) : AT (__pad_lma)
+	{
+		LONG(0x52416b64)
+		LONG(0x4d)
+		. = ALIGN(4);  /* REQUIRED. LD is flaky without it. */
+	} = 0xff
+	__rom_end__ = __pad_lma + SIZEOF(.pad);
+
+
+	/* Stabs debugging sections.  */
+	.stab 0 : { *(.stab) }
+	.stabstr 0 : { *(.stabstr) }
+	.stab.excl 0 : { *(.stab.excl) }
+	.stab.exclstr 0 : { *(.stab.exclstr) }
+	.stab.index 0 : { *(.stab.index) }
+	.stab.indexstr 0 : { *(.stab.indexstr) }
+	.comment 0 : { *(.comment) }
+	/*	DWARF debug sections.
+		Symbols in the DWARF debugging sections are relative to the beginning
+		of the section so we begin them at 0.  */
+	/* DWARF 1 */
+	.debug          0 : { *(.debug) }
+	.line           0 : { *(.line) }
+	/* GNU DWARF 1 extensions */
+	.debug_srcinfo  0 : { *(.debug_srcinfo) }
+	.debug_sfnames  0 : { *(.debug_sfnames) }
+	/* DWARF 1.1 and DWARF 2 */
+	.debug_aranges  0 : { *(.debug_aranges) }
+	.debug_pubnames 0 : { *(.debug_pubnames) }
+	/* DWARF 2 */
+	.debug_info     0 : { *(.debug_info) }
+	.debug_abbrev   0 : { *(.debug_abbrev) }
+	.debug_line     0 : { *(.debug_line) }
+	.debug_frame    0 : { *(.debug_frame) }
+	.debug_str      0 : { *(.debug_str) }
+	.debug_loc      0 : { *(.debug_loc) }
+	.debug_macinfo  0 : { *(.debug_macinfo) }
+	/* SGI/MIPS DWARF 2 extensions */
+	.debug_weaknames 0 : { *(.debug_weaknames) }
+	.debug_funcnames 0 : { *(.debug_funcnames) }
+	.debug_typenames 0 : { *(.debug_typenames) }
+	.debug_varnames  0 : { *(.debug_varnames) }
+	.stack 0x80000 : { _stack = .; *(.stack) }
+	/* These must appear regardless of  .  */
+  .note.gnu.arm.ident 0 : { KEEP (*(.note.gnu.arm.ident)) }
+  .ARM.attributes 0 : { KEEP (*(.ARM.attributes)) }
+  /DISCARD/ : { *(.note.GNU-stack) }
+}

package/src/platforms/gba/lib/libgba/gba_crt0.s

@@ -0,0 +1,258 @@
+/*--------------------------------------------------------------------------------
+	This Source Code Form is subject to the terms of the Mozilla Public License,
+	v. 2.0. If a copy of the MPL was not distributed with this file, You can
+	obtain one at https://mozilla.org/MPL/2.0/.
+--------------------------------------------------------------------------------*/
+
+	.section	".crt0","ax"
+	.global     _start
+	.align
+
+	.arm
+	.cpu arm7tdmi
+
+@---------------------------------------------------------------------------------
+_start:
+@---------------------------------------------------------------------------------
+	b	rom_header_end
+
+	.fill   156,1,0			@ Nintendo Logo Character Data (8000004h)
+	.fill	16,1,0			@ Game Title
+	.byte   0x30,0x31		@ Maker Code (80000B0h)
+	.byte   0x96			@ Fixed Value (80000B2h)
+	.byte   0x00			@ Main Unit Code (80000B3h)
+	.byte   0x00			@ Device Type (80000B4h)
+	.fill	7,1,0			@ unused
+	.byte	0x00			@ Software Version No (80000BCh)
+	.byte	0xf0			@ Complement Check (80000BDh)
+	.byte	0x00,0x00    		@ Checksum (80000BEh)
+
+@---------------------------------------------------------------------------------
+rom_header_end:
+@---------------------------------------------------------------------------------
+	b	start_vector			@ This branch must be here for proper
+						@ positioning of the following header.
+
+	.GLOBAL	__boot_method, __slave_number
+@---------------------------------------------------------------------------------
+__boot_method:
+@---------------------------------------------------------------------------------
+	.byte   0				@ boot method (0=ROM boot, 3=Multiplay boot)
+@---------------------------------------------------------------------------------
+__slave_number:
+@---------------------------------------------------------------------------------
+	.byte   0				@ slave # (1=slave#1, 2=slave#2, 3=slave#3)
+
+	.byte   0 				@ reserved
+	.byte   0 				@ reserved
+	.word   0    				@ reserved
+	.word   0				@ reserved
+	.word   0    				@ reserved
+	.word   0    				@ reserved
+	.word   0    				@ reserved
+	.word   0    				@ reserved
+
+	.global     start_vector
+	.align
+@---------------------------------------------------------------------------------
+start_vector:
+@---------------------------------------------------------------------------------
+	mov	r0, #0x4000000			@ REG_BASE
+	str	r0, [r0, #0x208]
+
+	mov	r0, #0x12			@ Switch to IRQ Mode
+	msr	cpsr, r0
+	ldr	sp, =__sp_irq			@ Set IRQ stack
+	mov	r0, #0x1f			@ Switch to System Mode
+	msr	cpsr, r0
+	ldr	sp, =__sp_usr			@ Set user stack
+
+@---------------------------------------------------------------------------------
+@ Enter Thumb mode
+@---------------------------------------------------------------------------------
+	add	r0, pc, #1
+	bx	r0
+
+	.thumb
+
+	ldr	r0, =__text_start
+	lsl	r0, #5				@ Was code compiled at 0x08000000 or higher?
+	bcs     DoEWRAMClear			@ yes, you can not run it in external WRAM
+
+	mov     r0, pc
+	lsl     r0, #5				@ Are we running from ROM (0x8000000 or higher) ?
+	bcc     SkipEWRAMClear			@ No, so no need to do a copy.
+
+@---------------------------------------------------------------------------------
+@ We were started in ROM, silly emulators. :P
+@ So we need to copy to ExWRAM.
+@---------------------------------------------------------------------------------
+	mov	r2, #2
+	lsl	r2, r2, #24			@ r2= 0x02000000
+	ldr	r3, =__end__			@ last ewram address
+	sub	r3, r2				@ r3= actual binary size
+	mov	r6, r2				@ r6= 0x02000000
+	lsl	r1, r2, #2			@ r1= 0x08000000
+
+	bl	CopyMem
+
+	bx	r6				@ Jump to the code to execute
+
+@---------------------------------------------------------------------------------
+DoEWRAMClear:					@ Clear External WRAM to 0x00
+@---------------------------------------------------------------------------------
+	mov	r1, #0x40
+	lsl	r1, #12				@ r1 = 0x40000
+	lsl	r0, r1, #7			@ r0 = 0x2000000
+	bl	ClearMem
+
+@---------------------------------------------------------------------------------
+SkipEWRAMClear:					@ Clear Internal WRAM to 0x00
+@---------------------------------------------------------------------------------
+
+@---------------------------------------------------------------------------------
+@ Clear BSS section to 0x00
+@---------------------------------------------------------------------------------
+	ldr	r0, =__bss_start__
+	ldr	r1, =__bss_end__
+	sub	r1, r0
+	bl	ClearMem
+
+@---------------------------------------------------------------------------------
+@ Clear SBSS section to 0x00
+@---------------------------------------------------------------------------------
+	ldr	r0, =__sbss_start__
+	ldr	r1, =__sbss_end__
+	sub	r1, r0
+	bl	ClearMem
+
+@---------------------------------------------------------------------------------
+@ Copy initialized data (data section) from LMA to VMA (ROM to RAM)
+@---------------------------------------------------------------------------------
+	ldr	r1, =__data_lma
+	ldr	r2, =__data_start__
+	ldr	r4, =__data_end__
+	bl	CopyMemChk
+
+@---------------------------------------------------------------------------------
+@ Copy internal work ram (iwram section) from LMA to VMA (ROM to RAM)
+@---------------------------------------------------------------------------------
+	ldr	r1,= __iwram_lma
+	ldr	r2,= __iwram_start__
+	ldr	r4,= __iwram_end__
+	bl	CopyMemChk
+
+@---------------------------------------------------------------------------------
+@ Copy internal work ram overlay 0 (iwram0 section) from LMA to VMA (ROM to RAM)
+@---------------------------------------------------------------------------------
+	ldr	r2,= __load_stop_iwram0
+	ldr	r1,= __load_start_iwram0
+	sub	r3, r2, r1			@ Is there any data to copy?
+	beq	CIW0Skip			@ no
+
+	ldr	r2,= __iwram_overlay_start
+	bl	CopyMem
+@---------------------------------------------------------------------------------
+CIW0Skip:
+@---------------------------------------------------------------------------------
+@ Copy external work ram (ewram section) from LMA to VMA (ROM to RAM)
+@---------------------------------------------------------------------------------
+	ldr	r1, =__ewram_lma
+	ldr	r2, =__ewram_start
+	ldr	r4, =__ewram_end
+	bl	CopyMemChk
+
+@---------------------------------------------------------------------------------
+CEW0Skip:
+@---------------------------------------------------------------------------------
+@ set heap end
+@---------------------------------------------------------------------------------
+	ldr	r1, =fake_heap_end
+	ldr	r0, =__eheap_end
+	str	r0, [r1]
+@---------------------------------------------------------------------------------
+@ global constructors
+@---------------------------------------------------------------------------------
+	ldr	r3, =__libc_init_array
+	bl	_blx_r3_stub
+@---------------------------------------------------------------------------------
+@ Jump to user code
+@---------------------------------------------------------------------------------
+	mov	r0, #0				@ int argc
+	mov	r1, #0				@ char	*argv[]
+	ldr	r3, =main
+	bl	_blx_r3_stub
+
+	swi	#0x00				@ SoftReset
+
+@---------------------------------------------------------------------------------
+@ Clear memory to 0x00 if length != 0
+@---------------------------------------------------------------------------------
+@ r0 = Start Address
+@ r1 = Length
+@---------------------------------------------------------------------------------
+ClearMem:
+@---------------------------------------------------------------------------------
+	mov	r2,#3				@ These	commands are used in cases where
+	add	r1,r2				@ the length is	not a multiple of 4,
+	bic	r1,r2				@ even though it should be.
+
+	beq	ClearMX				@ Length is zero so exit
+
+	mov	r2,#0
+@---------------------------------------------------------------------------------
+ClrLoop:
+@---------------------------------------------------------------------------------
+	stmia	r0!, {r2}
+	sub	r1,#4
+	bne	ClrLoop
+@---------------------------------------------------------------------------------
+ClearMX:
+@---------------------------------------------------------------------------------
+	bx	lr
+
+@---------------------------------------------------------------------------------
+_blx_r3_stub:
+@---------------------------------------------------------------------------------
+	bx	r3
+
+@---------------------------------------------------------------------------------
+@ Copy memory if length	!= 0
+@---------------------------------------------------------------------------------
+@ r1 = Source Address
+@ r2 = Dest Address
+@ r4 = Dest Address + Length
+@---------------------------------------------------------------------------------
+CopyMemChk:
+@---------------------------------------------------------------------------------
+	sub	r3, r4, r2			@ Is there any data to copy?
+@---------------------------------------------------------------------------------
+@ Copy memory
+@---------------------------------------------------------------------------------
+@ r1 = Source Address
+@ r2 = Dest Address
+@ r3 = Length
+@---------------------------------------------------------------------------------
+CopyMem:
+@---------------------------------------------------------------------------------
+	mov	r0, #3				@ These commands are used in cases where
+	add	r3, r0				@ the length is not a multiple	of 4,
+	bic	r3, r0				@ even	though it should be.
+	beq	CIDExit				@ Length is zero so exit
+
+@---------------------------------------------------------------------------------
+CIDLoop:
+@---------------------------------------------------------------------------------
+	ldmia	r1!, {r0}
+	stmia	r2!, {r0}
+	sub	r3, #4
+	bne	CIDLoop
+@---------------------------------------------------------------------------------
+CIDExit:
+@---------------------------------------------------------------------------------
+	bx	lr
+
+	.align
+	.pool
+	.end
+

package/src/platforms/gba/lib/libgba/include/BoyScout.h

@@ -0,0 +1,128 @@
+//////////////////////////////////////////////////////////////////////////
+// File: BoyScout.h                                                     //
+//                                                                      //
+// Description: Header file for BoyScout music playback on the GameBoy. //
+//                                                                      //
+// Author: Christer Andersson (c) 2001                                  //
+// Addon:  Willem Kokke                                                 //
+//                                                                      //
+//////////////////////////////////////////////////////////////////////////
+
+//////////////////////////////////////////////////////////////
+// New section of functions were written by Willem Kokke.   //
+// He also fixed a silly miss in the wave RAM copy of the   //
+// v.0.93 playback libraries. Thanks alot mate :O)          //
+//                                                          //
+// / Christer                                               //
+//////////////////////////////////////////////////////////////
+
+// Make sure header is only included once
+#ifndef HEADER_BOYSCOUT_H
+#define HEADER_BOYSCOUT_H
+
+// DEFINES ////////
+
+#define PATTERN_PARAMETER_EMPTY	10000
+
+#define SOUND_CHANNEL_COUNT		4
+
+#define SOUND1_PARAMETER_COUNT	7
+#define SOUND2_PARAMETER_COUNT	5
+#define SOUND3_PARAMETER_COUNT	4
+#define SOUND4_PARAMETER_COUNT	7
+
+// Play states
+#define PLAYSTATE_STOP		1
+#define PLAYSTATE_PLAY		2
+#define PLAYSTATE_LOOP		4
+
+
+// STRUCTS ////////
+
+// Iterator for traversing compressed data
+typedef struct SRLEIterator
+{
+	unsigned char *pData;
+	unsigned char iValue;
+	unsigned char mask;
+	unsigned char cValue;
+	short nValue;
+	unsigned char iValuePos;
+} SRLEIterator;
+
+// Sound 1 pattern
+typedef struct
+{
+	unsigned short nLength;
+	unsigned char *apParams[SOUND1_PARAMETER_COUNT];
+} SSound1Pattern;
+
+// Sound 2 pattern
+typedef struct
+{
+	unsigned short nLength;
+	unsigned char *apParams[SOUND2_PARAMETER_COUNT];
+} SSound2Pattern;
+
+// Sound 3 pattern
+typedef struct
+{
+	unsigned short nLength;
+	unsigned char *apParams[SOUND3_PARAMETER_COUNT];
+} SSound3Pattern;
+
+// Sound 4 pattern
+typedef struct
+{
+	unsigned short nLength;
+	unsigned char *apParams[SOUND4_PARAMETER_COUNT];
+} SSound4Pattern;
+
+// PROTOTYPES /////
+
+void RLEISet(unsigned char *pData, SRLEIterator *pRLEIterator);
+void RLEINext(SRLEIterator *pRLEIterator);
+
+void BoyScoutInitialize();
+void BoyScoutOpenSong(const unsigned char *pSongData);
+void BoyScoutPlaySong(int nLoop);
+void BoyScoutStopSong();
+unsigned short BoyScoutGetNeededSongMemory(const unsigned char *pSongData);
+void BoyScoutSetMemoryArea(unsigned int nMemoryAddress);
+unsigned int BoyScoutGetMemoryArea();
+int BoyScoutUpdateSong();
+
+void DMA3Copy32(unsigned int Src, unsigned int Dst, unsigned short Count);
+
+// WK Set to 1 to use dma, or to 0 to use software copy
+// Software copy is the preffered option, it's faster and more stable
+#define USE_DMA 0
+
+// WK  some functions to manipulate the speed of the original song
+// You directly manipulate the time a beat takes
+// a beat takes x/60, where x is the value you give
+// increasing this value slows the song down, decreasing speeds it up
+
+// TODO?  move the timing to a timer to get a better control through increades granularity
+
+unsigned char BoyScoutGetNormalSpeed();
+unsigned char BoyScoutGetSpeed();
+
+void BoyScoutIncSpeed(unsigned char speed);
+void BoyScoutDecSpeed(unsigned char speed);
+void BoyScoutSetSpeed(unsigned char speed);
+
+
+// WK  some functions to mute individual channels
+void BoyScoutMuteChannel1(int mute);
+void BoyScoutMuteChannel2(int mute);
+void BoyScoutMuteChannel3(int mute);
+void BoyScoutMuteChannel4(int mute);
+
+#endif
+
+
+
+
+
+