react-native-tgfx 0.0.0 → 0.0.2-alpha.0

package/cpp/third_party/tgfx/CMakeLists.txt

@@ -0,0 +1,909 @@
+cmake_minimum_required(VERSION 3.13)
+project(TGFX)
+
+if (APPLE)
+    enable_language(OBJC OBJCXX)
+endif ()
+
+#set(CMAKE_VERBOSE_MAKEFILE ON)
+include(./third_party/vendor_tools/vendor.cmake)
+
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED ON)
+cmake_policy(SET CMP0063 NEW)
+set(CMAKE_CXX_VISIBILITY_PRESET hidden)
+
+set(TGFX_VERSION "2.1.1")
+
+# Options for building tgfx
+option(TGFX_BUILD_SVG "Enable building the SVG module" OFF)
+option(TGFX_BUILD_PDF "Enable building the PDF module" OFF)
+option(TGFX_BUILD_LAYERS "Enable building the layers module" OFF)
+option(TGFX_BUILD_HELLO2D "Enable building the tgfx-hello2d library for testing" OFF)
+option(TGFX_USE_OPENGL "Use OpenGL as the GPU backend" ON)
+option(TGFX_USE_METAL "Use Metal as the GPU backend on Apple platforms" OFF)
+option(TGFX_USE_WEBGPU "Use WebGPU as the GPU backend on web platform" OFF)
+option(TGFX_USE_QT "Enable building with the Qt framework." OFF)
+option(TGFX_USE_SWIFTSHADER "Enable building with the SwiftShader library" OFF)
+option(TGFX_USE_ANGLE "Enable building with the ANGLE library" OFF)
+option(TGFX_USE_VULKAN "Use Vulkan as the GPU backend" OFF)
+option(TGFX_USE_TEXT_GAMMA_CORRECTION "Enable gamma correction when rendering text" OFF)
+option(TGFX_ENABLE_STENCIL_COVER_PATH "Enable the stencil-and-cover GPU path renderer for non-antialiased fills" ON)
+
+# EMSCRIPTEN_PTHREADS can be set by vendor tools for building the wasm-mt architecture.
+if (NOT WEB OR EMSCRIPTEN_PTHREADS)
+    option(TGFX_USE_THREADS "Enable support for multithreaded rendering" ON)
+endif ()
+
+if (APPLE OR (WEB AND NOT TGFX_USE_THREADS))
+    option(TGFX_USE_FREETYPE "Use Freetype as the vector backend" OFF)
+else ()
+    option(TGFX_USE_FREETYPE "Use Freetype as the vector backend" ON)
+endif ()
+
+if (IOS OR WEB)
+    option(TGFX_USE_WEBP_DECODE "Enable embedded WEBP decoding support" ON)
+elseif (NOT ANDROID AND NOT OHOS)
+    option(TGFX_USE_PNG_DECODE "Enable embedded PNG decoding support" ON)
+    option(TGFX_USE_PNG_ENCODE "Enable embedded PNG encoding support" ON)
+    option(TGFX_USE_JPEG_DECODE "Enable embedded JPEG decoding support" ON)
+    option(TGFX_USE_JPEG_ENCODE "Enable embedded JPEG encoding support" ON)
+    option(TGFX_USE_WEBP_DECODE "Enable embedded WEBP decoding support" ON)
+    option(TGFX_USE_WEBP_ENCODE "Enable embedded WEBP encoding support" ON)
+endif ()
+
+if (MACOS OR IOS)
+    option(TGFX_BUILD_FRAMEWORK "Enable building framework" OFF)
+else ()
+    set(TGFX_BUILD_FRAMEWORK OFF)
+endif ()
+
+
+if ($ENV{CLION_IDE})
+    set(CLION_IDE ON)
+else ()
+    set(CLION_IDE OFF)
+endif ()
+get_directory_property(HasParent PARENT_DIRECTORY)
+if (MACOS AND CLION_IDE AND NOT HasParent)
+    # CLion project needs test targets.
+    option(TGFX_BUILD_TESTS "Enable building tgfx test targets" ON)
+endif ()
+
+if (TGFX_BUILD_SVG OR TGFX_BUILD_PDF)
+    set(TGFX_USE_PNG_ENCODE ON)
+    set(TGFX_USE_JPEG_DECODE ON)
+endif ()
+
+if (TGFX_BUILD_TESTS)
+    set(TGFX_BUILD_SVG ON)
+    set(TGFX_BUILD_PDF ON)
+    set(TGFX_BUILD_HELLO2D ON)
+    set(TGFX_USE_FREETYPE ON)
+else ()
+    set(TGFX_BUILD_TESTS OFF)
+endif ()
+
+if (TGFX_BUILD_HELLO2D)
+    set(TGFX_BUILD_LAYERS ON)
+endif ()
+
+if (TGFX_USE_FREETYPE)
+    # Freetype needs libpng
+    set(TGFX_USE_PNG_DECODE ON)
+endif ()
+
+if (TGFX_USE_VULKAN)
+    if (NOT WIN32 AND NOT APPLE AND NOT OHOS AND NOT ANDROID)
+        message(FATAL_ERROR "TGFX_USE_VULKAN is currently supported on Windows, macOS, OHOS and Android only.")
+    endif ()
+    set(TGFX_USE_OPENGL OFF)
+    set(TGFX_USE_METAL OFF)
+    set(TGFX_USE_QT OFF)
+    # Keep TGFX_USE_SWIFTSHADER — in Vulkan mode it only controls ICD file copy,
+    # not EGL/GLES library linking.
+    set(TGFX_USE_ANGLE OFF)
+elseif (TGFX_USE_METAL)
+    if (NOT APPLE)
+        message(FATAL_ERROR "TGFX_USE_METAL is only supported on Apple platforms.")
+    endif ()
+    if (IOS AND CMAKE_OSX_DEPLOYMENT_TARGET VERSION_LESS "13.0")
+        message(FATAL_ERROR "TGFX_USE_METAL on iOS requires CMAKE_OSX_DEPLOYMENT_TARGET >= 13.0.")
+    endif ()
+    set(TGFX_USE_OPENGL OFF)
+    set(TGFX_USE_QT OFF)
+    set(TGFX_USE_SWIFTSHADER OFF)
+    set(TGFX_USE_ANGLE OFF)
+elseif (TGFX_USE_WEBGPU)
+    if (NOT WEB)
+        message(FATAL_ERROR "TGFX_USE_WEBGPU is only supported on web platform.")
+    endif ()
+    set(TGFX_USE_OPENGL OFF)
+    set(TGFX_USE_QT OFF)
+    set(TGFX_USE_SWIFTSHADER OFF)
+    set(TGFX_USE_ANGLE OFF)
+else ()
+    if (TGFX_USE_QT)
+        set(TGFX_USE_SWIFTSHADER OFF)
+        set(TGFX_USE_ANGLE OFF)
+    elseif (TGFX_USE_SWIFTSHADER)
+        set(TGFX_USE_ANGLE OFF)
+    endif ()
+
+    if (TGFX_USE_QT OR TGFX_USE_SWIFTSHADER OR TGFX_USE_ANGLE)
+        set(TGFX_USE_OPENGL ON)
+    endif ()
+endif ()
+
+if (NOT TGFX_USE_METAL AND NOT TGFX_USE_OPENGL AND NOT TGFX_USE_VULKAN AND NOT TGFX_USE_WEBGPU)
+    message(FATAL_ERROR "At least one GPU backend (TGFX_USE_METAL, TGFX_USE_OPENGL, TGFX_USE_VULKAN, or TGFX_USE_WEBGPU) must be enabled.")
+endif ()
+
+message("TGFX_VERSION: ${TGFX_VERSION}")
+message("TGFX_BUILD_SVG: ${TGFX_BUILD_SVG}")
+message("TGFX_BUILD_PDF: ${TGFX_BUILD_PDF}")
+message("TGFX_BUILD_LAYERS: ${TGFX_BUILD_LAYERS}")
+message("TGFX_USE_OPENGL: ${TGFX_USE_OPENGL}")
+message("TGFX_USE_METAL: ${TGFX_USE_METAL}")
+message("TGFX_USE_VULKAN: ${TGFX_USE_VULKAN}")
+message("TGFX_USE_WEBGPU: ${TGFX_USE_WEBGPU}")
+message("TGFX_USE_QT: ${TGFX_USE_QT}")
+message("TGFX_USE_SWIFTSHADER: ${TGFX_USE_SWIFTSHADER}")
+message("TGFX_USE_ANGLE: ${TGFX_USE_ANGLE}")
+message("TGFX_USE_THREADS: ${TGFX_USE_THREADS}")
+message("TGFX_USE_FREETYPE: ${TGFX_USE_FREETYPE}")
+message("TGFX_USE_PNG_DECODE: ${TGFX_USE_PNG_DECODE}")
+message("TGFX_USE_PNG_ENCODE: ${TGFX_USE_PNG_ENCODE}")
+message("TGFX_USE_JPEG_DECODE: ${TGFX_USE_JPEG_DECODE}")
+message("TGFX_USE_JPEG_ENCODE: ${TGFX_USE_JPEG_ENCODE}")
+message("TGFX_USE_WEBP_DECODE: ${TGFX_USE_WEBP_DECODE}")
+message("TGFX_USE_WEBP_ENCODE: ${TGFX_USE_WEBP_ENCODE}")
+message("TGFX_BUILD_TESTS: ${TGFX_BUILD_TESTS}")
+message("TGFX_BUILD_FRAMEWORK: ${TGFX_BUILD_FRAMEWORK}")
+message("TGFX_USE_TEXT_GAMMA_CORRECTION: ${TGFX_USE_TEXT_GAMMA_CORRECTION}")
+message("TGFX_ENABLE_STENCIL_COVER_PATH: ${TGFX_ENABLE_STENCIL_COVER_PATH}")
+
+if (NOT CMAKE_OSX_DEPLOYMENT_TARGET)
+    if (DEPLOYMENT_TARGET)
+        set(CMAKE_OSX_DEPLOYMENT_TARGET ${DEPLOYMENT_TARGET})
+    elseif (MACOS)
+        if (CMAKE_SYSTEM_PROCESSOR STREQUAL "aarch64")
+            set(CMAKE_OSX_DEPLOYMENT_TARGET "11.0")
+        else ()
+            set(CMAKE_OSX_DEPLOYMENT_TARGET "10.15")
+        endif ()
+    elseif (IOS)
+        if (TGFX_USE_METAL)
+            set(CMAKE_OSX_DEPLOYMENT_TARGET "13.0")
+        else ()
+            set(CMAKE_OSX_DEPLOYMENT_TARGET "9.0")
+        endif ()
+    endif ()
+endif ()
+
+file(GLOB_RECURSE TGFX_HEADERS include/*.h)
+list(APPEND TGFX_FILES ${TGFX_HEADERS})
+# collects tgfx common files.
+file(GLOB_RECURSE SRC_FILES
+        src/core/filters/*.*
+        src/core/images/*.*
+        src/core/shaders/*.*
+        src/core/shapes/*.*
+        src/core/utils/*.*
+        src/gpu/glsl/*.*
+        src/gpu/ops/*.*
+        src/gpu/processors/*.*
+        src/gpu/proxies/*.*
+        src/gpu/resources/*.*
+        src/gpu/tasks/*.*)
+list(APPEND TGFX_FILES ${SRC_FILES})
+file(GLOB PLATFORM_COMMON_FILES
+        src/core/*.*
+        src/gpu/*.*
+        src/core/codecs/*.*
+        src/core/vectors/*.*
+        src/platform/*.*)
+list(APPEND TGFX_FILES ${PLATFORM_COMMON_FILES})
+
+if (NOT TGFX_USE_METAL AND NOT TGFX_USE_VULKAN)
+    file(GLOB SHADER_COMPILER_FILES src/gpu/ShaderCompiler.*)
+    if (SHADER_COMPILER_FILES)
+        list(REMOVE_ITEM TGFX_FILES ${SHADER_COMPILER_FILES})
+    endif ()
+endif ()
+
+if (TGFX_BUILD_SVG)
+    file(GLOB_RECURSE SVG_FILES
+            src/svg/*.*)
+    list(APPEND TGFX_FILES ${SVG_FILES})
+endif ()
+
+if (TGFX_BUILD_LAYERS)
+    file(GLOB_RECURSE LAYERS_FILES
+            src/layers/*.*)
+    list(APPEND TGFX_FILES ${LAYERS_FILES})
+endif ()
+
+if (TGFX_BUILD_PDF)
+    file(GLOB_RECURSE PDF_FILES
+            src/pdf/*.*)
+    list(APPEND TGFX_FILES ${PDF_FILES})
+endif ()
+
+if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
+    list(APPEND TGFX_COMPILE_OPTIONS -Werror -Wall -Wextra -Weffc++ -Wconversion -pedantic -Werror=return-type -Wno-unused-command-line-argument)
+endif ()
+
+if (WIN32)
+    list(APPEND TGFX_DEFINES NOMINMAX _USE_MATH_DEFINES)
+endif ()
+
+if (MSVC)
+    list(APPEND TGFX_COMPILE_OPTIONS "/utf-8")
+    list(APPEND TGFX_COMPILE_OPTIONS /w44251 /w44275)
+    list(APPEND TGFX_COMPILE_OPTIONS /W4)
+endif (MSVC)
+
+# Sets flags
+if (CMAKE_BUILD_TYPE MATCHES "Debug")
+    list(APPEND TGFX_DEFINES DEBUG)
+    #set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fsanitize=address -fno-omit-frame-pointer -g -O1")
+endif ()
+
+if (TGFX_USE_PNG_DECODE)
+    list(APPEND TGFX_DEFINES TGFX_USE_PNG_DECODE)
+    set(TGFX_USE_PNG ON)
+endif ()
+
+if (TGFX_USE_PNG_ENCODE)
+    list(APPEND TGFX_DEFINES TGFX_USE_PNG_ENCODE)
+    set(TGFX_USE_PNG ON)
+endif ()
+
+if (TGFX_USE_JPEG_DECODE)
+    list(APPEND TGFX_DEFINES TGFX_USE_JPEG_DECODE)
+    set(TGFX_USE_JPEG ON)
+endif ()
+
+if (TGFX_USE_JPEG_ENCODE)
+    list(APPEND TGFX_DEFINES TGFX_USE_JPEG_ENCODE)
+    set(TGFX_USE_JPEG ON)
+endif ()
+
+if (TGFX_USE_WEBP_DECODE)
+    list(APPEND TGFX_DEFINES TGFX_USE_WEBP_DECODE)
+    set(TGFX_USE_WEBP ON)
+endif ()
+
+if (TGFX_USE_WEBP_ENCODE)
+    list(APPEND TGFX_DEFINES TGFX_USE_WEBP_ENCODE)
+    set(TGFX_USE_WEBP ON)
+endif ()
+
+if (TGFX_USE_JPEG)
+    list(APPEND TGFX_STATIC_VENDORS libjpeg-turbo)
+    file(GLOB_RECURSE GFX_PLATFORM_FILES src/core/codecs/jpeg/*.*)
+    list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+    list(APPEND TGFX_INCLUDES third_party/out/libjpeg-turbo/${INCLUDE_ENTRY})
+endif ()
+
+if (TGFX_USE_WEBP)
+    list(APPEND TGFX_STATIC_VENDORS libwebp)
+    file(GLOB_RECURSE GFX_PLATFORM_FILES src/core/codecs/webp/*.*)
+    list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+    list(APPEND TGFX_INCLUDES third_party/libwebp/src)
+endif ()
+
+if (TGFX_USE_PNG)
+    set(TGFX_USE_ZLIB ON)
+    list(APPEND TGFX_STATIC_VENDORS libpng)
+    file(GLOB_RECURSE GFX_PLATFORM_FILES src/core/codecs/png/*.*)
+    list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+    list(APPEND TGFX_INCLUDES third_party/out/libpng/${INCLUDE_ENTRY})
+endif ()
+
+if (TGFX_BUILD_SVG OR TGFX_BUILD_PDF OR ANDROID)
+    # SVG and PDF exports require glyphs to be convertible back to Unicode.
+    # Android also needs this for COLRv1 emoji rendering via native API.
+    list(APPEND TGFX_DEFINES TGFX_USE_GLYPH_TO_UNICODE)
+    if (TGFX_BUILD_PDF)
+        list(APPEND TGFX_DEFINES TGFX_USE_ADVANCED_TYPEFACE_PROPERTY)
+        set(TGFX_USE_ZLIB ON)
+    endif ()
+endif ()
+
+if (TGFX_USE_ZLIB)
+    list(APPEND TGFX_STATIC_VENDORS zlib)
+    list(APPEND TGFX_INCLUDES third_party/out/zlib/${INCLUDE_ENTRY})
+endif ()
+
+if (TGFX_USE_THREADS)
+    list(APPEND TGFX_DEFINES TGFX_USE_THREADS)
+endif ()
+
+if (TGFX_ENABLE_STENCIL_COVER_PATH)
+    list(APPEND TGFX_DEFINES TGFX_ENABLE_STENCIL_COVER_PATH)
+endif ()
+
+if (TGFX_USE_FREETYPE)
+    list(APPEND TGFX_DEFINES TGFX_USE_FREETYPE)
+    list(APPEND TGFX_STATIC_VENDORS freetype)
+    file(GLOB_RECURSE GFX_PLATFORM_FILES src/core/vectors/freetype/*.*)
+    list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+    list(APPEND TGFX_INCLUDES third_party/freetype/include)
+elseif (APPLE)
+    # Uses CoreGraphics instead.
+    list(APPEND TGFX_DEFINES TGFX_USE_CORE_GRAPHICS)
+    file(GLOB_RECURSE GFX_PLATFORM_FILES src/core/vectors/coregraphics/*.*)
+    list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+endif ()
+
+if (TGFX_USE_TEXT_GAMMA_CORRECTION)
+    list(APPEND TGFX_DEFINES TGFX_USE_TEXT_GAMMA_CORRECTION)
+endif ()
+
+if (TGFX_USE_VULKAN)
+    file(GLOB_RECURSE GFX_PLATFORM_FILES src/gpu/vulkan/*.*)
+    list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+    list(APPEND TGFX_DEFINES TGFX_USE_VULKAN VK_NO_PROTOTYPES)
+    if (WIN32)
+        list(APPEND TGFX_DEFINES VK_USE_PLATFORM_WIN32_KHR)
+    elseif (ANDROID)
+        list(APPEND TGFX_DEFINES VK_USE_PLATFORM_ANDROID_KHR)
+    elseif (OHOS)
+        list(APPEND TGFX_DEFINES VK_USE_PLATFORM_OHOS)
+    endif ()
+
+    # Vulkan-Headers (header-only)
+    list(APPEND TGFX_INCLUDES third_party/Vulkan-Headers/include)
+
+    # volk (compile volk.c directly, same pattern as lz4)
+    list(APPEND TGFX_INCLUDES third_party/volk)
+    file(GLOB VOLK_FILES third_party/volk/volk.c)
+    list(APPEND TGFX_FILES ${VOLK_FILES})
+
+    # VMA (header-only). Added as SYSTEM include later to suppress
+    # nullability-extension warnings from vk_mem_alloc.h on Apple Clang.
+
+    # shaderc + SPIRV-Cross (shared with Metal backend)
+    list(APPEND TGFX_STATIC_VENDORS shaderc SPIRV-Cross)
+    list(APPEND TGFX_INCLUDES third_party/shaderc/libshaderc/include)
+    list(APPEND TGFX_INCLUDES third_party/SPIRV-Cross)
+    list(APPEND TGFX_DEFINES SPIRV_CROSS_EXCEPTIONS_TO_ASSERTIONS)
+elseif (TGFX_USE_OPENGL)
+    file(GLOB GFX_PLATFORM_FILES src/gpu/opengl/*.*)
+    list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+    file(GLOB_RECURSE GFX_PROCESSOR_FILES src/gpu/opengl/processors/*.*)
+    list(APPEND TGFX_FILES ${GFX_PROCESSOR_FILES})
+elseif (TGFX_USE_WEBGPU)
+    file(GLOB_RECURSE GFX_PLATFORM_FILES src/gpu/webgpu/*.*)
+    list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+    list(APPEND TGFX_DEFINES TGFX_USE_WEBGPU)
+    list(APPEND TGFX_STATIC_VENDORS shaderc)
+    list(APPEND TGFX_INCLUDES third_party/shaderc/libshaderc/include)
+    if (NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/third_party/shaderc/third_party/glslang)
+        message(FATAL_ERROR "shaderc sub-dependencies not found. Please run ./sync_deps.sh first.")
+    endif ()
+    # Tint: SPIR-V to WGSL shader conversion for WebGPU
+    set(TINT_BUILD_CMD_TOOLS OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_TESTS OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_BENCHMARKS OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_AS_OTHER_OS ON CACHE BOOL "" FORCE)
+    set(TINT_BUILD_SPV_READER ON CACHE BOOL "" FORCE)
+    set(TINT_BUILD_WGSL_WRITER ON CACHE BOOL "" FORCE)
+    set(TINT_BUILD_WGSL_READER OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_SPV_WRITER OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_MSL_WRITER OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_HLSL_WRITER OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_GLSL_WRITER OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_GLSL_VALIDATOR OFF CACHE BOOL "" FORCE)
+    set(TINT_BUILD_IR ON CACHE BOOL "" FORCE)
+    set(TINT_SPIRV_TOOLS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/third_party/shaderc/third_party/spirv-tools" CACHE STRING "" FORCE)
+    set(TINT_SPIRV_HEADERS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/third_party/shaderc/third_party/spirv-headers" CACHE STRING "" FORCE)
+    add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/third_party/tint ${CMAKE_CURRENT_BINARY_DIR}/tint EXCLUDE_FROM_ALL)
+    list(APPEND TGFX_INCLUDES ${CMAKE_CURRENT_SOURCE_DIR}/third_party/tint/include)
+    list(APPEND TGFX_INCLUDES ${CMAKE_CURRENT_SOURCE_DIR}/third_party/tint)
+elseif (APPLE)
+    if (TGFX_USE_METAL)
+        file(GLOB_RECURSE GFX_PLATFORM_FILES src/gpu/metal/*.*)
+        list(APPEND TGFX_FILES ${GFX_PLATFORM_FILES})
+        find_library(Metal_LIBS Metal REQUIRED)
+        list(APPEND TGFX_SHARED_LIBS ${Metal_LIBS})
+        list(APPEND TGFX_DEFINES TGFX_USE_METAL)
+        # Add shaderc and SPIRV-Cross for GLSL to MSL conversion
+        list(APPEND TGFX_STATIC_VENDORS shaderc SPIRV-Cross)
+        list(APPEND TGFX_INCLUDES third_party/shaderc/libshaderc/include)
+        list(APPEND TGFX_INCLUDES third_party/SPIRV-Cross)
+        list(APPEND TGFX_DEFINES SPIRV_CROSS_EXCEPTIONS_TO_ASSERTIONS)
+    endif ()
+endif ()
+
+# Auto-sync shaderc sub-dependencies (glslang, SPIRV-Tools, etc.) if any backend needs shaderc.
+# This runs at configure time; for offline builds, run manually before cmake:
+#   python third_party/shaderc/utils/git-sync-deps
+if (NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/third_party/shaderc/third_party/glslang)
+    find_package(Python3 COMPONENTS Interpreter QUIET)
+    if (Python3_FOUND)
+        message(STATUS "Syncing shaderc sub-dependencies...")
+        execute_process(
+                COMMAND ${Python3_EXECUTABLE}
+                ${CMAKE_CURRENT_SOURCE_DIR}/third_party/shaderc/utils/git-sync-deps
+                WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/third_party/shaderc
+                RESULT_VARIABLE SYNC_RESULT)
+        if (NOT SYNC_RESULT EQUAL 0)
+            message(FATAL_ERROR "Failed to sync shaderc sub-dependencies. For offline builds, run: python third_party/shaderc/utils/git-sync-deps")
+        endif ()
+    else ()
+        message(FATAL_ERROR "shaderc sub-dependencies missing and Python3 not found. Run manually: python third_party/shaderc/utils/git-sync-deps")
+    endif ()
+endif ()
+
+file(GLOB_RECURSE EGL_PLATFORM_FILES src/gpu/opengl/egl/*.*)
+
+if (TGFX_USE_QT)
+    set(CMAKE_AUTOMOC ON)
+    # need to set the CMAKE_PREFIX_PATH to local QT installation path, for example :
+    #set(CMAKE_PREFIX_PATH /Users/username/Qt/6.6.1/macos/lib/cmake)
+    find_package(Qt6 REQUIRED COMPONENTS Core Widgets OpenGL Quick)
+    if (Qt6_VERSION VERSION_LESS "6.2")
+        message(FATAL_ERROR "Qt6 version 6.2 or higher is required. Found: ${Qt6_VERSION}")
+    endif ()
+    list(APPEND TGFX_SHARED_LIBS Qt6::Widgets Qt6::OpenGL
+            Qt6::Quick)
+
+    file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/qt/*.*)
+    list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+    if (MACOS)
+        file(GLOB CGL_PLATFORM_FILES src/gpu/opengl/cgl/CGLHardwareTexture.mm)
+        list(APPEND TGFX_FILES ${CGL_PLATFORM_FILES})
+        list(APPEND TGFX_DEFINES GL_SILENCE_DEPRECATION)
+        find_library(OpenGL_LIBS OpenGL REQUIRED)
+        list(APPEND TGFX_SHARED_LIBS ${OpenGL_LIBS})
+    endif ()
+elseif (TGFX_USE_SWIFTSHADER)
+    if (TGFX_USE_VULKAN)
+        # Vulkan + SwiftShader: copy SwiftShader files to build directory. At runtime, the
+        # autotest script renames vk_swiftshader to the platform Vulkan loader name (vulkan-1.dll
+        # on Windows, libvulkan.dylib on macOS) so that volk loads it directly without requiring
+        # a Vulkan SDK or ICD environment variables.
+        file(GLOB VK_SWIFTSHADER_ICD_FILES
+                vendor/swiftshader/${PLATFORM}/${ARCH}/vk_swiftshader*
+                vendor/swiftshader/${PLATFORM}/${ARCH}/libvk_swiftshader*)
+        if (VK_SWIFTSHADER_ICD_FILES)
+            file(COPY ${VK_SWIFTSHADER_ICD_FILES} DESTINATION ${CMAKE_BINARY_DIR})
+        endif ()
+    else ()
+        # OpenGL + SwiftShader: link EGL/GLES libraries as before.
+        list(APPEND TGFX_INCLUDES vendor/swiftshader/include)
+        # SwiftShader ships prebuilt binaries without a debug variant, so always use the release path.
+        if (WIN32)
+            file(GLOB SWIFTSHADER_LIBS vendor/swiftshader/${PLATFORM}/${ARCH}/*${CMAKE_STATIC_LIBRARY_SUFFIX})
+        else ()
+            file(GLOB SWIFTSHADER_LIBS vendor/swiftshader/${PLATFORM}/${ARCH}/*${CMAKE_SHARED_LIBRARY_SUFFIX})
+        endif ()
+        list(APPEND TGFX_SHARED_LIBS ${SWIFTSHADER_LIBS})
+        list(APPEND TGFX_FILES ${EGL_PLATFORM_FILES})
+    endif ()
+elseif (TGFX_USE_ANGLE)
+    file(GLOB ANGLE_LIBS vendor/angle/${PLATFORM}/${ARCH}/*${CMAKE_STATIC_LIBRARY_SUFFIX})
+    list(APPEND TGFX_STATIC_LIBS ${ANGLE_LIBS})
+    list(APPEND TGFX_INCLUDES vendor/angle/include)
+    list(APPEND TGFX_DEFINES TGFX_USE_ANGLE)
+    file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/egl/*.*)
+    list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+elseif (TGFX_USE_OPENGL)
+    set(TGFX_USE_NATIVE_GL ON)
+endif ()
+
+list(APPEND TGFX_STATIC_VENDORS pathkit)
+list(APPEND TGFX_INCLUDES third_party/pathkit)
+list(APPEND TGFX_STATIC_VENDORS skcms)
+list(APPEND TGFX_INCLUDES third_party/skcms)
+list(APPEND TGFX_INCLUDES third_party/concurrentqueue)
+list(APPEND TGFX_STATIC_VENDORS highway)
+list(APPEND TGFX_INCLUDES third_party/highway)
+if (TGFX_BUILD_SVG)
+    list(APPEND TGFX_STATIC_VENDORS expat)
+    list(APPEND TGFX_INCLUDES third_party/expat)
+    if (WIN32)
+        list(APPEND TGFX_DEFINES XML_STATIC)
+    endif ()
+endif ()
+if (TGFX_BUILD_PDF)
+    if (HARFBUZZ_LIB AND HARFBUZZ_SUBSET_LIB AND HARFBUZZ_INCLUDE)
+        # Prebuilt HarfBuzz static libraries and headers provided externally.
+        # HARFBUZZ_LIB: path to libharfbuzz.a
+        # HARFBUZZ_SUBSET_LIB: path to libharfbuzz-subset.a
+        # HARFBUZZ_INCLUDE: path to HarfBuzz headers directory
+        message("HARFBUZZ_LIB: ${HARFBUZZ_LIB}")
+        message("HARFBUZZ_SUBSET_LIB: ${HARFBUZZ_SUBSET_LIB}")
+        message("HARFBUZZ_INCLUDE: ${HARFBUZZ_INCLUDE}")
+        list(APPEND TGFX_INCLUDES ${HARFBUZZ_INCLUDE})
+        # Use TGFX_SHARED_LIBS to avoid embedding into the static libtgfx archive.
+        list(APPEND TGFX_SHARED_LIBS ${HARFBUZZ_LIB} ${HARFBUZZ_SUBSET_LIB})
+    else ()
+        # Built-in HarfBuzz, compile from third_party.
+        list(APPEND TGFX_STATIC_VENDORS harfbuzz)
+        list(APPEND TGFX_INCLUDES third_party/harfbuzz/src)
+    endif ()
+endif ()
+
+if (WEB)
+    file(GLOB_RECURSE PLATFORM_FILES src/platform/web/*.*)
+    list(APPEND TGFX_FILES ${PLATFORM_FILES})
+    list(APPEND TGFX_DEFINES TGFX_BUILD_FOR_WEB TGFX_USE_FALLBACK_MD5)
+    if (TGFX_USE_NATIVE_GL)
+        file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/webgl/*.*)
+        list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+    endif ()
+    list(APPEND TGFX_COMPILE_OPTIONS -fno-rtti -DEMSCRIPTEN_HAS_UNBOUND_TYPE_NAMES=0)
+    if (TGFX_USE_WEBGPU)
+        list(APPEND TGFX_COMPILE_OPTIONS "SHELL:-s USE_WEBGPU=1")
+    endif ()
+elseif (OHOS)
+    find_library(PIXELMAP_NDK_LIB pixelmap_ndk.z)
+    find_library(IMAGE_SOURCE_NDK_LIB image_source_ndk.z)
+    find_library(PIXELMAP_LIB pixelmap)
+    find_library(IMAGE_SOURCE_LIB image_source)
+    find_library(ACE_NDK_LIB ace_ndk.z)
+    find_library(HILOG_NDK_LIB hilog_ndk.z)
+    find_library(ACE_NAPI_LIB ace_napi.z)
+    find_library(NATIVE_BUFFER_LIB native_buffer)
+    find_library(NATIVE_WINDOW_LIB native_window)
+    list(APPEND TGFX_SHARED_LIBS ${PIXELMAP_NDK_LIB} ${IMAGE_SOURCE_NDK_LIB} ${PIXELMAP_LIB}
+            ${IMAGE_SOURCE_LIB} ${ACE_NDK_LIB} ${HILOG_NDK_LIB} ${ACE_NAPI_LIB} ${NATIVE_BUFFER_LIB}
+            ${NATIVE_WINDOW_LIB})
+    file(GLOB_RECURSE PLATFORM_FILES src/platform/ohos/*.*)
+    list(APPEND TGFX_FILES ${PLATFORM_FILES})
+    if (TGFX_USE_VULKAN)
+        find_library(VULKAN_LIB vulkan)
+        list(APPEND TGFX_SHARED_LIBS ${VULKAN_LIB})
+    elseif (TGFX_USE_NATIVE_GL)
+        find_library(EGL_LIB EGL)
+        find_library(GLES_LIB GLESv3)
+        list(APPEND TGFX_SHARED_LIBS ${EGL_LIB} ${GLES_LIB})
+        file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/egl/*.*)
+        list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+    endif ()
+elseif (IOS)
+    # finds all required platform libraries.
+    find_library(UIKit_LIBS UIKit REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${UIKit_LIBS})
+    find_library(Foundation_LIBS Foundation REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${Foundation_LIBS})
+    find_library(QuartzCore_LIBS QuartzCore REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${QuartzCore_LIBS})
+    find_library(CoreGraphics_LIBS CoreGraphics REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${CoreGraphics_LIBS})
+    find_library(CoreText_LIBS CoreText REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${CoreText_LIBS})
+    find_library(CoreMedia_LIBS CoreMedia REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${CoreMedia_LIBS})
+    find_library(ImageIO_LIBS ImageIO REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${ImageIO_LIBS})
+    find_library(CORE_VIDEO CoreVideo)
+    list(APPEND TGFX_SHARED_LIBS ${CORE_VIDEO})
+    find_library(ICONV_LIBRARIES NAMES iconv libiconv libiconv-2 c)
+    list(APPEND TGFX_SHARED_LIBS ${ICONV_LIBRARIES})
+
+    file(GLOB_RECURSE PLATFORM_FILES src/platform/apple/*.*)
+    list(APPEND TGFX_FILES ${PLATFORM_FILES})
+
+    if (TGFX_USE_NATIVE_GL)
+        list(APPEND TGFX_DEFINES GLES_SILENCE_DEPRECATION)
+        find_library(OpenGLES_LIBS OpenGLES REQUIRED)
+        list(APPEND TGFX_SHARED_LIBS ${OpenGLES_LIBS})
+        file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/eagl/*.*)
+        list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+    endif ()
+elseif (MACOS)
+    # finds all required platform libraries.
+    find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${APPLICATION_SERVICES_FRAMEWORK})
+    find_library(QUARTZ_CORE QuartzCore REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${QUARTZ_CORE})
+    find_library(COCOA Cocoa REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${COCOA})
+    find_library(FOUNDATION Foundation REQUIRED)
+    list(APPEND TGFX_SHARED_LIBS ${FOUNDATION})
+    find_library(ICONV_LIBRARIES NAMES iconv libiconv libiconv-2 c)
+    list(APPEND TGFX_SHARED_LIBS ${ICONV_LIBRARIES})
+    find_library(CORE_MEDIA CoreMedia)
+    list(APPEND TGFX_SHARED_LIBS ${CORE_MEDIA})
+
+    file(GLOB_RECURSE PLATFORM_FILES src/platform/apple/*.*)
+    list(APPEND TGFX_FILES ${PLATFORM_FILES})
+
+    if (TGFX_USE_NATIVE_GL)
+        list(APPEND TGFX_DEFINES GL_SILENCE_DEPRECATION)
+        find_library(OpenGL_LIBS OpenGL REQUIRED)
+        list(APPEND TGFX_SHARED_LIBS ${OpenGL_LIBS})
+        file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/cgl/*.*)
+        list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+    endif ()
+
+elseif (ANDROID)
+
+    find_library(LOG_LIB log)
+    list(APPEND TGFX_SHARED_LIBS ${LOG_LIB})
+    find_library(ANDROID_LIB android)
+    list(APPEND TGFX_SHARED_LIBS ${ANDROID_LIB})
+    find_library(JNIGRAPHICS_LIB jnigraphics)
+    list(APPEND TGFX_SHARED_LIBS ${JNIGRAPHICS_LIB})
+
+    file(GLOB_RECURSE PLATFORM_FILES src/platform/android/*.*)
+    list(APPEND TGFX_FILES ${PLATFORM_FILES})
+
+    if (TGFX_USE_VULKAN)
+        # SurfaceTexture depends on GL and is not available in Vulkan mode.
+        # Only exclude the internal implementation; SurfaceTextureReader.cpp is kept with a stub.
+        list(FILTER TGFX_FILES EXCLUDE REGEX ".*/SurfaceTexture\\.(cpp|h)$")
+        find_library(VULKAN_LIB vulkan)
+        list(APPEND TGFX_SHARED_LIBS ${VULKAN_LIB})
+    elseif (TGFX_USE_NATIVE_GL)
+        find_library(GLESV2_LIB GLESv2)
+        list(APPEND TGFX_SHARED_LIBS ${GLESV2_LIB})
+        find_library(GLESV3_LIB GLESv3)
+        list(APPEND TGFX_SHARED_LIBS ${GLESV3_LIB})
+        find_library(EGL_LIB EGL)
+        list(APPEND TGFX_SHARED_LIBS ${EGL_LIB})
+        file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/egl/*.*)
+        list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+    endif ()
+
+    # optimizes the output size
+    list(APPEND TGFX_COMPILE_OPTIONS -ffunction-sections -fdata-sections -Os -fno-exceptions -fno-rtti)
+
+elseif (WIN32)
+    find_library(Bcrypt_LIB Bcrypt)
+    list(APPEND TGFX_STATIC_LIBS ${Bcrypt_LIB})
+    find_library(ws2_32_LIB ws2_32)
+    list(APPEND TGFX_STATIC_LIBS ${ws2_32_LIB})
+    find_library(DWrite_LIB DWrite)
+    list(APPEND TGFX_STATIC_LIBS ${DWrite_LIB})
+    find_library(WindowsCodecs_LIB windowscodecs)
+    list(APPEND TGFX_STATIC_LIBS ${WindowsCodecs_LIB})
+    find_library(Ole32_LIB Ole32)
+    list(APPEND TGFX_STATIC_LIBS ${Ole32_LIB})
+
+    file(GLOB_RECURSE PLATFORM_FILES src/platform/win/*.*)
+    list(APPEND TGFX_FILES ${PLATFORM_FILES})
+
+    if (TGFX_USE_NATIVE_GL)
+        file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/wgl/*.*)
+        find_library(OPENGL_LIB opengl32)
+        list(APPEND TGFX_STATIC_LIBS ${OPENGL_LIB})
+        list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+    endif ()
+elseif (CMAKE_HOST_SYSTEM_NAME MATCHES "Linux")
+    find_package(Threads)
+    list(APPEND TGFX_SHARED_LIBS ${CMAKE_THREAD_LIBS_INIT})
+    list(APPEND TGFX_SHARED_LIBS dl)
+    list(APPEND TGFX_COMPILE_OPTIONS -fPIC -pthread)
+    find_library(CRYPTO_LIB crypto)
+    if (CRYPTO_LIB)
+        list(APPEND TGFX_SHARED_LIBS ${CRYPTO_LIB})
+    else ()
+        list(APPEND TGFX_DEFINES TGFX_USE_FALLBACK_MD5)
+    endif ()
+
+    file(GLOB_RECURSE PLATFORM_FILES src/platform/mock/*.*)
+    list(APPEND TGFX_FILES ${PLATFORM_FILES})
+
+    if (TGFX_USE_NATIVE_GL)
+        find_library(GLESV2_LIB GLESv2)
+        list(APPEND TGFX_SHARED_LIBS ${GLESV2_LIB})
+        find_library(EGL_LIB EGL)
+        list(APPEND TGFX_SHARED_LIBS ${EGL_LIB})
+        file(GLOB_RECURSE GPU_PLATFORM_FILES src/gpu/opengl/egl/*.*)
+        list(APPEND TGFX_FILES ${GPU_PLATFORM_FILES})
+    endif ()
+endif ()
+
+add_vendor_target(tgfx-vendor STATIC_VENDORS ${TGFX_STATIC_VENDORS} SHARED_VENDORS ${TGFX_SHARED_VENDORS} CONFIG_DIR ${CMAKE_CURRENT_SOURCE_DIR})
+find_vendor_libraries(tgfx-vendor STATIC TGFX_VENDOR_STATIC_LIBRARIES SHARED TGFX_VENDOR_SHARED_LIBRARIES)
+list(APPEND TGFX_STATIC_LIBS ${TGFX_VENDOR_STATIC_LIBRARIES})
+list(APPEND TGFX_SHARED_LIBS ${TGFX_VENDOR_SHARED_LIBRARIES})
+
+if (HasParent)
+    set(TGFX_STATIC_LIBS ${TGFX_STATIC_LIBS} PARENT_SCOPE)
+    set(TGFX_SHARED_LIBS ${TGFX_SHARED_LIBS} PARENT_SCOPE)
+    set(TGFX_DEFINES ${TGFX_DEFINES} PARENT_SCOPE)
+endif ()
+
+foreach (FILE_PATH ${TGFX_FILES})
+    get_filename_component(FILE_NAME "${FILE_PATH}" NAME_WE)
+    if (NOT FILE_NAME)
+        list(APPEND TGFX_EXCLUDE_FILES ${FILE_PATH})
+    endif ()
+endforeach ()
+
+if (TGFX_EXCLUDE_FILES)
+    list(REMOVE_ITEM TGFX_FILES ${TGFX_EXCLUDE_FILES})
+endif ()
+
+add_library(tgfx STATIC ${TGFX_FILES})
+add_dependencies(tgfx tgfx-vendor)
+target_compile_definitions(tgfx PRIVATE ${TGFX_DEFINES})
+target_compile_options(tgfx PRIVATE ${TGFX_COMPILE_OPTIONS})
+target_include_directories(tgfx PUBLIC include PRIVATE src)
+target_include_directories(tgfx PRIVATE ${TGFX_INCLUDES})
+if (TGFX_USE_VULKAN)
+    target_include_directories(tgfx SYSTEM PRIVATE third_party/VulkanMemoryAllocator/include)
+endif ()
+merge_libraries_into(tgfx ${TGFX_STATIC_LIBS})
+target_link_libraries(tgfx ${TGFX_SHARED_LIBS})
+if (TGFX_USE_WEBGPU)
+    target_link_libraries(tgfx libtint)
+endif ()
+set_target_properties(tgfx PROPERTIES PREFIX "")
+
+if (TGFX_BUILD_FRAMEWORK)
+    set(TGFX_IDENTIFIER "org.tgfx")
+    set_target_properties(tgfx PROPERTIES
+            FRAMEWORK TRUE
+            MACOSX_FRAMEWORK_IDENTIFIER ${TGFX_IDENTIFIER}
+            MACOSX_FRAMEWORK_BUNDLE_VERSION ${TGFX_VERSION}
+            MACOSX_FRAMEWORK_SHORT_VERSION_STRING ${TGFX_VERSION})
+    set(CMAKE_XCODE_ATTRIBUTE_DEFINES_MODULE YES)
+    set(CMAKE_XCODE_ATTRIBUTE_PRODUCT_BUNDLE_IDENTIFIER ${TGFX_IDENTIFIER})
+    foreach (header ${TGFX_HEADERS})
+        file(RELATIVE_PATH dir ${CMAKE_CURRENT_SOURCE_DIR}/include ${header})
+        get_filename_component(dir "${dir}" DIRECTORY)
+        if (dir)
+            set(location "Headers/${dir}")
+        else ()
+            set(location "Headers")
+        endif ()
+        set_source_files_properties(${header} PROPERTIES MACOSX_PACKAGE_LOCATION "${location}")
+    endforeach ()
+endif ()
+
+
+if (TGFX_BUILD_HELLO2D)
+    file(GLOB_RECURSE DRAWER_FILES hello2d/src/*.*)
+    add_library(tgfx-hello2d STATIC ${DRAWER_FILES})
+    set_target_properties(tgfx-hello2d PROPERTIES PREFIX "")
+    target_compile_definitions(tgfx-hello2d PRIVATE ${TGFX_DEFINES})
+    target_compile_options(tgfx-hello2d PRIVATE ${TGFX_COMPILE_OPTIONS})
+    target_include_directories(tgfx-hello2d PUBLIC hello2d/include PRIVATE include hello2d/src)
+    target_link_libraries(tgfx-hello2d)
+endif ()
+
+if (TGFX_BUILD_TESTS)
+    # Determine backend name for cache isolation
+    if (TGFX_USE_SWIFTSHADER)
+        set(BACKEND_SUFFIX "-swiftshader")
+    else ()
+        set(BACKEND_SUFFIX "")
+    endif ()
+    if (TGFX_USE_VULKAN)
+        set(TGFX_BACKEND_NAME "vulkan${BACKEND_SUFFIX}")
+    elseif (TGFX_USE_METAL)
+        set(TGFX_BACKEND_NAME "metal")
+    else ()
+        set(TGFX_BACKEND_NAME "opengl${BACKEND_SUFFIX}")
+    endif ()
+
+    set(CACHE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/test/baseline/.cache/${TGFX_BACKEND_NAME})
+    file(MAKE_DIRECTORY ${CACHE_DIR})
+    execute_process(COMMAND git rev-parse --short HEAD OUTPUT_VARIABLE HEAD_COMMIT OUTPUT_STRIP_TRAILING_WHITESPACE)
+    file(WRITE ${CACHE_DIR}/HEAD "${HEAD_COMMIT}")
+    if (NOT TGFX_SKIP_BASELINE_CHECK)
+        set(CacheVersionFile ${CACHE_DIR}/version.json)
+        if (EXISTS ${CacheVersionFile})
+            execute_process(COMMAND git diff -G. --name-only origin/main:test/baseline/version.json ${CacheVersionFile} OUTPUT_VARIABLE HAS_DIFF)
+        else ()
+            set(HAS_DIFF ON)
+        endif ()
+        if (HAS_DIFF)
+            string(REPLACE "-" "_" BACKEND_ARG_NAME "${TGFX_BACKEND_NAME}")
+            string(TOUPPER "${BACKEND_ARG_NAME}" BACKEND_ARG_NAME)
+            message(WARNING "The local md5 cache for '${TGFX_BACKEND_NAME}' is out of date! Please run './update_baseline.sh USE_${BACKEND_ARG_NAME}' to regenerate the cache.")
+        endif ()
+    endif ()
+
+    file(GLOB_RECURSE TGFX_TEST_FILES test/src/*.*)
+
+    if (TGFX_USE_METAL)
+        file(GLOB_RECURSE TGFX_TEST_OPENGL_FILES test/src/opengl/*.*)
+        list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_OPENGL_FILES})
+        file(GLOB_RECURSE TGFX_TEST_VULKAN_FILES test/src/vulkan/*.*)
+        if (TGFX_TEST_VULKAN_FILES)
+            list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_VULKAN_FILES})
+        endif ()
+    elseif (TGFX_USE_VULKAN)
+        file(GLOB_RECURSE TGFX_TEST_OPENGL_FILES test/src/opengl/*.*)
+        if (TGFX_TEST_OPENGL_FILES)
+            list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_OPENGL_FILES})
+        endif ()
+        file(GLOB_RECURSE TGFX_TEST_METAL_FILES test/src/metal/*.*)
+        if (TGFX_TEST_METAL_FILES)
+            list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_METAL_FILES})
+        endif ()
+    else ()
+        file(GLOB_RECURSE TGFX_TEST_METAL_FILES test/src/metal/*.*)
+        list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_METAL_FILES})
+        file(GLOB_RECURSE TGFX_TEST_VULKAN_FILES test/src/vulkan/*.*)
+        if (TGFX_TEST_VULKAN_FILES)
+            list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_VULKAN_FILES})
+        endif ()
+    endif ()
+
+    file(GLOB_RECURSE TGFX_TEST_WEBGL_FILES test/src/webgl/*.*)
+    if (TGFX_TEST_WEBGL_FILES)
+        list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_WEBGL_FILES})
+    endif ()
+
+    file(GLOB_RECURSE TGFX_TEST_WEBGPU_FILES test/src/webgpu/*.*)
+    if (TGFX_TEST_WEBGPU_FILES)
+        list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_WEBGPU_FILES})
+    endif ()
+
+    list(APPEND TGFX_TEST_LIBS tgfx-hello2d tgfx ${TGFX_SHARED_LIBS})
+    list(APPEND TGFX_TEST_INCLUDES src test/src hello2d/include third_party/json/include)
+
+    add_vendor_target(test-vendor STATIC_VENDORS googletest)
+    find_vendor_libraries(test-vendor STATIC TEST_VENDOR_STATIC_LIBRARIES)
+    list(APPEND TGFX_TEST_LIBS ${TEST_VENDOR_STATIC_LIBRARIES})
+    list(APPEND TGFX_TEST_INCLUDES
+            third_party/googletest/googletest
+            third_party/googletest/googletest/include)
+
+    list(APPEND TGFX_TEST_COMPILE_OPTIONS ${TGFX_COMPILE_OPTIONS})
+    if (NOT MSVC)
+        list(APPEND TGFX_TEST_COMPILE_OPTIONS -fno-access-control)
+        list(APPEND TGFX_TEST_DEFINES TGFX_TEST_ACCESS_PRIVATE)
+    endif ()
+    list(APPEND TGFX_TEST_DEFINES ${TGFX_DEFINES} TGFX_BACKEND_NAME="${TGFX_BACKEND_NAME}")
+
+    foreach (FILE_PATH ${TGFX_TEST_FILES})
+        get_filename_component(FILE_NAME "${FILE_PATH}" NAME_WE)
+        if (NOT FILE_NAME)
+            list(APPEND TGFX_TEST_EXCLUDE_FILES ${FILE_PATH})
+        endif ()
+    endforeach ()
+
+    if (TGFX_TEST_EXCLUDE_FILES)
+        list(REMOVE_ITEM TGFX_TEST_FILES ${TGFX_TEST_EXCLUDE_FILES})
+    endif ()
+
+    list(APPEND TGFX_BASELINE_DEFINES ${TGFX_TEST_DEFINES} UPDATE_BASELINE)
+    if (NOT TGFX_SKIP_GENERATE_BASELINE_IMAGES)
+        list(APPEND TGFX_BASELINE_DEFINES GENERATE_BASELINE_IMAGES)
+    endif ()
+
+    # Determine target suffix from backend name (e.g. "opengl-swiftshader" → "OpenGL")
+    if (TGFX_USE_VULKAN)
+        set(TEST_TARGET_SUFFIX "Vulkan")
+    elseif (TGFX_USE_METAL)
+        set(TEST_TARGET_SUFFIX "Metal")
+    else ()
+        set(TEST_TARGET_SUFFIX "OpenGL")
+    endif ()
+
+    # used to update the local md5 data for baseline testing and generate baseline images to the
+    # out/ directory. each image has a "_base" suffix.
+    add_executable(UpdateBaseline_${TEST_TARGET_SUFFIX} ${TGFX_TEST_FILES})
+    add_dependencies(UpdateBaseline_${TEST_TARGET_SUFFIX} test-vendor)
+    target_include_directories(UpdateBaseline_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_TEST_INCLUDES})
+    target_include_directories(UpdateBaseline_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_INCLUDES})
+    target_compile_definitions(UpdateBaseline_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_BASELINE_DEFINES})
+    target_compile_options(UpdateBaseline_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_TEST_COMPILE_OPTIONS})
+    target_link_options(UpdateBaseline_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_TEST_LINK_OPTIONS})
+    target_link_libraries(UpdateBaseline_${TEST_TARGET_SUFFIX} ${TGFX_TEST_LIBS})
+
+    add_executable(TGFXFullTest_${TEST_TARGET_SUFFIX} ${TGFX_TEST_FILES})
+    add_dependencies(TGFXFullTest_${TEST_TARGET_SUFFIX} test-vendor)
+    target_compile_definitions(TGFXFullTest_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_TEST_DEFINES})
+    target_compile_options(TGFXFullTest_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_TEST_COMPILE_OPTIONS})
+    target_include_directories(TGFXFullTest_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_TEST_INCLUDES})
+    target_include_directories(TGFXFullTest_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_INCLUDES})
+    target_link_options(TGFXFullTest_${TEST_TARGET_SUFFIX} PRIVATE ${TGFX_TEST_LINK_OPTIONS})
+    target_link_libraries(TGFXFullTest_${TEST_TARGET_SUFFIX} ${TGFX_TEST_LIBS})
+endif ()
+
+# Export TGFX_INCLUDES to the parent scope for external test targets (e.g., web/test).
+if (NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
+    set(TGFX_INCLUDES "${TGFX_INCLUDES}" PARENT_SCOPE)
+endif ()