dartpy 7.0.0.dev0__cp313-cp313-manylinux_2_39_x86_64.whl

share/dart/cmake/DARTConfig.cmake

@@ -0,0 +1,194 @@
+###############################################################################
+# CMake config file for DART
+#
+# This sets the following variables:
+#   DART_INCLUDE_DIRS - Directories containing the DART include files.
+#   DART_LIBRARIES    - Libraries needed to use DART.
+#   DART_VERSION      - DART version.
+#
+# and the following `IMPORTED` targets:
+#   dart     - Main target.
+#   dart-<C> - Target for specific component (e.g., dart-collision-bullet).
+
+# Specify CMake minimum required version
+if(NOT CMAKE_MINIMUM_REQUIRED_VERSION)
+  cmake_minimum_required(VERSION 3.22.1)
+else()
+  # Support if() IN_LIST operator
+  if(POLICY CMP0057)
+    cmake_policy(SET CMP0057 NEW)
+  endif()
+endif()
+
+#===============================================================================
+# Helper Function Definitions
+#===============================================================================
+
+
+####### Expanded from @PACKAGE_INIT@ by configure_package_config_file() #######
+####### Any changes to this file will be overwritten by the next CMake run ####
+####### The input file was DARTConfig.cmake.in                            ########
+
+get_filename_component(PACKAGE_PREFIX_DIR "${CMAKE_CURRENT_LIST_DIR}/../../../" ABSOLUTE)
+
+macro(set_and_check _var _file)
+  set(${_var} "${_file}")
+  if(NOT EXISTS "${_file}")
+    message(FATAL_ERROR "File or directory ${_file} referenced by variable ${_var} does not exist !")
+  endif()
+endmacro()
+
+macro(check_required_components _NAME)
+  foreach(comp ${${_NAME}_FIND_COMPONENTS})
+    if(NOT ${_NAME}_${comp}_FOUND)
+      if(${_NAME}_FIND_REQUIRED_${comp})
+        set(${_NAME}_FOUND FALSE)
+      endif()
+    endif()
+  endforeach()
+endmacro()
+
+####################################################################################
+
+#===============================================================================
+function(dart_traverse_components output_variable)
+  set(output_components)
+
+  foreach(component ${ARGN})
+    # We should be able to elminate the <C>_VISITED property by detecting
+    # whether the <C>_FOUND property is DEFINED. Unfortunately, DEFINED checks
+    # whether or not define_property() was called, not whether the variable was
+    # set. The exact behavior seems to vary between CMake versions, so we use
+    # an extra variable instead.
+    get_property(is_visited DIRECTORY PROPERTY "DART_${component}_VISITED")
+    set_property(DIRECTORY PROPERTY "DART_${component}_VISITED" TRUE)
+
+    if(NOT is_visited)
+      set(component_include
+        "${CMAKE_CURRENT_LIST_DIR}/dart_${component}Component.cmake")
+      set(target_include
+        "${CMAKE_CURRENT_LIST_DIR}/dart_${component}Targets.cmake")
+
+      if(EXISTS "${component_include}" AND EXISTS "${target_include}")
+        include("${component_include}")
+
+        set_property(DIRECTORY
+          PROPERTY "DART_${component}_INCLUDE_DIRS"
+          ${dart_${component}_INCLUDE_DIRS})
+        set_property(DIRECTORY
+          PROPERTY "DART_${component}_DEFINITIONS"
+          ${dart_${component}_DEFINITIONS})
+        set_property(DIRECTORY
+          PROPERTY "DART_${component}_LIBRARIES"
+          ${dart_${component}_LIBRARIES})
+        set_property(DIRECTORY
+          PROPERTY "DART_${component}_DEPENDENCIES"
+          ${dart_${component}_DEPENDENCIES})
+
+        dart_traverse_components("${output_variable}"
+          ${dart_${component}_DEPENDENCIES})
+
+        include("${target_include}")
+
+        # This is not necessary in recent versions of cmake, which supports
+        # transitive includes via INTERFACE_INCLUDE_DIRECTORIES.
+        foreach(dependency ${dart_${component}_DEPENDENCIES})
+          set_property(DIRECTORY APPEND
+            PROPERTY "DART_${component}_INCLUDE_DIRS"
+            ${dart_${dependency}_INCLUDE_DIRS})
+          set_property(DIRECTORY APPEND
+            PROPERTY "DART_${component}_DEFINITIONS"
+            ${dart_${dependency}_DEFINITIONS})
+          # LIBRARIES is automatically inherited via INTERFACE_LINK_LIBRARIES.
+        endforeach()
+
+        list(APPEND output_components "${component}")
+      else()
+        set_property(DIRECTORY PROPERTY "DART_${component}_FOUND" FALSE)
+      endif()
+    endif()
+  endforeach()
+
+  set("${output_variable}" ${output_components} PARENT_SCOPE)
+endfunction()
+
+#===============================================================================
+function(dart_export_variable variable)
+  set("${variable}" ${${variable}} CACHE INTERNAL "")
+endfunction()
+
+#===============================================================================
+function(dart_export_property variable)
+  get_property(value DIRECTORY PROPERTY "${variable}")
+  set("${variable}" ${value} CACHE INTERNAL "")
+endfunction()
+
+#===============================================================================
+function(dart_export_notfound variable)
+  set("${variable}" "${variable}-NOTFOUND" CACHE INTERNAL "")
+endfunction()
+
+#===============================================================================
+function(dart_package_init)
+  dart_traverse_components(required_components "${ARGN}")
+
+  set(DART_INCLUDE_DIRS)
+  set(DART_DEFINITIONS)
+  set(DART_LIBRARIES)
+
+  foreach(component ${ARGN})
+    dart_export_property("DART_${component}_FOUND")
+
+    if(DART_${component}_FOUND)
+      dart_export_property("DART_${component}_INCLUDE_DIRS")
+      dart_export_property("DART_${component}_DEFINITIONS")
+      dart_export_property("DART_${component}_LIBRARIES")
+      dart_export_property("DART_${component}_DEPENDENCIES")
+
+      list(APPEND DART_INCLUDE_DIRS ${DART_${component}_INCLUDE_DIRS})
+      list(APPEND DART_DEFINITIONS ${DART_${component}_DEFINITIONS})
+      list(APPEND DART_LIBRARIES ${DART_${component}_LIBRARIES})
+    else()
+      dart_export_notfound("DART_${component}_INCLUDE_DIRS")
+      dart_export_notfound("DART_${component}_DEFINITIONS")
+      dart_export_notfound("DART_${component}_LIBRARIES")
+      dart_export_notfound("DART_${component}_DEPENDENCIES")
+    endif()
+  endforeach()
+
+  dart_export_variable(DART_INCLUDE_DIRS)
+  dart_export_variable(DART_DEFINITIONS)
+  dart_export_variable(DART_LIBRARIES)
+endfunction()
+
+#===============================================================================
+# Main
+#===============================================================================
+
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
+
+# Default component: dart
+list(APPEND DART_FIND_COMPONENTS dart)
+
+# Components
+if(DART_FIND_COMPONENTS)
+  set_and_check(DART_PACKAGE_INCLUDE_DIRS "${PACKAGE_PREFIX_DIR}/include")
+  set(DART_INCLUDE_DIRS
+    ${DART_PACKAGE_INCLUDE_DIRS}
+    
+    CACHE INTERNAL "")
+
+  dart_package_init(${DART_FIND_COMPONENTS})
+endif()
+
+list(REMOVE_AT CMAKE_MODULE_PATH -1)
+
+# Use find_package_handle_standard_args to generate output. This handles the
+# REQUIRED keyword, sets DART_FOUND, and generates the appropriate
+# STATUS and FATAL_ERROR messages.
+include(FindPackageHandleStandardArgs)
+
+find_package_handle_standard_args(DART
+  FOUND_VAR DART_FOUND
+  REQUIRED_VARS DART_INCLUDE_DIRS DART_LIBRARIES
+  HANDLE_COMPONENTS)

share/dart/cmake/DARTConfigVersion.cmake

@@ -0,0 +1,65 @@
+# This is a basic version file for the Config-mode of find_package().
+# It is used by write_basic_package_version_file() as input file for configure_file()
+# to create a version-file which can be installed along a config.cmake file.
+#
+# The created file sets PACKAGE_VERSION_EXACT if the current version string and
+# the requested version string are exactly the same and it sets
+# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version,
+# but only if the requested major version is the same as the current one.
+# The variable CVF_VERSION must be set before calling configure_file().
+
+
+set(PACKAGE_VERSION "..")
+
+if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
+  set(PACKAGE_VERSION_COMPATIBLE FALSE)
+else()
+
+  if(".." MATCHES "^([0-9]+)\\.")
+    set(CVF_VERSION_MAJOR "${CMAKE_MATCH_1}")
+    if(NOT CVF_VERSION_MAJOR VERSION_EQUAL 0)
+      string(REGEX REPLACE "^0+" "" CVF_VERSION_MAJOR "${CVF_VERSION_MAJOR}")
+    endif()
+  else()
+    set(CVF_VERSION_MAJOR "..")
+  endif()
+
+  if(PACKAGE_FIND_VERSION_RANGE)
+    # both endpoints of the range must have the expected major version
+    math (EXPR CVF_VERSION_MAJOR_NEXT "${CVF_VERSION_MAJOR} + 1")
+    if (NOT PACKAGE_FIND_VERSION_MIN_MAJOR STREQUAL CVF_VERSION_MAJOR
+        OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND NOT PACKAGE_FIND_VERSION_MAX_MAJOR STREQUAL CVF_VERSION_MAJOR)
+          OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND NOT PACKAGE_FIND_VERSION_MAX VERSION_LESS_EQUAL CVF_VERSION_MAJOR_NEXT)))
+      set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    elseif(PACKAGE_FIND_VERSION_MIN_MAJOR STREQUAL CVF_VERSION_MAJOR
+        AND ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS_EQUAL PACKAGE_FIND_VERSION_MAX)
+        OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MAX)))
+      set(PACKAGE_VERSION_COMPATIBLE TRUE)
+    else()
+      set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    endif()
+  else()
+    if(PACKAGE_FIND_VERSION_MAJOR STREQUAL CVF_VERSION_MAJOR)
+      set(PACKAGE_VERSION_COMPATIBLE TRUE)
+    else()
+      set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    endif()
+
+    if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
+      set(PACKAGE_VERSION_EXACT TRUE)
+    endif()
+  endif()
+endif()
+
+
+# if the installed or the using project don't have CMAKE_SIZEOF_VOID_P set, ignore it:
+if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "" OR "8" STREQUAL "")
+  return()
+endif()
+
+# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
+if(NOT CMAKE_SIZEOF_VOID_P STREQUAL "8")
+  math(EXPR installedBits "8 * 8")
+  set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
+  set(PACKAGE_VERSION_UNSUITABLE TRUE)
+endif()

share/dart/cmake/DARTFindBullet.cmake

@@ -0,0 +1,96 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+# Bullet. Force MODULE mode to use the FindBullet.cmake file distributed with
+# CMake. Otherwise, we may end up using the BulletConfig.cmake file distributed
+# with Bullet, which uses relative paths and may break transitive dependencies.
+
+# On Windows/MSVC, we need to handle Debug/Release library configuration carefully
+# to avoid runtime library mismatches (MDd vs MD)
+if(MSVC)
+  # Store original CMAKE_CONFIGURATION_TYPES and CMAKE_BUILD_TYPE
+  set(_BULLET_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES ${CMAKE_FIND_LIBRARY_SUFFIXES})
+
+  # For multi-config generators (like Visual Studio), set library suffixes appropriately
+  # FindBullet.cmake looks for libraries with _Debug/_d suffix for debug builds
+  if(CMAKE_BUILD_TYPE MATCHES "Debug")
+    # Prefer Debug versions first, then fall back to Release
+    set(CMAKE_FIND_LIBRARY_SUFFIXES "_Debug.lib" "_d.lib" ".lib")
+  else()
+    # For Release, RelWithDebInfo, MinSizeRel
+    set(CMAKE_FIND_LIBRARY_SUFFIXES ".lib" "_Release.lib")
+  endif()
+endif()
+
+find_package(Bullet COMPONENTS BulletMath BulletCollision MODULE QUIET)
+
+# On Windows/MSVC, validate that library configuration matches build configuration
+if(MSVC AND BULLET_FOUND)
+  # Restore original suffixes first
+  if(DEFINED _BULLET_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES)
+    set(CMAKE_FIND_LIBRARY_SUFFIXES ${_BULLET_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES})
+    unset(_BULLET_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES)
+  endif()
+
+  # Check if we have a configuration mismatch
+  set(_BULLET_HAS_DEBUG_LIBS FALSE)
+  set(_BULLET_HAS_RELEASE_LIBS FALSE)
+  set(_BULLET_CONFIG_MISMATCH FALSE)
+
+  foreach(_bullet_lib ${BULLET_LIBRARIES})
+    if(_bullet_lib MATCHES ".*_d\\.lib$" OR _bullet_lib MATCHES ".*_Debug\\.lib$")
+      set(_BULLET_HAS_DEBUG_LIBS TRUE)
+    elseif(_bullet_lib MATCHES ".*\\.lib$")
+      set(_BULLET_HAS_RELEASE_LIBS TRUE)
+    endif()
+  endforeach()
+
+  # Check for mismatch and disable Bullet if found
+  if(CMAKE_BUILD_TYPE MATCHES "Debug" AND _BULLET_HAS_RELEASE_LIBS AND NOT _BULLET_HAS_DEBUG_LIBS)
+    set(_BULLET_CONFIG_MISMATCH TRUE)
+    message(WARNING
+      "Bullet libraries appear to be Release builds, but CMAKE_BUILD_TYPE is Debug. "
+      "This will cause LNK2038 runtime library mismatch errors on Windows/MSVC. "
+      "Disabling Bullet support to avoid link errors."
+      "\n"
+      "To enable Bullet support:"
+      "\n"
+      "  1. Build Bullet in Debug mode (with -DCMAKE_BUILD_TYPE=Debug)\n"
+      "  2. Or change DART build to Release mode: -DCMAKE_BUILD_TYPE=Release\n"
+      "  3. Or use RelWithDebInfo: -DCMAKE_BUILD_TYPE=RelWithDebInfo"
+    )
+    set(BULLET_FOUND FALSE)
+  elseif(NOT CMAKE_BUILD_TYPE MATCHES "Debug" AND _BULLET_HAS_DEBUG_LIBS AND NOT _BULLET_HAS_RELEASE_LIBS)
+    set(_BULLET_CONFIG_MISMATCH TRUE)
+    message(WARNING
+      "Bullet libraries appear to be Debug builds, but CMAKE_BUILD_TYPE is ${CMAKE_BUILD_TYPE}. "
+      "This will cause runtime library mismatch errors on Windows/MSVC. "
+      "Disabling Bullet support to avoid link errors."
+      "\n"
+      "To enable Bullet support:"
+      "\n"
+      "  1. Build Bullet in Release mode (with -DCMAKE_BUILD_TYPE=Release)\n"
+      "  2. Or change DART build to Debug mode: -DCMAKE_BUILD_TYPE=Debug"
+    )
+    set(BULLET_FOUND FALSE)
+  endif()
+
+  unset(_BULLET_HAS_DEBUG_LIBS)
+  unset(_BULLET_HAS_RELEASE_LIBS)
+  unset(_BULLET_CONFIG_MISMATCH)
+elseif(DEFINED _BULLET_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES)
+  # Restore original suffixes if not done above
+  set(CMAKE_FIND_LIBRARY_SUFFIXES ${_BULLET_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES})
+  unset(_BULLET_ORIG_CMAKE_FIND_LIBRARY_SUFFIXES)
+endif()
+
+if((BULLET_FOUND OR Bullet_FOUND) AND NOT TARGET Bullet)
+  add_library(Bullet INTERFACE IMPORTED)
+  target_include_directories(Bullet INTERFACE ${BULLET_INCLUDE_DIRS})
+  target_link_libraries(Bullet INTERFACE ${BULLET_LIBRARIES})
+endif()

share/dart/cmake/DARTFindEigen3.cmake

@@ -0,0 +1,9 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(Eigen3 3.4.0 REQUIRED CONFIG)

share/dart/cmake/DARTFindIPOPT.cmake

@@ -0,0 +1,20 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(IPOPT 3.11.9 QUIET MODULE)
+
+# HAVE_CSTDDEF is necessary to workaround this bug:
+# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=684062
+if(IPOPT_FOUND AND NOT TARGET IPOPT::ipopt)
+  add_library(IPOPT::ipopt INTERFACE IMPORTED)
+  set_target_properties(IPOPT::ipopt PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES "${IPOPT_INCLUDE_DIRS}"
+    INTERFACE_LINK_LIBRARIES "${IPOPT_LIBRARIES}"
+    INTERFACE_COMPILE_DEFINITIONS HAVE_CSTDDEF
+  )
+endif()

share/dart/cmake/DARTFindNLOPT.cmake

@@ -0,0 +1,17 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(NLOPT 2.4.1 QUIET MODULE)
+
+if(NLOPT_FOUND AND NOT TARGET NLOPT::nlopt)
+  add_library(NLOPT::nlopt INTERFACE IMPORTED)
+  set_target_properties(NLOPT::nlopt PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES "${NLOPT_INCLUDE_DIRS}"
+    INTERFACE_LINK_LIBRARIES "${NLOPT_LIBRARIES}"
+  )
+endif()

share/dart/cmake/DARTFindODE.cmake

@@ -0,0 +1,23 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(ODE QUIET CONFIG NAMES ODE ode)
+
+if(NOT ODE_FOUND AND NOT ode_FOUND)
+
+  find_package(ODE 0.16.2 QUIET MODULE)
+
+  if(ODE_FOUND AND NOT TARGET ODE::ODE)
+    add_library(ODE::ODE INTERFACE IMPORTED)
+    set_target_properties(ODE::ODE PROPERTIES
+      INTERFACE_INCLUDE_DIRECTORIES "${ODE_INCLUDE_DIRS}"
+      INTERFACE_LINK_LIBRARIES "${ODE_LIBRARIES}"
+    )
+  endif()
+
+endif()

share/dart/cmake/DARTFindOpenSceneGraph.cmake

@@ -0,0 +1,69 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(OpenSceneGraph 3.0.0 QUIET
+  COMPONENTS osg osgViewer osgManipulator osgGA osgDB osgShadow osgUtil
+)
+
+# OpenSceneGraph 3.6.5 or less are not compatible with macOS 10.15 (Catalina) or greater
+# See:
+#   - https://github.com/openscenegraph/OpenSceneGraph/issues/926
+#   - https://github.com/dartsim/dart/issues/1439
+if(APPLE)
+  if(OPENSCENEGRAPH_VERSION VERSION_LESS 3.7.0)
+    message(
+      WARNING
+      "OSG (${OPENSCENEGRAPH_VERSION} < 3.7.0) doesn't work on macOS 10.15 or greater. "
+      "See: https://github.com/openscenegraph/OpenSceneGraph/issues/926"
+    )
+  endif()
+endif()
+
+# It seems that OPENSCENEGRAPH_FOUND will inadvertently get set to true when
+# OpenThreads is found, even if OpenSceneGraph is not installed. This is quite
+# possibly a bug in OSG's cmake configuration file. For now, it seems that
+# requiring OSG_FOUND to be true as well fixes this.
+if(OPENSCENEGRAPH_FOUND AND OSG_FOUND)
+  if(DART_VERBOSE)
+    message(STATUS "Looking for OpenSceneGraph - ${OPENSCENEGRAPH_VERSION} found")
+  endif()
+else()
+  # dart-gui-osg requires both OSG and OpenThreads. This section attempts to
+  # identify which of those are missing from the building machine and offer
+  # advice to the user for getting dart-gui-osg to build.
+  find_package(OpenThreads QUIET)
+  if(OPENTHREADS_FOUND)
+    set(warning_msg "Could NOT find OpenSceneGraph")
+  else()
+    if(OSG_LIBRARY)
+      set(warning_msg "Could NOT find OpenThreads")
+    else()
+      set(warning_msg "Could NOT find OpenSceneGraph nor OpenThreads")
+    endif()
+  endif()
+  message(
+    STATUS
+    "${warning_msg} -- we will skip dart-gui-osg\n"
+    "If you believe you do have both OSG and OpenThreads installed, try setting OSG_DIR"
+  )
+  return()
+endif()
+
+# Define an imported target "osg::osg" if it's not defined in the provided find
+# module.
+#
+# This is required to make the DART module that uses OpenSceneGraph relocatable.
+# For that, any DART targets (e.g., dart-gui-osg) should use "osg::osg" instead
+# of OPENSCENEGRAPH_INCLUDE_DIRS and OPENSCENEGRAPH_LIBRARIES because the
+# variables contain absolute paths of OpenSceneGraph that could be different in
+# where the system that DART is built and where the system that consumes DART.
+if((OPENSCENEGRAPH_FOUND OR OpenSceneGraph_FOUND) AND NOT TARGET osg::osg)
+    add_library(osg::osg INTERFACE IMPORTED)
+    target_include_directories(osg::osg INTERFACE "${OPENSCENEGRAPH_INCLUDE_DIRS}")
+    target_link_libraries(osg::osg INTERFACE "${OPENSCENEGRAPH_LIBRARIES}")
+endif()

share/dart/cmake/DARTFindassimp.cmake

@@ -0,0 +1,18 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(assimp 5.2.0 REQUIRED MODULE)
+
+# Set target assimp if not set
+if((ASSIMP_FOUND OR assimp_FOUND) AND NOT TARGET assimp)
+  add_library(assimp INTERFACE IMPORTED)
+  set_target_properties(assimp PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES "${ASSIMP_INCLUDE_DIRS}"
+    INTERFACE_LINK_LIBRARIES "${ASSIMP_LIBRARIES}"
+  )
+endif()

share/dart/cmake/DARTFindfcl.cmake

@@ -0,0 +1,23 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(fcl 0.7.0 CONFIG)
+if(NOT FCL_FOUND AND NOT fcl_FOUND)
+  find_package(fcl 0.7.0 REQUIRED MODULE)
+endif()
+
+# Set target fcl if not set
+# Upstream provides the target since 0.5.0 but some package managers don't
+# install the config file, which defines the target.
+if((FCL_FOUND OR fcl_FOUND) AND NOT TARGET fcl)
+  add_library(fcl INTERFACE IMPORTED)
+  set_target_properties(fcl PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES "${FCL_INCLUDE_DIRS}"
+    INTERFACE_LINK_LIBRARIES "${FCL_LIBRARIES}"
+  )
+endif()

share/dart/cmake/DARTFindfmt.cmake

@@ -0,0 +1,9 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(fmt)

share/dart/cmake/DARTFindimgui.cmake

@@ -0,0 +1,21 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(imgui CONFIG)
+
+if(NOT imgui_FOUND)
+  find_package(imgui REQUIRED MODULE)
+endif()
+
+if(imgui_FOUND AND NOT TARGET imgui::imgui)
+  add_library(imgui::imgui INTERFACE IMPORTED)
+  set_target_properties(imgui::imgui PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES "${imgui_INCLUDE_DIRS}"
+    INTERFACE_LINK_LIBRARIES "${imgui_LIBRARIES}"
+  )
+endif()

share/dart/cmake/DARTFindoctomap.cmake

@@ -0,0 +1,17 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(octomap 1.9.7 QUIET CONFIG)
+
+if(octomap_FOUND AND NOT TARGET octomap)
+  add_library(octomap INTERFACE IMPORTED)
+  set_target_properties(octomap PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES "${OCTOMAP_INCLUDE_DIRS}"
+    INTERFACE_LINK_LIBRARIES "${OCTOMAP_LIBRARIES}"
+  )
+endif()

share/dart/cmake/DARTFindspdlog.cmake

@@ -0,0 +1,9 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(spdlog 1.9.2 QUIET CONFIG)

share/dart/cmake/DARTFindtinyxml2.cmake

@@ -0,0 +1,27 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(tinyxml2 QUIET CONFIG)
+if(tinyxml2_FOUND)
+  set(TINYXML2_FOUND        ${tinyxml2_FOUND})
+  set(TINYXML2_INCLUDE_DIRS ${tinyxml2_INCLUDE_DIRS})
+  set(TINYXML2_LIBRARIES    ${tinyxml2_LIBRARIES})
+  set(TINYXML2_VERSION      ${tinyxml2_VERSION})
+endif()
+
+if(NOT tinyxml2_FOUND)
+  find_package(tinyxml2 QUIET MODULE)
+endif()
+
+if((TINYXML2_FOUND OR tinyxml2_FOUND) AND NOT TARGET tinyxml2::tinyxml2)
+  add_library(tinyxml2::tinyxml2 INTERFACE IMPORTED)
+  set_target_properties(tinyxml2::tinyxml2 PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES "${TINYXML2_INCLUDE_DIRS}"
+    INTERFACE_LINK_LIBRARIES "${TINYXML2_LIBRARIES}"
+  )
+endif()

share/dart/cmake/DARTFindurdfdom.cmake

@@ -0,0 +1,29 @@
+# Copyright (c) 2011-2025, The DART development contributors
+# All rights reserved.
+#
+# The list of contributors can be found at:
+#   https://github.com/dartsim/dart/blob/main/LICENSE
+#
+# This file is provided under the "BSD-style" License
+
+find_package(urdfdom QUIET CONFIG)
+
+if(MSVC)
+  # Remove invalid path (i.e., /include) from urdfdom_INCLUDE_DIRS. This happens
+  # when it's installed by vcpkg on Windows. See:
+  # - https://github.com/dartsim/dart/issues/1365
+  # - https://github.com/ros/urdfdom/issues/140
+  if ("/include" IN_LIST urdfdom_INCLUDE_DIRS)
+    list(REMOVE_ITEM urdfdom_INCLUDE_DIRS "/include")
+    find_package(TinyXML REQUIRED MODULE)
+    list(APPEND urdfdom_INCLUDE_DIRS ${TinyXML_INCLUDE_DIRS})
+  endif()
+endif()
+
+if(urdfdom_FOUND AND NOT TARGET urdfdom)
+  add_library(urdfdom INTERFACE IMPORTED)
+  set_target_properties(urdfdom PROPERTIES
+    INTERFACE_INCLUDE_DIRECTORIES "${urdfdom_INCLUDE_DIRS}"
+    INTERFACE_LINK_LIBRARIES "${urdfdom_LIBRARIES}"
+  )
+endif()