oh-my-devpod 0.14.2

package/runtime/vendor/zsh/ohmyzsh/plugins/supervisor/_supervisorctl

@@ -0,0 +1,143 @@
+#compdef supervisorctl
+
+typeset -A opt_args
+local context state line
+
+_supervisorctl() {
+    _arguments -s -S \
+        {--configuration,-c}"[configuration file path (default /etc/supervisor.conf)]:FILENAME:_files" \
+        {--help,-h}"[print usage message and exit]:" \
+        {--interactive,-i}"[start an interactive shell after executing commands]" \
+        {--serverurl,-s}"[URL on which supervisord server is listening (default "http://localhost:9001").]" \
+        {--username,-u}"[username to use for authentication with server]:USERNAME:_users" \
+        {--password,-p}"[password to use for authentication with server]:PASSWORD:" \
+        {--history-file,-r}"[keep a readline history (if readline is available)]:FILENAME:_files" \
+        "*::supervisorctl commands:_supervisorctl_command"
+}
+
+(( $+functions[_supervisorctl_command] )) ||
+_supervisorctl_command() {
+    local cmd ret=1
+
+    (( $+supervisorctl_cmds )) || _supervisorctl_cmds=(
+        "add:Activates any updates in config for process/group" \
+        "avail:Display all configured processes" \
+        "clear:Clear process/multiple-process/all-process log files" \
+        "exit:Exit the supervisor shell." \
+        "fg:Connect to a process in foreground mode" \
+        "maintail:tail of supervisor main log file" \
+        "open:Connect to a remote supervisord process. (for UNIX domain socket, use unix:///socket/path)" \
+        "pid:Get the PID of supervisord." \
+        "quit:Exit the supervisor shell." \
+        "reload:Restart the remote supervisord." \
+        "remove:Removes process/group from active config" \
+        "reread:Reload the daemon's configuration files" \
+        "restart:Restart process or group." \
+        "shutdown:Shut the remote supervisord down." \
+        "start:Start process or groups." \
+        "status:Get process status info." \
+        "stop:Stop process or group." \
+        "tail:tail of process stdout" \
+        "update:Reload config and add/remove as necessary" \
+        "version:Show the version of the remote supervisord process" \
+        "help:Show help" \
+        )
+
+    if (( CURRENT == 1 )); then
+        _describe -t commands 'supervisorctl subcommand' _supervisorctl_cmds \
+            || compadd "$@" - ${(s.:.)${(j.:.)_supervisorctl_syns}}
+    else
+        local curcontext="$curcontext"
+
+        cmd="${${_supervisorctl_cmds[(r)$words[1]:*]%%:*}:-${(k)_supervisorctl_syns[(r)(*:|)$words[1](:*|)]}}"
+        if (( $#cmd )); then
+            curcontext="${curcontext%:*:*}:supervisorctl-${cmd}:"
+            _call_function ret _supervisorctl_$cmd || _message 'no more arguments'
+        else
+            _message "unknown supervisorctl command: $words[1]"
+        fi
+        return ret
+    fi
+}
+
+# get supervisor contoroll processes
+(( $+functions[_get_supervisor_procs] )) ||
+_get_supervisor_procs() {
+    local cache_policy
+    zstyle -s ":completion:${curcontext}:" cache-policy cache_policy
+    if [[ -z "$cache_policy" ]]; then
+        zstyle ":completion:${curcontext}:" cache-policy _supervisor_procs_caching_policy
+    fi
+
+    if ( [[ ${+_supervisor_procs} -eq 0 ]] || _cache_invalid supervisor_procs ) \
+        && ! _retrieve_cache supervisor_procs; then
+
+        _supervisor_procs=(${${(f)"$(supervisorctl status >/dev/null 2>&1 | awk -F' ' '{print $1}')"}})
+        _store_cache supervisor_procs _supervisor_procs
+    fi
+
+    local expl
+    _wanted supervisor_procs expl 'supervisor processes' compadd -a _supervisor_procs
+}
+
+_supervisor_procs_caching_policy() {
+    local -a oldp
+    oldp=( "$1"(Nmw+1) )
+    (( $#oldp ))
+}
+
+(( $+functions[_supervisorctl_add] )) ||
+_supervisorctl_add() {
+    _arguments -s \
+        "--help[use help system]" \
+        "*::supervisorctl commands:_supervisorctl"
+}
+
+(( $+functions[_supervisorctl_help] )) ||
+_supervisorctl_help() {
+    _arguments -s \
+        "*:supervisorctl commands:_supervisorctl"
+}
+
+(( $+functions[_supervisorctl_maintail] )) ||
+_supervisorctl_maintail() {
+    _arguments -s \
+        '-f[Continuous tail of supervisor main log file (Ctrl-C to exit)]'
+}
+
+(( $+functions[_supervisorctl_start] )) ||
+_supervisorctl_start() {
+    # TODO: add 'all'
+    _arguments -s \
+        '*::supervisor process:_get_supervisor_procs'
+}
+
+(( $+functions[_supervisorctl_restart] )) ||
+_supervisorctl_restart() {
+    # TODO: add 'all'
+    _arguments -s \
+        '*::supervisor process:_get_supervisor_procs'
+}
+
+(( $+functions[_supervisorctl_status] )) ||
+_supervisorctl_status() {
+    _arguments \
+        '*::supervisor process:_get_supervisor_procs'
+}
+
+(( $+functions[_supervisorctl_stop] )) ||
+_supervisorctl_stop() {
+    # TODO: add 'all'
+    _arguments -s \
+        '*::supervisor process:_get_supervisor_procs'
+}
+
+(( $+functions[_supervisorctl_tail] )) ||
+_supervisorctl_tail() {
+    # TODO: add 'stderr'
+    _arguments -s \
+        '-f[Continuous tail of named process stdout Ctrl-C to exit.]' \
+        '*::supervisor process:_get_supervisor_procs'
+}
+
+_supervisorctl "$@"

package/runtime/vendor/zsh/ohmyzsh/plugins/supervisor/_supervisord

@@ -0,0 +1,33 @@
+#compdef supervisord
+
+typeset -A opt_args
+local context state line
+
+_arguments \
+    {--configuration,-c}"[configuration file]:FILENAME:_files" \
+    {--nodaemon,-n}"[run in the foreground (same as 'nodaemon true' in config file)]" \
+    {--help,-h}"[print this usage message and exit]:" \
+    {--version,-v}"[print supervisord version number and exit]:" \
+    {--user,-u}"[run supervisord as this user]:USER:_users" \
+    {--umask,-m}"[use this umask for daemon subprocess (default is 022)]" \
+    {--directory,-d}"[directory to chdir to when daemonized]" \
+    {--logfile,-l}"[use FILENAME as logfile path]:FILENAME:_files" \
+    {--logfile_maxbytes,-y}"[use BYTES to limit the max size of logfile]" \
+    {--logfile_backups,-z}"[number of backups to keep when max bytes reached]" \
+    {--loglevel,-e}"[use LEVEL as log level (debug,info,warn,error,critical)]:level:->levels" \
+    {--pidfile,-j}"[write a pid file for the daemon process to FILENAME]:FILENAME:_files" \
+    {--identifier,-i}"[identifier used for this instance of supervisord]" \
+    {--childlogdir,-q}"[the log directory for child process logs]:child log directory:_files -/" \
+    {--nocleanup,-k}"[prevent the process from performing cleanup (removal of old automatic child log files) at startup.]" \
+    {--minfds,-a}"[the minimum number of file descriptors for start success]" \
+    {--strip_ansi,-t}"[strip ansi escape codes from process output]" \
+    "--minprocs[the minimum number of processes available for start success]" \
+    "--profile_options[run supervisord under profiler and output results based on OPTIONS, which is a comma-sep'd list of 'cumulative', 'calls', and/or 'callers', e.g. 'cumulative,callers')]" \
+    "*::args:_gnu_generic"
+
+case $state in
+levels)
+    levels=("debug" "info" "warn" "error" "critical")
+    _describe -t levels 'supervisord levels' levels && return 0
+    ;;
+esac

package/runtime/vendor/zsh/ohmyzsh/plugins/supervisor/supervisor.plugin.zsh

@@ -0,0 +1,14 @@
+# DECLARATION: This plugin was created by hhatto. What I did is just making a portal from https://bitbucket.org/hhatto/zshcompfunc4supervisor.
+
+alias sup='sudo supervisorctl'
+alias supad='sudo supervisorctl add'
+alias supa='sudo supervisorctl avail'
+alias suprl='sudo supervisorctl reload'
+alias suprm='sudo supervisorctl remove'
+alias suprr='sudo supervisorctl reread'
+alias suprs='sudo supervisorctl restart'
+alias sups='sudo supervisorctl status'
+alias supsr='sudo supervisorctl start'
+alias supso='sudo supervisorctl stop'
+alias supt='sudo supervisorctl tail'
+alias supu='sudo supervisorctl update'

package/runtime/vendor/zsh/ohmyzsh/plugins/suse/README.md

@@ -0,0 +1,98 @@
+# suse
+
+Aliases for [Zypper](https://en.opensuse.org/Portal:Zypper) according to the official Zypper's alias
+
+To use it add `suse` to the plugins array in you zshrc file.
+
+```zsh
+plugins=(... suse)
+```
+
+**Maintainer**: [r-darwish](https://github.com/r-darwish)
+
+## Main commands
+
+| Alias            | Commands                      | Description                                                    |
+| ---------------- | ----------------------------- | -------------------------------------------------------------- |
+| z                | `sudo zypper`                 | call zypper                                                    |
+| zh               | `zypper -h`                   | print help                                                     |
+| zhse             | `zypper -h se`                | print help for the search command                              |
+| zlicenses        | `zypper licenses`             | prints a report about licenses and EULAs of installed packages |
+| zps              | `sudo zypper ps`              | list process using deleted files                               |
+| zshell           | `sudo zypper shell`           | open a zypper shell session                                    |
+| zsource-download | `sudo zypper source-download` | download source rpms for all installed packages                |
+| ztos             | `zypper tos`                  | shows the ID string of the target operating system             |
+| zvcmp            | `zypper vcmp`                 | tell whether version1 is older or newer than version2          |
+
+## Packages commands
+
+| Alias | Commands          | Description                                                        |
+| ----- | ----------------- | ------------------------------------------------------------------ |
+| zin   | `sudo zypper in`  | install packages                                                   |
+| zinr  | `sudo zypper inr` | install newly added packages recommended by already installed ones |
+| zrm   | `sudo zypper rm`  | remove packages                                                    |
+| zsi   | `sudo zypper si`  | install source of a package                                        |
+| zve   | `sudo zypper ve`  | verify dependencies of installed packages                          |
+
+## Updates commands
+
+| Alias  | Commands            | Description            |
+| ------ | ------------------- | ---------------------- |
+| zdup   | `sudo zypper dup`   | upgrade packages       |
+| zlp    | `zypper lp`         | list necessary patches |
+| zlu    | `zypper lu`         | list updates           |
+| zpchk  | `sudo zypper pchk`  | check for patches      |
+| zup    | `sudo zypper up`    | update packages        |
+| zpatch | `sudo zypper patch` | install patches        |
+
+## Request commands
+
+| Alias         | Commands                   | Description                                          |
+| ------------- | -------------------------- | ---------------------------------------------------- |
+| zif           | `zypper if`                | display info about packages                          |
+| zpa           | `zypper pa`                | list packages                                        |
+| zpatch-info   | `zypper patch-info`        | display info about patches                           |
+| zpattern-info | `zypper pattern-info`      | display info about patterns                          |
+| zproduct-info | `zypper product-info`      | display info about products                          |
+| zpch          | `zypper pch`               | list all patches                                     |
+| zpd           | `zypper pd`                | list products                                        |
+| zpt           | `zypper pt`                | list patterns                                        |
+| zse           | `zypper se`                | search for packages                                  |
+| zwp           | `zypper wp`                | list all packages providing the specified capability |
+
+NOTE: `--no-refresh` is passed to zypper for speeding up the calls and avoid errors due to lack
+of root privileges. If you need to refresh the repositories, call `sudo zypper ref` (`zref` alias)
+before running these aliases.
+
+Related: [#9798](https://github.com/ohmyzsh/ohmyzsh/pull/9798).
+
+## Repositories commands
+
+| Alias | Commands            | Description                              |
+| ----- | ------------------- | ---------------------------------------- |
+| zar   | `sudo zypper ar`    | add a repository                         |
+| zcl   | `sudo zypper clean` | clean cache                              |
+| zlr   | `zypper lr`         | list repositories                        |
+| zmr   | `sudo zypper mr`    | modify repositories                      |
+| znr   | `sudo zypper nr`    | rename repositories (for the alias only) |
+| zref  | `sudo zypper ref`   | refresh repositories                     |
+| zrr   | `sudo zypper rr`    | remove repositories                      |
+
+## Services commands
+
+| Alias | Commands           | Description                                                    |
+| ----- | ------------------ | -------------------------------------------------------------- |
+| zas   | `sudo zypper as`   | adds a service specified by URI to the system                  |
+| zms   | `sudo zypper ms`   | modify properties of specified services                        |
+| zrefs | `sudo zypper refs` | refreshing a service mean executing the service's special task |
+| zrs   | `sudo zypper rs`   | remove specified repository index service from the system      |
+| zls   | `zypper ls`        | list services defined on the system                            |
+
+## Package Locks Management commands
+
+| Alias | Commands         | Description                         |
+| ----- | ---------------- | ----------------------------------- |
+| zal   | `sudo zypper al` | add a package lock                  |
+| zcl   | `sudo zypper cl` | remove unused locks                 |
+| zll   | `zypper ll`      | list currently active package locks |
+| zrl   | `sudo zypper rl` | remove specified package lock       |

package/runtime/vendor/zsh/ohmyzsh/plugins/suse/suse.plugin.zsh

@@ -0,0 +1,59 @@
+#Main commands
+alias z='sudo zypper'
+alias zh='zypper -h'
+alias zhse='zypper -h se'
+alias zlicenses='zypper licenses'
+alias zps='sudo zypper ps'
+alias zshell='sudo zypper shell'
+alias zsource-download='sudo zypper source-download'
+alias ztos='zypper tos'
+alias zvcmp='zypper vcmp'
+
+#Packages commands
+alias zin='sudo zypper in'
+alias zinr='sudo zypper inr'
+alias zrm='sudo zypper rm'
+alias zsi='sudo zypper si'
+alias zve='sudo zypper ve'
+
+#Updates commands
+alias zdup='sudo zypper dup'
+alias zlp='zypper lp'
+alias zlu='zypper lu'
+alias zpchk='sudo zypper pchk'
+alias zup='sudo zypper up'
+alias zpatch='sudo zypper patch'
+
+#Request commands
+alias zif='zypper --no-refresh if'
+alias zpa='zypper --no-refresh pa'
+alias zpatch-info='zypper --no-refresh patch-info'
+alias zpattern-info='zypper --no-refresh pattern-info'
+alias zproduct-info='zypper --no-refresh product-info'
+alias zpch='zypper --no-refresh pch'
+alias zpd='zypper --no-refresh pd'
+alias zpt='zypper --no-refresh pt'
+alias zse='zypper --no-refresh se'
+alias zwp='zypper --no-refresh wp'
+
+#Repositories commands
+alias zar='sudo zypper ar'
+alias zcl='sudo zypper clean'
+alias zlr='zypper lr'
+alias zmr='sudo zypper mr'
+alias znr='sudo zypper nr'
+alias zref='sudo zypper ref'
+alias zrr='sudo zypper rr'
+
+#Services commands
+alias zas='sudo zypper as'
+alias zms='sudo zypper ms'
+alias zrefs='sudo zypper refs'
+alias zrs='sudo zypper rs'
+alias zls='zypper ls'
+
+#Package Locks Management commands
+alias zal='sudo zypper al'
+alias zcl='sudo zypper cl'
+alias zll='zypper ll'
+alias zrl='sudo zypper rl'

package/runtime/vendor/zsh/ohmyzsh/plugins/svcat/README.md

@@ -0,0 +1,9 @@
+# svcat
+
+This plugin provides completion for the [Kubernetes service catalog cli](https://github.com/kubernetes-incubator/service-catalog).
+
+To use it, add `svcat` to the plugins array in your zshrc file.
+
+```
+plugins=(... svcat)
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/svcat/svcat.plugin.zsh

@@ -0,0 +1,6 @@
+# Autocompletion for svcat.
+#
+
+if [ $commands[svcat] ]; then
+  source <(svcat completion zsh)
+fi

package/runtime/vendor/zsh/ohmyzsh/plugins/svn/README.md

@@ -0,0 +1,67 @@
+# `svn` plugin
+
+This plugin adds some utility functions to display additional information regarding your current
+svn repository. See https://subversion.apache.org/ for the full svn documentation.
+
+To use it, add `svn` to your plugins array:
+
+```zsh
+plugins=(... svn)
+```
+
+## Functions
+
+| Command               | Description                                 |
+|:----------------------|:--------------------------------------------|
+| `svn_prompt_info`     | Shows svn prompt in themes                  |
+| `in_svn`              | Checks if we're in an svn repository        |
+| `svn_get_repo_name`   | Get repository name                         |
+| `svn_get_branch_name` | Get branch name (see [caveats](#caveats))   |
+| `svn_get_rev_nr`      | Get revision number                         |
+| `svn_dirty`           | Checks if there are changes in the svn repo |
+
+## Caveats
+
+The plugin expects the first directory to be the current branch / tag / trunk. So it returns
+the first path element if you don't use branches.
+
+## Usage on themes
+
+To use this in the `agnoster` theme follow these instructions:
+
+1. Enable the svn plugin
+
+2. Add the following lines to your `zshrc` file:
+
+    ```shell
+    prompt_svn() {
+        local rev branch
+        if in_svn; then
+            rev=$(svn_get_rev_nr)
+            branch=$(svn_get_branch_name)
+            if [[ $(svn_dirty_choose_pwd 1 0) -eq 1 ]]; then
+                prompt_segment yellow black
+                echo -n "$rev@$branch"
+                echo -n "±"
+            else
+                prompt_segment green black
+                echo -n "$rev@$branch"
+            fi
+        fi
+    }
+    ```
+
+3. Override the agnoster `build_prompt()` function:
+
+    ```zsh
+    build_prompt() {
+        RETVAL=$?
+        prompt_status
+        prompt_context
+        prompt_dir
+        prompt_git
+        prompt_svn
+        prompt_end
+    }
+    ```
+

package/runtime/vendor/zsh/ohmyzsh/plugins/svn/svn.plugin.zsh

@@ -0,0 +1,89 @@
+svn_prompt_info() {
+  local info display
+  info="$(LANG= svn info 2>/dev/null)" || return 1
+
+  if [[ "$SVN_SHOW_BRANCH" = true ]]; then
+    display="$(svn_get_branch_name "$info")"
+  else
+    display="$(svn_get_repo_name "$info")"
+  fi
+
+  printf '%s%s%s%s%s%s%s%s%s%s' \
+    "$ZSH_PROMPT_BASE_COLOR" \
+    "$ZSH_THEME_SVN_PROMPT_PREFIX" \
+    "$ZSH_THEME_REPO_NAME_COLOR" \
+    "${display:gs/%/%%}" \
+    "$ZSH_PROMPT_BASE_COLOR" \
+    "$ZSH_THEME_SVN_PROMPT_SUFFIX" \
+    "$ZSH_PROMPT_BASE_COLOR" \
+    "$(svn_dirty $info)" \
+    "$(svn_dirty_pwd)" \
+    "$ZSH_PROMPT_BASE_COLOR"
+}
+
+in_svn() {
+  svn info &>/dev/null
+}
+
+svn_get_repo_name() {
+  local info name
+  info="${1:-$(LANG= svn info 2>/dev/null)}"
+  name="$(sed -n 's/^Repository\ Root:\ .*\///p' <<< "$info")"
+  omz_urldecode "$name"
+}
+
+svn_get_branch_name() {
+  local info branch
+  info="${1:-$(LANG= svn info 2>/dev/null)}"
+  branch=$(
+    awk -F/ '/^URL:/ {
+      for (i=0; i<=NF; i++) {
+        if ($i == "branches" || $i == "tags" ) {
+          print $(i+1)
+          break
+        };
+        if ($i == "trunk") {
+          print $i
+          break
+        }
+      }
+    }' <<< "$info"
+  )
+  branch="$(omz_urldecode "$branch")"
+
+  echo "${branch:-$(svn_get_repo_name "$info")}"
+}
+
+svn_get_rev_nr() {
+  sed -n 's/Revision:\ //p' <<<"${1:-$(LANG= svn info 2>/dev/null)}"
+}
+
+svn_dirty() {
+  svn_dirty_choose "${1:-$(LANG= svn info 2>/dev/null)}" $ZSH_THEME_SVN_PROMPT_DIRTY $ZSH_THEME_SVN_PROMPT_CLEAN
+}
+
+svn_dirty_choose() {
+  local root
+  root=$(sed -n 's/^Working Copy Root Path: //p' <<< "${1:-$(LANG= svn info 2>/dev/null)}")
+  if LANG= svn status "$root" 2>/dev/null | command grep -Eq '^\s*[ACDIM!?L]'; then
+    # Grep exits with 0 when "One or more lines were selected", return "dirty".
+    echo $2
+  else
+    # Otherwise, no lines were found, or an error occurred. Return clean.
+    echo $3
+  fi
+}
+
+svn_dirty_pwd () {
+  svn_dirty_choose_pwd $ZSH_THEME_SVN_PROMPT_DIRTY_PWD $ZSH_THEME_SVN_PROMPT_CLEAN_PWD
+}
+
+svn_dirty_choose_pwd () {
+  if LANG= svn status "$PWD" 2>/dev/null | command grep -Eq '^\s*[ACDIM!?L]'; then
+    # Grep exits with 0 when "One or more lines were selected", return "dirty".
+    echo $1
+  else
+    # Otherwise, no lines were found, or an error occurred. Return clean.
+    echo $2
+  fi
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/svn-fast-info/README.md

@@ -0,0 +1,56 @@
+# svn-fast-info plugin
+
+Faster alternative to the main SVN plugin implementation. Works with svn 1.6 and newer.
+Use as a drop-in replacement to the svn plugin, not as complementary.
+
+To use it, add `svn-fast-info` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... svn-fast-info)
+```
+
+It's faster because it has an efficient use of svn (single svn call) which saves a lot on a huge codebase.
+It displays the current status of the local files (added, deleted, modified, replaced, or else...)
+
+Use `svn_prompt_info` method to display the svn repository status in your theme.
+
+## Functions
+
+- `svn_prompt_info`: displays all the available information regarding the status of the svn repository.
+
+- `svn_repo_need_upgrade`: shows whether the repository needs upgrading. `svn_prompt_info` queries the
+  rest of functions or not based on the result of this function.
+
+- `svn_current_branch_name`: shows the current branch.
+
+- `svn_repo_root_name`: displays the repository root.
+
+- `svn_current_revision`: shows the currently checked-out revision.
+
+- `svn_status_info`: shows a bunch of symbols depending on the status of the files in the repository.
+
+## Options
+
+- `ZSH_THEME_SVN_PROMPT_PREFIX`: sequence displayed at the beginning of the prompt info output.
+
+- `ZSH_THEME_SVN_PROMPT_SUFFIX`: sequence displayed at the end of the prompt info output.
+
+- `ZSH_THEME_SVN_PROMPT_CLEAN`: sequence displayed when the status of the repository is clean.
+
+- `ZSH_THEME_SVN_PROMPT_ADDITIONS`: sequence displayed if there are added files in the repository.
+  **Default:** `+`.
+
+- `ZSH_THEME_SVN_PROMPT_DELETIONS`: sequence displayed if there are deleted files in the repository.
+  **Default:** `✖`.
+
+- `ZSH_THEME_SVN_PROMPT_MODIFICATIONS`: sequence displayed if there are modified files in the repository.
+  **Default:** `✎`.
+
+- `ZSH_THEME_SVN_PROMPT_REPLACEMENTS`: sequence displayed if there are replaced files in the repository.
+  **Default:** `∿`.
+
+- `ZSH_THEME_SVN_PROMPT_UNTRACKED`: sequence displayed if there are untracked files in the repository.
+  **Default:** `?`.
+
+- `ZSH_THEME_SVN_PROMPT_DIRTY`: sequence displayed if the repository is dirty.
+  **Default:** `!`.

package/runtime/vendor/zsh/ohmyzsh/plugins/svn-fast-info/svn-fast-info.plugin.zsh

@@ -0,0 +1,74 @@
+function svn_prompt_info() {
+  local info
+  info=$(LANG= svn info 2>&1) || return 1 # capture stdout and stderr
+  local repo_need_upgrade=$(svn_repo_need_upgrade $info)
+
+  if [[ -n $repo_need_upgrade ]]; then
+    printf '%s%s%s%s%s%s%s\n' \
+      "$ZSH_PROMPT_BASE_COLOR" \
+      "$ZSH_THEME_SVN_PROMPT_PREFIX" \
+      "$ZSH_PROMPT_BASE_COLOR" \
+      "$repo_need_upgrade" \
+      "$ZSH_PROMPT_BASE_COLOR" \
+      "$ZSH_THEME_SVN_PROMPT_SUFFIX" \
+      "$ZSH_PROMPT_BASE_COLOR"
+  else
+    printf '%s%s%s%s %s%s%s:%s%s%s%s' \
+      "$ZSH_PROMPT_BASE_COLOR" \
+      "$ZSH_THEME_SVN_PROMPT_PREFIX" \
+      "$(svn_status_info $info)" \
+      "$ZSH_PROMPT_BASE_COLOR" \
+      \
+      "$ZSH_THEME_BRANCH_NAME_COLOR" \
+      "${$(svn_current_branch_name $info):gs/%/%%}" \
+      "$ZSH_PROMPT_BASE_COLOR" \
+      \
+      "$(svn_current_revision $info)" \
+      "$ZSH_PROMPT_BASE_COLOR" \
+      "$ZSH_THEME_SVN_PROMPT_SUFFIX" \
+      "$ZSH_PROMPT_BASE_COLOR"
+  fi
+}
+
+function svn_repo_need_upgrade() {
+  command grep -q "E155036" <<< "${1:-$(LANG= svn info 2>/dev/null)}" && \
+    echo "E155036: upgrade repo with svn upgrade"
+}
+
+function svn_current_branch_name() {
+  omz_urldecode "$(
+    command grep '^URL:' <<< "${1:-$(svn info 2>/dev/null)}" | command grep -Eo '(tags|branches)/[^/]+|trunk'
+  )"
+}
+
+function svn_repo_root_name() {
+  command grep '^Repository\ Root:' <<< "${1:-$(LANG= svn info 2>/dev/null)}" | sed 's#.*/##'
+}
+
+function svn_current_revision() {
+  echo "${1:-$(LANG= svn info 2>/dev/null)}" | sed -n 's/Revision: //p'
+}
+
+function svn_status_info() {
+  local svn_status_string="$ZSH_THEME_SVN_PROMPT_CLEAN"
+  local svn_status="$(svn status 2>/dev/null)";
+  if command grep -E '^\s*A' &>/dev/null <<< "$svn_status"; then
+    svn_status_string+="${ZSH_THEME_SVN_PROMPT_ADDITIONS:-+}"
+  fi
+  if command grep -E '^\s*D' &>/dev/null <<< "$svn_status"; then
+    svn_status_string+="${ZSH_THEME_SVN_PROMPT_DELETIONS:-✖}"
+  fi
+  if command grep -E '^\s*M' &>/dev/null <<< "$svn_status"; then
+    svn_status_string+="${ZSH_THEME_SVN_PROMPT_MODIFICATIONS:-✎}"
+  fi
+  if command grep -E '^\s*[R~]' &>/dev/null <<< "$svn_status"; then
+    svn_status_string+="${ZSH_THEME_SVN_PROMPT_REPLACEMENTS:-∿}"
+  fi
+  if command grep -E '^\s*\?' &>/dev/null <<< "$svn_status"; then
+    svn_status_string+="${ZSH_THEME_SVN_PROMPT_UNTRACKED:-?}"
+  fi
+  if command grep -E '^\s*[CI!L]' &>/dev/null <<< "$svn_status"; then
+    svn_status_string+="${ZSH_THEME_SVN_PROMPT_DIRTY:-!}"
+  fi
+  echo $svn_status_string
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/swiftpm/README.md

@@ -0,0 +1,20 @@
+# Swift Package Manager
+
+This plugin provides a few utilities that make you faster on your daily work with the [Swift Package Manager](https://github.com/apple/swift-package-manager), as well as autocompletion for Swift 5.9.
+
+To start using it, add the `swiftpm` plugin to your `plugins` array in `~/.zshrc`:
+
+```zsh
+plugins=(... swiftpm)
+```
+
+## Aliases
+
+| Alias | Description                         | Command                            |
+|-------|-------------------------------------|------------------------------------|
+| `spi` | Initialize a new package            | `swift package init`               |
+| `spf` | Fetch package dependencies          | `swift package fetch`              |
+| `spu` | Update package dependencies         | `swift package update`             |
+| `spx` | Generates an Xcode project          | `swift package generate-xcodeproj` |
+| `sps` | Print the resolved dependency graph | `swift package show-dependencies`  |
+| `spd` | Print parsed Package.swift as JSON  | `swift package dump-package`       |