oh-my-devpod 0.14.2

package/runtime/vendor/zsh/ohmyzsh/plugins/codeclimate/_codeclimate

@@ -0,0 +1,82 @@
+#compdef codeclimate
+
+_codeclimate_all_engines() {
+  engines_all=(`codeclimate engines:list | tail -n +2 | gawk '{ print $2 }' | gawk -F: '{ print $1 }'`)
+}
+
+_codeclimate_installed_engines() {
+  _codeclimate_all_engines
+
+  engines_installed=()
+
+  if [ -e .codeclimate.yml ]
+  then
+    for engine in $engines_all
+    do
+      if grep -q $engine ".codeclimate.yml"
+      then
+        engines_installed+=$engine
+      fi
+    done
+  fi
+}
+
+_codeclimate_not_installed_engines() {
+  _codeclimate_all_engines
+
+  engines_not_installed=()
+
+  if [ -e .codeclimate.yml ]
+  then
+    for engine in $engines_all
+    do
+      if ! grep -q $engine ".codeclimate.yml"
+      then
+        engines_not_installed+=$engine
+      fi
+    done
+  fi
+}
+
+local curcontext="$curcontext" state line ret=1
+local expl
+local -a engines_all engines_installed engines_not_installed
+
+_arguments \
+  '1: :->cmds' \
+  '*:: :->args' && ret=0
+
+case $state in
+  cmds)
+    _values "bundle command" \
+      "analyze[Analyze all relevant files in the current working directory]" \
+      "console[Start an interactive session providing access to the classes within the CLI]" \
+      "engines\:disable[Prevents the engine from being used in this project]" \
+      "engines\:enable[This engine will be run the next time your project is analyzed]" \
+      "engines\:install[Compares the list of engines in your .codeclimate.yml file to those that are currently installed, then installs any missing engines]" \
+      "engines\:list[Lists all available engines in the Code Climate Docker Hub]" \
+      "engines\:remove[Removes an engine from your .codeclimate.yml file]" \
+      "help[Displays a list of commands that can be passed to the Code Climate CLI]" \
+      "init[Generates a new .codeclimate.yml file in the current working directory]" \
+      "validate-config[Validates the .codeclimate.yml file in the current working directory]" \
+      "version[Displays the current version of the Code Climate CLI]"
+    ret=0
+    ;;
+  args)
+    case $line[1] in
+      engines:enable)
+        _codeclimate_not_installed_engines
+        _wanted engines_not_installed expl 'not installed engines' compadd -a engines_not_installed ;;
+      engines:disable|engines:remove)
+        _codeclimate_installed_engines
+        _wanted engines_installed expl 'installed engines' compadd -a engines_installed ;;
+      analyze)
+        _arguments \
+          '-f:Output Format:(text json)'
+        ret=0
+        ;;
+    esac
+    ;;
+esac
+
+return ret

package/runtime/vendor/zsh/ohmyzsh/plugins/coffee/README.md

@@ -0,0 +1,31 @@
+# Coffeescript Plugin
+
+This plugin provides aliases for quickly compiling and previewing your
+coffeescript code.
+
+When writing Coffeescript it's very common to want to preview the output of a
+certain snippet of code, either because you want to test the output or because
+you'd like to execute it in a browser console which doesn't accept Coffeescript.
+
+Preview the compiled result of your coffeescript with `cf "code"` as per the
+following:
+
+```zsh
+$ cf 'if a then b else c'
+if (a) {
+  b;
+} else {
+  c;
+}
+```
+
+Also provides the following aliases:
+
+* **cfc:** Copies the compiled JS to your clipboard. Very useful when you want
+           to run the code in a JS console.
+
+* **cfp:** Compiles from your currently copied clipboard. Useful when you want
+           to compile large/multi-line snippets
+
+* **cfpc:** Paste coffeescript from clipboard, compile to JS, then copy the
+            the result back to clipboard.

package/runtime/vendor/zsh/ohmyzsh/plugins/coffee/_coffee

@@ -0,0 +1,81 @@
+#compdef coffee
+# ------------------------------------------------------------------------------
+# Copyright (c) 2011 GitHub zsh-users - https://github.com/zsh-users
+# All rights reserved.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions are met:
+#     * Redistributions of source code must retain the above copyright
+#       notice, this list of conditions and the following disclaimer.
+#     * Redistributions in binary form must reproduce the above copyright
+#       notice, this list of conditions and the following disclaimer in the
+#       documentation and/or other materials provided with the distribution.
+#     * Neither the name of the zsh-users nor the
+#       names of its contributors may be used to endorse or promote products
+#       derived from this software without specific prior written permission.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
+# ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
+# WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
+# DISCLAIMED. IN NO EVENT SHALL ZSH-USERS BE LIABLE FOR ANY
+# DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
+# (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
+# LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
+# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
+# SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+# ------------------------------------------------------------------------------
+# Description
+# -----------
+#
+#  Completion script for Coffee.js v0.6.11 (https://coffeescript.org)
+#
+# ------------------------------------------------------------------------------
+# Authors
+# -------
+#
+#  * Mario Fernandez (https://github.com/sirech)
+#  * Dong Weiming (https://github.com/dongweiming)
+#
+# ------------------------------------------------------------------------------
+
+local curcontext="$curcontext" state line ret=1 version
+local -a opts
+typeset -A opt_args
+version=(${(f)"$(_call_program version $words[1] --version)"}) || return ret
+version=${${(z)${version[1]}}[3]}
+
+autoload -Uz is-at-least
+if ! is-at-least 1.6.3 "$version"; then
+  opts+=('(-l --lint)'{-l,--lint}'[pipe the compiled JavaScript through JavaScript Lint]'
+         '(-r --require)'{-r,--require}'[require a library before executing your script]:library')
+fi
+
+
+_arguments -C \
+  '(- *)'{-h,--help}'[display this help message]' \
+  '(- *)'{-v,--version}'[display the version number]' \
+  $opts \
+  '(-b --bare)'{-b,--bare}'[compile without a top-level function wrapper]' \
+  '(-e --eval)'{-e,--eval}'[pass a string from the command line as input]:Inline Script' \
+  '(-i --interactive)'{-i,--interactive}'[run an interactive CoffeeScript REPL]' \
+  '(-j --join)'{-j,--join}'[concatenate the source CoffeeScript before compiling]:Destination JS file:_files -g "*.js"' \
+  '(--nodejs)--nodejs[pass options directly to the "node" binary]' \
+  '(-c --compile)'{-c,--compile}'[compile to JavaScript and save as .js files]' \
+  '(-o --output)'{-o,--output}'[set the output directory for compiled JavaScript]:Output Directory:_files -/' \
+  '(-n -t -p)'{-n,--nodes}'[print out the parse tree that the parser produces]' \
+  '(-n -t -p)'{-p,--print}'[print out the compiled JavaScript]' \
+  '(-n -t -p)'{-t,--tokens}'[print out the tokens that the lexer/rewriter produce]' \
+  '(-s --stdio)'{-s,--stdio}'[listen for and compile scripts over stdio]' \
+  '(-w --watch)'{-w,--watch}'[watch scripts for changes and rerun commands]' \
+  '*:script or directory:_files' && ret=0
+
+return ret
+
+# Local Variables:
+# mode: Shell-Script
+# sh-indentation: 2
+# indent-tabs-mode: nil
+# sh-basic-offset: 2
+# End:
+# vim: ft=zsh sw=2 ts=2 et

package/runtime/vendor/zsh/ohmyzsh/plugins/coffee/coffee.plugin.zsh

@@ -0,0 +1,16 @@
+#!/bin/zsh
+
+# compile a string of coffeescript and print to output
+cf () {
+  coffee -peb "$1"
+}
+# compile & copy to clipboard
+cfc () {
+  cf "$1" | clipcopy
+}
+
+# compile from clipboard & print
+alias cfp='cf "$(clippaste)"'
+
+# compile from clipboard and copy to clipboard
+alias cfpc='cfp | clipcopy'

package/runtime/vendor/zsh/ohmyzsh/plugins/colemak/README.md

@@ -0,0 +1,48 @@
+# Colemak plugin
+
+This plugin remaps keys in `zsh`'s [`vi`-style navigation mode](http://zsh.sourceforge.net/Doc/Release/Zsh-Line-Editor.html#Keymaps)
+for a [Colemak](https://colemak.com/) keyboard layout, to match the QWERTY position:
+
+![Colemak layout on a US keyboard](https://colemak.com/wiki/images/6/6c/Colemak2.png)
+
+To use it, add it to the plugins array in your `~/.zshrc` file:
+
+```
+plugins=(... colemak)
+```
+
+You will also need to enable `vi` mode, so add another line to `~/.zshrc`:
+```
+bindkey -v
+```
+
+Restart your shell and hit the `<ESC>` key to activate `vicmd` (navigation) mode,
+and start navigating `zsh` with your new keybindings!
+
+## Key bindings for vicmd
+
+| Old        | New        | Binding                   | Description                                        |
+|------------|------------|---------------------------|----------------------------------------------------|
+| `CTRL`+`j` | `CTRL`+`n` | accept-line               | Insert new line                                    |
+| `j`        | `n`        | down-line-or-history      | Move one line down or command history forwards     |
+| `k`        | `e`        | up-line-or-history        | Move one line up or command history backwards      |
+| `l`        | `i`        | vi-forward-char           | Move one character to the right                    |
+| `n`        | `k`        | vi-repeat-search          | Repeat command search forwards                     |
+| `N`        | `K`        | vi-rev-repeat-search      | Repeat command search backwards                    |
+| `i`        | `u`        | vi-insert                 | Enter insert mode                                  |
+| `I`        | `U`        | vi-insert-bol             | Move to first non-blank char and enter insert mode |
+| `<none>`   | `l`        | vi-undo-change            | Undo change                                        |
+| `J`        | `N`        | vi-join                   | Join the current line with the next one            |
+| `e`        | `j`        | vi-forward-word-end       | Move to the end of the next word                   |
+| `E`        | `J`        | vi-forward-blank-word-end | Move to end of the current or next word            |
+
+## Key bindings for less
+
+| Keyboard shortcut | `less` key binding |
+|-------------------|--------------------|
+| `n`               | forw-line          |
+| `e`               | back-line          |
+| `k`               | repeat-search      |
+| `ESC`+`k`         | repeat-search-all  |
+| `K`               | reverse-search     |
+| `ESC`+`K`         | reverse-search-all |

package/runtime/vendor/zsh/ohmyzsh/plugins/colemak/colemak-less

@@ -0,0 +1,6 @@
+n    forw-line
+e    back-line
+k    repeat-search
+\ek  repeat-search-all
+K    reverse-search
+\eK  reverse-search-all

package/runtime/vendor/zsh/ohmyzsh/plugins/colemak/colemak.plugin.zsh

@@ -0,0 +1,38 @@
+# ctrl-j newline
+bindkey '^n' accept-line
+bindkey -a '^n' accept-line
+
+# another rotation to match qwerty
+bindkey -a 'n' down-line-or-history
+bindkey -a 'e' up-line-or-history
+bindkey -a 'i' vi-forward-char
+
+# make qwerty
+bindkey -a 'k' vi-repeat-search
+bindkey -a 'K' vi-rev-repeat-search
+bindkey -a 'u' vi-insert
+bindkey -a 'U' vi-insert-bol
+bindkey -a 'l' vi-undo-change
+bindkey -a 'N' vi-join
+
+# spare
+bindkey -a 'j' vi-forward-word-end
+bindkey -a 'J' vi-forward-blank-word-end
+
+# Handle $0 according to the standard:
+# https://zdharma-continuum.github.io/Zsh-100-Commits-Club/Zsh-Plugin-Standard.html
+0="${${ZERO:-${0:#$ZSH_ARGZERO}}:-${(%):-%N}}"
+0="${${(M)0:#/*}:-$PWD/$0}"
+
+# New less versions will read this file directly
+export LESSKEYIN="${0:h:A}/colemak-less"
+
+# Only run lesskey if less version is older than v582
+less_ver=$(less --version | awk '{print $2;exit}')
+autoload -Uz is-at-least
+if ! is-at-least 582 $less_ver; then
+  # Old less versions will read this transformed file
+  export LESSKEY="${0:h:A}/.less"
+  lesskey -o "$LESSKEY" "$LESSKEYIN" 2>/dev/null
+fi
+unset less_ver

package/runtime/vendor/zsh/ohmyzsh/plugins/colored-man-pages/README.md

@@ -0,0 +1,32 @@
+# Colored man pages plugin
+
+This plugin adds colors to man pages.
+
+To use it, add `colored-man-pages` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... colored-man-pages)
+```
+
+It will also automatically colorize man pages displayed by `dman` or `debman`,
+from [`debian-goodies`](https://packages.debian.org/stable/debian-goodies).
+
+You can also try to color other pages by prefixing the respective command with `colored`:
+
+```zsh
+colored git help clone
+```
+
+## Customization
+
+The plugin declares global associative array `less_termcap`, which maps termcap capabilities to escape
+sequences for the `less` pager. This mapping can be further customized by the user after the plugin is
+loaded. Check out sources for more.
+
+For example: `less_termcap[md]` maps to `LESS_TERMCAP_md` which is the escape sequence that tells `less`
+how to print something in bold. It's currently shown in bold red, but if you want to change it, you
+can redefine `less_termcap[md]` in your zshrc file, after OMZ is sourced:
+
+```zsh
+less_termcap[md]="${fg_bold[blue]}" # this tells less to print bold text in bold blue
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/colored-man-pages/colored-man-pages.plugin.zsh

@@ -0,0 +1,54 @@
+# Requires colors autoload.
+# See termcap(5).
+
+# Set up once, and then reuse. This way it supports user overrides after the
+# plugin is loaded.
+typeset -AHg less_termcap
+
+# bold & blinking mode
+less_termcap[mb]="${fg_bold[red]}"
+less_termcap[md]="${fg_bold[red]}"
+less_termcap[me]="${reset_color}"
+# standout mode
+less_termcap[so]="${fg_bold[yellow]}${bg[blue]}"
+less_termcap[se]="${reset_color}"
+# underlining
+less_termcap[us]="${fg_bold[green]}"
+less_termcap[ue]="${reset_color}"
+
+# Handle $0 according to the standard:
+# https://zdharma-continuum.github.io/Zsh-100-Commits-Club/Zsh-Plugin-Standard.html
+0="${${ZERO:-${0:#$ZSH_ARGZERO}}:-${(%):-%N}}"
+0="${${(M)0:#/*}:-$PWD/$0}"
+
+# Absolute path to this file's directory.
+typeset -g __colored_man_pages_dir="${0:A:h}"
+
+function colored() {
+  local -a environment
+
+  # Convert associative array to plain array of NAME=VALUE items.
+  local k v
+  for k v in "${(@kv)less_termcap}"; do
+    environment+=( "LESS_TERMCAP_${k}=${v}" )
+  done
+
+  # Prefer `less` whenever available, since we specifically configured
+  # environment for it.
+  environment+=( PAGER="${commands[less]:-$PAGER}" )
+  environment+=( GROFF_NO_SGR=1 )
+
+  # See ./nroff script.
+  if [[ "$OSTYPE" = solaris* ]]; then
+    environment+=( PATH="${__colored_man_pages_dir}:$PATH" )
+  fi
+
+  command env "${environment[@]}" "$@"
+}
+
+# Colorize man and dman/debman (from debian-goodies)
+function man \
+  dman \
+  debman {
+  colored $0 "$@"
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/colored-man-pages/nroff

@@ -0,0 +1,12 @@
+#!/bin/sh
+
+# The whole point of this wrapper is to replace emboldening factor -u0 with
+# -u1 under certain circumstances on Solaris.
+
+if [ "$1,$2,$3" = "-u0,-Tlp,-man" ]; then
+  shift
+  exec /usr/bin/nroff -u1 "$@"
+else
+  # Some other invocation of nroff
+  exec /usr/bin/nroff "$@"
+fi

package/runtime/vendor/zsh/ohmyzsh/plugins/colorize/README.md

@@ -0,0 +1,56 @@
+# colorize
+
+With this plugin you can syntax-highlight file contents of over 300 supported languages and other text formats.
+
+Colorize will highlight the content based on the filename extension. If it can't find a syntax-highlighting
+method for a given extension, it will try to find one by looking at the file contents. If no highlight method
+is found it will just cat the file normally, without syntax highlighting.
+
+## Setup
+
+To use it, add colorize to the plugins array of your `~/.zshrc` file:
+```
+plugins=(... colorize)
+```
+
+## Configuration
+
+### Requirements
+
+This plugin requires that at least one of the following tools is installed:
+
+* [Chroma](https://github.com/alecthomas/chroma)
+* [Pygments](https://pygments.org/download/)
+
+### Colorize tool
+
+Colorize supports `pygmentize` and `chroma` as syntax highlighter. By default colorize uses `pygmentize` unless it's not installed and `chroma` is. This can be overridden by the `ZSH_COLORIZE_TOOL` environment variable:
+
+```
+ZSH_COLORIZE_TOOL=chroma
+```
+
+### Styles
+
+Pygments offers multiple styles. By default, the `default` style is used, but you can choose another theme by setting the `ZSH_COLORIZE_STYLE` environment variable:
+
+```
+ZSH_COLORIZE_STYLE="colorful"
+```
+
+### Chroma Formatter Settings
+
+Chroma supports terminal output in 8 color, 256 color, and true-color. If you need to change the default terminal output style from the standard 8 color output, set the `ZSH_COLORIZE_CHROMA_FORMATTER` environment variable:
+
+```
+ZSH_COLORIZE_CHROMA_FORMATTER=terminal256
+```
+
+## Usage
+
+* `ccat <file> [files]`: colorize the contents of the file (or files, if more than one are provided).
+  If no files are passed it will colorize the standard input.
+
+* `cless [less-options] <file> [files]`: colorize the contents of the file (or files, if more than one are provided) and open less.
+  If no files are passed it will colorize the standard input.
+  The LESSOPEN and LESSCLOSE will be overwritten for this to work, but only in a local scope.

package/runtime/vendor/zsh/ohmyzsh/plugins/colorize/colorize.plugin.zsh

@@ -0,0 +1,114 @@
+# Easier alias to use the plugin
+alias ccat="colorize_cat"
+alias cless="colorize_less"
+
+# '$0:A' gets the absolute path of this file
+ZSH_COLORIZE_PLUGIN_PATH=$0:A
+
+colorize_check_requirements() {
+    local -a available_tools
+    available_tools=("chroma" "pygmentize")
+
+    if [ -z "$ZSH_COLORIZE_TOOL" ]; then
+        if (( $+commands[pygmentize] )); then
+            ZSH_COLORIZE_TOOL="pygmentize"
+        elif (( $+commands[chroma] )); then
+            ZSH_COLORIZE_TOOL="chroma"
+        else
+            echo "Neither 'pygments' nor 'chroma' is installed!" >&2
+            return 1
+        fi
+    fi
+
+    if [[ ${available_tools[(Ie)$ZSH_COLORIZE_TOOL]} -eq 0 ]]; then
+        echo "ZSH_COLORIZE_TOOL '$ZSH_COLORIZE_TOOL' not recognized. Available options are 'pygmentize' and 'chroma'." >&2
+        return 1
+    elif ! (( $+commands[$ZSH_COLORIZE_TOOL] )); then
+        echo "Package '$ZSH_COLORIZE_TOOL' is not installed!" >&2
+        return 1
+    fi
+}
+
+colorize_cat() {
+    if ! colorize_check_requirements; then
+        return 1
+    fi
+
+    # If the environment variable ZSH_COLORIZE_STYLE
+    # is set, use that theme instead. Otherwise,
+    # use the default.
+    if [ -z "$ZSH_COLORIZE_STYLE" ]; then
+        # Both pygmentize & chroma support 'emacs'
+        ZSH_COLORIZE_STYLE="emacs"
+    fi
+
+    # Use stdin if stdin is not attached to a terminal.
+    if [ ! -t 0 ]; then
+        if [[ "$ZSH_COLORIZE_TOOL" == "pygmentize" ]]; then
+            pygmentize -O style="$ZSH_COLORIZE_STYLE" -g
+        else
+            chroma --style="$ZSH_COLORIZE_STYLE" --formatter="${ZSH_COLORIZE_CHROMA_FORMATTER:-terminal}" "$@"
+        fi
+        return $?
+    fi
+
+    # Guess lexer from file extension, or guess it from file contents if unsuccessful.
+    local FNAME lexer
+    for FNAME in "$@"; do
+        if [[ "$ZSH_COLORIZE_TOOL" == "pygmentize" ]]; then
+            lexer=$(pygmentize -N "$FNAME")
+            if [[ $lexer != text ]]; then
+                pygmentize -O style="$ZSH_COLORIZE_STYLE" -l "$lexer" "$FNAME"
+            else
+                pygmentize -O style="$ZSH_COLORIZE_STYLE" -g "$FNAME"
+            fi
+        else
+            chroma --style="$ZSH_COLORIZE_STYLE" --formatter="${ZSH_COLORIZE_CHROMA_FORMATTER:-terminal}" "$FNAME"
+        fi
+    done
+}
+
+# The less option 'F - Forward forever; like "tail -f".' will not work in this implementation
+# caused by the lack of the ability to follow the file within pygmentize.
+colorize_less() {
+    if ! colorize_check_requirements; then
+        return 1
+    fi
+
+    _cless() {
+        # LESS="-R $LESS" enables raw ANSI colors, while maintain already set options.
+        local LESS="-R $LESS"
+
+        # This variable tells less to pipe every file through the specified command
+        # (see the man page of less INPUT PREPROCESSOR).
+        # 'zsh -ic "colorize_cat %s 2> /dev/null"' would not work for huge files like
+        # the ~/.zsh_history. For such files the tty of the preprocessor will be suspended.
+        # Therefore we must source this file to make colorize_cat available in the
+        # preprocessor without the interactive mode.
+        # `2>/dev/null` will suppress the error for large files 'broken pipe' of the python
+        # script pygmentize, which will show up if less has not fully "loaded the file"
+        # (e.g. when not scrolled to the bottom) while already the next file will be displayed.
+        local LESSOPEN="| zsh -c 'source \"$ZSH_COLORIZE_PLUGIN_PATH\"; \
+        ZSH_COLORIZE_TOOL=$ZSH_COLORIZE_TOOL ZSH_COLORIZE_STYLE=$ZSH_COLORIZE_STYLE \
+        colorize_cat %s 2> /dev/null'"
+
+        # LESSCLOSE will be set to prevent any errors by executing a user script
+        # which assumes that his LESSOPEN has been executed.
+        local LESSCLOSE=""
+
+        LESS="$LESS" LESSOPEN="$LESSOPEN" LESSCLOSE="$LESSCLOSE" command less "$@"
+    }
+
+    if [ -t 0 ]; then
+        _cless "$@"
+    else
+        # The input is not associated with a terminal, therefore colorize_cat will
+        # colorize this input and pass it to less.
+        # Less has now to decide what to use. If any files have been provided, less
+        # will ignore the input by default, otherwise the colorized input will be used.
+        # If files have been supplied and the input has been redirected, this will
+        # lead to unnecessary overhead, but retains the ability to use the less options
+        # without checking for them inside this script.
+        colorize_cat | _cless "$@"
+    fi
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/command-not-found/README.md

@@ -0,0 +1,36 @@
+# command-not-found plugin
+
+This plugin uses the command-not-found package for zsh to provide suggested packages to be installed if a command cannot be found.
+
+To use it, add `command-not-found` to the plugins array of your zshrc file:
+
+```zsh
+plugins=(... command-not-found)
+```
+
+An example of how this plugin works in Ubuntu:
+```
+$ mutt
+The program 'mutt' can be found in the following packages:
+ * mutt
+ * mutt-kz
+ * mutt-patched
+Try: sudo apt install <selected package>
+```
+
+### Supported platforms
+
+It works out of the box with the command-not-found packages for:
+
+- [Ubuntu](https://launchpad.net/ubuntu/+source/command-not-found)
+- [Debian](https://packages.debian.org/search?keywords=command-not-found)
+- [Arch Linux](https://wiki.archlinux.org/title/Zsh#pkgfile_"command_not_found"_handler)
+- [macOS (Homebrew)](https://github.com/Homebrew/brew/blob/main/docs/Command-Not-Found.md)
+- [Fedora](https://fedoraproject.org/wiki/Features/PackageKitCommandNotFound)
+- [NixOS](https://github.com/NixOS/nixpkgs/tree/master/nixos/modules/programs/command-not-found)
+- [Termux](https://github.com/termux/command-not-found)
+- [SUSE](https://www.unix.com/man-page/suse/1/command-not-found/)
+- [Gentoo](https://github.com/AndrewAmmerlaan/command-not-found-gentoo/tree/main)
+- [Void Linux](https://codeberg.org/classabbyamp/xbps-command-not-found)
+
+You can add support for other platforms by submitting a Pull Request.