oh-my-devpod 0.14.2

package/runtime/vendor/zsh/ohmyzsh/plugins/extract/README.md

@@ -0,0 +1,69 @@
+# extract plugin
+
+This plugin defines a function called `extract` that extracts the archive file you pass it, and it supports a
+wide variety of archive filetypes.
+
+This way you don't have to know what specific command extracts a file, you just do `extract <filename>` and
+the function takes care of the rest.
+
+To use it, add `extract` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... extract)
+```
+
+## Supported file extensions
+
+| Extension         | Description                             |
+| :---------------- | :-------------------------------------- |
+| `7z`              | 7zip file                               |
+| `apk`             | Android app file                        |
+| `aar`             | Android library file                    |
+| `bz2`             | Bzip2 file                              |
+| `cab`             | Microsoft cabinet archive               |
+| `cpio`            | Cpio archive                            |
+| `deb`             | Debian package                          |
+| `ear`             | Enterprise Application aRchive          |
+| `exe`             | Windows executable file                 |
+| `gz`              | Gzip file                               |
+| `ipa`             | iOS app package                         |
+| `ipsw`            | iOS firmware file                       |
+| `jar`             | Java Archive                            |
+| `lrz`             | LRZ archive                             |
+| `lz4`             | LZ4 archive                             |
+| `lzma`            | LZMA archive                            |
+| `obscpio`         | cpio archive used on OBS                |
+| `pk3`             | Renamed Zip archive used by Quake games |
+| `pk4`             | Renamed Zip archive used by Quake games |
+| `pk7`             | Renamed 7zip file used by Quake games   |
+| `rar`             | WinRAR archive                          |
+| `rpm`             | RPM package                             |
+| `sublime-package` | Sublime Text package                    |
+| `tar`             | Tarball                                 |
+| `tar.bz2`         | Tarball with bzip2 compression          |
+| `tar.gz`          | Tarball with gzip compression           |
+| `tar.lrz`         | Tarball with lrzip compression          |
+| `tar.lz`          | Tarball with lzip compression           |
+| `tar.lz4`         | Tarball with lz4 compression            |
+| `tar.xz`          | Tarball with lzma2 compression          |
+| `tar.zma`         | Tarball with lzma compression           |
+| `tar.zst`         | Tarball with zstd compression           |
+| `tbz`             | Tarball with bzip compression           |
+| `tbz2`            | Tarball with bzip2 compression          |
+| `tgz`             | Tarball with gzip compression           |
+| `tlz`             | Tarball with lzma compression           |
+| `txz`             | Tarball with lzma2 compression          |
+| `tzst`            | Tarball with zstd compression           |
+| `vsix`            | VS Code extension zip file              |
+| `war`             | Web Application archive (Java-based)    |
+| `whl`             | Python wheel file                       |
+| `xpi`             | Mozilla XPI module file                 |
+| `xz`              | LZMA2 archive                           |
+| `Z`               | Z archive (LZW)                         |
+| `zip`             | Zip archive                             |
+| `zlib`            | zlib archive                            |
+| `zst`             | Zstandard file (zstd)                   |
+| `zpaq`            | Zpaq file                               |
+
+See [list of archive formats](https://en.wikipedia.org/wiki/List_of_archive_formats) for more information
+regarding archive formats.

package/runtime/vendor/zsh/ohmyzsh/plugins/extract/_extract

@@ -0,0 +1,57 @@
+#compdef extract
+#autoload
+
+local -a exts=(
+  7z
+  aar
+  apk
+  bz2
+  cab
+  cpio
+  crx
+  deb
+  ear
+  gz
+  ipa
+  ipsw
+  jar
+  lrz
+  lz4
+  lzma
+  obscpio
+  pk3
+  pk4
+  pk7
+  rar
+  rpm
+  sublime-package
+  tar
+  tar.bz2
+  tar.gz
+  tar.lrz
+  tar.lz
+  tar.lz4
+  tar.xz
+  tar.zma
+  tar.zst
+  tbz
+  tbz2
+  tgz
+  tlz
+  txz
+  tzst
+  vsix
+  war
+  whl
+  xpi
+  xz
+  Z
+  zip
+  zpaq
+  zst
+)
+
+_arguments \
+  '(-r --remove)'{-r,--remove}'[Remove archive.]' \
+  "*::archive file:_files -g '(#i)*.(${(j:|:)exts})(-.)'" \
+    && return 0

package/runtime/vendor/zsh/ohmyzsh/plugins/extract/extract.plugin.zsh

@@ -0,0 +1,145 @@
+alias x=extract
+
+extract() {
+  setopt localoptions noautopushd
+
+  if (( $# == 0 )); then
+    cat >&2 <<'EOF'
+Usage: extract [-option] [file ...]
+
+Options:
+    -r, --remove    Remove archive after unpacking.
+EOF
+  fi
+
+  local remove_archive=1
+  if [[ "$1" == "-r" ]] || [[ "$1" == "--remove" ]]; then
+    remove_archive=0
+    shift
+  fi
+
+  local pwd="$PWD"
+  while (( $# > 0 )); do
+    if [[ ! -f "$1" ]]; then
+      echo "extract: '$1' is not a valid file" >&2
+      shift
+      continue
+    fi
+
+    local success=0
+    local file="$1" full_path="${1:A}"
+    local extract_dir="${1:t:r}"
+
+    # Remove the .tar extension if the file name is .tar.*
+    if [[ $extract_dir =~ '\.tar$' ]]; then
+      extract_dir="${extract_dir:r}"
+    fi
+
+    # If there's a file or directory with the same name as the archive
+    # add a random string to the end of the extract directory
+    if [[ -e "$extract_dir" ]]; then
+      local rnd="${(L)"${$(( [##36]$RANDOM*$RANDOM ))}":1:5}"
+      extract_dir="${extract_dir}-${rnd}"
+    fi
+
+    # Create an extraction directory based on the file name
+    command mkdir -p "$extract_dir"
+    builtin cd -q "$extract_dir"
+    echo "extract: extracting to $extract_dir" >&2
+
+    case "${file:l}" in
+      (*.tar.gz|*.tgz)
+        (( $+commands[pigz] )) && { tar -I pigz -xvf "$full_path" } || tar zxvf "$full_path" ;;
+      (*.tar.bz2|*.tbz|*.tbz2)
+        (( $+commands[pbzip2] )) && { tar -I pbzip2 -xvf "$full_path" } || tar xvjf "$full_path" ;;
+      (*.tar.xz|*.txz)
+        (( $+commands[pixz] )) && { tar -I pixz -xvf "$full_path" } || {
+        tar --xz --help &> /dev/null \
+        && tar --xz -xvf "$full_path" \
+        || xzcat "$full_path" | tar xvf - } ;;
+      (*.tar.zma|*.tlz)
+        tar --lzma --help &> /dev/null \
+        && tar --lzma -xvf "$full_path" \
+        || lzcat "$full_path" | tar xvf - ;;
+      (*.tar.zst|*.tzst)
+        tar --zstd --help &> /dev/null \
+        && tar --zstd -xvf "$full_path" \
+        || zstdcat "$full_path" | tar xvf - ;;
+      (*.tar) tar xvf "$full_path" ;;
+      (*.tar.lz) (( $+commands[lzip] )) && tar xvf "$full_path" ;;
+      (*.tar.lz4) lz4 -c -d "$full_path" | tar xvf - ;;
+      (*.tar.lrz) (( $+commands[lrzuntar] )) && lrzuntar "$full_path" ;;
+      (*.gz) (( $+commands[pigz] )) && pigz -cdk "$full_path" > "${file:t:r}" || gunzip -ck "$full_path" > "${file:t:r}" ;;
+      (*.bz2) (( $+commands[pbzip2] )) && pbzip2 -d "$full_path" || bunzip2 "$full_path" ;;
+      (*.xz) unxz "$full_path" ;;
+      (*.lrz) (( $+commands[lrunzip] )) && lrunzip "$full_path" ;;
+      (*.lz4) lz4 -d "$full_path" ;;
+      (*.lzma) unlzma "$full_path" ;;
+      (*.z) uncompress "$full_path" ;;
+      (*.zip|*.war|*.jar|*.ear|*.sublime-package|*.ipa|*.ipsw|*.xpi|*.apk|*.aar|*.whl|*.vsix|*.crx|*.pk3|*.pk4) unzip "$full_path" ;;
+      (*.rar)
+        if (( $+commands[unrar] )); then
+          unrar x -ad "$full_path"
+        elif (( $+commands[unar] )); then
+          unar -o . "$full_path"
+        else
+          echo "extract: cannot extract RAR files: install unrar or unar" >&2
+          success=1
+        fi ;;
+      (*.rpm)
+        rpm2cpio "$full_path" | cpio --quiet -id ;;
+      (*.7z | *.7z.[0-9]* | *.pk7) 7za x "$full_path" ;;
+      (*.deb)
+        command mkdir -p "control" "data"
+        ar vx "$full_path" > /dev/null
+        builtin cd -q control; extract ../control.tar.*
+        builtin cd -q ../data; extract ../data.tar.*
+        builtin cd -q ..; command rm *.tar.* debian-binary ;;
+      (*.zst) unzstd --stdout "$full_path" > "${file:t:r}" ;;
+      (*.cab|*.exe) cabextract "$full_path" ;;
+      (*.cpio|*.obscpio) cpio -idmvF "$full_path" ;;
+      (*.zpaq) zpaq x "$full_path" ;;
+      (*.zlib) zlib-flate -uncompress < "$full_path" > "${file:r}" ;;
+      (*)
+        echo "extract: '$file' cannot be extracted" >&2
+        success=1 ;;
+    esac
+
+    (( success = success > 0 ? success : $? ))
+    (( success == 0 && remove_archive == 0 )) && command rm "$full_path"
+    shift
+
+    # Go back to original working directory
+    builtin cd -q "$pwd"
+
+    # If content of extract dir is a single directory, move its contents up
+    # Glob flags:
+    # - D: include files starting with .
+    # - N: no error if directory is empty
+    # - Y2: at most give 2 files
+    local -a content
+    content=("${extract_dir}"/*(DNY2))
+    if [[ ${#content} -eq 1 && -e "${content[1]}" ]]; then
+      # The extracted file/folder (${content[1]}) may have the same name as $extract_dir
+      # If so, we need to rename it to avoid conflicts in a 3-step process
+      #
+      # 1. Move and rename the extracted file/folder to a temporary random name
+      # 2. Delete the empty folder
+      # 3. Rename the extracted file/folder to the original name
+      if [[ "${content[1]:t}" == "$extract_dir" ]]; then
+        # =(:) gives /tmp/zsh<random>, with :t it gives zsh<random>
+        local tmp_name==(:); tmp_name="${tmp_name:t}"
+        command mv "${content[1]}" "$tmp_name" \
+        && command rmdir "$extract_dir" \
+        && command mv "$tmp_name" "$extract_dir"
+      # Otherwise, if the extracted folder name already exists in the current
+      # directory (because of a previous file / folder), keep the extract_dir
+      elif [[ ! -e "${content[1]:t}" ]]; then
+        command mv "${content[1]}" . \
+        && command rmdir "$extract_dir"
+      fi
+    elif [[ ${#content} -eq 0 ]]; then
+      command rmdir "$extract_dir"
+    fi
+  done
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/eza/README.md

@@ -0,0 +1,144 @@
+# eza plugin
+
+This provides aliases that invoke the [`eza`](https://github.com/eza-community/eza) utility rather than `ls`
+
+To use it add `eza` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... eza)
+```
+
+## Configuration
+
+All configurations are done using the `zstyle` command in the `:omz:plugins:eza` namespace.
+
+**NOTE:** The configuring needs to be done prior to OMZ loading the plugins. When the plugin is loaded,
+changing the `zstyle` won't have any effect.
+
+### `dirs-first`
+
+```zsh
+zstyle ':omz:plugins:eza' 'dirs-first' yes|no
+```
+
+If `yes`, directories will be grouped first.
+
+Default: `no`
+
+### `git-status`
+
+```zsh
+zstyle ':omz:plugins:eza' 'git-status' yes|no
+```
+
+If `yes`, always add `--git` flag to indicate git status (if tracked / in a git repo).
+
+Default: `no`
+
+### `header`
+
+```zsh
+zstyle ':omz:plugins:eza' 'header' yes|no
+```
+
+If `yes`, always add `-h` flag to add a header row for each column.
+
+Default: `no`
+
+### `show-group`
+
+```zsh
+zstyle ':omz:plugins:eza' 'show-group' yes|no
+```
+
+If `yes` (default), always add `-g` flag to show the group ownership.
+
+Default: `yes`
+
+### `icons`
+
+```zsh
+zstyle ':omz:plugins:eza' 'icons' yes|no
+```
+
+If `yes`, sets the `--icons` option of `eza`, adding icons for files and folders.
+
+Default: `no`
+
+### `color-scale`
+
+```zsh
+zstyle ':omz:plugins:eza' 'color-scale' all|age|size
+```
+
+Highlight levels of field(s) distinctly. Use comma(,) separated list of `all`, `age`, `size`
+
+Default: `none`
+
+### `color-scale-mode`
+
+```zsh
+zstyle ':omz:plugins:eza' 'color-scale-mode' gradient|fixed
+```
+
+Choose the mode for highlighting:
+
+- `gradient` (default) -- gradient coloring
+- `fixed` -- fixed coloring
+
+Default: `gradient`
+
+### `size-prefix`
+
+```zsh
+zstyle ':omz:plugins:eza' 'size-prefix' (binary|none|si)
+```
+
+Choose the prefix to be used in displaying file size:
+
+- `binary` -- use [binary prefixes](https://en.wikipedia.org/wiki/Binary_prefix) such as "Ki", "Mi", "Gi" and
+  so on
+- `none` -- don't use any prefix, show size in bytes
+- `si` (default) -- use [Metric/S.I. prefixes](https://en.wikipedia.org/wiki/Metric_prefix)
+
+Default: `si`
+
+### `time-style`
+
+```zsh
+zstyle ':omz:plugins:eza' 'time-style' $TIME_STYLE
+```
+
+Sets the `--time-style` option of `eza`. (See `man eza` for the options)
+
+Default: Not set, which means the default behavior of `eza` will take place.
+
+### `hyperlink`
+
+```zsh
+zstyle ':omz:plugins:eza' 'hyperlink' yes|no
+```
+
+If `yes`, always add `--hyperlink` flag to create hyperlink with escape codes.
+
+Default: `no`
+
+## Aliases
+
+**Notes:**
+
+- Aliases may be modified by Configuration
+- The term "files" without "only" qualifier means both files & directories
+
+| Alias  | Command           | Description                                                                |
+| ------ | ----------------- | -------------------------------------------------------------------------- |
+| `la`   | `eza -la`         | List all files (except . and ..) as a long list                            |
+| `ldot` | `eza -ld .*`      | List dotfiles only (directories shown as entries instead of recursed into) |
+| `lD`   | `eza -lD`         | List only directories (excluding dotdirs) as a long list                   |
+| `lDD`  | `eza -laD`        | List only directories (including dotdirs) as a long list                   |
+| `ll`   | `eza -l`          | List files as a long list                                                  |
+| `ls`   | `eza`             | Plain eza call                                                             |
+| `lsd`  | `eza -d`          | List specified files with directories as entries, in a grid                |
+| `lsdl` | `eza -dl`         | List specified files with directories as entries, in a long list           |
+| `lS`   | `eza -l -ssize`   | List files as a long list, sorted by size                                  |
+| `lT`   | `eza -l -snewest` | List files as a long list, sorted by date (newest last)                    |

package/runtime/vendor/zsh/ohmyzsh/plugins/eza/eza.plugin.zsh

@@ -0,0 +1,76 @@
+if ! (( $+commands[eza] )); then
+  print "zsh eza plugin: eza not found. Please install eza before using this plugin." >&2
+  return 1
+fi
+
+typeset -a _EZA_HEAD
+typeset -a _EZA_TAIL
+
+function _configure_eza() {
+  local _val
+  # Get the head flags
+  if zstyle -T ':omz:plugins:eza' 'show-group'; then
+    _EZA_HEAD+=("g")
+  fi
+  if zstyle -t ':omz:plugins:eza' 'header'; then
+    _EZA_HEAD+=("h")
+  fi
+  zstyle -s ':omz:plugins:eza' 'size-prefix' _val
+  case "${_val:l}" in
+    binary)
+      _EZA_HEAD+=("b")
+      ;;
+    none)
+      _EZA_HEAD+=("B")
+      ;;
+  esac
+  # Get the tail long-options
+  if zstyle -t ':omz:plugins:eza' 'dirs-first'; then
+    _EZA_TAIL+=("--group-directories-first")
+  fi
+  if zstyle -t ':omz:plugins:eza' 'git-status'; then
+    _EZA_TAIL+=("--git")
+  fi
+  if zstyle -t ':omz:plugins:eza' 'icons'; then
+    _EZA_TAIL+=("--icons=auto")
+  fi
+  zstyle -s ':omz:plugins:eza' 'color-scale' _val
+  if [[ $_val ]]; then
+    _EZA_TAIL+=("--color-scale=$_val")
+  fi
+  zstyle -s ':omz:plugins:eza' 'color-scale-mode' _val
+  if [[ $_val == (gradient|fixed) ]]; then
+    _EZA_TAIL+=("--color-scale-mode=$_val")
+  fi
+  zstyle -s ':omz:plugins:eza' 'time-style' _val
+  if [[ $_val ]]; then
+    _EZA_TAIL+=("--time-style='$_val'")
+  fi
+  if zstyle -t ":omz:plugins:eza" "hyperlink"; then
+    _EZA_TAIL+=("--hyperlink")
+  fi
+}
+
+_configure_eza
+
+function _alias_eza() {
+  local _head="${(j::)_EZA_HEAD}$2"
+  local _tail="${(j: :)_EZA_TAIL}"
+  alias "$1"="eza${_head:+ -}${_head}${_tail:+ }${_tail}${3:+ }$3"
+}
+
+_alias_eza la   la
+_alias_eza ldot ld ".*"
+_alias_eza lD   lD
+_alias_eza lDD  lDa
+_alias_eza ll   l
+_alias_eza ls
+_alias_eza lsd  d
+_alias_eza lsdl dl
+_alias_eza lS   "l -ssize"
+_alias_eza lT   "l -snewest"
+
+unfunction _alias_eza
+unfunction _configure_eza
+unset _EZA_HEAD
+unset _EZA_TAIL

package/runtime/vendor/zsh/ohmyzsh/plugins/fabric/README.md

@@ -0,0 +1,9 @@
+# Fabric
+
+This plugin provides completion for [Fabric](https://www.fabfile.org/).
+
+To use it add fabric to the plugins array in your zshrc file.
+
+```zsh
+plugins=(... fabric)
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/fabric/_fab

@@ -0,0 +1,69 @@
+#compdef fab
+#autoload
+
+local curcontext=$curcontext state line
+declare -A opt_args
+
+declare -a target_list
+target_list=("${(@f)$(fab -l 2>/dev/null | awk '{
+    if (NF == 0 || NR == 1) next
+    if (NF < 2) print $1
+    else {
+        docstring=substr($0, index($0,$2))
+        gsub(":", "\\:", docstring)
+        print $1":"docstring
+    }
+}')}")
+
+_fab_targets() {
+    [[ -n "$target_list" ]] || return
+    _describe -t commands "fabric targets" target_list
+}
+
+output_levels=(
+    'status: Status messages, i.e. noting when Fabric is done running, if the user used a keyboard interrupt, or when servers are disconnected from. These messages are almost always relevant and rarely verbose.'
+    'aborts: Abort messages. Like status messages, these should really only be turned off when using Fabric as a library, and possibly not even then. Note that even if this output group is turned off, aborts will still occur – there just won’t be any output about why Fabric aborted!'
+    'warnings: Warning messages. These are often turned off when one expects a given operation to fail, such as when using grep to test existence of text in a file. If paired with setting env.warn_only to True, this can result in fully silent warnings when remote programs fail. As with aborts, this setting does not control actual warning behavior, only whether warning messages are printed or hidden.'
+    'running: Printouts of commands being executed or files transferred, e.g. [myserver] run: ls /var/www. Also controls printing of tasks being run, e.g. [myserver] Executing task ''foo''.'
+    'stdout: Local, or remote, stdout, i.e. non-error output from commands.'
+    'stderr: Local, or remote, stderr, i.e. error-related output from commands.'
+    'user: User-generated output, i.e. local output printed by fabfile code via use of the fastprint or puts functions.'
+)
+
+_arguments -w -S -C \
+  '(-)'{-h,--help}'[show this help message and exit]: :->noargs' \
+  '(-)'{-V,--version}'[show program''s version number and exit]: :->noargs' \
+  '(-)--list[print list of possible commands and exit]: :->noargs' \
+  '(-)--shortlist[print non-verbose list of possible commands and exit]: :->noargs' \
+  '(--reject-unknown-hosts)--reject-unknown-hosts[reject unknown hosts]' \
+  '(--no-pty)--no-pty[do not use pseudo-terminal in run/sudo]' \
+  "(-d+ --display=-)"{-d+,--display=-}"[print detailed info about a given command]: :_fab_targets" \
+  '(-D --disable-known-hosts)'{-D,--disable-known-hosts}'[do not load user known_hosts file]' \
+  '(-r --reject-unknown-hosts)'{-r,--reject-unknown-hosts}'[reject unknown hosts]' \
+  '(-u+ --user=-)'{-u+,--user=-}'[username to use when connecting to remote hosts]: :' \
+  '(-p+ --password=-)'{-p+,--password=-}'[password for use with authentication and/or sudo]: :' \
+  '(-H+ --hosts=-)'{-H+,--hosts=-}'[comma separated list of hosts to operate on]: :' \
+  '(-R+ --roles=-)'{-R+,--roles=-}'[comma separated list of roles to operate on]: :' \
+  '(-a --no-agent)'{-a,--no-agent}'[don''t use the running SSH agent]' \
+  '(-k --no-keys)'{-k,--no-keys}'[don''t load private key files from ~/.ssh/]' \
+  '(-w --warn-only)'{-w,--warn-only}'[warn instead of abort, when commands fail]' \
+  '-i+[path to SSH private key file. May be repeated]: :_files' \
+  "(-f+ --fabfile=)"{-f+,--fabfile=}"[Python module file to import]: :_files -g *.py" \
+  '(-c+ --config=-)'{-c+,--config=-}'[specify location of config file to use]: :_files' \
+  '(-s+ --shell=-)'{-s+,--shell=-}'[specify a new shell, defaults to ''/bin/bash -l -c'']: :' \
+  '(--hide=-)--hide=-[comma-separated list of output levels to hide]: :->levels' \
+  '(--show=-)--show=-[comma-separated list of output levels to show]: :->levels' \
+  '*::: :->subcmds' && return 0
+
+if [[ CURRENT -ge 1 ]]; then
+    case $state in
+        noargs)
+             _message "nothing to complete";;
+        levels)
+            _describe -t commands "output levels" output_levels;;
+        *)
+            _fab_targets;;
+    esac
+
+    return
+fi

package/runtime/vendor/zsh/ohmyzsh/plugins/fancy-ctrl-z/README.md

@@ -0,0 +1,24 @@
+# fancy-ctrl-z
+
+Allows pressing Ctrl-Z again to switch back to a background job.
+
+To use it, add `fancy-ctrl-z` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... fancy-ctrl-z)
+```
+
+## Motivation
+
+I frequently need to execute random commands in my shell. To achieve it I pause
+Vim by pressing Ctrl-z, type command and press fg<Enter> to switch back to Vim.
+The fg part really hurts me. I just wanted to hit Ctrl-z once again to get back
+to Vim. I could not find a solution, so I developed one on my own that
+works wonderfully with ZSH.
+
+Source: http://sheerun.net/2014/03/21/how-to-boost-your-vim-productivity/
+
+Credits:
+- original idea by @sheerun
+- added to OMZ by @mbologna
+

package/runtime/vendor/zsh/ohmyzsh/plugins/fancy-ctrl-z/fancy-ctrl-z.plugin.zsh

@@ -0,0 +1,12 @@
+fancy-ctrl-z () {
+  if [[ $#BUFFER -eq 0 ]]; then
+    BUFFER="fg"
+    zle accept-line -w
+  else
+    zle push-input -w
+    zle clear-screen -w
+  fi
+}
+zle -N fancy-ctrl-z
+bindkey '^Z' fancy-ctrl-z
+

package/runtime/vendor/zsh/ohmyzsh/plugins/fasd/README.md

@@ -0,0 +1,21 @@
+# fasd
+
+[`Fasd`](https://github.com/clvv/fasd) (pronounced similar to "fast") is a command-line productivity booster. Fasd offers quick access to files and directories for POSIX shells.
+
+To use it, add `fasd` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... fasd)
+```
+
+## Installation
+
+Please find detailed installation guide [`here`](https://github.com/whjvenyl/fasd#install)
+
+## Aliases
+
+| Alias | Command                                   | Description                                                 |
+|-------|-------------------------------------------|-------------------------------------------------------------|
+| v     | `fasd -f -e "$EDITOR"`                    | List frequent/recent files matching the given filename.     |
+| o     | `fasd -a -e xdg-open`                     | List frequent/recent files and directories matching.        |
+| j     | `fasd_cd -d -i`                           | cd with interactive selection                               |

package/runtime/vendor/zsh/ohmyzsh/plugins/fasd/fasd.plugin.zsh

@@ -0,0 +1,16 @@
+# check if fasd is installed
+if (( ! ${+commands[fasd]} )); then
+  return
+fi
+
+fasd_cache="${ZSH_CACHE_DIR}/fasd-init-cache"
+if [[ "$commands[fasd]" -nt "$fasd_cache" || ! -s "$fasd_cache" ]]; then
+  fasd --init posix-alias zsh-hook zsh-ccomp zsh-ccomp-install \
+    zsh-wcomp zsh-wcomp-install >| "$fasd_cache"
+fi
+source "$fasd_cache"
+unset fasd_cache
+
+alias v='f -e "$EDITOR"'
+alias o='a -e xdg-open'
+alias j='zz'