oh-my-devpod 0.14.2

package/runtime/vendor/zsh/ohmyzsh/plugins/capistrano/README.md

@@ -0,0 +1,14 @@
+# Capistrano
+
+This plugin provides completion for [Capistrano](https://capistranorb.com/).
+
+To use it add capistrano to the plugins array in your zshrc file.
+
+```bash
+plugins=(... capistrano)
+```
+
+For a working completion use the `capit` command instead of `cap`, because cap is a
+[reserved word in zsh](http://zsh.sourceforge.net/Doc/Release/Zsh-Modules.html#The-zsh_002fcap-Module).
+
+`capit` automatically runs cap with bundler if a Gemfile is found.

package/runtime/vendor/zsh/ohmyzsh/plugins/capistrano/_capistrano

@@ -0,0 +1,49 @@
+#compdef capit
+#autoload
+
+# Added `capit` because `cap` is a reserved word. `cap` completion doesn't work.
+# http://zsh.sourceforge.net/Doc/Release/Zsh-Modules.html#The-zsh_002fcap-Module
+
+local curcontext="$curcontext" state line ret=1
+local -a _configs
+
+_arguments -C \
+  '1: :->cmds' \
+  '2:: :->args' && ret=0
+
+_cap_tasks() {
+  if [[ -f config/deploy.rb || -f Capfile ]]; then
+    if [[ ! -f .cap_tasks~ ]]; then
+      capit --tasks | sed 's/\(\[\)\(.*\)\(\]\)/\2:/' | awk '{command=$2; $1=$2=$3=""; gsub(/^[ \t\r\n]+/, "", $0); gsub(":", "\\:", command); print command"["$0"]"}' > .cap_tasks~
+    fi
+
+    OLD_IFS=$IFS
+    IFS=$'\n'
+    _values 'cap commands' $(< .cap_tasks~)
+    IFS=$OLD_IFS
+    # zmodload zsh/mapfile
+    # _values ${(f)mapfile[.cap_tasks~]}
+  fi
+}
+
+_cap_stages() {
+  compadd $(find config/deploy -name \*.rb | cut -d/ -f3 | sed s:.rb::g)
+}
+
+case $state in
+  cmds)
+    # check if it uses multistage
+    if [[ -d config/deploy ]]; then
+      _cap_stages
+    else
+      _cap_tasks
+    fi
+    ret=0
+    ;;
+  args)
+    _cap_tasks
+    ret=0
+    ;;
+esac
+
+return ret

package/runtime/vendor/zsh/ohmyzsh/plugins/capistrano/capistrano.plugin.zsh

@@ -0,0 +1,11 @@
+# Added `capit` because `cap` is a reserved word. `cap` completion doesn't work.
+# http://zsh.sourceforge.net/Doc/Release/Zsh-Modules.html#The-zsh_002fcap-Module
+
+function capit() {
+  if [ -f Gemfile ]
+  then
+    bundle exec cap $*
+  else
+    cap $*
+  fi
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/cask/README.md

@@ -0,0 +1,15 @@
+# Cask plugin
+
+[Cask](https://github.com/cask/cask) is a project management tool for Emacs that helps
+automate the package development cycle; development, dependencies, testing, building,
+packaging and more.
+
+This plugin loads `cask` completion from non-standard locations, such as if installed
+via Homebrew or others. To enable it, add `cask` to your plugins array:
+
+```zsh
+plugins=(... cask)
+```
+
+Make sure you have the `cask` directory in your `$PATH` before loading Oh My Zsh,
+otherwise you'll get a "command not found" error.

package/runtime/vendor/zsh/ohmyzsh/plugins/cask/cask.plugin.zsh

@@ -0,0 +1,26 @@
+() {
+  emulate -L zsh
+
+  if ! (( $+commands[cask] )); then
+    print "zsh cask plugin: cask command not found" >&2
+    return
+  fi
+
+  cask_base=${commands[cask]:h:h}
+
+  # Plain cask installation location (for Cask 0.7.2 and earlier)
+  comp_files=($cask_base/etc/cask_completion.zsh)
+
+  # Mac Homebrew installs the completion in a different location
+  if (( $+commands[brew] )); then
+    comp_files+=($(brew --prefix)/share/zsh/site-functions/cask_completion.zsh)
+  fi
+
+  # Load first found file
+  for f in $comp_files; do
+    if [[ -f "$f" ]]; then
+      source "$f"
+      break
+    fi
+  done
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/catimg/README.md

@@ -0,0 +1,24 @@
+# catimg
+
+Plugin for displaying images on the terminal using the `catimg.sh` script provided by
+[posva](https://github.com/posva/catimg)
+
+To use it, add `catimg` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... catimg)
+```
+
+## Requirements
+
+- `magick convert` (ImageMagick)
+
+## Functions
+
+| Function | Description                              |
+| -------- | ---------------------------------------- |
+| `catimg` | Displays the given image on the terminal |
+
+## Usage examples
+
+[![asciicast](https://asciinema.org/a/204702.png)](https://asciinema.org/a/204702)

package/runtime/vendor/zsh/ohmyzsh/plugins/catimg/catimg.plugin.zsh

@@ -0,0 +1,19 @@
+################################################################################
+# catimg script by Eduardo San Martin Morote aka Posva                         #
+# https://posva.net                                                            #
+#                                                                              #
+# Output the content of an image to the stdout using the 256 colors of the     #
+# terminal.                                                                    #
+# GitHub: https://github.com/posva/catimg                                      #
+################################################################################
+
+
+function catimg() {
+  if (( $+commands[magick] )); then
+    CONVERT_CMD="magick" zsh $ZSH/plugins/catimg/catimg.sh $@
+  elif (( $+commands[convert] )); then
+    CONVERT_CMD="convert" zsh $ZSH/plugins/catimg/catimg.sh $@
+  else
+    echo "catimg need magick/convert (ImageMagick) to work)"
+  fi
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/catimg/catimg.sh

@@ -0,0 +1,92 @@
+################################################################################
+# catimg script by Eduardo San Martin Morote aka Posva                         #
+# https://posva.net                                                            #
+#                                                                              #
+# Output the content of an image to the stdout using the 256 colors of the     #
+# terminal.                                                                    #
+# GitHub: https://github.com/posva/catimg                                      #
+################################################################################
+
+# this should come from outside, either `magick` or `convert`
+# from imagemagick v7 and ahead `convert` is deprecated
+: ${CONVERT_CMD:=convert}
+
+function help() {
+  echo "Usage catimg [-h] [-w width] [-c char] img"
+  echo "By default char is \"  \" and w is the terminal width"
+}
+
+# VARIABLES
+COLOR_FILE=$(dirname $0)/colors.png
+CHAR="  "
+
+WIDTH=""
+IMG=""
+
+while getopts qw:c:h opt; do
+  case "$opt" in
+    w) WIDTH="$OPTARG" ;;
+    c) CHAR="$OPTARG" ;;
+    h) help; exit ;;
+    *) help ; exit 1;;
+    esac
+  done
+
+while [ "$1" ]; do
+  IMG="$1"
+  shift
+done
+
+if [ "$IMG" = "" -o ! -f "$IMG" ]; then
+  help
+  exit 1
+fi
+
+if [ ! "$WIDTH" ]; then
+  COLS=$(expr $(tput cols) "/" $(echo -n "$CHAR" | wc -c))
+else
+  COLS=$(expr $WIDTH "/" $(echo -n "$CHAR" | wc -c))
+fi
+WIDTH=$($CONVERT_CMD "$IMG" -print "%w\n" /dev/null)
+if [ "$WIDTH" -gt "$COLS" ]; then
+  WIDTH=$COLS
+fi
+
+REMAP=""
+if $CONVERT_CMD "$IMG" -resize $COLS\> +dither -remap $COLOR_FILE /dev/null ; then
+  REMAP="-remap $COLOR_FILE"
+else
+  echo "The version of convert is too old, don't expect good results :(" >&2
+  # $CONVERT_CMD "$IMG" -colors 256 PNG8:tmp.png
+  # IMG="tmp.png"
+fi
+
+# Display the image
+I=0
+$CONVERT_CMD "$IMG" -resize $COLS\> +dither `echo $REMAP` txt:- 2>/dev/null |
+sed -e 's/.*none.*/NO NO NO/g' -e '1d;s/^.*(\(.*\)[,)].*$/\1/g;y/,/ /' |
+while read R G B f; do
+  if [ ! "$R" = "NO" ]; then
+    if [ "$R" -eq "$G" -a "$G" -eq "$B" ]; then
+      ((
+      I++,
+      IDX = 232 + R * 23 / 255
+      ))
+    else
+      ((
+      I++,
+      IDX = 16
+      + R * 5 / 255 * 36
+      + G * 5 / 255 * 6
+      + B * 5 / 255
+      ))
+    fi
+    #echo "$R,$G,$B: $IDX"
+    echo -ne "\e[48;5;${IDX}m${CHAR}"
+  else
+    (( I++ ))
+    echo -ne "\e[0m${CHAR}"
+  fi
+  # New lines
+  (( $I % $WIDTH )) || echo -e "\e[0m"
+done

package/runtime/vendor/zsh/ohmyzsh/plugins/celery/README.md

@@ -0,0 +1,9 @@
+# Celery
+
+This plugin provides completion for [Celery](http://www.celeryproject.org/).
+
+To use it add celery to the plugins array in your zshrc file.
+
+```bash
+plugins=(... celery)
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/celery/_celery

@@ -0,0 +1,129 @@
+#compdef celery
+#autoload
+
+#celery zsh  completion
+
+_celery () {
+local -a _1st_arguments ifargs dopts controlargs
+
+typeset -A opt_args
+
+_1st_arguments=('worker' 'events' 'beat' 'shell' 'multi' 'amqp' 'status' 'inspect' \
+                'control' 'purge' 'list' 'migrate' 'call' 'result' 'report')
+ifargs=('--app=' '--broker=' '--loader=' '--config=' '--version')
+dopts=('--detach' '--umask=' '--gid=' '--uid=' '--pidfile=' '--logfile=' '--loglevel=')
+controlargs=('--timeout' '--destination')
+_arguments \
+        '(-A --app=)'{-A,--app}'[app instance to use (e.g. module.attr_name):APP]' \
+        '(-b --broker=)'{-b,--broker}'[url to broker.  default is "amqp://guest@localhost//":BROKER]' \
+        '(--loader)--loader[name of custom loader class to use.:LOADER]' \
+        '(--config)--config[Name of the configuration module:CONFIG]' \
+        '(--workdir)--workdir[Optional directory to change to after detaching.:WORKING_DIRECTORY]' \
+        '(-q --quiet)'{-q,--quiet}'[Don"t show as much output.]' \
+        '(-C --no-color)'{-C,--no-color}'[Don"t display colors.]' \
+        '(--version)--version[show program"s version number and exit]' \
+        '(- : *)'{-h,--help}'[show this help message and exit]' \
+        '*:: :->subcmds' && return 0
+
+if (( CURRENT == 1 )); then
+    _describe -t commands "celery subcommand" _1st_arguments
+    return
+fi
+
+case "$words[1]" in
+    worker)
+    _arguments \
+    '(-C --concurrency=)'{-C,--concurrency=}'[Number of child processes processing the queue. The default is the number of CPUs.]' \
+    '(--pool)--pool=:::(processes eventlet gevent threads solo)' \
+    '(--purge --discard)'{--discard,--purge}'[Purges all waiting tasks before the daemon is started.]' \
+    '(-f --logfile=)'{-f,--logfile=}'[Path to log file. If no logfile is specified, stderr is used.]' \
+    '(--loglevel=)--loglevel=:::(critical error warning info debug)' \
+    '(-N --hostname=)'{-N,--hostname=}'[Set custom hostname, e.g. "foo.example.com".]' \
+    '(-B --beat)'{-B,--beat}'[Also run the celerybeat periodic task scheduler.]' \
+    '(-s --schedule=)'{-s,--schedule=}'[Path to the schedule database if running with the -B option. Defaults to celerybeat-schedule.]' \
+    '(-S --statedb=)'{-S,--statedb=}'[Path to the state database.Default: None]' \
+    '(-E --events)'{-E,--events}'[Send events that can be captured by monitors like celeryev, celerymon, and others.]' \
+    '(--time-limit=)--time-limit=[nables a hard time limit (in seconds int/float) for tasks]' \
+    '(--soft-time-limit=)--soft-time-limit=[Enables a soft time limit (in seconds int/float) for tasks]' \
+    '(--maxtasksperchild=)--maxtasksperchild=[Maximum number of tasks a pool worker can execute before it"s terminated and replaced by a new worker.]' \
+    '(-Q --queues=)'{-Q,--queues=}'[List of queues to enable for this worker, separated by comma. By default all configured queues are enabled.]' \
+    '(-I --include=)'{-I,--include=}'[Comma separated list of additional modules to import.]' \
+    '(--pidfile=)--pidfile=[Optional file used to store the process pid.]' \
+    '(--autoscale=)--autoscale=[Enable autoscaling by providing max_concurrency, min_concurrency.]' \
+    '(--autoreload)--autoreload[Enable autoreloading.]' \
+    '(--no-execv)--no-execv[Don"t do execv after multiprocessing child fork.]'
+    compadd -a ifargs
+    ;;
+    inspect)
+    _values -s \
+    'active[dump active tasks (being processed)]' \
+    'active_queues[dump queues being consumed from]' \
+    'ping[ping worker(s)]' \
+    'registered[dump of registered tasks]' \
+    'report[get bugreport info]' \
+    'reserved[dump reserved tasks (waiting to be processed)]' \
+    'revoked[dump of revoked task ids]' \
+    'scheduled[dump scheduled tasks (eta/countdown/retry)]' \
+    'stats[dump worker statistics]'
+    compadd -a controlargs ifargs
+    ;;
+    control)
+    _values -s \
+    'add_consumer[tell worker(s) to start consuming a queue]' \
+    'autoscale[change autoscale settings]' \
+    'cancel_consumer[tell worker(s) to stop consuming a queue]' \
+    'disable_events[tell worker(s) to disable events]' \
+    'enable_events[tell worker(s) to enable events]' \
+    'pool_grow[start more pool processes]' \
+    'pool_shrink[use less pool processes]' \
+    'rate_limit[tell worker(s) to modify the rate limit for a task type]' \
+    'time_limit[tell worker(s) to modify the time limit for a task type.]'
+    compadd -a controlargs ifargs
+    ;;
+    multi)
+    _values -s \
+    '--nosplash[Don"t display program info.]' \
+    '--verbose[Show more output.]' \
+    '--no-color[Don"t display colors.]' \
+    '--quiet[Don"t show as much output.]' \
+    'start' 'restart' 'stopwait' 'stop' 'show' \
+    'names' 'expand' 'get' 'kill'
+    compadd -a ifargs
+    ;;
+    amqp)
+    _values -s \
+    'queue.declare' 'queue.purge' 'exchange.delete' 'basic.publish' \
+    'exchange.declare' 'queue.delete' 'queue.bind' 'basic.get'
+    ;;
+    list)
+    _values -s, 'bindings'
+    ;;
+    shell)
+    _values -s \
+    '--ipython[force iPython.]' \
+    '--bpython[force bpython.]' \
+    '--python[force default Python shell.]' \
+    '--without-tasks[don"t add tasks to locals.]' \
+    '--eventlet[use eventlet.]' \
+    '--gevent[use gevent.]'
+    compadd -a ifargs
+    ;;
+    beat)
+    _arguments \
+    '(-s --schedule=)'{-s,--schedule=}'[Path to the schedule database. Defaults to celerybeat-schedule.]' \
+    '(-S --scheduler=)'{-S,--scheduler=}'[Scheduler class to use. Default is celery.beat.PersistentScheduler.]' \
+    '(--max-interval)--max-interval[]'
+    compadd -a dopts fargs
+    ;;
+    events)
+    _arguments \
+    '(-d --dump)'{-d,--dump}'[Dump events to stdout.]' \
+    '(-c --camera=)'{-c,--camera=}'[Take snapshots of events using this camera.]' \
+    '(-F --frequency=)'{-F,--frequency=}'[Camera: Shutter frequency.  Default is every 1.0 seconds.]' \
+    '(-r --maxrate=)'{-r,--maxrate=}'[Camera: Optional shutter rate limit (e.g. 10/m).]'
+    compadd -a dopts fargs
+    ;;
+    *)
+        ;;
+    esac
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/charm/README.md

@@ -0,0 +1,9 @@
+# Charm plugin
+
+This plugin adds completion for the [charm](https://github.com/charmbracelet/charm) CLI.
+
+To use it, add `charm` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... charm)
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/charm/charm.plugin.zsh

@@ -0,0 +1,14 @@
+# Autocompletion for the Charm CLI (charm).
+if (( ! $+commands[charm] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `charm`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_charm" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _charm
+  _comps[charm]=_charm
+fi
+
+charm completion zsh >| "$ZSH_CACHE_DIR/completions/_charm" &|

package/runtime/vendor/zsh/ohmyzsh/plugins/chezmoi/README.md

@@ -0,0 +1,11 @@
+# chezmoi Plugin
+
+## Introduction
+
+This `chezmoi` plugin sets up completion for [chezmoi](https://chezmoi.io).
+
+To use it, add `chezmoi` to the plugins array of your zshrc file:
+
+```bash
+plugins=(... chezmoi)
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/chezmoi/chezmoi.plugin.zsh

@@ -0,0 +1,14 @@
+# COMPLETION FUNCTION
+if (( ! $+commands[chezmoi] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `chezmoi`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_chezmoi" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _chezmoi
+  _comps[chezmoi]=_chezmoi
+fi
+
+chezmoi completion zsh >| "$ZSH_CACHE_DIR/completions/_chezmoi" &|

package/runtime/vendor/zsh/ohmyzsh/plugins/chruby/README.md

@@ -0,0 +1,21 @@
+# chruby plugin
+
+This plugin loads [chruby](https://github.com/postmodern/chruby), a tool that changes the
+current Ruby version, and completion and a prompt function to display the Ruby version.
+Supports brew and manual installation of chruby.
+
+To use it, add `chruby` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... chruby)
+```
+
+## Usage
+
+If you'd prefer to specify an explicit path to load chruby from
+you can set variables like so:
+
+```zsh
+zstyle :omz:plugins:chruby path /local/path/to/chruby.sh
+zstyle :omz:plugins:chruby auto /local/path/to/auto.sh
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/chruby/chruby.plugin.zsh

@@ -0,0 +1,90 @@
+## load chruby from different locations
+
+_source-from-omz-settings() {
+  local _chruby_path _chruby_auto
+
+  zstyle -s :omz:plugins:chruby path _chruby_path || return 1
+  zstyle -s :omz:plugins:chruby auto _chruby_auto || return 1
+
+  if [[ -r ${_chruby_path} ]]; then
+    source ${_chruby_path}
+  fi
+
+  if [[ -r ${_chruby_auto} ]]; then
+    source ${_chruby_auto}
+  fi
+}
+
+_source-from-default-location() {
+  [[ -r /usr/local/share/chruby/chruby.sh ]] || return 1
+
+  source /usr/local/share/chruby/chruby.sh
+  source /usr/local/share/chruby/auto.sh
+}
+
+_source-from-homebrew() {
+  (( $+commands[brew] )) || return 1
+
+  local _brew_prefix
+  # check default brew prefix
+  if [[ -h /usr/local/opt/chruby ]];then
+    _brew_prefix="/usr/local/opt/chruby"
+  elif [[ -h /opt/homebrew/opt/chruby ]]; then
+    _brew_prefix="/opt/homebrew/opt/chruby"
+  else
+    # ok , it is not default prefix
+    # this call to brew is expensive ( about 400 ms ), so at least let's make it only once
+    _brew_prefix=$(brew --prefix chruby)
+  fi
+
+  [[ -r "$_brew_prefix" ]] || return 1
+
+  source $_brew_prefix/share/chruby/chruby.sh
+  source $_brew_prefix/share/chruby/auto.sh
+}
+
+# Load chruby
+_source-from-omz-settings || \
+  _source-from-default-location || \
+  _source-from-homebrew
+
+unfunction _source-from-homebrew \
+           _source-from-default-location \
+           _source-from-omz-settings
+
+
+## chruby utility functions and aliases
+
+# rvm and rbenv plugins also provide this alias
+alias rubies='chruby'
+
+function current_ruby() {
+  local ruby
+  ruby="$(chruby | grep \* | tr -d '* ')"
+  if [[ $(chruby | grep -c \*) -eq 1 ]]; then
+    echo ${ruby}
+  else
+    echo "system"
+  fi
+}
+
+function chruby_prompt_info() {
+  echo "${$(current_ruby):gs/%/%%}"
+}
+
+# Complete chruby command with installed rubies
+_chruby() {
+  compadd $(chruby | tr -d '* ')
+  if PATH="/usr/local/bin:/usr/bin:/bin:/usr/sbin:/sbin" command ruby &>/dev/null; then
+    compadd system
+  fi
+}
+
+compdef _chruby chruby
+
+
+# Simple definition completer for ruby-build
+if command ruby-build &> /dev/null; then
+  _ruby-build() { compadd $(ruby-build --definitions) }
+  compdef _ruby-build ruby-build
+fi

package/runtime/vendor/zsh/ohmyzsh/plugins/chucknorris/README.md

@@ -0,0 +1,45 @@
+# chucknorris
+
+Fortunes plugin for Chuck Norris for Oh My Zsh. Perfectly suitable as MOTD.
+
+To use it add `chucknorris` to the plugins array in you zshrc file.
+
+```zsh
+plugins=(... chucknorris)
+```
+
+## Usage
+
+| Command     | Description                     |
+| ----------- | ------------------------------- |
+| `chuck`     | Print random Chuck Norris quote |
+| `chuck_cow` | Print quote in cowthink         |
+
+Example: output of `chuck_cow`:
+
+```
+Last login: Fri Jan 30 23:12:26 on ttys001
+ ______________________________________
+( When Chuck Norris plays Monopoly, it )
+( affects the actual world economy.    )
+ --------------------------------------
+        o   ^__^
+         o  (oo)\_______
+            (__)\       )\/\
+                ||----w |
+                ||     ||
+```
+
+## Requirements
+
+- `fortune`
+- `cowsay` if using `chuck_cow`
+
+Available via homebrew, apt, ...
+
+> [!NOTE]  
+> In addition to installing `fortune`, it may be necessary to run:
+> 
+> `strfile $ZSH/plugins/chucknorris/fortunes/chucknorris\n`
+> 
+> (include the "\n" literally) to write the fortune data to the proper directory.

package/runtime/vendor/zsh/ohmyzsh/plugins/chucknorris/chucknorris.plugin.zsh

@@ -0,0 +1,24 @@
+() {
+  # %x: name of file containing code being executed
+  local fortunes_dir="${${(%):-%x}:h}/fortunes"
+
+  # Aliases
+  alias chuck="fortune -a $fortunes_dir"
+  alias chuck_cow="chuck | cowthink"
+
+  # Automatically generate or update Chuck's compiled fortune data file
+  if [[ "$fortunes_dir/chucknorris" -ot "$fortunes_dir/chucknorris.dat" ]]; then
+    return
+  fi
+
+  # For some reason, Cygwin puts strfile in /usr/sbin, which is not on the path by default
+  local strfile="${commands[strfile]:-/usr/sbin/strfile}"
+  if [[ ! -x "$strfile" ]]; then
+    echo "[oh-my-zsh] chucknorris depends on strfile, which is not installed" >&2
+    echo "[oh-my-zsh] strfile is often provided as part of the 'fortune' package" >&2
+    return
+  fi
+
+  # Generate the compiled fortune data file
+  $strfile "$fortunes_dir/chucknorris" "$fortunes_dir/chucknorris.dat" >/dev/null
+}