oh-my-devpod 0.14.2

package/runtime/vendor/zsh/ohmyzsh/plugins/magic-enter/magic-enter.plugin.zsh

@@ -0,0 +1,42 @@
+# Default commands
+: ${MAGIC_ENTER_GIT_COMMAND:="git status -u ."} # run when in a git repository
+: ${MAGIC_ENTER_JJ_COMMAND:="jj st --no-pager ."} # run when in a jj repository
+: ${MAGIC_ENTER_OTHER_COMMAND:="ls -lh ."}      # run anywhere else
+
+magic-enter() {
+  # Only run MAGIC_ENTER commands when in PS1 and command line is empty
+  # http://zsh.sourceforge.net/Doc/Release/Zsh-Line-Editor.html#User_002dDefined-Widgets
+  if [[ -n "$BUFFER" || "$CONTEXT" != start ]]; then
+    return
+  fi
+
+  # needs to be before git to handle colocated repositories
+  if (( $+commands[jj] )) && command jj st >/dev/null 2>&1; then
+    BUFFER="$MAGIC_ENTER_JJ_COMMAND"
+  elif (( $+commands[git] )) && command git rev-parse --is-inside-work-tree >/dev/null 2>&1; then
+    BUFFER="$MAGIC_ENTER_GIT_COMMAND"
+  else
+    BUFFER="$MAGIC_ENTER_OTHER_COMMAND"
+  fi
+}
+
+# Wrapper for the accept-line zle widget (run when pressing Enter)
+
+# If the wrapper already exists don't redefine it
+(( ! ${+functions[_magic-enter_accept-line]} )) || return 0
+
+case "$widgets[accept-line]" in
+  # Override the current accept-line widget, calling the old one
+  user:*) zle -N _magic-enter_orig_accept-line "${widgets[accept-line]#user:}"
+    function _magic-enter_accept-line() {
+      magic-enter
+      zle _magic-enter_orig_accept-line -- "$@"
+    } ;;
+  # If no user widget defined, call the original accept-line widget
+  builtin) function _magic-enter_accept-line() {
+      magic-enter
+      zle .accept-line
+    } ;;
+esac
+
+zle -N accept-line _magic-enter_accept-line

package/runtime/vendor/zsh/ohmyzsh/plugins/man/README.md

@@ -0,0 +1,13 @@
+# Man plugin
+
+This plugin adds a shortcut to insert man before the previous command.
+
+To use it, add `man` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... man)
+```
+# Keyboard Shortcuts
+| Shortcut                          | Description                                                            |
+|-----------------------------------|------------------------------------------------------------------------|
+| <kbd>Esc</kbd> + man              | add man before the previous command to see the manual for this command |

package/runtime/vendor/zsh/ohmyzsh/plugins/man/man.plugin.zsh

@@ -0,0 +1,37 @@
+# ------------------------------------------------------------------------------
+# Author
+# ------
+#
+# * Jerry Ling<jerryling315@gmail.com>
+#
+# ------------------------------------------------------------------------------
+# Usage
+# -----
+#
+# man will be inserted before the command
+#
+# ------------------------------------------------------------------------------
+
+man-command-line() {
+    # if there is no command typed, use the last command
+    [[ -z "$BUFFER" ]] && zle up-history
+
+    # if typed command begins with man, do nothing
+    [[ "$BUFFER" = man\ * ]] && return
+
+    # get command and possible subcommand
+    # http://zsh.sourceforge.net/Doc/Release/Expansion.html#Parameter-Expansion-Flags
+    local -a args
+    args=(${${(Az)BUFFER}[1]} ${${(Az)BUFFER}[2]})
+
+    # check if man page exists for command and first argument
+    if man "${args[1]}-${args[2]}" >/dev/null 2>&1; then
+        BUFFER="man $args"
+    else
+        BUFFER="man ${args[1]}"
+    fi
+}
+
+zle -N man-command-line
+# Defined shortcut keys: [Esc]man
+bindkey "\e"man man-command-line

package/runtime/vendor/zsh/ohmyzsh/plugins/marked2/README.md

@@ -0,0 +1,13 @@
+## marked2
+
+Plugin for Marked 2, a previewer for Markdown files on Mac OS X
+
+### Requirements
+
+ * [Marked 2](http://marked2app.com)
+
+### Usage
+
+ * If `marked` is called without an argument, open Marked
+
+ * If `marked` is passed a file, open it in Marked

package/runtime/vendor/zsh/ohmyzsh/plugins/marked2/marked2.plugin.zsh

@@ -0,0 +1,7 @@
+#
+# If marked is called without an argument, open Marked
+# If marked is passed a file, open it in Marked
+#
+function marked() {
+    open -a "marked 2.app" "$1"
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/marktext/README.md

@@ -0,0 +1,17 @@
+## marktext
+
+Plugin for MarkText, a previewer for Markdown files on Mac OS X
+
+### Requirements
+
+ * [MarkText](https://github.com/marktext/marktext)
+
+### Usage
+
+ * If `marktext` is called without an argument, open MarkText
+
+ * If `marktext` is passed a file, open it in MarkText
+
+### Credits
+
+ * just copied from plugins/marked2, all credits to marked2 plugin author

package/runtime/vendor/zsh/ohmyzsh/plugins/marktext/marktext.plugin.zsh

@@ -0,0 +1,7 @@
+#
+# If marktext is called without an argument, open MarkText
+# If marktext is passed a file, open it in MarkText
+#
+function marktext() {
+    open -a "MarkText.app" "$1"
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/mercurial/README.md

@@ -0,0 +1,69 @@
+# Mercurial plugin
+
+This plugin adds some handy aliases for using Mercurial as well as a few
+utility and prompt functions that can be used in a theme.
+
+To use it, add `mercurial` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... mercurial)
+```
+
+## Aliases
+
+| Alias   | Command                                     |
+| ------- | ------------------------------------------- |
+| `hga`   | `hg add`                                    |
+| `hgc`   | `hg commit`                                 |
+| `hgca`  | `hg commit --amend`                         |
+| `hgci`  | `hg commit --interactive`                   |
+| `hgb`   | `hg branch`                                 |
+| `hgba`  | `hg branches`                               |
+| `hgbk`  | `hg bookmarks`                              |
+| `hgco`  | `hg checkout`                               |
+| `hgd`   | `hg diff`                                   |
+| `hged`  | `hg diffmerge`                              |
+| `hgp`   | `hg push`                                   |
+| `hgs`   | `hg status`                                 |
+| `hgsl`  | `hg log --limit 20 --template "<template>"` |
+| `hgun`  | `hg resolve --list`                         |
+| `hgi`   | `hg incoming`                               |
+| `hgl`   | `hg pull -u`                                |
+| `hglr`  | `hg pull --rebase`                          |
+| `hgo`   | `hg outgoing`                               |
+| `hglg`  | `hg log --stat -v`                          |
+| `hglgp` | `hg log --stat -p -v`                       |
+
+## Prompt usage
+
+- Switch to a theme which uses `hg_prompt_info`
+
+- Or customize the `$PROMPT` variable of your current theme to contain current folder mercurial repo info.
+  This can be done by putting a custom version of the theme in `$ZSH_CUSTOM` or by changing `$PROMPT` in
+  `.zshrc` after loading the theme.
+
+  For example, for the `robbyrussell` theme you need to modify `$PROMPT` var by adding `$(hg_prompt_info)`
+  after `$(git_prompt_info)`, so it looks like this:
+
+  ```zsh
+  PROMPT='${ret_status}%{$fg_bold[green]%}%p %{$fg[cyan]%}%c %{$fg_bold[blue]%}$(git_prompt_info)$(hg_prompt_info)%{$fg_bold[blue]%} % %{$reset_color%}'
+  ```
+
+You can also redefine additional vars used in the plugin (after Oh My Zsh is sourced):
+
+```zsh
+ZSH_THEME_HG_PROMPT_PREFIX="%{$fg_bold[magenta]%}hg:(%{$fg[red]%}"
+ZSH_THEME_HG_PROMPT_SUFFIX="%{$reset_color%}"
+ZSH_THEME_HG_PROMPT_DIRTY="%{$fg[magenta]%}) %{$fg[yellow]%}✗%{$reset_color%}"
+ZSH_THEME_HG_PROMPT_CLEAN="%{$fg[magenta]%})"
+```
+
+### Display repo branch and directory status in prompt
+
+This is the same as git plugin does. **Note**: additional changes to `.zshrc`, or using a theme designed
+to use `hg_prompt_info`, are required in order for this to work.
+
+## Maintainers
+
+- [ptrv](https://github.com/ptrv): original creator
+- [oshybystyi](https://github.com/oshybystyi)

package/runtime/vendor/zsh/ohmyzsh/plugins/mercurial/mercurial.plugin.zsh

@@ -0,0 +1,118 @@
+# aliases
+alias hga='hg add'
+alias hgc='hg commit'
+alias hgca='hg commit --amend'
+alias hgci='hg commit --interactive'
+alias hgb='hg branch'
+alias hgba='hg branches'
+alias hgbk='hg bookmarks'
+alias hgco='hg checkout'
+alias hgd='hg diff'
+alias hged='hg diffmerge'
+alias hgp='hg push'
+alias hgs='hg status'
+alias hgsl='hg log --limit 20 --template "{node|short} | {date|isodatesec} | {author|person}: {desc|strip|firstline}\n" '
+alias hgun='hg resolve --list'
+# pull and update
+alias hgi='hg incoming'
+alias hgl='hg pull -u'
+alias hglr='hg pull --rebase'
+alias hgo='hg outgoing'
+alias hglg='hg log --stat -v'
+alias hglgp='hg log --stat  -p -v'
+
+function hgic() {
+  hg incoming "$@" | grep "changeset" | wc -l
+}
+
+function hgoc() {
+  hg outgoing "$@" | grep "changeset" | wc -l
+}
+
+# functions
+function hg_root() {
+  local dir="$PWD"
+  while [[ "$dir" != "/" ]]; do
+    if [[ -d "$dir/.hg" ]]; then
+      echo "$dir"
+      return 0
+    fi
+    dir="${dir:h}"
+  done
+  return 1
+}
+
+function in_hg() {
+  hg_root >/dev/null
+}
+
+function hg_get_branch_name() {
+  local dir
+  if ! dir=$(hg_root); then
+    return
+  fi
+
+  if [[ ! -f "$dir/.hg/branch" ]]; then
+    echo default
+    return
+  fi
+
+  echo "$(<"$dir/.hg/branch")"
+}
+
+function hg_get_bookmark_name() {
+  local dir
+  if ! dir=$(hg_root); then
+    return
+  fi
+
+  if [[ ! -f "$dir/.hg/bookmarks.current" ]]; then
+    return
+  fi
+
+  echo "$(<"$dir/.hg/bookmarks.current")"
+}
+
+function hg_prompt_info {
+  local dir branch dirty
+  if ! dir=$(hg_root); then
+    return
+  fi
+
+  if [[ ! -f "$dir/.hg/branch" ]]; then
+    branch=default
+  else
+    branch="$(<"$dir/.hg/branch")"
+  fi
+
+  dirty="$(hg_dirty)"
+
+  echo "${ZSH_THEME_HG_PROMPT_PREFIX}${branch:gs/%/%%}${dirty}${ZSH_THEME_HG_PROMPT_SUFFIX}"
+}
+
+function hg_dirty {
+  # Do nothing if clean / dirty settings aren't defined
+  if [[ -z "$ZSH_THEME_HG_PROMPT_DIRTY" && -z "$ZSH_THEME_HG_PROMPT_CLEAN" ]]; then
+    return
+  fi
+
+  # Check if there are modifications
+  local hg_status
+  if [[ "$DISABLE_UNTRACKED_FILES_DIRTY" = true ]]; then
+    if ! hg_status="$(hg status -q 2>/dev/null)"; then
+      return
+    fi
+  else
+    if ! hg_status="$(hg status 2>/dev/null)"; then
+      return
+    fi
+  fi
+
+  # grep exits with 0 when dirty
+  if command grep -Eq '^\s*[ACDIMR!?L].*$' <<< "$hg_status"; then
+    echo $ZSH_THEME_HG_PROMPT_DIRTY
+    return
+  fi
+
+  echo $ZSH_THEME_HG_PROMPT_CLEAN
+}

package/runtime/vendor/zsh/ohmyzsh/plugins/meteor/README.md

@@ -0,0 +1,46 @@
+# meteor plugin
+
+The [meteor plugin](https://github.com/ohmyzsh/ohmyzsh/tree/master/plugins/meteor) provides many
+[useful aliases](#aliases) as well as completion for the `meteor` command.
+
+Enable it by adding `meteor` to the plugins array in your zshrc file:
+
+```zsh
+plugins=(... meteor)
+```
+
+## Aliases
+
+| Alias   | Command                    | Description                                                      |
+|---------|----------------------------|------------------------------------------------------------------|
+| `ma`    | `meteor add`               | Add a package to this project                                    |
+| `map`   | `meteor add-platform`      | Add a platform to this project                                   |
+| `mad`   | `meteor admin`             | Administrative commands                                          |
+| `mau`   | `meteor authorized`        | View or change authorized users and organizations for a site     |
+| `mb`    | `meteor build`             | Build this project for all platforms                             |
+| `mcl`   | `meteor claim`             | Claim a site deployed with an old Meteor version                 |
+| `mca`   | `meteor configure-android` | Run the Android configuration tool from Meteor's ADK environment |
+| `mc`    | `meteor create`            | Create a new project                                             |
+| `mdb`   | `meteor debug`             | Run the project, but suspend the server process for debugging    |
+| `mde`   | `meteor deploy`            | Deploy this project to Meteor                                    |
+| `mis`   | `meteor install-sdk`       | Installs SDKs for a platform                                     |
+| `ml`    | `meteor list`              | List the packages explicitly used by your project                |
+| `mlp`   | `meteor list-platforms`    | List the platforms added to your project                         |
+| `mls`   | `meteor list-sites`        | List sites for which you are authorized                          |
+| `mli`   | `meteor login`             | Log in to your Meteor developer account                          |
+| `mlo`   | `meteor logout`            | Log out of your Meteor developer account                         |
+| `mlog`  | `meteor logs`              | Show logs for specified site                                     |
+| `mm`    | `meteor mongo`             | Connect to the Mongo database for the specified site             |
+| `mp`    | `meteor publish`           | Publish a new version of a package to the package server         |
+| `mpa`   | `meteor publish-for-arch`  | Builds an already-published package for a new platform           |
+| `mpr`   | `meteor publish-release`   | Publish a new meteor release to the package server               |
+| `mr`    | `meteor remove`            | Remove a package from this project                               |
+| `mrp`   | `meteor remove-platform`   | Remove a platform from this project                              |
+| `mre`   | `meteor reset`             | Reset the project state. Erases the local database               |
+| `m`     | `meteor run`               | **[default]** Run this project in local development mode         |
+| `ms`    | `meteor search`            | Search through the package server database                       |
+| `msh`   | `meteor shell`             | Launch a Node REPL for interactively evaluating server-side code |
+| `msw`   | `meteor show`              | Show detailed information about a release or package             |
+| `mt`    | `meteor test-packages`     | Test one or more packages                                        |
+| `mu`    | `meteor update`            | Upgrade this project's dependencies to their latest versions     |
+| `mw`    | `meteor whoami`            | Prints the username of your Meteor developer account             |

package/runtime/vendor/zsh/ohmyzsh/plugins/meteor/_meteor

@@ -0,0 +1,67 @@
+#compdef meteor
+#autoload
+
+# Meteor Autocomplete plugin for Oh-My-Zsh, based on homebrew completion
+# Original author: Dimitri JORGE (https://github.com/jorge-d)
+
+_meteor_all_packages() {
+  packages=(`meteor list | cut -d" " -f1`)
+}
+_meteor_installed_packages() {
+  installed_packages=(`meteor list --using`)
+}
+
+local -a _1st_arguments
+_1st_arguments=(
+  "add-platform:Add a platform to this project."
+  "add:Add a package to this project."
+  "admin:Administrative commands."
+  "authorized:View or change authorized users and organizations for a site."
+  "build:Build this project for all platforms."
+  "claim:Claim a site deployed with an old Meteor version."
+  "configure-android:Run the Android configuration tool from Meteor's ADK environment."
+  "create:Create a new project."
+  "debug:Run the project, but suspend the server process for debugging."
+  "deploy:Deploy this project to Meteor."
+  "install-sdk:Installs SDKs for a platform."
+  "lint:Build this project and run the linters printing all errors and warnings."
+  "list-platforms:List the platforms added to your project."
+  "list-sites:List sites for which you are authorized."
+  "list:List the packages explicitly used by your project."
+  "login:Log in to your Meteor developer account."
+  "logout:Log out of your Meteor developer account."
+  "logs:Show logs for specified site."
+  "mongo:Connect to the Mongo database for the specified site."
+  "publish-for-arch:Builds an already-published package for a new platform."
+  "publish-release:Publish a new meteor release to the package server."
+  "publish:Publish a new version of a package to the package server."
+  "remove-platform:Remove a platform from this project."
+  "remove:Remove a package from this project."
+  "reset:Reset the project state. Erases the local database."
+  "run:[default] Run this project in local development mode."
+  "search:Search through the package server database."
+  "shell:Launch a Node REPL for interactively evaluating server-side code."
+  "show:Show detailed information about a release or package."
+  "test-packages:Test one or more packages."
+  "update:Upgrade this project's dependencies to their latest versions."
+  "whoami:Prints the username of your Meteor developer account."
+)
+
+local expl
+local -a packages installed_packages
+
+if (( CURRENT == 2 )); then
+  _describe -t commands "meteor subcommand" _1st_arguments
+  return
+fi
+
+case "$words[2]" in
+    help)
+      _describe -t commands "meteor subcommand" _1st_arguments ;;
+    remove)
+      _meteor_installed_packages
+      _wanted installed_packages expl 'installed packages' compadd -a installed_packages ;;
+    add)
+      _meteor_all_packages
+      _wanted packages expl 'all packages' compadd -a packages ;;
+esac

package/runtime/vendor/zsh/ohmyzsh/plugins/meteor/meteor.plugin.zsh

@@ -0,0 +1,33 @@
+# Aliases in alphabetical order
+
+alias ma='meteor add'                  # Add a package to this project.
+alias map='meteor add-platform'        # Add a platform to this project.
+alias mad='meteor admin'               # Administrative commands.
+alias mau='meteor authorized'          # View or change authorized users and organizations for a site.
+alias mb='meteor build'                # Build this project for all platforms.
+alias mcl='meteor claim'               # Claim a site deployed with an old Meteor version.
+alias mca='meteor configure-android'   # Run the Android configuration tool from Meteor's ADK environment.
+alias mc='meteor create'               # Create a new project.
+alias mdb='meteor debug'               # Run the project, but suspend the server process for debugging.
+alias mde='meteor deploy'              # Deploy this project to Meteor.
+alias mis='meteor install-sdk'         # Installs SDKs for a platform.
+alias ml='meteor list'                 # List the packages explicitly used by your project.
+alias mlp='meteor list-platforms'      # List the platforms added to your project.
+alias mls='meteor list-sites'          # List sites for which you are authorized.
+alias mli='meteor login'               # Log in to your Meteor developer account.
+alias mlo='meteor logout'              # Log out of your Meteor developer account.
+alias mlog='meteor logs'               # Show logs for specified site.
+alias mm='meteor mongo'                # Connect to the Mongo database for the specified site.
+alias mp='meteor publish'              # Publish a new version of a package to the package server.
+alias mpa='meteor publish-for-arch'    # Builds an already-published package for a new platform.
+alias mpr='meteor publish-release'     # Publish a new meteor release to the package server.
+alias mr='meteor remove'               # Remove a package from this project.
+alias mrp='meteor remove-platform'     # Remove a platform from this project.
+alias mre='meteor reset'               # Reset the project state. Erases the local database.
+alias m='meteor run'                   # [default] Run this project in local development mode.
+alias ms='meteor search'               # Search through the package server database.
+alias msh='meteor shell'               # Launch a Node REPL for interactively evaluating server-side code.
+alias msw='meteor show'                # Show detailed information about a release or package.
+alias mt='meteor test-packages'        # Test one or more packages.
+alias mu='meteor update'               # Upgrade this project's dependencies to their latest versions.
+alias mw='meteor whoami'               # Prints the username of your Meteor developer account.

package/runtime/vendor/zsh/ohmyzsh/plugins/microk8s/README.md

@@ -0,0 +1,24 @@
+# MicroK8s plugin
+
+This plugin provides completion and useful aliases for [MicroK8s](https://microk8s.io/).
+
+To use it, add `microk8s` to the plugins array in your zshrc file.
+
+```zsh
+plugins=(... microk8s)
+```
+
+## Aliases
+
+| Alias | Command          | Description                                                                                              |
+|-------|------------------|----------------------------------------------------------------------------------------------------------|
+| mco   | microk8s.config  | Shows the Kubernetes config file.                                                                        |
+| mct   | microk8s.ctr     | Interact with containerd CLI.                                                                            |
+| mdi   | microk8s.disable | Disables an addon.                                                                                       |
+| me    | microk8s.enable  | Enables an addon.                                                                                        |
+| mh    | microk8s.helm    | Interact with Helm CLI.                                                                                  |
+| mis   | microk8s.istio   | Interact with Istio CLI.                                                                                 |
+| mk    | microk8s.kubectl | Interact with Kubernetes CLI.                                                                            |
+| msp   | microk8s.stop    | Stops all Kubernetes services.                                                                           |
+| mst   | microk8s.start   | Starts MicroK8s after it is being stopped.                                                               |
+| msts  | microk8s.status  | Provides an overview of the MicroK8s state (running / not running) as well as the set of enabled addons. |

package/runtime/vendor/zsh/ohmyzsh/plugins/microk8s/microk8s.plugin.zsh

@@ -0,0 +1,82 @@
+# ---------------------------------------------------------- #
+# Aliases and Completions for MicroK8s (https://microk8s.io) #
+# Author: Shaun Tabone (https://github.com/xontab)           #
+# ---------------------------------------------------------- #
+
+# Helper function to cache and load completions
+_microk8s_cache_completion() {
+  local cache="${ZSH_CACHE_DIR}/microk8s_$(echo $1)_completion"
+  if [[ ! -f $cache ]]; then
+    $2 $cache
+  fi
+
+  [[ -f $cache ]] && source $cache
+}
+
+# ---------------------------------------------------------- #
+# microk8s.enable                                            #
+# ALIAS: me                                                  #
+# ---------------------------------------------------------- #
+_microk8s_enable_get_command_list() {
+  microk8s.enable --help | tail -n +7 | awk '{$1=$1;print}'
+}
+
+_microk8s_enable() {
+   compadd -X "MicroK8s Addons" $(_microk8s_enable_get_command_list)
+}
+
+compdef _microk8s_enable microk8s.enable
+alias me='microk8s.enable'
+
+# ---------------------------------------------------------- #
+# microk8s.disable                                           #
+# ALIAS: mdi                                                 #
+# ---------------------------------------------------------- #
+_microk8s_disable_get_command_list() {
+  microk8s.disable --help | tail -n +7 | awk '{$1=$1;print}'
+}
+
+_microk8s_disable() {
+  compadd -X "MicroK8s Addons" $(_microk8s_disable_get_command_list)
+}
+
+compdef _microk8s_disable microk8s.disable
+alias mdi='microk8s.disable'
+
+# ---------------------------------------------------------- #
+# microk8s.kubectl                                           #
+# ALIAS: mk                                                  #
+# ---------------------------------------------------------- #
+_microk8s_kubectl_completion() {
+  if [ $commands[microk8s.kubectl] ]; then
+    microk8s.kubectl 2>/dev/null >/dev/null && microk8s.kubectl completion zsh | sed 's/__start_kubectl kubectl/__start_kubectl microk8s.kubectl/g' >$1
+  fi
+}
+
+_microk8s_cache_completion 'kubectl' _microk8s_kubectl_completion
+
+alias mk='microk8s.kubectl'
+
+# ---------------------------------------------------------- #
+# microk8s.helm                                              #
+# ALIAS: mh                                                  #
+# ---------------------------------------------------------- #
+_microk8s_helm_completion() {
+  if [ $commands[microk8s.helm] ]; then
+    microk8s.helm completion zsh | sed 's/__start_helm helm/__start_helm microk8s.helm/g' >$1
+  fi
+}
+
+_microk8s_cache_completion 'helm' _microk8s_helm_completion
+
+alias mh='microk8s.helm'
+
+# ---------------------------------------------------------- #
+# Other Aliases                                              #
+# ---------------------------------------------------------- #
+alias mco='microk8s.config'
+alias mct='microk8s.ctr'
+alias mis='microk8s.istio'
+alias mst='microk8s.start'
+alias msts='microk8s.status'
+alias msp='microk8s.stop'

package/runtime/vendor/zsh/ohmyzsh/plugins/minikube/README.md

@@ -0,0 +1,9 @@
+# minikube
+
+This plugin provides completion for [minikube](https://github.com/kubernetes/minikube).
+
+To use it, add `minikube` to the plugins array in your zshrc file.
+
+```
+plugins=(... minikube)
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/minikube/minikube.plugin.zsh

@@ -0,0 +1,13 @@
+if (( ! $+commands[minikube] )); then
+  return
+fi
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `minikube`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_minikube" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _minikube
+  _comps[minikube]=_minikube
+fi
+
+minikube completion zsh >| "$ZSH_CACHE_DIR/completions/_minikube" &|

package/runtime/vendor/zsh/ohmyzsh/plugins/mise/README.md

@@ -0,0 +1,32 @@
+# mise
+
+Adds integration with [mise](https://github.com/jdx/mise) (formerly `rtx`), a runtime executor compatible with
+npm, nodenv, pyenv, etc. mise is written in rust and is very fast. 20x-200x faster than asdf. With that being
+said, mise is compatible with asdf plugins and .tool-versions files. It can be used as a drop-in replacement.
+
+## Installation
+
+1. [Download & install mise](https://github.com/jdx/mise#installation) by running the following:
+
+```bash
+curl https://mise.jdx.dev/install.sh | sh
+```
+
+2. [Enable mise](https://github.com/jdx/mise#quickstart) by adding it to your `plugins` definition in
+   `~/.zshrc`.
+
+```bash
+plugins=(mise)
+```
+
+## Usage
+
+See the [mise readme](https://github.com/jdx/mise#table-of-contents) for information on how to use mise. Here
+are a few examples:
+
+```bash
+mise install node         Install the current version specified in .tool-versions/.mise.toml
+mise use -g node@system   Use system node as global default
+mise install node@20.0.0  Install a specific version number
+mise use -g node@20       Use node-20.x as global default
+```

package/runtime/vendor/zsh/ohmyzsh/plugins/mise/mise.plugin.zsh

@@ -0,0 +1,17 @@
+if (( ! $+commands[mise] )); then
+  return
+fi
+
+# Load mise hooks
+eval "$(mise activate zsh)"
+
+# If the completion file doesn't exist yet, we need to autoload it and
+# bind it to `mise`. Otherwise, compinit will have already done that.
+if [[ ! -f "$ZSH_CACHE_DIR/completions/_mise" ]]; then
+  typeset -g -A _comps
+  autoload -Uz _mise
+  _comps[mise]=_mise
+fi
+
+# Generate and load mise completion
+mise completion zsh >| "$ZSH_CACHE_DIR/completions/_mise" &|