smalruby-editor 0.0.12-x86-mingw32 → 0.1.0-x86-mingw32

data/app/assets/javascripts/blocks/sound.js.coffee.erb

@@ -0,0 +1,75 @@
+# 「音」ジャンル
+
+<%
+  category = 'sound'
+  color = 296
+%>
+
+# [▼プリセット音声]
+<% n = "#{category}_preset_sounds" %>
+Blockly.Blocks['<%= n %>'] =
+  init: ()->
+    sounds = [
+      ['ピアノのド', 'piano_do.wav'],
+      ['ピアノのレ', 'piano_re.wav'],
+      ['ピアノのミ', 'piano_mi.wav'],
+      ['ピアノのファ', 'piano_fa.wav'],
+      ['ピアノのソ', 'piano_so.wav'],
+      ['ピアノのラ', 'piano_ra.wav'],
+      ['ピアノのシ', 'piano_si.wav'],
+      ['ピアノの高いド', 'piano_do_2.wav'],
+    ]
+    @setHelpUrl('')
+    @setColour(<%= color %>)
+    @appendDummyInput().appendField(new Blockly.FieldDropdown(sounds), 'NAME')
+    @setOutput(true, 'String')
+    @setTooltip('')
+
+Blockly.Ruby['<%= n %>'] = (block) ->
+  code = Blockly.Ruby.quote_(@getFieldValue('NAME'))
+  [code, Blockly.Ruby.ORDER_ATOMIC]
+
+# [▼]の音を鳴らす
+<% n = "#{category}_play" %>
+Blockly.Blocks['<%= n %>'] =
+  init: ()->
+    @setHelpUrl('')
+    @setColour(<%= color %>)
+    @appendValueInput('NAME').setCheck('String')
+    @appendDummyInput().appendField('の音を鳴らす')
+    @setInputsInline(true)
+    @setPreviousStatement(true)
+    @setNextStatement(true)
+    @setTooltip('')
+
+Blockly.Ruby['<%= n %>'] = (block) ->
+  arg = Blockly.Ruby.valueToCode(@, 'NAME', Blockly.Ruby.ORDER_NONE) || ''
+  Blockly.Ruby.characterMethodCall_('play', "name: #{arg}")
+
+# すべての音を止める
+<% n = "#{category}_stop" %>
+Blockly.Blocks['<%= n %>'] =
+  init: ()->
+    @setHelpUrl('')
+    @setColour(<%= color %>)
+    @appendDummyInput()
+      .appendField('すべての音を止める')
+    @setPreviousStatement(true)
+    @setNextStatement(true)
+    @setTooltip('')
+
+Blockly.Ruby['<%= n %>'] = (block) ->
+  'stop\n'
+
+# 変数:ボリューム
+<% n = "#{category}_volume" %>
+Blockly.Blocks['<%= n %>'] =
+  init: ()->
+    @setHelpUrl('')
+    @setColour(<%= color %>)
+    @appendDummyInput().appendField('ボリューム')
+    @setOutput(true, 'Number')
+    @setTooltip('')
+
+Blockly.Ruby['<%= n %>'] = (block) ->
+  ['volume', Blockly.Ruby.ORDER_ATOMIC]

data/app/assets/javascripts/collections/character_set.js.coffee

@@ -0,0 +1,12 @@
+# キャラクターの一覧を表現するコレクション
+Smalruby.CharacterSet = Backbone.Collection.extend
+  model: Smalruby.Character
+
+  uniqueName: (costume = Smalruby.Character.PRESET_COSTUMES[0])->
+    prefix = costume.substring(costume.lastIndexOf('/') + 1).replace(/\.[^.]*$/, '').replace(/[\d]*$/, '')
+    max = 0
+    r = new RegExp('^' + prefix + '(\\d+)$')
+    _.each @pluck('name'), (name) ->
+      if name.match(r)
+        max = _.max([max, parseInt(RegExp.$1)])
+    "#{prefix}#{max + 1}"

data/app/assets/javascripts/generators/ruby.js.coffee.erb

@@ -0,0 +1,188 @@
+Blockly.Ruby = new Blockly.Generator('Ruby')
+
+Blockly.Ruby.addReservedWords '
+BEGIN    class    ensure   nil      self     when
+END      def      false    not      super    while
+alias    defined? for      or       then     yield
+and      do       if       redo     true     __LINE__
+begin    else     in       rescue   undef    __FILE__
+break    elsif    module   retry    unless   __ENCODING__
+case     end      next     return   until
+'.split(/\s+/)
+
+# TODO: 確認すること
+Blockly.Ruby.ORDER_ATOMIC = 0            # 0 "" ...
+Blockly.Ruby.ORDER_COLLECTION = 1        # tuples, lists, dictionaries
+Blockly.Ruby.ORDER_STRING_CONVERSION = 1 # `expression...`
+Blockly.Ruby.ORDER_MEMBER = 2            # . []
+Blockly.Ruby.ORDER_FUNCTION_CALL = 2     # ()
+Blockly.Ruby.ORDER_EXPONENTIATION = 3    # **
+Blockly.Ruby.ORDER_UNARY_SIGN = 4        # + -
+Blockly.Ruby.ORDER_BITWISE_NOT = 4       # ~
+Blockly.Ruby.ORDER_MULTIPLICATIVE = 5    # * / // %
+Blockly.Ruby.ORDER_ADDITIVE = 6          # + -
+Blockly.Ruby.ORDER_BITWISE_SHIFT = 7     # << >>
+Blockly.Ruby.ORDER_BITWISE_AND = 8       # &
+Blockly.Ruby.ORDER_BITWISE_XOR = 9       # ^
+Blockly.Ruby.ORDER_BITWISE_OR = 10       # |
+Blockly.Ruby.ORDER_RELATIONAL = 11       # in, not in, is, is not,
+                                         # <, <=, >, >=, <>, !=, ==
+Blockly.Ruby.ORDER_LOGICAL_NOT = 12      # not
+Blockly.Ruby.ORDER_LOGICAL_AND = 13      # and
+Blockly.Ruby.ORDER_LOGICAL_OR = 14       # or
+Blockly.Ruby.ORDER_CONDITIONAL = 15      # if else
+Blockly.Ruby.ORDER_LAMBDA = 16           # lambda
+Blockly.Ruby.ORDER_NONE = 99             # (...)
+
+Blockly.Ruby.INFINITE_LOOP_TRAP = null
+
+Blockly.Ruby.init = ->
+  @definitions_ = Object.create(null)
+
+  if Blockly.Variables
+    if !@variableDB_
+      @variableDB_ = new Blockly.Names(Blockly.Ruby.RESERVED_WORDS_)
+    else
+      @variableDB_.reset()
+
+    @definitions_['require_smalruby'] = 'require "smalruby"'
+    @definitions_['receiver_stack'] = ['main']
+    @definitions_['character_stack'] = []
+
+Blockly.Ruby.characterStack = ->
+  @definitions_['character_stack']
+
+Blockly.Ruby.character = ->
+  _.last(@characterStack())
+
+Blockly.Ruby.receiverStack = ->
+  @definitions_['receiver_stack']
+
+Blockly.Ruby.receiver = ->
+  _.last(@receiverStack())
+
+Blockly.Ruby.receiverName = (options = {}) ->
+  opts =
+    object: Blockly.Ruby.character()
+    dropSelf: true
+  _.extend(opts, options)
+  r = @receiver()
+  if r == opts.object
+    if opts.dropSelf
+      ''
+    else
+      'self.'
+  else
+    "#{opts.object.get('name')}."
+
+Blockly.Ruby.cs = Blockly.Ruby.characterStack
+Blockly.Ruby.cs_ = Blockly.Ruby.characterStack
+Blockly.Ruby.c = Blockly.Ruby.character
+Blockly.Ruby.c_ = Blockly.Ruby.character
+Blockly.Ruby.rs = Blockly.Ruby.receiverStack
+Blockly.Ruby.rs_ = Blockly.Ruby.receiverStack
+Blockly.Ruby.r = Blockly.Ruby.r
+Blockly.Ruby.r_ = Blockly.Ruby.r
+Blockly.Ruby.rn = Blockly.Ruby.receiverName
+Blockly.Ruby.rn_ = Blockly.Ruby.receiverName
+
+Blockly.Ruby.characterMethodCall_ = (method, args, options = {}) ->
+  res = @characterMethodCallInput_(method, args, options)
+  if res[0]
+    "#{res[0]}\n"
+  else
+    ''
+
+Blockly.Ruby.characterMethodCallInput_ = (method, args, options = {}) ->
+  code =
+    if @c_()
+      if args && args.length > 0
+        "#{@rn_(options)}#{method}(#{args})"
+      else
+        "#{@rn_(options)}#{method}"
+    else
+      null
+  [code, @ORDER_FUNCTION_CALL]
+
+Blockly.Ruby.characterSetVariable_ = (name, val, operator = '=') ->
+  if @c_()
+    "#{@rn_({ dropSelf: false})}#{name} #{operator} #{val}\n"
+  else
+    ''
+
+Blockly.Ruby.characterEvent_ = (block, bodyName, name, arg = null) ->
+  if c = @c_()
+    @rs_().push(c)
+    try
+      body = Blockly.Ruby.statementToCode(block, bodyName) || '\n'
+    finally
+      @rs_().pop()
+
+    if arg
+      arg = ", #{arg}"
+    else
+      arg = ''
+
+    """
+
+
+    #{@rn_()}on(:#{name}#{arg}) do
+    #{body}end
+
+    """
+  else
+    ''
+
+Blockly.Ruby.finish = (code) ->
+  requires = []
+  definitions = []
+  for name of Blockly.Ruby.definitions_
+    do (name) ->
+      def = Blockly.Ruby.definitions_[name]
+      if _.isString(def)
+        if def.match(/^require\s*('\S+'|"\S+")/)
+          requires.push(def)
+        else
+          definitions.push(def)
+
+  if definitions.length == 0 && code.length == 0
+    return ''
+
+  allDefs = requires.join('\n') + '\n\n'
+  if definitions.length > 0
+    allDefs += definitions.join('\n')
+      .replace(/\n\n+/g, '\n\n').replace(/\n*$/, '\n')
+  allDefs + code
+
+Blockly.Ruby.scrubNakedValue = (line) ->
+  line + '\n'
+
+Blockly.Ruby.quote_ = (string) ->
+  # TODO: 実装すること
+  # stringに"を含んでいたら、aから順番にstringに含まれるか試して、含ま
+  # れていない文字を使って%Qa...aとしようかな。でも生成したソースコード
+  # の可読性が下がりますね。
+  '\"' + string + '\"'
+
+Blockly.Ruby.scrub_ = (block, code) ->
+  if code == null
+    return ''
+
+  commentCode = ''
+  if !block.outputConnection || !block.outputConnection.targetConnection
+    comment = block.getCommentText()
+    if comment
+      commentCode += @prefixLines(comment, '# ') + '\n'
+
+    for input in block.inputList
+      do (input) =>
+        if input.type == Blockly.INPUT_VALUE
+          childBlock = input.connection.targetBlock()
+          if childBlock
+            comment = @allNestedComments(childBlock)
+            if comment
+              commentCode += @prefixLines(comment, '# ')
+
+  nextBlock = block.nextConnection && block.nextConnection.targetBlock()
+  nextCode = this.blockToCode(nextBlock)
+  commentCode + code + nextCode

data/app/assets/javascripts/models/character.js.coffee

@@ -0,0 +1,66 @@
+Smalruby.Character = Backbone.Model.extend({
+  defaults:
+    name: null
+    costumes: [],
+    costumeIndex: 0
+    x: 0
+    y: 0
+    angle: 0
+    visible: true
+    using: false
+
+  initialize: ->
+    @objects = []
+    if @get('costumes').length == 0
+      @set({ costumes: [Smalruby.Character.PRESET_COSTUMES[0]] })
+
+  link: (object) ->
+    @objects.push(object)
+    @objects = _.uniq(@objects)
+    if @objects.length > 0
+      @set('using', true)
+
+  unlink: (object) ->
+    @objects = _.without(@objects, object)
+    if @objects.length == 0
+      @set('using', false)
+
+  namePrefix: ->
+    Smalruby.Character.costumeToNamePrefix(@get('name'))
+
+  costume: ->
+    @get('costumes')[@get('costumeIndex')]
+
+  costumeUrl: (index = @get('costumeIndex')) ->
+    basename = @get('costumes')[index]
+    if _.indexOf(Smalruby.Character.PRESET_COSTUMES, basename) == -1
+      basename
+    else
+      "/smalruby/assets/#{basename}"
+
+  nextCostume: ->
+    i = @get('costumeIndex') + 1
+    i = 0 if i >= @get('costumes').length
+    @set({ 'costumeIndex': i })
+    i
+}, {
+  PRESET_COSTUMES: [
+    'car1.png'
+    'car2.png'
+    'car3.png'
+    'car4.png'
+    'ball1.png'
+    'ball2.png'
+    'ball3.png'
+    'ball4.png'
+    'ball5.png'
+    'ball6.png'
+    'cat1.png'
+    'cat2.png'
+    'cat3.png'
+    'frog1.png'
+  ]
+
+  costumeToNamePrefix: (costume) ->
+    costume.substring(costume.lastIndexOf('/') + 1).replace(/\.[^.]*$/, '').replace(/[\d]*$/, '')
+})

data/app/assets/javascripts/models/scene.js.coffee

@@ -0,0 +1,5 @@
+Smalruby.Scene = Backbone.Model.extend
+  defaults:
+    width: 640
+    height: 480
+    color: 'black'

data/app/assets/javascripts/models/source_code.js.coffee

@@ -0,0 +1,64 @@
+# ソースコードを表現するモデル
+Smalruby.SourceCode = Backbone.Model.extend
+  defaults:
+    filename: null
+    data: null
+
+  initialize: ->
+    unless @get('filename')
+      filename = Smalruby.Views.MainMenuView.getFilename()
+      if filename.length == 0
+        c = Smalruby.Collections.CharacterSet.first()
+        if c
+          filename = "#{c.get('name')}.rb"
+        else
+          filename = '1.rb'
+      @set('filename', filename)
+
+    if @get('filename').match(/\.xml$/)
+      data = Smalruby.dumpXml()
+    else
+      if window.blockMode
+        data = Blockly.Ruby.workspaceToCode()
+      else
+        data =window.textEditor.getSession().getDocument().getValue()
+
+    @set('data', data)
+
+  run: ->
+    @post_('run')
+
+  check: ->
+    @post_('check')
+
+  save2: ->
+    @post_('')
+
+  write: (force = false) ->
+    action = 'write'
+    action += '?force=1' if force
+    @delete_(action)
+
+  post_: (action) ->
+    dfr = $.Deferred()
+    $.ajax
+      url: "/source_codes/#{action}"
+      type: 'POST'
+      data:
+        source_code:
+          filename: @get('filename')
+          data: @get('data')
+      dataType: 'json'
+      success: (data, textStatus, jqXHR) -> dfr.resolve(data)
+      error: dfr.reject
+    dfr.promise()
+
+  delete_: (action) ->
+    dfr = $.Deferred()
+    $.ajax
+      url: "/source_codes/#{action}"
+      type: 'DELETE'
+      dataType: 'json'
+      success: (data, textStatus, jqXHR) -> dfr.resolve(data)
+      error: dfr.reject
+    dfr.promise()

data/app/assets/javascripts/ruby_mode.js.coffee.erb

@@ -0,0 +1,12 @@
+$ ->
+  window.textEditor = textEditor = ace.edit('text-editor')
+  textEditor.setTheme('ace/theme/clouds')
+  textEditor.setShowInvisibles(true)
+  textEditor.gotoLine(0, 0)
+  textEditor.on 'change', (e) ->
+    window.changed = true
+
+  session = textEditor.getSession()
+  session.setMode('ace/mode/ruby')
+  session.setTabSize(2)
+  session.setUseSoftTabs(true)

data/app/assets/javascripts/smalruby.js.coffee

@@ -0,0 +1,97 @@
+window.SmalrubyEditor = {}
+window.changed = false
+window.textEditor = null
+window.blockMode = true
+
+window.successMessage = (title, msg = '', selector = '#messages') ->
+  html = $('<div class="alert alert-success" style="display: none">')
+    .append("<h4><i class=\"icon-star\"></i>#{title}</h4>")
+    .append(msg)
+  $(selector).append(html)
+  html.fadeIn('slow')
+    .delay(3000)
+    .fadeOut('slow')
+
+window.errorMessage = (msg, selector = '#messages') ->
+  html = $('<div class="alert alert-error" style="display: none">')
+    .append('<button type="button" class="close" data-dismiss="alert">×</button>')
+    .append('<h4><i class="icon-exclamation-sign"></i>エラー</h4>')
+    .append(msg)
+  $(selector).append(html)
+  html.fadeIn('slow')
+
+window.Smalruby =
+  Models: {}
+  Collections: {}
+  Views: {}
+  Routers: {}
+  initialize: ->
+    # HACK: Underscoreのテンプレートの<%, %>はHamlと組み合わせたときに
+    #   HTML要素の属性がHamlによってエスケープされてしまうため使いにく
+    #   い。そこで、それぞれ{{, }}に変更する。
+    _.extend(_.templateSettings, {
+      escape: /{{-([\s\S]+?)}}/
+      evaluate: /{{([\s\S]+?)}}/
+      interpolate: /{{=([\s\S]+?)}}/
+    })
+
+    @Collections.CharacterSet = new Smalruby.CharacterSet()
+
+    @Views.MainMenuView = new Smalruby.MainMenuView()
+    @Views.CharacterSelectorView = new Smalruby.CharacterSelectorView
+      model: @Collections.CharacterSet
+    @Views.CharacterModalView = new Smalruby.CharacterModalView
+      el: $('#character-modal')
+
+    $('a[data-toggle="tab"]').on 'shown', (e) ->
+      if $(e.target).attr('href') == '#block-tab'
+        window.blockMode = true
+      else
+        window.blockMode = false
+        data = Blockly.Ruby.workspaceToCode()
+        if $.trim(data).length > 0
+          window.textEditor.getSession().getDocument().setValue(data)
+          window.textEditor.moveCursorTo(0, 0)
+        window.textEditor.focus()
+
+    Smalruby.downloading = false
+    window.onbeforeunload = (event) ->
+      if !Smalruby.downloading && window.changed
+        return '作成中のプログラムが消えてしまうよ！'
+      else
+        Smalruby.downloading = false
+        return
+
+  loadXml: (data, workspace = Blockly.mainWorkspace) ->
+    xml = Blockly.Xml.textToDom(data)
+    workspace.clear()
+    chars = []
+    i = 0
+    while (xmlChild = xml.childNodes[i])
+      if xmlChild.nodeName.toLowerCase() == 'character'
+        c = new Smalruby.Character
+          name: xmlChild.getAttribute('name')
+          costumes: xmlChild.getAttribute('costumes').split(',')
+          x: parseInt(xmlChild.getAttribute('x'), 10)
+          y: parseInt(xmlChild.getAttribute('y'), 10)
+          angle: parseInt(xmlChild.getAttribute('angle'), 10)
+        chars.push(c)
+      i++
+    Smalruby.Collections.CharacterSet.reset(chars)
+    Blockly.Xml.domToWorkspace(workspace, xml)
+
+  dumpXml: (workspace = Blockly.mainWorkspace, charSet = Smalruby.Collections.CharacterSet) ->
+    xmlDom = Blockly.Xml.workspaceToDom(workspace)
+    blocklyDom = xmlDom.firstChild
+    charSet.each (c) ->
+      e = goog.dom.createDom('character')
+      e.setAttribute('x', c.get('x'))
+      e.setAttribute('y', c.get('y'))
+      e.setAttribute('name', c.get('name'))
+      e.setAttribute('costumes', c.get('costumes').join(','))
+      e.setAttribute('angle', c.get('angle'))
+      xmlDom.insertBefore(e, blocklyDom)
+    Blockly.Xml.domToPrettyText(xmlDom)
+
+$(document).ready ->
+  Smalruby.initialize()