v86 0.3.4 → 0.3.7

package/bios/seabios/vgasrc/vgabios.h

@@ -0,0 +1,88 @@
+#ifndef __VGABIOS_H
+#define __VGABIOS_H
+
+#include "config.h" // CONFIG_VGA_EMULATE_TEXT
+#include "farptr.h" // GET_FARVAR
+#include "types.h" // u8
+
+// Save/Restore flags
+#define SR_HARDWARE   0x0001
+#define SR_BDA        0x0002
+#define SR_DAC        0x0004
+#define SR_REGISTERS  0x0008
+#define SR_SAVE       0x0100
+#define SR_RESTORE    0x0200
+
+// Mode flags
+#define MF_LEGACY     0x0001
+#define MF_GRAYSUM    0x0002
+#define MF_NOPALETTE  0x0008
+#define MF_CUSTOMCRTC 0x0800
+#define MF_LINEARFB   0x4000
+#define MF_NOCLEARMEM 0x8000
+#define MF_VBEFLAGS   0xfe00
+
+// Memory model types
+#define MM_TEXT            0x00
+#define MM_CGA             0x01
+#define MM_HERCULES        0x02
+#define MM_PLANAR          0x03
+#define MM_PACKED          0x04
+#define MM_NON_CHAIN_4_256 0x05
+#define MM_DIRECT          0x06
+#define MM_YUV             0x07
+
+struct vgamode_s {
+    u8 memmodel;
+    u16 width;
+    u16 height;
+    u8 depth;
+    u8 cwidth;
+    u8 cheight;
+    u16 sstart;
+};
+
+// Custom internal storage in BDA (don't change here without also
+// updating vgaentry.S)
+#define VGA_CUSTOM_BDA 0xb9
+
+struct vga_bda_s {
+    u8 flags;
+    u16 vbe_mode;
+    u16 vgamode_offset;
+} PACKED;
+
+#define BF_PM_MASK      0x0f
+#define BF_EMULATE_TEXT 0x10
+#define BF_SWCURSOR     0x20
+#define BF_EXTRA_STACK  0x40
+
+#define GET_BDA_EXT(var) \
+    GET_FARVAR(SEG_BDA, ((struct vga_bda_s *)VGA_CUSTOM_BDA)->var)
+#define SET_BDA_EXT(var, val) \
+    SET_FARVAR(SEG_BDA, ((struct vga_bda_s *)VGA_CUSTOM_BDA)->var, (val))
+#define MASK_BDA_EXT(var, off, on)                                      \
+    SET_BDA_EXT(var, (GET_BDA_EXT(var) & ~(off)) | (on))
+
+static inline int vga_emulate_text(void) {
+    return CONFIG_VGA_EMULATE_TEXT && GET_BDA_EXT(flags) & BF_EMULATE_TEXT;
+}
+
+// Write to global variables (during "post" phase only)
+#define SET_VGA(var, val) SET_FARVAR(get_global_seg(), (var), (val))
+
+// Debug settings
+#define DEBUG_VGA_POST 1
+#define DEBUG_VGA_10 9
+
+// vgabios.c
+int vga_bpp(struct vgamode_s *vmode_g);
+u16 calc_page_size(u8 memmodel, u16 width, u16 height);
+u16 get_cursor_shape(void);
+struct cursorpos get_cursor_pos(u8 page);
+int bda_save_restore(int cmd, u16 seg, void *data);
+struct vgamode_s *get_current_mode(void);
+int vga_set_mode(int mode, int flags);
+extern struct video_func_static static_functionality;
+
+#endif // vgabios.h

package/bios/seabios/vgasrc/vgaentry.S

@@ -0,0 +1,161 @@
+// Rom layout and bios assembler to C interface.
+//
+// Copyright (C) 2009-2013  Kevin O'Connor <kevin@koconnor.net>
+//
+// This file may be distributed under the terms of the GNU LGPLv3 license.
+
+
+#include "asm-offsets.h" // BREGS_*
+#include "config.h" // CONFIG_*
+#include "entryfuncs.S" // ENTRY_*
+
+
+/****************************************************************
+ * Rom Header
+ ****************************************************************/
+
+        .section .rom.header
+        .code16
+        .global _rom_header, _rom_header_size, _rom_header_checksum
+_rom_header:
+        .word 0xaa55
+_rom_header_size:
+        .byte 0
+_rom_header_entry:
+        jmp _optionrom_entry
+_rom_header_checksum:
+        .byte 0
+_rom_header_other:
+        .space 17
+_rom_header_pcidata:
+#if CONFIG_VGA_PCI == 1
+        .word rom_pci_data
+#else
+        .word 0
+#endif
+_rom_header_pnpdata:
+        .word 0
+_rom_header_other2:
+        .word 0
+_rom_header_signature:
+        .asciz "IBM"
+
+
+/****************************************************************
+ * Entry points
+ ****************************************************************/
+
+        // This macro implements a call while avoiding instructions
+        // that old versions of x86emu have problems with.
+        .macro VGA_CALLL cfunc
+#if CONFIG_VGA_FIXUP_ASM
+        pushw %ax
+        callw \cfunc
+#else
+        calll \cfunc
+#endif
+        .endm
+
+        // This macro is the same as ENTRY_ARG except VGA_CALLL is used.
+        .macro ENTRY_ARG_VGA cfunc
+        cli
+        cld
+        PUSHBREGS
+        movw %ss, %ax           // Move %ss to %ds
+        movw %ax, %ds
+        movl %esp, %ebx         // Backup %esp, then zero high bits
+        movzwl %sp, %esp
+        movl %esp, %eax         // First arg is pointer to struct bregs
+        VGA_CALLL \cfunc
+        movl %ebx, %esp         // Restore %esp (including high bits)
+        POPBREGS
+        .endm
+
+        DECLFUNC entry_104f05
+entry_104f05:
+        ENTRY_ARG_VGA vbe_104f05
+        lretw
+
+        DECLFUNC _optionrom_entry
+_optionrom_entry:
+        ENTRY_ARG_VGA vga_post
+        lretw
+
+        DECLFUNC entry_10
+entry_10:
+        ENTRY_ARG_VGA handle_10
+        iretw
+
+#define VGA_CUSTOM_BDA_FLAGS 0xb9
+#define BF_EXTRA_STACK 0x40
+
+        // Entry point using extra stack
+        DECLFUNC entry_10_extrastack
+entry_10_extrastack:
+        cli
+        cld
+        pushw %ds
+        pushl %eax
+
+        movw $SEG_BDA, %ax      // Check if extra stack is enabled
+        movw %ax, %ds
+        testb $BF_EXTRA_STACK, VGA_CUSTOM_BDA_FLAGS
+        jz 1f
+
+        movw %cs:ExtraStackSeg, %ds // Set %ds:%eax to space on ExtraStack
+        movl $(CONFIG_VGA_EXTRA_STACK_SIZE-PUSHBREGS_size-16), %eax
+        SAVEBREGS_POP_DSEAX     // Save registers on extra stack
+        movl %esp, PUSHBREGS_size+8(%eax)
+        movw %ss, PUSHBREGS_size+12(%eax)
+        popl BREGS_code(%eax)
+        popw BREGS_flags(%eax)
+
+        movw %ds, %dx           // Setup %ss/%esp and call function
+        movw %dx, %ss
+        movl %eax, %esp
+        VGA_CALLL handle_10
+
+        movl %esp, %eax         // Restore registers and return
+        movw PUSHBREGS_size+12(%eax), %ss
+        movl PUSHBREGS_size+8(%eax), %esp
+        popl %edx
+        popw %dx
+        pushw BREGS_flags(%eax)
+        pushl BREGS_code(%eax)
+        RESTOREBREGS_DSEAX
+        iretw
+
+1:      // Use regular entry point if the extra stack is disabled
+        popl %eax
+        popw %ds
+        jmp entry_10
+
+        // Timer irq handling
+        DECLFUNC entry_timer_hook
+entry_timer_hook:
+        ENTRY handle_timer_hook
+        ljmpw *%cs:Timer_Hook_Resume
+
+        // Timer irq handling on extra stack
+        DECLFUNC entry_timer_hook_extrastack
+entry_timer_hook_extrastack:
+        cli
+        cld
+        pushw %ds               // Set %ds:%eax to space on ExtraStack
+        pushl %eax
+        movw %cs:ExtraStackSeg, %ds
+        movl $(CONFIG_VGA_EXTRA_STACK_SIZE-PUSHBREGS_size-8), %eax
+        SAVEBREGS_POP_DSEAX
+        movl %esp, PUSHBREGS_size(%eax)
+        movw %ss, PUSHBREGS_size+4(%eax)
+
+        movw %ds, %dx           // Setup %ss/%esp and call function
+        movw %dx, %ss
+        movl %eax, %esp
+        calll handle_timer_hook
+
+        movl %esp, %eax         // Restore registers and return
+        movw PUSHBREGS_size+4(%eax), %ss
+        movl PUSHBREGS_size(%eax), %esp
+        RESTOREBREGS_DSEAX
+        ljmpw *%cs:Timer_Hook_Resume