src-mcp 1.0.1

package/assets/queries/php/highlights.scm

@@ -0,0 +1,319 @@
+(php_tag) @tag
+"?>" @tag
+
+; Variables
+
+(relative_scope) @variable.builtin
+
+(variable_name) @variable
+
+((name) @constant
+ (#match? @constant "^_?[A-Z][A-Z\\d_]+$"))
+
+((name) @constructor
+ (#match? @constructor "^[A-Z]"))
+
+((name) @variable.builtin
+ (#eq? @variable.builtin "this"))
+
+; Types
+[
+  (primitive_type)
+  (cast_type)
+] @type.builtin
+
+(named_type
+  [ (name) @type
+    (qualified_name (name) @type)])
+
+(base_clause
+  [ (name) @type
+    (qualified_name (name) @type)])
+
+(enum_declaration
+  name: (name) @type.enum)
+
+(interface_declaration
+  name: (name) @constructor)
+
+(class_declaration
+  name: (name) @constructor)
+
+(trait_declaration
+  name:(name) @constructor)
+
+(namespace_definition
+  name: (namespace_name (name) @namespace))
+
+(namespace_name_as_prefix 
+  (namespace_name (name) @namespace))
+
+(namespace_use_clause
+  [ (name) @namespace
+    (qualified_name (name) @type) ])
+
+(namespace_aliasing_clause (name) @namespace)
+
+(class_interface_clause
+  [(name) @type
+   (qualified_name (name) @type)])
+
+(scoped_call_expression
+  scope: [(name) @type
+          (qualified_name (name) @type)])
+
+(class_constant_access_expression
+  . [(name) @constructor
+     (qualified_name (name) @constructor)]
+  (name) @constant)
+
+(use_declaration (name) @type)
+
+(binary_expression
+  operator: "instanceof"
+  right: [(name) @type
+          (qualified_name (name) @type)])
+
+; Superglobals
+(subscript_expression
+  (variable_name(name) @constant.builtin
+    (#match? @constant.builtin "^_?[A-Z][A-Z\\d_]+$")))
+
+; Functions
+
+(array_creation_expression "array" @function.builtin)
+(list_literal "list" @function.builtin)
+
+(method_declaration
+  name: (name) @function.method)
+
+(function_call_expression
+  function: (_) @function)
+
+(scoped_call_expression
+  name: (name) @function)
+
+(member_call_expression
+  name: (name) @function.method)
+
+(function_definition
+  name: (name) @function)
+
+(nullsafe_member_call_expression
+    name: (name) @function.method)
+
+(object_creation_expression
+  [(name) @constructor
+   (qualified_name (name) @constructor)])
+
+; Parameters
+[
+  (simple_parameter)
+  (variadic_parameter)
+] @variable.parameter
+
+(argument
+    (name) @variable.parameter)
+
+; Member
+
+(property_element
+  (variable_name) @variable.other.member)
+
+(member_access_expression
+  name: (variable_name (name)) @variable.other.member)
+(member_access_expression
+  name: (name) @variable.other.member)
+
+; Attributes
+(attribute_list) @attribute
+
+; Basic tokens
+
+[
+  (string)
+  (encapsed_string)
+  (heredoc_body)
+  (nowdoc_body)
+  (shell_command_expression) 
+] @string
+(escape_sequence) @constant.character.escape
+
+(boolean) @constant.builtin.boolean
+(null) @constant.builtin
+(integer) @constant.numeric.integer
+(float) @constant.numeric.float
+(comment) @comment
+
+(goto_statement (name) @label)
+(named_label_statement (name) @label)
+
+; Keywords
+
+[
+  "default" 
+  "echo" 
+  "enum" 
+  "extends" 
+  "final" 
+  "goto"
+  "global" 
+  "implements" 
+  "insteadof" 
+  "new" 
+  "private" 
+  "protected" 
+  "public" 
+  "clone"
+  "unset"
+] @keyword
+
+[
+  "if" 
+  "else" 
+  "elseif" 
+  "endif" 
+  "switch" 
+  "endswitch" 
+  "case" 
+  "match" 
+  "declare" 
+  "enddeclare" 
+  "??"
+] @keyword.control.conditional
+
+[
+  "for"
+  "endfor"
+  "foreach" 
+  "endforeach" 
+  "while" 
+  "endwhile" 
+  "do"
+] @keyword.control.repeat
+
+[
+  
+  "include_once" 
+  "include" 
+  "require_once" 
+  "require" 
+  "use"
+] @keyword.control.import
+
+[
+  "return" 
+  "break" 
+  "continue" 
+  "yield"
+] @keyword.control.return
+
+[
+  "throw" 
+  "try" 
+  "catch" 
+  "finally"
+] @keyword.control.exception
+
+[
+  "as" 
+  "or"
+  "xor"
+  "and"
+  "instanceof"
+] @keyword.operator
+
+[
+  "fn" 
+  "function" 
+] @keyword.function
+
+[
+  "namespace" 
+  "class" 
+  "interface" 
+  "trait" 
+  "abstract" 
+] @keyword.storage.type
+
+[
+  "static"
+  "const"
+  "readonly"
+] @keyword.storage.modifier
+
+[
+  ","
+  ";"
+  ":"
+  "\\"
+ ] @punctuation.delimiter
+
+[
+  (php_tag)
+  "?>"
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  "#["
+] @punctuation.bracket
+
+[
+  "="
+
+  "."
+  "-"
+  "*"
+  "/"
+  "+"
+  "%"
+  "**"
+
+  "~"
+  "|"
+  "^"
+  "&"
+  "<<"
+  ">>"
+
+  "->"
+  "?->"
+
+  "=>"
+
+  "<"
+  "<="
+  ">="
+  ">"
+  "<>"
+  "=="
+  "!="
+  "==="
+  "!=="
+
+  "!"
+  "&&"
+  "||"
+
+  ".="
+  "-="
+  "+="
+  "*="
+  "/="
+  "%="
+  "**="
+  "&="
+  "|="
+  "^="
+  "<<="
+  ">>="
+  "??="
+  "--"
+  "++"
+
+  "@"
+  "::"
+] @operator

package/assets/queries/php/indents.scm

@@ -0,0 +1,18 @@
+[
+  (array_creation_expression)
+  (arguments)
+  (formal_parameters)
+  (compound_statement)
+  (declaration_list)
+  (binary_expression)
+  (return_statement)
+  (expression_statement)
+  (switch_block)
+  (anonymous_function_use_clause)
+] @indent
+
+[
+  "}"
+  ")"
+  "]"
+] @outdent

package/assets/queries/php/injections.scm

@@ -0,0 +1,25 @@
+((text) @injection.content
+ (#set! injection.language "html")
+ (#set! injection.combined))
+
+((comment) @injection.content
+ (#set! injection.language "comment"))
+
+((function_call_expression
+ function: (name) @_function
+ arguments: (arguments . (argument (_ (string_value) @injection.content))))
+ (#match? @_function "^preg_")
+ (#set! injection.language "regex"))
+
+((function_call_expression
+ function: (name) @_function
+ arguments: (arguments (_) (argument (_ (string_value) @injection.content))))
+ (#match? @_function "^mysqli_")
+ (#set! injection.language "sql"))
+
+((member_call_expression
+ object: (_)
+ name: (name) @_function
+ arguments: (arguments . (argument (_ (string_value) @injection.content))))
+ (#match? @_function "^(prepare|query)$")
+ (#set! injection.language "sql"))

package/assets/queries/php/rainbows.scm

@@ -0,0 +1,15 @@
+[
+  (declaration_list)
+  (compound_statement)
+  (array_creation_expression)
+  (subscript_expression)
+  (parenthesized_expression)
+  (formal_parameters)
+  (arguments)
+  (catch_clause)
+  (foreach_statement)
+  (switch_block)
+  (anonymous_function_use_clause)
+] @rainbow.scope
+
+["(" ")" "[" "]" "{" "}"] @rainbow.bracket

package/assets/queries/php/tags.scm

@@ -0,0 +1,26 @@
+(class_declaration
+  name: (name) @name) @definition.class
+
+(function_definition
+  name: (name) @name) @definition.function
+
+(method_declaration
+  name: (name) @name) @definition.function
+
+(object_creation_expression
+  [
+    (qualified_name (name) @name)
+    (variable_name (name) @name)
+  ]) @reference.class
+
+(function_call_expression
+  function: [
+    (qualified_name (name) @name)
+    (variable_name (name)) @name
+  ]) @reference.call
+
+(scoped_call_expression
+  name: (name) @name) @reference.call
+
+(member_call_expression
+  name: (name) @name) @reference.call

package/assets/queries/php/textobjects.scm

@@ -0,0 +1,52 @@
+(class_declaration
+  body: (_) @class.inside) @class.around
+
+(interface_declaration
+  body: (_) @class.inside) @class.around
+
+(trait_declaration
+  body: (_) @class.inside) @class.around
+
+(enum_declaration
+  body: (_) @class.inside) @class.around
+
+(function_definition
+  body: (_) @function.inside) @function.around
+
+(method_declaration
+  body: (_) @function.inside) @function.around
+
+(arrow_function 
+  body: (_) @function.inside) @function.around
+  
+(anonymous_function_creation_expression
+  body: (_) @function.inside) @function.around
+
+(anonymous_function_use_clause
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(formal_parameters
+  ([
+    (simple_parameter)
+    (variadic_parameter)
+    (property_promotion_parameter)
+  ] @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(arguments
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(comment) @comment.inside
+
+(comment)+ @comment.around
+
+(array_creation_expression
+  (array_element_initializer
+    (_) @entry.inside
+  ) @entry.around @entry.movement)
+
+(list_literal
+  (_) @entry.inside @entry.around @entry.movement)
+
+[
+  (enum_case)
+] @entry.around @entry.movement