src-mcp 1.0.1

package/assets/queries/scala/textobjects.scm

@@ -0,0 +1,65 @@
+; Function queries
+
+(function_definition
+  body: (_) @function.inside) @function.around ; Does not include end marker
+
+(lambda_expression
+  (_) @function.inside) @function.around
+
+; Scala 3 braceless lambda
+(colon_argument
+  (_) @function.inside) @function.around
+
+
+; Class queries
+
+(object_definition
+  body: (_)? @class.inside) @class.around
+
+(class_definition
+  body: (_)? @class.inside) @class.around
+
+(trait_definition
+  body: (_)? @class.inside) @class.around
+
+(type_definition) @class.around
+
+(enum_case_definitions) @class.around
+
+(enum_definition
+  body: (_)? @class.inside) @class.around
+
+
+; Parameter queries
+
+(parameters
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(class_parameters
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(parameter_types
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(bindings
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+; Does not match context bounds or higher-kinded types
+(type_parameters
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(arguments
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(type_arguments
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+
+; Comment queries
+
+[(comment) (block_comment)] @comment.inside
+[(comment) (block_comment)] @comment.around ; Does not match consecutive block comments
+
+
+; Test queries
+; Not supported

package/assets/queries/svelte/folds.scm

@@ -0,0 +1,13 @@
+; inherits: html
+
+[
+  (if_statement)
+  (else_if_block)
+  (else_block)
+  (each_statement)
+  (await_statement)
+  (then_block)
+  (catch_block)
+  (key_statement)
+  (snippet_statement)
+] @fold

package/assets/queries/svelte/highlights.scm

@@ -0,0 +1,38 @@
+; inherits: html
+
+(raw_text) @none
+
+[
+  "as"
+  "key"
+  "html"
+  "debug"
+  "snippet"
+  "render"
+] @keyword
+
+"const" @keyword.storage.modifier
+
+[
+  "if"
+  "else if"
+  "else"
+  "then"
+  "await"
+] @keyword.control.conditional
+
+"each" @keyword.control.repeat
+
+"catch" @keyword.control.exception
+
+[
+  "{"
+  "}"
+] @punctuation.bracket
+
+[
+  "#"
+  ":"
+  "/"
+  "@"
+] @punctuation.delimiter

package/assets/queries/svelte/indents.scm

@@ -0,0 +1,24 @@
+[
+  (element)
+  (start_tag)
+  (if_statement)
+  (else_if_block)
+  (else_block)
+  (then_block)
+  (each_statement)
+  (key_statement)
+  (snippet_statement)
+  (await_statement)
+  (style_element)
+  (script_element)
+  (expression)
+] @indent
+
+[
+  (end_tag)
+  (if_end)
+  (each_end)
+  (await_end)
+  (key_end)
+  (snippet_end)
+] @outdent

package/assets/queries/svelte/injections.scm

@@ -0,0 +1,46 @@
+; inherits html
+((style_element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @_lang)))
+  (raw_text) @injection.content)
+  (#eq? @_attr "lang")
+  (#any-of? @_lang "scss" "postcss" "less")
+  (#set! injection.language "scss"))
+
+((svelte_raw_text) @injection.content
+  (#set! injection.language "typescript"))
+
+((script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @_lang)))
+  (raw_text) @injection.content)
+  (#eq? @_attr "lang")
+  (#any-of? @_lang "ts" "typescript")
+  (#set! injection.language "typescript"))
+
+((script_element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @_lang)))
+  (raw_text) @injection.content)
+  (#eq? @_attr "lang")
+  (#any-of? @_lang "js" "javascript")
+  (#set! injection.language "javascript"))
+
+((element
+  (start_tag
+    (attribute
+      (attribute_name) @_attr
+      (quoted_attribute_value
+        (attribute_value) @injection.language)))
+  (text) @injection.content)
+  (#eq? @_attr "lang")
+  (#eq? @injection.language "pug"))

package/assets/queries/svelte/locals.scm

@@ -0,0 +1 @@
+; inherits: html

package/assets/queries/swift/highlights.scm

@@ -0,0 +1,200 @@
+; Upstream: https://github.com/alex-pinkus/tree-sitter-swift/blob/57c1c6d6ffa1c44b330182d41717e6fe37430704/queries/highlights.scm
+
+(line_string_literal
+  ["\\(" ")"] @punctuation.special)
+
+["." ";" ":" "," ] @punctuation.delimiter
+["(" ")" "[" "]" "{" "}" "<" ">"] @punctuation.bracket
+
+; Operators
+[
+  "!"
+  "?"
+  "+"
+  "-"
+  "\\"
+  "*"
+  "/"
+  "%"
+  "="
+  "+="
+  "-="
+  "*="
+  "/="
+  "<"
+  ">"
+  "<="
+  ">="
+  "++"
+  "--"
+  "&"
+  "~"
+  "%="
+  "!="
+  "!=="
+  "=="
+  "==="
+  "??"
+
+  "->"
+
+  "..<"
+  "..."
+  (custom_operator)
+] @operator
+
+"?" @type
+(type_annotation "!" @type)
+
+; Identifiers
+(simple_identifier) @variable
+(attribute) @variable
+(type_identifier) @type
+(self_expression) @variable.builtin
+(user_type (type_identifier) @variable.builtin (#eq? @variable.builtin "Self"))
+
+; Declarations
+"func" @keyword.function
+[
+  (visibility_modifier)
+  (member_modifier)
+  (function_modifier)
+  (property_modifier)
+  (parameter_modifier)
+  (inheritance_modifier)
+] @keyword
+
+(function_declaration (simple_identifier) @function.method)
+(protocol_function_declaration (simple_identifier) @function.method)
+(init_declaration ["init" @constructor])
+(deinit_declaration ["deinit" @constructor])
+
+(throws) @keyword
+"async" @keyword
+"await" @keyword
+(where_keyword) @keyword
+(parameter external_name: (simple_identifier) @variable.parameter)
+(parameter name: (simple_identifier) @variable.parameter)
+(type_parameter (type_identifier) @variable.parameter)
+(inheritance_constraint (identifier (simple_identifier) @variable.parameter))
+(equality_constraint (identifier (simple_identifier) @variable.parameter))
+(pattern bound_identifier: (simple_identifier)) @variable
+
+[
+  "typealias"
+  "struct"
+  "class"
+  "actor"
+  "enum"
+  "protocol"
+  "extension"
+  "indirect"
+  "nonisolated"
+  "override"
+  "convenience"
+  "required"
+  "mutating"
+  "associatedtype"
+  "package"
+  "any"
+] @keyword
+
+(opaque_type ["some" @keyword])
+(existential_type ["any" @keyword])
+
+(precedence_group_declaration
+ ["precedencegroup" @keyword]
+ (simple_identifier) @type)
+(precedence_group_attribute
+ (simple_identifier) @keyword
+ [(simple_identifier) @type
+  (boolean_literal) @constant.builtin.boolean])
+
+[
+  (getter_specifier)
+  (setter_specifier)
+  (modify_specifier)
+] @keyword
+
+(class_body (property_declaration (pattern (simple_identifier) @variable.other.member)))
+(protocol_property_declaration (pattern (simple_identifier) @variable.other.member))
+
+(import_declaration "import" @keyword.control.import)
+
+(enum_entry "case" @keyword)
+
+; Function calls
+(call_expression (simple_identifier) @function) ; foo()
+(call_expression ; foo.bar.baz(): highlight the baz()
+  (navigation_expression
+    (navigation_suffix (simple_identifier) @function)))
+((navigation_expression
+   (simple_identifier) @type) ; SomeType.method(): highlight SomeType as a type
+   (#match? @type "^[A-Z]"))
+(call_expression (simple_identifier) @keyword (#eq? @keyword "defer")) ; defer { ... }
+
+(navigation_suffix
+  (simple_identifier) @variable.other.member)
+
+(try_operator) @operator
+(try_operator ["try" @keyword])
+
+(directive) @function.macro
+(diagnostic) @function.macro
+
+; Statements
+(for_statement "for" @keyword.control.repeat)
+(for_statement "in" @keyword.control.repeat)
+(for_statement item: (simple_identifier) @variable)
+(else) @keyword
+(as_operator) @keyword
+
+["while" "repeat" "continue" "break"] @keyword.control.repeat
+
+["let" "var"] @keyword
+
+(guard_statement "guard" @keyword.control.conditional)
+(if_statement "if" @keyword.control.conditional)
+(switch_statement "switch" @keyword.control.conditional)
+(switch_entry "case" @keyword)
+(switch_entry "fallthrough" @keyword)
+(switch_entry (default_keyword) @keyword)
+"return" @keyword.return
+(ternary_expression
+  ["?" ":"] @keyword.control.conditional)
+
+["do" (throw_keyword) (catch_keyword)] @keyword
+
+(statement_label) @label
+
+; Comments
+(comment) @comment
+(multiline_comment) @comment
+
+; String literals
+(line_str_text) @string
+(str_escaped_char) @string
+(multi_line_str_text) @string
+(raw_str_part) @string
+(raw_str_end_part) @string
+(raw_str_interpolation_start) @punctuation.special
+["\"" "\"\"\""] @string
+
+; Lambda literals
+(lambda_literal "in" @keyword.operator)
+
+; Basic literals
+[
+  (hex_literal)
+  (oct_literal)
+  (bin_literal)
+] @constant.numeric
+(integer_literal) @constant.numeric.integer
+(real_literal) @constant.numeric.float
+(boolean_literal) @constant.builtin.boolean
+"nil" @constant.builtin
+
+(value_parameter_pack ["each" @keyword])
+(value_pack_expansion ["repeat" @keyword])
+(type_parameter_pack ["each" @keyword])
+(type_pack_expansion ["repeat" @keyword])

package/assets/queries/swift/indents.scm

@@ -0,0 +1,100 @@
+[
+  (protocol_body)
+  (class_body)
+  (enum_class_body)
+  (function_declaration)
+  (init_declaration)
+  (deinit_declaration)
+  (computed_property)
+  (subscript_declaration)
+  (computed_getter)
+  (computed_setter)
+  (for_statement)
+  (while_statement)
+  (repeat_while_statement)
+  (do_statement)
+  (if_statement)
+  (switch_statement)
+  (guard_statement)
+  (type_parameters)
+  (tuple_type)
+  (array_type)
+  (dictionary_type)
+  (call_expression)
+  (tuple_expression)
+  (array_literal)
+  (dictionary_literal)
+  (lambda_literal)
+  (willset_didset_block)
+  (willset_clause)
+  (didset_clause)
+  (value_arguments)
+] @indent
+
+[
+  "}"
+  "]"
+  ")"
+  ">"
+] @outdent
+
+(assignment
+  .
+  (_) @expr-start
+  (_) @indent
+  (#not-same-line? @indent @expr-start)
+  (#set! "scope" "all")
+)
+
+(control_transfer_statement
+  .
+  (_) @expr-start
+  (_) @indent
+  (#not-same-line? @indent @expr-start)
+  (#set! "scope" "all")
+)
+
+(if_statement
+  (if_statement) @outdent
+)
+
+(switch_entry
+  .
+  _ @indent
+  (#set! "scope" "tail")
+)
+
+(init_declaration
+  (parameter) @indent
+)
+
+(modifiers
+  (attribute) @indent
+)
+
+(type_parameters
+  ">" @outdent
+)
+
+(tuple_expression
+  ")" @outdent
+)
+
+(tuple_type
+  ")" @outdent
+)
+
+(modifiers
+  (attribute
+    ")" @outdent
+  )
+)
+
+(ERROR
+  [
+    "<"
+    "{"
+    "("
+    "["
+  ]
+) @indent

package/assets/queries/swift/injections.scm

@@ -0,0 +1,10 @@
+; Upstream: https://github.com/alex-pinkus/tree-sitter-swift/blob/57c1c6d6ffa1c44b330182d41717e6fe37430704/queries/injections.scm
+
+; Parse regex syntax within regex literals
+
+((regex_literal) @injection.content
+ (#set! injection.language "regex"))
+
+((comment) @injection.content
+ (#set! injection.language "comment")
+ (#set! injection.include-children))

package/assets/queries/swift/locals.scm

@@ -0,0 +1,19 @@
+; Upstream: https://github.com/alex-pinkus/tree-sitter-swift/blob/57c1c6d6ffa1c44b330182d41717e6fe37430704/queries/locals.scm
+(import_declaration (identifier) @local.definition.namespace)
+(function_declaration name: (simple_identifier) @local.definition.function)
+
+; Scopes
+[
+ (for_statement)
+ (while_statement)
+ (repeat_while_statement)
+ (do_statement)
+ (if_statement)
+ (guard_statement)
+ (switch_statement)
+ (property_declaration)
+ (function_declaration)
+ (class_declaration)
+ (protocol_declaration)
+ (lambda_literal)
+] @local.scope

package/assets/queries/swift/rainbows.scm

@@ -0,0 +1,60 @@
+[
+  (array_literal)
+  (array_type)
+  (attribute)
+  (availability_condition)
+  (call_expression)
+  (call_suffix)
+  (catch_block)
+  (class_body)
+  (class_declaration)
+  (computed_getter)
+  (computed_property)
+  (computed_setter)
+  (dictionary_literal)
+  (dictionary_type)
+  (didset_clause)
+  (do_statement)
+  (enum_class_body)
+  (enum_entry)
+  (enum_type_parameters)
+  (for_statement)
+  (function_body)
+  (function_declaration)
+  (guard_statement)
+  (if_statement)
+  (init_declaration)
+  (lambda_literal)
+  (line_string_literal)
+  (modifiers)
+  (navigation_expression)
+  (optional_type)
+  (pattern)
+  (protocol_body)
+  (protocol_declaration)
+  (protocol_function_declaration)
+  (protocol_property_requirements)
+  (property_declaration)
+  (source_file)
+  (statements)
+  (subscript_declaration)
+  (switch_entry)
+  (switch_pattern)
+  (switch_statement)
+  (tuple_expression)
+  (tuple_type)
+  (tuple_type_item)
+  (type_annotation)
+  (value_arguments)
+  (visibility_modifier)
+  (while_statement)
+  (willset_didset_block)
+] @rainbow.scope
+
+[
+  "(" ")"
+  "[" "]"
+  "{" "}"
+  "<" ">"
+  "\\("
+] @rainbow.bracket

package/assets/queries/swift/textobjects.scm

@@ -0,0 +1,23 @@
+(class_declaration
+  body: (_) @class.inside) @class.around
+
+(protocol_declaration
+  body: (_) @class.inside) @class.around
+
+(function_declaration
+  body: (_) @function.inside) @function.around
+
+(parameter
+  (_) @parameter.inside) @parameter.around
+
+(lambda_parameter
+  (_) @parameter.inside) @parameter.around
+
+[
+  (comment)
+  (multiline_comment)
+] @comment.inside
+
+(comment)+ @comment.around
+
+(multiline_comment) @comment.around

package/assets/queries/tsx/highlights.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: ecma,_typescript,_jsx

package/assets/queries/tsx/indents.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _jsx,_typescript,ecma

package/assets/queries/tsx/injections.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _jsx,_typescript,ecma

package/assets/queries/tsx/locals.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _jsx,_typescript,ecma

package/assets/queries/tsx/rainbows.scm

@@ -0,0 +1,2 @@
+; inherits: typescript
+; inherits: jsx

package/assets/queries/tsx/tags.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _jsx,_typescript,ecma

package/assets/queries/tsx/textobjects.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _jsx,_typescript,ecma

package/assets/queries/typescript/highlights.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: ecma,_typescript

package/assets/queries/typescript/indents.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _typescript,ecma

package/assets/queries/typescript/injections.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _typescript,ecma

package/assets/queries/typescript/locals.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _typescript,ecma

package/assets/queries/typescript/rainbows.scm

@@ -0,0 +1,19 @@
+; inherits: ecma
+
+[
+  (import_require_clause)
+  (enum_body)
+  (lookup_type)
+  (parenthesized_type)
+  (object_type)
+  (type_parameters)
+  (index_signature)
+  (array_type)
+  (tuple_type)
+] @rainbow.scope
+
+(type_arguments ["<" ">"] @rainbow.bracket) @rainbow.scope
+
+[
+  "{|" "|}"
+] @rainbow.bracket

package/assets/queries/typescript/tags.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _typescript,ecma

package/assets/queries/typescript/textobjects.scm

@@ -0,0 +1,3 @@
+; See runtime/queries/ecma/README.md for more info.
+
+; inherits: _typescript,ecma