src-mcp 1.0.1

package/assets/queries/cpp/highlights.scm

@@ -0,0 +1,177 @@
+; inherits: c
+
+; Constants
+
+(this) @variable.builtin
+(null) @constant.builtin
+
+; Types
+
+(using_declaration ("using" "namespace" (identifier) @namespace))
+(using_declaration ("using" "namespace" (qualified_identifier name: (identifier) @namespace)))
+(namespace_definition name: (namespace_identifier) @namespace)
+(namespace_identifier) @namespace
+
+(auto) @type
+"decltype" @type
+
+(ref_qualifier ["&" "&&"] @type.builtin)
+(reference_declarator ["&" "&&"] @type.builtin)
+(abstract_reference_declarator ["&" "&&"] @type.builtin)
+
+; -------
+; Functions
+; -------
+; Support up to 4 levels of nesting of qualifiers
+; i.e. a::b::c::d::func();
+(call_expression
+  function: (qualified_identifier
+    name: (identifier) @function))
+(call_expression
+  function: (qualified_identifier
+    name: (qualified_identifier
+      name: (identifier) @function)))
+(call_expression
+  function: (qualified_identifier
+    name: (qualified_identifier
+      name: (qualified_identifier
+        name: (identifier) @function))))
+(call_expression
+  function: (qualified_identifier
+    name: (qualified_identifier
+      name: (qualified_identifier
+        name: (qualified_identifier
+          name: (identifier) @function)))))
+
+(template_function
+  name: (identifier) @function)
+
+(template_method
+  name: (field_identifier) @function)
+
+; Support up to 4 levels of nesting of qualifiers
+; i.e. a::b::c::d::func();
+(function_declarator
+  declarator: (qualified_identifier
+    name: (identifier) @function))
+(function_declarator
+  declarator: (qualified_identifier
+    name: (qualified_identifier
+      name: (identifier) @function)))
+(function_declarator
+  declarator: (qualified_identifier
+    name: (qualified_identifier
+      name: (qualified_identifier
+        name: (identifier) @function))))
+(function_declarator
+  declarator: (qualified_identifier
+    name: (qualified_identifier
+      name: (qualified_identifier
+        name: (qualified_identifier
+          name: (identifier) @function)))))
+
+(function_declarator
+  declarator: (field_identifier) @function)
+
+; Constructors
+
+(class_specifier
+  (type_identifier) @type
+  (field_declaration_list
+    (function_definition
+      (function_declarator
+        (identifier) @constructor)))
+        (#eq? @type @constructor)) 
+(destructor_name "~" @constructor
+  (identifier) @constructor)
+
+; Parameters
+
+(parameter_declaration
+  declarator: (reference_declarator (identifier) @variable.parameter))
+(optional_parameter_declaration
+  declarator: (identifier) @variable.parameter)
+
+; Keywords
+
+(template_argument_list (["<" ">"] @punctuation.bracket))
+(template_parameter_list (["<" ">"] @punctuation.bracket))
+(default_method_clause "default" @keyword)
+
+"static_assert" @function.special
+
+[
+  "<=>"
+  "[]"
+  "()"
+] @operator
+
+
+; These casts are parsed as function calls, but are not.
+((identifier) @keyword (#eq? @keyword "static_cast"))
+((identifier) @keyword (#eq? @keyword "dynamic_cast"))
+((identifier) @keyword (#eq? @keyword "reinterpret_cast"))
+((identifier) @keyword (#eq? @keyword "const_cast"))
+
+[
+  "co_await"
+  "co_return"
+  "co_yield"
+  "concept"
+  "delete"
+  "new"
+  "operator"
+  "requires"
+  "using"
+] @keyword
+
+[
+  "catch"
+  "noexcept"
+  "throw"
+  "try"
+] @keyword.control.exception
+
+
+[
+  "and"
+  "and_eq"
+  "bitor"
+  "bitand"
+  "not"
+  "not_eq"
+  "or"
+  "or_eq"
+  "xor"
+  "xor_eq"
+] @keyword.operator
+
+[
+  "class"  
+  "namespace"
+  "typename"
+  "template"
+] @keyword.storage.type
+
+[
+  "constexpr"
+  "constinit"
+  "consteval"
+  "mutable"
+] @keyword.storage.modifier
+
+; Modifiers that aren't plausibly type/storage related.
+[
+  "explicit"
+  "friend"
+  "virtual"
+  (virtual_specifier) ; override/final
+  "private"
+  "protected"
+  "public"
+  "inline" ; C++ meaning differs from C!
+] @keyword
+
+; Strings
+
+(raw_string_literal) @string

package/assets/queries/cpp/indents.scm

@@ -0,0 +1,3 @@
+; inherits: c
+
+(access_specifier) @outdent

package/assets/queries/cpp/injections.scm

@@ -0,0 +1,4 @@
+; inherits: c
+(raw_string_literal
+  delimiter: (raw_string_delimiter) @injection.language
+  (raw_string_content) @injection.content)

package/assets/queries/cpp/rainbows.scm

@@ -0,0 +1,49 @@
+[
+  ; c
+  (preproc_params)
+  (preproc_defined)
+  (argument_list)
+  (attribute_specifier)
+  (ms_declspec_modifier)
+  (declaration_list)
+  (parenthesized_declarator)
+  (parenthesized_expression)
+  (abstract_parenthesized_declarator)
+  (array_declarator)
+  (compound_statement)
+  (initializer_list)
+  (compound_literal_expression)
+  (enumerator_list)
+  (field_declaration_list)
+  (parameter_list)
+  (for_statement)
+  ; (macro_type_specifier) - not part of cpp
+  (subscript_expression)
+  (subscript_designator)
+  (cast_expression)
+
+  ; cpp
+  (decltype)
+  (explicit_function_specifier)
+  (template_parameter_list)
+  (template_argument_list)
+  (parameter_list)
+  (argument_list)
+  (structured_binding_declarator)
+  (noexcept)
+  (throw_specifier)
+  (static_assert_declaration)
+  (condition_clause)
+  (for_range_loop)
+  (new_declarator)
+  (delete_expression "[" "]")
+  (lambda_capture_specifier)
+  (sizeof_expression)
+] @rainbow.scope
+
+[
+  "(" ")"
+  "{" "}"
+  "[" "]"
+  "<" ">"
+] @rainbow.bracket

package/assets/queries/cpp/tags.scm

@@ -0,0 +1,12 @@
+; inherits: c
+
+(function_declarator
+  declarator: (qualified_identifier name: (identifier) @definition.function))
+
+(struct_specifier
+  name: (type_identifier) @definition.struct
+  body: (field_declaration_list))
+
+(class_specifier
+  name: (type_identifier) @definition.class
+  body: (field_declaration_list))

package/assets/queries/cpp/textobjects.scm

@@ -0,0 +1,7 @@
+; inherits: c
+
+(lambda_expression
+  body: (_) @function.inside) @function.around
+
+(class_specifier
+  body: (_) @class.inside) @class.around

package/assets/queries/ecma/highlights.scm

@@ -0,0 +1,288 @@
+; Tokens
+;-------
+
+[
+  ";"
+  (optional_chain) ; ?.
+  "."
+  ","
+] @punctuation.delimiter
+
+[
+  "-"
+  "--"
+  "-="
+  "+"
+  "++"
+  "+="
+  "*"
+  "*="
+  "**"
+  "**="
+  "/"
+  "/="
+  "%"
+  "%="
+  "<"
+  "<="
+  "<<"
+  "<<="
+  "="
+  "=="
+  "==="
+  "!"
+  "!="
+  "!=="
+  "=>"
+  ">"
+  ">="
+  ">>"
+  ">>="
+  ">>>"
+  ">>>="
+  "~"
+  "^"
+  "&"
+  "|"
+  "^="
+  "&="
+  "|="
+  "&&"
+  "||"
+  "??"
+  "&&="
+  "||="
+  "??="
+  "..."
+] @operator
+
+(ternary_expression ["?" ":"] @operator)
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+]  @punctuation.bracket
+
+(template_substitution
+  "${" @punctuation.special
+  "}" @punctuation.special) @embedded
+
+[
+  "async"
+  "debugger"
+  "extends"
+  "from"
+  "get"
+  "new"
+  "set"
+  "target"
+  "with"
+] @keyword
+
+[
+  "of"
+  "as"
+  "in"
+  "delete"
+  "typeof"
+  "instanceof"
+  "void"
+] @keyword.operator
+
+[
+  "function"
+] @keyword.function
+
+[
+  "class"
+  "let"
+  "var"
+] @keyword.storage.type
+
+[
+  "const"
+  "static"
+] @keyword.storage.modifier
+
+[
+  "default"
+  "yield"
+  "finally"
+  "do"
+  "await"
+] @keyword.control
+
+[
+  "if"
+  "else"
+  "switch"
+  "case"
+] @keyword.control.conditional
+
+[
+  "while"
+  "for"
+] @keyword.control.repeat
+
+[
+  "import"
+  "export"
+] @keyword.control.import
+
+[
+  "return"
+  "break"
+  "continue"
+] @keyword.control.return
+
+[
+  "throw"
+  "try"
+  "catch"
+] @keyword.control.exception
+
+; Variables
+;----------
+
+(identifier) @variable
+
+; Properties
+;-----------
+
+(property_identifier) @variable.other.member
+(private_property_identifier) @variable.other.member.private
+(shorthand_property_identifier) @variable.other.member
+(shorthand_property_identifier_pattern) @variable.other.member
+
+; Function and method definitions
+;--------------------------------
+
+(function_expression
+  name: (identifier) @function)
+(function_declaration
+  name: (identifier) @function)
+(method_definition
+  name: (property_identifier) @function.method)
+(method_definition
+  name: (private_property_identifier) @function.method.private)
+
+(pair
+  key: (property_identifier) @function.method
+  value: [(function_expression) (arrow_function)])
+(pair
+  key: (private_property_identifier) @function.method.private
+  value: [(function_expression) (arrow_function)])
+
+(assignment_expression
+  left: (member_expression
+    property: (property_identifier) @function.method)
+  right: [(function_expression) (arrow_function)])
+(assignment_expression
+  left: (member_expression
+    property: (private_property_identifier) @function.method.private)
+  right: [(function_expression) (arrow_function)])
+
+(variable_declarator
+  name: (identifier) @function
+  value: [(function_expression) (arrow_function)])
+
+(assignment_expression
+  left: (identifier) @function
+  right: [(function_expression) (arrow_function)])
+
+; Function and method parameters
+;-------------------------------
+
+; Arrow function parameters in the form `p => ...` are supported by both
+; javascript and typescript grammars without conflicts.
+(arrow_function
+  parameter: (identifier) @variable.parameter)
+
+; Function and method calls
+;--------------------------
+
+(call_expression
+  function: (identifier) @function)
+
+(call_expression
+  function: (member_expression
+    property: (property_identifier) @function.method))
+(call_expression
+  function: (member_expression
+    property: (private_property_identifier) @function.method.private))
+
+; Literals
+;---------
+
+(this) @variable.builtin
+(super) @variable.builtin
+
+[
+  (null)
+  (undefined)
+] @constant.builtin
+
+[
+  (true)
+  (false)
+] @constant.builtin.boolean
+
+(comment) @comment
+
+[
+  (string)
+  (template_string)
+] @string
+
+(escape_sequence) @constant.character.escape
+
+(regex) @string.regexp
+(number) @constant.numeric.integer
+
+; Special identifiers
+;--------------------
+
+((identifier) @constructor
+ (#match? @constructor "^[A-Z]"))
+
+([
+    (identifier)
+    (shorthand_property_identifier)
+    (shorthand_property_identifier_pattern)
+ ] @constant
+ (#match? @constant "^[A-Z_][A-Z\\d_]+$"))
+
+((identifier) @variable.builtin
+ (#match? @variable.builtin "^(arguments|module|console|window|document)$")
+ (#is-not? local))
+
+(call_expression
+ (identifier) @function.builtin
+ (#any-of? @function.builtin
+  "eval"
+  "fetch"
+  "isFinite"
+  "isNaN"
+  "parseFloat"
+  "parseInt"
+  "decodeURI"
+  "decodeURIComponent"
+  "encodeURI"
+  "encodeURIComponent"
+  "require"
+  "alert"
+  "prompt"
+  "btoa"
+  "atob"
+  "confirm"
+  "structuredClone"
+  "setTimeout"
+  "clearTimeout"
+  "setInterval"
+  "clearInterval"
+  "queueMicrotask")
+ (#is-not? local))

package/assets/queries/ecma/indents.scm

@@ -0,0 +1,28 @@
+[
+  (array)
+  (object)
+  (arguments)
+  (formal_parameters)
+
+  (statement_block)
+  (switch_statement)
+  (object_pattern)
+  (class_body)
+  (named_imports)
+
+  (binary_expression)
+  (return_statement)
+  (template_substitution)
+  (export_clause)
+] @indent
+
+[
+  (switch_case)
+  (switch_default)
+] @indent @extend
+
+[
+  "}"
+  "]"
+  ")"
+] @outdent

package/assets/queries/ecma/injections.scm

@@ -0,0 +1,100 @@
+; Parse the contents of tagged template literals using
+; a language inferred from the tag.
+
+(call_expression
+  function: [
+    (identifier) @injection.language
+    (member_expression
+      property: (property_identifier) @injection.language)
+  ]
+  arguments: (template_string) @injection.content
+  (#any-of? @injection.language "html" "css" "json" "sql" "js" "ts" "bash"))
+
+; Parse the contents of $ template literals as shell commands
+
+(call_expression
+  function: [
+    (identifier) @_template_function_name
+    (member_expression
+      property: (property_identifier) @_template_function_name)
+  ]
+  arguments: (template_string) @injection.content
+ (#eq? @_template_function_name "$")
+ (#set! injection.language "bash"))
+
+; GraphQL detection generally matches the rules provided by the 'GraphQL: Syntax Highlighting'
+; VSCode extension: https://github.com/graphql/graphiql/blob/8f25b38f4ab14dc99c046109f255fb283bccde52/packages/vscode-graphql-syntax/grammars/graphql.js.json
+
+; Parse the contents of 'gql' and 'graphql' template literals and function calls
+(
+  (call_expression
+    function: (identifier) @_template_function_name
+    arguments: [
+      ; Tagged template literal: NAME``
+      (template_string (string_fragment) @injection.content)
+      (
+        arguments . [
+          ; Function call containing a string literal: NAME('')
+          (string (string_fragment) @injection.content)
+          ; Function call containing a template literal: NAME(``)
+          (template_string (string_fragment) @injection.content)
+        ]
+      )
+    ]
+  )
+  (#any-of? @_template_function_name "gql" "graphql")
+  (#set! injection.language "graphql")
+)
+
+; Parse the contents of strings and tagged template literals that begin with a GraphQL comment '#graphql'
+(
+  [
+    (string (string_fragment) @injection.content)
+    (template_string (string_fragment) @injection.content)
+  ]
+  (#match? @injection.content "^\\s*#graphql")
+  (#set! injection.language "graphql")
+)
+
+; Parse the contents of strings and tagged template literals with leading ECMAScript comments '/* GraphQL */'
+(
+  ((comment) @_ecma_comment [
+    (string (string_fragment) @injection.content)
+    (template_string (string_fragment) @injection.content)
+  ])
+  (#eq? @_ecma_comment "/* GraphQL */")
+  (#set! injection.language "graphql")
+)
+
+; Parse regex syntax within regex literals
+
+((regex_pattern) @injection.content
+ (#set! injection.language "regex"))
+
+; Parse JSDoc annotations in multiline comments
+
+((comment) @injection.content
+ (#set! injection.language "jsdoc")
+ (#match? @injection.content "^/\\*+"))
+
+; Parse general tags in single line comments
+
+((comment) @injection.content
+ (#set! injection.language "comment")
+ (#match? @injection.content "^//"))
+
+; Match string literals passed to standard browser API methods that expects a
+; css selector as argument.
+; - https://developer.mozilla.org/en-US/docs/Web/API/Document/querySelector
+; - https://developer.mozilla.org/en-US/docs/Web/API/Document/querySelectorAll
+; - https://developer.mozilla.org/en-US/docs/Web/API/Element/closest
+; - https://developer.mozilla.org/en-US/docs/Web/API/Element/matches
+; e.g.
+; `const el = document.querySelector("div.user-panel.main input[name='login']");`
+(call_expression
+  function: (member_expression
+    object: (identifier) @_object
+    property: (property_identifier) @_property (#any-of? @_property "querySelector" "querySelectorAll" "closest" "matches"))
+  arguments: (arguments
+               (string (string_fragment) @injection.content))
+  (#set! injection.language "css"))

package/assets/queries/ecma/locals.scm

@@ -0,0 +1,26 @@
+; Scopes
+;-------
+
+[
+  (statement_block)
+  (arrow_function)
+  (function_expression)
+  (function_declaration)
+  (method_definition)
+  (for_statement)
+  (for_in_statement)
+  (catch_clause)
+  (finally_clause)
+] @local.scope
+
+; Definitions
+;------------
+
+; i => ...
+(arrow_function
+  parameter: (identifier) @local.definition.variable.parameter)
+
+; References
+;------------
+
+(identifier) @local.reference