src-mcp 1.0.1

package/assets/queries/c/highlights.scm

@@ -0,0 +1,167 @@
+
+(identifier) @variable
+
+((identifier) @constant
+  (#match? @constant "^[A-Z][A-Z\\d_]*$"))
+
+"sizeof" @keyword
+
+[
+  "enum"
+  "struct"
+  "typedef"
+  "union"
+] @keyword.storage.type
+
+[
+  (type_qualifier)
+  (storage_class_specifier)
+] @keyword.storage.modifier
+
+[
+  "goto"
+  "break"
+  "continue"
+] @keyword.control
+
+[
+  "do"
+  "for"
+  "while"
+] @keyword.control.repeat
+
+[
+  "if"
+  "else"
+  "switch"
+  "case"
+  "default"
+] @keyword.control.conditional
+
+"return" @keyword.control.return
+
+[
+  "defined"
+  "#define"
+  "#elif"
+  "#else"
+  "#endif"
+  "#if"
+  "#ifdef"
+  "#ifndef"
+  "#include"
+  (preproc_directive)
+] @keyword.directive
+
+"..." @punctuation
+
+["," "." ":" "::" ";" "->"] @punctuation.delimiter
+
+["(" ")" "[" "]" "{" "}" "[[" "]]"] @punctuation.bracket
+
+[
+  "+"
+  "-"
+  "*"
+  "/"
+  "++"
+  "--"
+  "%"
+  "=="
+  "!="
+  ">"
+  "<"
+  ">="
+  "<="
+  "&&"
+  "||"
+  "!"
+  "&"
+  "|"
+  "^"
+  "~"
+  "<<"
+  ">>"
+  "="
+  "+="
+  "-="
+  "*="
+  "/="
+  "%="
+  "<<="
+  ">>="
+  "&="
+  "^="
+  "|="
+  "?"
+] @operator
+
+(conditional_expression ":" @operator) ; After punctuation
+
+(pointer_declarator "*" @type.builtin) ; After Operators
+(abstract_pointer_declarator "*" @type.builtin)
+
+
+[(true) (false)] @constant.builtin.boolean
+
+(enumerator name: (identifier) @type.enum.variant)
+
+(string_literal) @string
+(system_lib_string) @string
+
+(null) @constant
+(number_literal) @constant.numeric
+(char_literal) @constant.character
+(escape_sequence) @constant.character.escape
+
+(field_identifier) @variable.other.member
+(statement_identifier) @label
+(type_identifier) @type
+(primitive_type) @type.builtin
+(sized_type_specifier) @type.builtin
+
+(call_expression
+  function: (identifier) @function)
+(call_expression
+  function: (field_expression
+    field: (field_identifier) @function))
+(call_expression (argument_list (identifier) @variable))
+(function_declarator
+  declarator: [(identifier) (field_identifier)] @function)
+
+; Up to 6 layers of declarators
+(parameter_declaration
+  declarator: (identifier) @variable.parameter)
+(parameter_declaration
+  (_
+    (identifier) @variable.parameter))
+(parameter_declaration
+  (_
+    (_
+      (identifier) @variable.parameter)))
+(parameter_declaration
+  (_
+    (_
+      (_
+        (identifier) @variable.parameter))))
+(parameter_declaration
+  (_
+    (_
+      (_
+        (_
+          (identifier) @variable.parameter)))))
+(parameter_declaration
+  (_
+    (_
+      (_
+        (_
+          (_
+            (identifier) @variable.parameter))))))
+
+(preproc_function_def
+  name: (identifier) @function.special)
+
+(attribute
+  name: (identifier) @attribute)
+
+(comment) @comment

package/assets/queries/c/indents.scm

@@ -0,0 +1,51 @@
+[
+  (compound_statement)
+  (declaration_list)
+  (field_declaration_list)
+  (enumerator_list)
+  (parameter_list)
+  (init_declarator)
+  (expression_statement)
+] @indent
+
+[
+  "case"
+  "}"
+  "]"
+  ")"
+] @outdent
+
+(if_statement
+  consequence: (_) @indent
+  (#not-kind-eq? @indent "compound_statement")
+  (#set! "scope" "all"))
+(while_statement
+  body: (_) @indent
+  (#not-kind-eq? @indent "compound_statement")
+  (#set! "scope" "all"))
+(do_statement
+  body: (_) @indent
+  (#not-kind-eq? @indent "compound_statement")
+  (#set! "scope" "all"))
+(for_statement
+  ")"
+  (_) @indent
+  (#not-kind-eq? @indent "compound_statement")
+  (#set! "scope" "all"))
+
+(parameter_list
+  . (parameter_declaration) @anchor
+  (#set! "scope" "tail")) @align
+(argument_list
+  . (_) @anchor
+  (#set! "scope" "tail")) @align
+; These are a bit opinionated since some people just indent binary/ternary expressions spanning multiple lines.
+; Since they are only triggered when a newline is inserted into an already complete binary/ternary expression,
+; this should happen rarely, so it is not a big deal either way.
+; Additionally, adding these queries has the advantage of preventing such continuation lines from being used
+; as the baseline when the `hybrid` indent heuristic is used (which is desirable since their indentation is so inconsistent). 
+(binary_expression
+  (#set! "scope" "tail")) @anchor @align
+(conditional_expression
+  "?" @anchor
+  (#set! "scope" "tail")) @align

package/assets/queries/c/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))

package/assets/queries/c/locals.scm

@@ -0,0 +1,38 @@
+;; Scopes
+(function_definition) @local.scope
+
+;; Definitions
+
+; Parameters
+; Up to 6 layers of declarators
+(parameter_declaration
+  (identifier) @local.definition.variable.parameter)
+(parameter_declaration
+  (_
+    (identifier) @local.definition.variable.parameter))
+(parameter_declaration
+  (_
+    (_
+      (identifier) @local.definition.variable.parameter)))
+(parameter_declaration
+  (_
+    (_
+      (_
+        (identifier) @local.definition.variable.parameter))))
+(parameter_declaration
+  (_
+    (_
+      (_
+        (_
+          (identifier) @local.definition.variable.parameter)))))
+(parameter_declaration
+  (_
+    (_
+      (_
+        (_
+          (_
+            (identifier) @local.definition.variable.parameter))))))
+
+;; References
+
+(identifier) @local.reference

package/assets/queries/c/rainbows.scm

@@ -0,0 +1,29 @@
+[
+  (preproc_params)
+  (preproc_defined)
+  (argument_list)
+  (attribute_specifier)
+  (ms_declspec_modifier)
+  (declaration_list)
+  (parenthesized_declarator)
+  (parenthesized_expression)
+  (abstract_parenthesized_declarator)
+  (array_declarator)
+  (compound_statement)
+  (initializer_list)
+  (compound_literal_expression)
+  (enumerator_list)
+  (field_declaration_list)
+  (parameter_list)
+  (for_statement)
+  (macro_type_specifier)
+  (subscript_expression)
+  (subscript_designator)
+  (cast_expression)
+] @rainbow.scope
+
+[
+  "(" ")"
+  "{" "}"
+  "[" "]"
+] @rainbow.bracket

package/assets/queries/c/tags.scm

@@ -0,0 +1,9 @@
+(function_declarator
+  declarator: [(identifier) (field_identifier)] @definition.function)
+
+(preproc_function_def name: (identifier) @definition.function)
+
+(type_definition
+  declarator: (type_identifier) @definition.type)
+
+(preproc_def name: (identifier) @definition.constant)

package/assets/queries/c/textobjects.scm

@@ -0,0 +1,27 @@
+(function_definition
+  body: (_) @function.inside) @function.around
+
+(struct_specifier
+  body: (_) @class.inside) @class.around
+
+(enum_specifier
+  body: (_) @class.inside) @class.around
+
+(union_specifier
+  body: (_) @class.inside) @class.around
+
+(parameter_list 
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(argument_list
+  ((_) @parameter.inside . ","? @parameter.around) @parameter.around)
+
+(comment) @comment.inside
+
+(comment)+ @comment.around
+
+(enumerator
+  (_) @entry.inside) @entry.around
+
+(initializer_list
+  (_) @entry.around)

package/assets/queries/c_sharp/highlights.scm

@@ -0,0 +1,208 @@
+(identifier) @variable
+
+;; Methods
+
+(method_declaration name: (identifier) @function)
+(local_function_statement name: (identifier) @function)
+
+;; Types
+
+(interface_declaration name: (identifier) @type)
+(class_declaration name: (identifier) @type)
+(enum_declaration name: (identifier) @type)
+(struct_declaration (identifier) @type)
+(record_declaration (identifier) @type)
+(namespace_declaration name: (identifier) @namespace)
+
+(generic_name (identifier) @type)
+(type_parameter (identifier) @type.parameter)
+(parameter type: (identifier) @type)
+(type_argument_list (identifier) @type)
+(as_expression right: (identifier) @type)
+(is_expression right: (identifier) @type)
+
+(constructor_declaration name: (identifier) @constructor)
+(destructor_declaration name: (identifier) @constructor)
+
+(_ type: (identifier) @type)
+
+(base_list (identifier) @type)
+
+(predefined_type) @type.builtin
+
+;; Enum
+(enum_member_declaration (identifier) @type.enum.variant)
+
+;; Literals
+
+(real_literal) @constant.numeric.float
+(integer_literal) @constant.numeric.integer
+(character_literal) @constant.character
+
+[
+  (string_literal)
+  (raw_string_literal)
+  (verbatim_string_literal)
+  (interpolated_string_expression)
+  (interpolation_start)
+  (interpolation_quote)
+ ] @string
+
+(escape_sequence) @constant.character.escape
+
+(boolean_literal) @constant.builtin.boolean
+(null_literal) @constant.builtin
+
+;; Comments
+
+(comment) @comment
+
+;; Tokens
+
+[
+  ";"
+  "."
+  ","
+] @punctuation.delimiter
+
+[
+  "--"
+  "-"
+  "-="
+  "&"
+  "&="
+  "&&"
+  "+"
+  "++"
+  "+="
+  "<"
+  "<="
+  "<<"
+  "<<="
+  "="
+  "=="
+  "!"
+  "!="
+  "=>"
+  ">"
+  ">="
+  ">>"
+  ">>="
+  ">>>"
+  ">>>="
+  "|"
+  "|="
+  "||"
+  "?"
+  "??"
+  "??="
+  "^"
+  "^="
+  "~"
+  "*"
+  "*="
+  "/"
+  "/="
+  "%"
+  "%="
+  ":"
+] @operator
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  (interpolation_brace)
+]  @punctuation.bracket
+
+;; Keywords
+
+[
+  (modifier)
+  "this"
+  (implicit_type)
+] @keyword
+
+[
+  "add"
+  "alias"
+  "as"
+  "base"
+  "break"
+  "case"
+  "catch"
+  "checked"
+  "class"
+  "continue"
+  "default"
+  "delegate"
+  "do"
+  "else"
+  "enum"
+  "event"
+  "explicit"
+  "extern"
+  "finally"
+  "for"
+  "foreach"
+  "global"
+  "goto"
+  "if"
+  "implicit"
+  "interface"
+  "is"
+  "lock"
+  "namespace"
+  "notnull"
+  "operator"
+  "params"
+  "return"
+  "remove"
+  "sizeof"
+  "stackalloc"
+  "static"
+  "struct"
+  "switch"
+  "throw"
+  "try"
+  "typeof"
+  "unchecked"
+  "using"
+  "while"
+  "new"
+  "await"
+  "in"
+  "yield"
+  "get"
+  "set"
+  "when"
+  "out"
+  "ref"
+  "from"
+  "where"
+  "select"
+  "record"
+  "init"
+  "with"
+  "let"
+] @keyword
+
+;; Attribute
+
+(attribute name: (identifier) @attribute)
+
+;; Parameters
+
+(parameter
+  name: (identifier) @variable.parameter)
+
+;; Type constraints
+
+(type_parameter_constraints_clause (identifier) @type.parameter)
+
+;; Method calls
+
+(invocation_expression (member_access_expression name: (identifier) @function))

package/assets/queries/c_sharp/injections.scm

@@ -0,0 +1,2 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))

package/assets/queries/c_sharp/tags.scm

@@ -0,0 +1,21 @@
+(class_declaration name: (identifier) @name) @definition.class
+
+(class_declaration (base_list (_) @name)) @reference.class
+
+(interface_declaration name: (identifier) @name) @definition.interface
+
+(interface_declaration (base_list (_) @name)) @reference.interface
+
+(method_declaration name: (identifier) @name) @definition.method
+
+(object_creation_expression type: (identifier) @name) @reference.class
+
+(type_parameter_constraints_clause (identifier) @name) @reference.class
+
+(type_parameter_constraint (type type: (identifier) @name)) @reference.class
+
+(variable_declaration type: (identifier) @name) @reference.class
+
+(invocation_expression function: (member_access_expression name: (identifier) @name)) @reference.send
+
+(namespace_declaration name: (identifier) @name) @definition.module

package/assets/queries/c_sharp/textobjects.scm

@@ -0,0 +1,20 @@
+[
+  (class_declaration body: (_) @class.inside)
+  (struct_declaration body: (_) @class.inside)
+  (interface_declaration body: (_) @class.inside)
+  (enum_declaration body: (_) @class.inside)
+  (delegate_declaration)
+  (record_declaration body: (_) @class.inside)
+] @class.around
+
+(constructor_declaration body: (_) @function.inside) @function.around
+
+(destructor_declaration body: (_) @function.inside) @function.around
+
+(method_declaration body: (_) @function.inside) @function.around
+
+(property_declaration (_) @function.inside) @function.around
+
+(parameter (_) @parameter.inside) @parameter.around
+
+(comment)+ @comment.around