src-mcp 1.0.1

package/assets/queries/ruby/highlights.scm

@@ -0,0 +1,191 @@
+; Operators
+[
+":"
+"?"
+"~"
+"=>"
+"->"
+"!"
+] @operator
+
+(assignment
+  "=" @operator)
+
+(operator_assignment
+  operator: ["+=" "-=" "*=" "**=" "/=" "||=" "|=" "&&=" "&=" "%=" ">>=" "<<=" "^="] @operator)
+
+(binary
+  operator: ["/" "|" "==" "===" "||" "&&" ">>" "<<" "<" ">" "<=" ">=" "&" "^" "!~" "=~" "<=>" "**" "*" "!=" "%" "-" "+"] @operator)
+
+(range
+  operator: [".." "..."] @operator)
+
+[
+  ","
+  ";"
+  "."
+  "&."
+] @punctuation.delimiter
+
+[
+  "|"
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+  "%w("
+  "%i("
+] @punctuation.bracket
+
+; Literals
+
+[
+  (string)
+  (bare_string)
+  (subshell)
+  (heredoc_body)
+  (heredoc_beginning)
+] @string
+
+[
+  (simple_symbol)
+  (delimited_symbol)
+  (bare_symbol)
+] @string.special.symbol
+
+(pair key: ((_)":" @string.special.symbol) @string.special.symbol)
+
+(regex) @string.regexp
+(escape_sequence) @constant.character.escape
+
+[
+  (integer)
+  (float)
+] @constant.numeric.integer
+
+[
+  (nil)
+  (true)
+  (false)
+] @constant.builtin
+
+(interpolation
+  "#{" @punctuation.special
+  "}" @punctuation.special) @embedded
+
+(comment) @comment
+
+; Identifiers
+
+((identifier) @function.method
+ (#is-not? local))
+
+[
+  (identifier)
+] @variable
+
+[
+  (class_variable)
+  (instance_variable)
+] @variable.other.member
+
+(constant) @constructor
+
+((identifier) @constant.builtin
+ (#match? @constant.builtin "^(__FILE__|__LINE__|__ENCODING__)$"))
+
+((constant) @constant.builtin
+ (#match? @constant.builtin "^(ENV|ARGV|ARGF|RUBY_PLATFORM|RUBY_RELEASE_DATE|RUBY_VERSION|STDERR|STDIN|STDOUT|TOPLEVEL_BINDING)$"))
+
+((constant) @constant
+ (#match? @constant "^[A-Z\\d_]+$"))
+
+(self) @variable.builtin
+(super) @function.builtin
+
+[(forward_parameter)(forward_argument)] @variable.parameter
+(keyword_parameter name:((_)":" @variable.parameter) @variable.parameter)
+(optional_parameter name:((_)"=" @operator) @variable.parameter)
+(optional_parameter name: (identifier) @variable.parameter)
+(splat_parameter name: (identifier) @variable.parameter) @variable.parameter
+(hash_splat_parameter name: (identifier) @variable.parameter) @variable.parameter
+(method_parameters (identifier) @variable.parameter)
+(block_parameter (identifier) @variable.parameter)
+(block_parameters (identifier) @variable.parameter)
+
+; Function definitions
+
+(alias (identifier) @function.method)
+(setter (identifier) @function.method)
+(method name: [(identifier) (constant)] @function.method)
+(singleton_method name: [(identifier) (constant)] @function.method)
+
+; Function calls
+
+(call
+  method: [(identifier) (constant)] @function.method)
+
+((identifier) @function.builtin
+ (#match? @function.builtin "^(attr|attr_accessor|attr_reader|attr_writer|include|prepend|refine|private|protected|public)$"))
+
+"defined?" @function.builtin
+
+; Keywords
+
+[
+  "BEGIN"
+  "END"
+  "alias"
+  "begin"
+  "class"
+  "do"
+  "end"
+  "module"
+  "in"
+  "rescue"
+  "ensure"
+] @keyword
+
+[
+  "if"
+  "else"
+  "elsif"
+  "when"
+  "case"
+  "unless"
+  "then"
+] @keyword.control.conditional
+
+[
+  "for"
+  "while"
+  "retry"
+  "until"
+  "redo"
+] @keyword.control.repeat
+
+[
+  "yield"
+  "return"
+  "next"
+  "break"
+] @keyword.control.return
+
+[
+  "def"
+  "undef"
+] @keyword.function
+
+((identifier) @keyword.control.import
+ (#match? @keyword.control.import "^(require|require_relative|load|autoload)$"))
+
+[
+  "or"
+  "and"
+  "not"
+] @keyword.operator
+
+((identifier) @keyword.control.exception
+ (#match? @keyword.control.exception "^(raise|fail)$"))

package/assets/queries/ruby/indents.scm

@@ -0,0 +1,24 @@
+[
+  (argument_list)
+  (array)
+  (begin)
+  (block)
+  (call)
+  (class)
+  (case)
+  (elsif)
+  (if)
+  (hash)
+  (method)
+  (module)
+  (singleton_class)
+  (singleton_method)
+] @indent
+
+[
+  ")"
+  "}"
+  "]"
+  "end"
+  "when"
+] @outdent

package/assets/queries/ruby/injections.scm

@@ -0,0 +1,35 @@
+((comment) @injection.content
+ (#set! injection.language "comment"))
+
+((heredoc_body 
+  (heredoc_content) @injection.content
+  (heredoc_end) @name
+  (#set! injection.language "sql")) 
+ (#eq? @name "SQL"))
+
+((heredoc_body
+  (heredoc_content) @injection.content
+  (heredoc_end) @name
+  (#set! injection.language "graphql"))
+ (#any-of? @name
+       "GQL"
+       "GRAPHQL"))
+
+((heredoc_body
+  (heredoc_content) @injection.content
+  (heredoc_end) @name
+  (#set! injection.language "erb"))
+ (#eq? @name "ERB"))
+
+; `<command>`
+; %x{<command>}
+(subshell
+  (string_content) @injection.content
+  (#set! injection.language "bash"))
+
+(call
+  method: (identifier) @_method (#any-of? @_method "system" "spawn" "exec")
+  arguments: (argument_list
+    (string
+      (string_content) @injection.content))
+  (#set! injection.language "bash"))

package/assets/queries/ruby/locals.scm

@@ -0,0 +1,20 @@
+((method) @local.scope
+ (#set! local.scope-inherits false))
+
+[
+  (lambda)
+  (block)
+  (do_block)
+] @local.scope
+
+(block_parameter (identifier) @local.definition.variable.parameter)
+(block_parameters (identifier) @local.definition.variable.parameter)
+(destructured_parameter (identifier) @local.definition.variable.parameter)
+(hash_splat_parameter (identifier) @local.definition.variable.parameter)
+(lambda_parameters (identifier) @local.definition.variable.parameter)
+(method_parameters (identifier) @local.definition.variable.parameter)
+(splat_parameter (identifier) @local.definition.variable.parameter)
+(keyword_parameter name: (identifier) @local.definition.variable.parameter)
+(optional_parameter name: (identifier) @local.definition.variable.parameter)
+
+(identifier) @local.reference

package/assets/queries/ruby/rainbows.scm

@@ -0,0 +1,28 @@
+[
+  (begin_block)
+  (end_block)
+  (singleton_method)
+  (block_parameters)
+  (parenthesized_statements)
+  (element_reference)
+  (argument_list "(" ")")
+  (block)
+  (destructured_left_assignment)
+  (interpolation)
+  (string_array)
+  (symbol_array)
+  (regex)
+  (array)
+  (hash)
+  (method_parameters)
+] @rainbow.scope
+
+[
+  "#{"
+  "{" "}"
+  "(" ")"
+  "%w(" "%i("
+  "[" "]"
+  "|"
+  "/"
+] @rainbow.bracket

package/assets/queries/ruby/tags.scm

@@ -0,0 +1,64 @@
+; Method definitions
+
+(
+  (comment)* @doc
+  .
+  [
+    (method
+      name: (_) @name) @definition.method
+    (singleton_method
+      name: (_) @name) @definition.method
+  ]
+  (#strip! @doc "^#\\s*")
+  (#select-adjacent! @doc @definition.method)
+)
+
+(alias
+  name: (_) @name) @definition.method
+
+(setter
+  (identifier) @ignore)
+
+; Class definitions
+
+(
+  (comment)* @doc
+  .
+  [
+    (class
+      name: [
+        (constant) @name
+        (scope_resolution
+          name: (_) @name)
+      ]) @definition.class
+    (singleton_class
+      value: [
+        (constant) @name
+        (scope_resolution
+          name: (_) @name)
+      ]) @definition.class
+  ]
+  (#strip! @doc "^#\\s*")
+  (#select-adjacent! @doc @definition.class)
+)
+
+; Module definitions
+
+(
+  (module
+    name: [
+      (constant) @name
+      (scope_resolution
+        name: (_) @name)
+    ]) @definition.module
+)
+
+; Calls
+
+(call method: (identifier) @name) @reference.call
+
+(
+  [(identifier) (constant)] @name @reference.call
+  (#is-not? local)
+  (#not-match? @name "^(lambda|load|require|require_relative|__FILE__|__LINE__)$")
+)

package/assets/queries/ruby/textobjects.scm

@@ -0,0 +1,56 @@
+; Class and Modules
+(class
+  body: (_)? @class.inside) @class.around
+
+(singleton_class
+  value: (_)
+  (_)+ @class.inside) @class.around
+
+(call
+  receiver: (constant) @class_const
+  method: (identifier) @class_method
+  (#match? @class_const "Class")
+  (#match? @class_method "new")
+  (do_block (_)+ @class.inside)) @class.around
+  
+(module
+  body: (_)? @class.inside) @class.around
+
+; Functions and Blocks
+(singleton_method
+  body: (_)? @function.inside) @function.around
+
+(method
+  body: (_)? @function.inside) @function.around
+
+(do_block
+  body: (_)? @function.inside) @function.around
+
+(block
+  body: (_)? @function.inside) @function.around
+
+; Parameters      
+(method_parameters
+  (_) @parameter.inside) @parameter.around
+        
+(block_parameters 
+  (_) @parameter.inside) @parameter.around
+        
+(lambda_parameters 
+  (_) @parameter.inside) @parameter.around
+
+; Comments
+(comment) @comment.inside 
+(comment)+ @comment.around
+
+(pair
+  (_) @entry.inside) @entry.around
+
+(array
+  (_) @entry.around)
+
+(string_array
+  (_) @entry.around)
+
+(symbol_array
+  (_) @entry.around)