jiji 1.2.5

data/swf/chart/fx/chart/ui/graph/Graph.as

@@ -0,0 +1,200 @@
+package fx.chart.ui.graph {
+
+  import fx.util.*;
+  import fx.chart.Chart;
+  import fx.chart.ui.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.external.*;
+
+  /**
+   * グラフ
+   */
+  public class Graph extends AbstractDrawChartUI {
+
+    public function Graph( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+    }
+
+    public function draw( data:Object, colors:Array ):void {
+      main.x = 0;
+      Util.clear( main );
+      Util.clear( axis );
+      Util.clear( lowAxis );
+
+      // データ数分のスプライトを作成
+      if ( !data["datas"] || data["datas"].length <= 0 ) { return; }
+      var sprites:Array = [];
+      for ( var i:int=0; i< data.datas[0].length; i++ ) {
+        var s:Sprite = new Sprite();
+        main.addChild( s );
+        sprites.push( s );
+      }
+      if ( data["options"]["graph_type"] == "rate" ) {
+        drawWithRate( data, colors, sprites );
+      } else if ( data["options"]["graph_type"] == "zero_base" ) {
+        drawZeroBase( data, colors, sprites );
+      } else {
+        drawBasic( data, colors, sprites );
+      }
+    }
+
+    /**
+     * レートにあわせてグラフを書く
+     */
+    private function drawWithRate( data:Object, colors:Array, sprites:Array ):void {
+
+      var pm:PositionManager = model.positionManager;
+      var height:int = rc.stage.candle.height;
+      var f:Function = function(value:*):int {
+        return  rc.stage.candle.bottom - pm.fromRate( value, height ); 
+      }
+      // グラフ
+      drawLineGraph( data, f, colors, sprites  );
+    }
+
+    /**
+     * 0を中心とするグラフを書く
+     */
+    private function drawZeroBase( data:Object, colors:Array, sprites:Array ):void {
+
+      var pm:PositionManager = model.positionManager;
+      var rect:Rectangle = rc.stage.graph;
+      var middle:int = rect.top + rect.height/2;
+        
+      var range:Array = range( data );
+      var m:Number = Math.max( Math.abs(range[0]), Math.abs(range[1]) );
+      var valueParPixel:Number = m*2 / rect.height;
+      
+      var f:Function = function(value:*):int {
+        return middle - int(value / valueParPixel); 
+      }
+    
+      // 背景線を引く
+      drawAxis( data, f );
+      
+      // 0
+      lowAxis.graphics.lineStyle( 0, Constants.COLOR_CANDLE, 1, true,
+        LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      var y:int = middle;
+      lowAxis.graphics.moveTo( rect.left,  y);
+      lowAxis.graphics.lineTo( rect.right,  y);
+      createText( "0", axis, Constants.TEXT_FORMAT_SCALE_Y,  0, middle-8, rect.left-2 );
+      
+      // グラフ
+      drawLineGraph( data, f , colors, sprites );
+    }
+
+    /**
+     * 最大値と最小値をマッピングするグラフを書く
+     */
+    private function drawBasic( data:Object, colors:Array, sprites:Array ):void {
+      var pm:PositionManager = model.positionManager;
+      var rect:Rectangle = rc.stage.graph;
+ 
+      var range:Array = range( data );
+      var diff:Number = range[1] - range[0];
+      var valueParPixel:Number = diff / rect.height;
+      
+      var f:Function = function(value:*):int {
+        return rc.stage.graph.bottom - int((value-range[0]) / valueParPixel); 
+      }
+      
+      // 背景線を引く
+      drawAxis( data,  f );
+        
+      // グラフ
+      drawLineGraph( data, f , colors, sprites );
+    }
+    /**
+     * 描画用のスプライトを造る。
+     */
+    private function createSprites( colors:Array,  sprites:Array ):Array {
+      var gs:Array = [];
+      for ( var i:int =0; i < sprites.length; i++ ) {
+        var g: Graphics = sprites[i].graphics;
+        g.lineStyle( 0, i < colors.length ? colors[i] : 0x557777, 0.8, false,
+          LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+        gs.push( g );
+      }
+      return gs;
+    }
+    
+    /**
+     * 最大値、最小値を取得する
+     */
+    private function range( data:Object ):Array {
+
+      var max:Number = Number.MIN_VALUE;
+      var min:Number = Number.MAX_VALUE;
+
+      // 線
+      if ( data["options"]["lines"] ) {
+        data["options"]["lines"].forEach( function( item:*,i:int,arr:Array ):void{
+          max = Math.max( max, item );
+          min = Math.min( min, item );
+        } );
+      }
+
+      // データ
+      data.datas.forEach( function( item:*, i:int, arr:Array ):void {
+        for ( var j:int =0; j < item.length-3; j++ ) {
+          max = Math.max( max, item[j] );
+          min = Math.min( min, item[j] );
+        }
+      } );
+
+      // マージンを上下に確保
+      if ( max == min ) {
+        var d:Number = max * 0.01;
+        min = max - d;
+        max = max + d;
+      } else {
+        max += (max - min ) * 0.1;
+        min -= (max - min ) * 0.1;
+      }
+      return [min,max];
+    }
+
+    /**
+     * 背景線を描画する。
+     */
+    private function drawAxis( data:Object, f:Function ):void {
+      var rect:Rectangle = rc.stage.graph;
+      lowAxis.graphics.lineStyle( 0, Constants.COLOR_AXIS_RIGHT, 1, true,
+        LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      if ( data["options"]["lines"] ) {
+        data["options"]["lines"].forEach( function( item:*,i:int,arr:Array ):void{
+            var y:int = f(item); 
+            lowAxis.graphics.moveTo( rect.left,  y);
+            lowAxis.graphics.lineTo( rect.right,  y);
+            createText( String(item), axis,  Constants.TEXT_FORMAT_SCALE_Y,  0, y-8, rect.left-2 );
+        } );
+      }
+    }
+    
+    /**
+     * 線グラフを描画する。
+     */
+    private function drawLineGraph( data:Object, f:Function, colors:Array, sprites:Array ):void {
+      if ( data.datas.length <= 0 ) { return; }
+      var pm:PositionManager = model.positionManager;
+      var gs:Array =createSprites( colors, sprites );
+      data.datas.forEach( function( item:*, i:int, arr:Array ):void {
+        var x:int =  pm.fromDate( item[item.length-1] ) + rc.stage.candle.left;
+        for ( var j:int =0; j < item.length-3; j++ ) {
+          var y:int = f( item[j] );
+          if ( i == 0 ) {
+            gs[j].moveTo( x, y )
+          } else {
+            gs[j].lineTo( x, y )
+          }
+        }
+      });
+    }
+  }
+}

data/swf/chart/fx/chart/ui/graph/GraphManager.as

@@ -0,0 +1,192 @@
+package fx.chart.ui.graph {
+
+  import fx.util.*;
+  import fx.chart.ui.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.external.*;
+  
+  /**
+   * グラフマネージャ
+   */
+  public class GraphManager extends AbstractDrawChartUI {
+
+     /**
+      * グラフ情報のマップ
+      */
+    private var infos:Object = {};
+
+    public function GraphManager( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+      
+      // 一覧UIを描く
+    }
+
+    /**
+     * グラフ一覧が更新された場合に呼び出される。
+     * swfの初期化時やpidが更新された場合に発生。
+     */
+    public function onGraphListChanged(ev:*):void {
+
+        // 既存のグラフは一旦破棄
+        for ( var i:* in infos ) {
+          for ( var j:* in infos[i] ) {
+            if ( infos[i][j].graph ) {
+              infos[i][j].graph.destroy();
+            }
+          }
+        }
+        infos = {};
+
+        // グラフ一覧を作成
+        for ( var graph:* in model.graphs ) {
+            infos[graph] = {};
+            var x:* = model.graphs[graph]["outputs"];
+            x ||= {};
+            for ( var g:* in x ) {
+              infos[graph][g] = new GraphInfo( x[g], null,  model, ctrl, rc );
+            }
+        }
+
+        // グラフデータを取得して描画。
+        updateGraphs();
+    }
+
+    /**
+     * ローソク足データが更新された場合に呼び出される。
+     */
+    public function onCandleDataChanged(ev:Event):void {
+        // グラフデータを再取得&&更新
+        updateGraphs();
+    }
+
+    public function on( name:Array ):void {
+      // レイヤーを非表示。
+      if ( infos && infos[name[0]] && infos[name[0]][name[1]]  ) {
+        var target:GraphInfo = infos[name[0]][name[1]];
+        target.visible = true;
+        
+        // データが未取得であればとってくる。
+        if ( !target.datas ) {
+          ctrl.requestOutputDatas( [name], function( map:Object ):void {
+            target.datas = null;
+            if ( map[name[0]][name[1]] ) {
+              target.datas = map[name[0]][name[1]];
+              // グラフ表示
+              target.draw( );
+              target.graph.setVisible(true);
+            }
+          });
+        } else {
+          // 取得済みであればレイヤーを表示するだけ。
+          target.graph.setVisible(true);
+          target.draw();
+        }
+      }
+    }
+    public function off( name:Array ):void {
+      // レイヤーを非表示。
+      if ( infos && infos[name[0]] && infos[name[0]][name[1]]  ) {
+        var target:GraphInfo = infos[name[0]][name[1]];
+        target.visible = false;
+        target.graph.setVisible(false);
+        target.draw();
+      }
+    }
+    /**
+     * グラフの色を更新する
+     */
+    public function setGraphColors( name:Array, colors:Array ):void {
+        // レイヤーを非表示。
+        if ( infos && infos[name[0]] && infos[name[0]][name[1]]  ) {
+            var target:GraphInfo = infos[name[0]][name[1]];
+            target.setColors( colors ); 
+            target.draw(); // グラフを再描画
+        }
+    }
+    
+    /**
+     * グラフを削除する
+     */
+    public function removeGraph( agentId:String ):void {
+        // レイヤーを非表示。
+        if ( infos && infos[agentId]  ) {
+            for ( var j:* in infos[agentId] ) {
+              off( [agentId, j] );
+            }
+        }
+    }
+    
+    /**
+     * グラフデータを再取得して更新する。
+     */
+    public function updateGraphs():void {
+        var names:Array = [];
+        for ( var i:* in infos ) {
+          for ( var j:* in infos[i] ) {
+              infos[i][j].datas = null;
+              if ( infos[i][j].visible ) {
+                names.push( [i,j] );
+              }
+          }
+        }
+        if ( names.length <= 0 ) { return; }
+        ctrl.requestOutputDatas( names, function( map:Object ):void {
+          names.forEach( function( item:*,i:int,arr:Array ):void {
+              if ( map[item[0]] && map[item[0]][item[1]] ) {
+                  infos[item[0]][item[1]].datas = map[item[0]][item[1]] ;
+                  // グラフ表示
+                  if ( infos[item[0]][item[1]].visible ) { 
+                    infos[item[0]][item[1]].draw( );
+                  }
+              }
+          } );
+        });
+    }
+  }
+}
+
+import fx.chart.ui.*;
+import fx.chart.model.*;
+import fx.chart.ctrl.*;
+import fx.chart.ui.graph.Graph;
+
+class GraphInfo {
+    
+  internal  var info:Object;
+  internal  var visible:Boolean;
+  internal  var datas:Array;
+  internal  var colors:Array;
+  internal  var graph:Graph;
+
+  function GraphInfo( info:Object, datas:Array,
+    model:Model, controller:Controller, rc:RenderingContext ) {
+    this.info = info;
+    this.visible = info["visible"] == false ? false : true;
+    this.datas = datas;
+    if ( info["colors"] && info["colors"] is Array ) {
+      setColors( info["colors"] ); 
+    }
+    this.graph = new Graph( model, controller, rc );
+  }
+  internal function draw():void {
+    graph.draw( {
+      "datas": datas,
+      "options": info
+    }, colors );
+  }
+  internal function setColors( colors:Array):void {
+      var self:GraphInfo = this;
+      self.colors = [];
+      colors.forEach( function(c:*,i:int,arr:Array):void {
+        if ( c is String && c.match(/\#([a-fA-F0-9]{6})/) ) {
+          self.colors.push( Number(c.replace(/^\#/, "0x")));
+        }
+      });
+  }
+}
+

data/swf/chart/fx/net/StubFactory.as

@@ -0,0 +1,113 @@
+package fx.net {
+  
+  import fx.util.*;
+    
+  /**
+   * スタブファクトリ
+   */
+  public class StubFactory  {
+    
+    /**
+     * エンドポイント
+     */
+    private var endPoint:String = "./json";
+
+    /**
+     * リスナ
+     */
+    public var listenerSupport:ListenerSupport = new ListenerSupport();
+    
+    /**
+     * コンストラクタ
+     */ 
+    public function StubFactory( endPoint:String ) {
+      this.endPoint = endPoint;
+    }
+    
+    /**
+     * スタブを生成する。
+     */
+    public function create( name:String ):* {
+      return new Stub( endPoint + "/" + name, this );
+    }
+    
+    
+  }
+}
+
+import flash.errors.*;
+import flash.events.*;
+import flash.net.URLLoader;
+import flash.net.URLRequest;
+import flash.net.URLRequestMethod;
+import flash.net.URLVariables;
+import flash.utils.Proxy;
+import flash.utils.flash_proxy;
+import com.adobe.serialization.json.JSON;
+import fx.net.*
+import fx.chart.ctrl.Event;
+
+// スタブ
+dynamic class Stub extends Proxy {
+  
+  /**現在進行中のリクエスト数*/
+  private static var requestCount:int = 0;
+  
+  private var endPoint:String;
+  private var sf:StubFactory;
+  
+  function Stub( endPoint:String, sf:StubFactory ) {
+    this.endPoint = endPoint;
+    this.sf = sf;
+  }
+  flash_proxy override function callProperty(name:*, ...rest):* {
+    var fail:Function = rest.pop();
+    var success:Function = rest.pop();
+    
+    // リクエストを生成
+    var request:URLRequest = new URLRequest();
+    request.url = endPoint;
+    var data:String = JSON.encode({
+        "method":name.toString(), "params":rest, "time":new Date().getTime()
+    });
+    //log(data);
+    //request.method = URLRequestMethod.POST;
+    var variable:URLVariables = new URLVariables();
+    variable.request = data;
+    request.data = variable;
+    
+    // ローダーを生成し、イベントハンドラを設定
+    var loader:URLLoader = new URLLoader();
+    loader.addEventListener(flash.events.Event.COMPLETE, function( ev:flash.events.Event):void {
+       changeRequestCount(-1);
+       //log(ev.target.data);
+       var result:Object = JSON.decode( ev.target.data)[0];
+       if ( result["error"] ) {
+          fail.apply(null, [result["error"]] );
+       } else {
+          success.apply(null, [result["result"]] );
+       }
+    });
+    loader.addEventListener(IOErrorEvent.IO_ERROR, function( ev:IOErrorEvent ):void {
+       changeRequestCount(-1);
+       fail.apply(null, [ev] );
+    });
+    loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, function( ev:SecurityErrorEvent ):void {
+       changeRequestCount(-1);
+       fail.apply(null, [ev] );
+    });
+    
+    try {
+        loader.load(request);
+        changeRequestCount(1);
+    } catch (error:*) {
+        fail.apply(null, [error] );
+    }
+  }
+  private function changeRequestCount( diff:int  ):void {
+      requestCount+= diff;
+      //log( "request count : " + String(requestCount) );
+      sf.listenerSupport.fire( fx.chart.ctrl.Event.REQUEST_COUNT_CHANGED, 
+              {"requestCount":requestCount} );
+  }
+}