jiji 1.2.5

data/swf/chart/fx/chart/ctrl/AutoUpdate.as

@@ -0,0 +1,96 @@
+package fx.chart.ctrl {
+
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.net.*;
+  import fx.util.*;
+  import flash.utils.Timer;
+  import flash.events.TimerEvent;
+  
+  /**
+   * 自動更新
+   */
+  public class AutoUpdate {
+
+    /**
+     * タイマー。未起動の場合null
+     */
+    private var timer:Timer;
+
+    /**
+     * 自動更新を有効化するかどうか
+     */
+    private var enable:Boolean;
+
+    /**
+     * モデル
+     */
+    private var model:Model;
+
+    /**
+     * コントローラー
+     */
+    private var ctrl:Controller;
+
+    public function AutoUpdate( model:Model,
+        controller:Controller ) {
+        this.model = model;
+        this.ctrl = controller;
+    }
+
+    /**
+     * 自動更新を開始する。
+     */
+    public function start():void {
+        
+      // タイマーを作成。
+      timer = new Timer(model.scaleTime*1000, 0);
+
+      // チャートを更新。
+      timer.addEventListener("timer", function(ev:TimerEvent):void {
+          ctrl.init( model.processId, model.pair, model.scale, null );
+      });
+      // タイマーを開始
+      timer.start();
+    }
+
+    /**
+     * 自動更新を停止する。
+     */
+    public function stop():void  {
+      if ( timer ) {
+        timer.stop();
+        timer = null;
+      }
+    }
+
+    /**
+     * スケールが変更された
+     */
+    public function onScaleChanged( ev:Event ):void {
+      // タイマーを再起動
+      stop();
+      start();
+    }
+
+    /**
+     * 日時の範囲が更新された
+     */
+    public function onRangeChanged( ev:Event ):void {
+        // 自動更新フラグが立っていれば日付を再設定
+        // 最新のデータが表示されるようにマージンを取る
+        if ( enable ) {
+          ctrl.changeDate(
+            Util.createDate( model.range.last * 1000 - model.scaleTime * 25 ) );
+        }
+    }
+
+    /**
+     * 自動更新を行なうかどうか。
+     */
+    public function setEnable( enable:Boolean ):void {
+      this.enable = enable;
+    }
+
+  }
+}

data/swf/chart/fx/chart/ctrl/Controller.as

@@ -0,0 +1,270 @@
+package fx.chart.ctrl {
+
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.net.*;
+  import fx.util.*;
+  import flash.net.*;
+
+  /**
+   * コントローラー
+   */
+  public class Controller {
+
+    private var model:Model;
+    private var listener:ListenerSupport = new ListenerSupport();
+  
+    private var rateService:*;
+    private var outputService:*;
+    private var tradeResultService:*;
+    private var processService:*;
+    
+    public var stubFactory:StubFactory;
+  
+    /**
+     * コンストラクタ
+     */
+    public function Controller(model:Model) {
+      this.model = model;
+
+      stubFactory = new StubFactory("./json");
+      rateService = stubFactory.create("rate");
+      tradeResultService = stubFactory.create("trade_result");
+      outputService = stubFactory.create("output");
+      processService = stubFactory.create("process");
+    }
+
+    /**
+     * イベントリスナを追加する。
+     */
+    public function addEventListener( type:String,
+      listener:Function, self:*=null, priority:int=0 ):void {
+        this.listener.addEventListener( type,listener,self, priority);
+    }
+    
+    /**
+     * イベントリスナを削除する。
+     */
+    public function removeEventListener( type:String,
+      listener:Function ):void {
+        this.listener.removeEventListener( type,listener);
+    }
+    
+    /**
+     * イベントをキックする
+     */
+    public function fire( type:String ):void {
+        var ev:Event = new Event( type, model );
+        listener.fire( type, ev );
+    }
+
+    /**
+     * プロセスIDを更新する
+     */
+    public function changeProcessId( pid:String ):void {
+      if ( model.processId != pid ) {
+        model.processId = pid;
+        updateChartData( );
+        updateEnableData( );
+        updateOutputList( );
+        fire( Event.PROCESS_ID_CHANGED );
+      }
+    }
+
+    /**
+     * 通貨ペアを更新する
+     */
+    public function changePair( pair:String ):void {
+      if ( model.pair != pair ) {
+        model.pair = pair;
+        save( "pair",  pair);
+        updateChartData( );
+        updateEnableData( );
+      }
+    }
+
+    /**
+     * スケールを更新する
+     */
+    public function changeScale( scale:String ):void {
+      if ( model.scale != scale ) {
+        model.scale = scale;
+        save( "scale",  scale );
+        updateAll();
+        fire( Event.SCALE_CHANGED );
+      }
+    }
+
+    /**
+     * 表示日時を更新する
+     */
+    public function changeDate( date:Date ):void {
+      if ( model.date != date ) {
+        model.date = date;
+        updateChartData( );
+        updateTradeData( );
+        updateProfitData( );
+        fire( Event.DATE_CHANGED );
+      }
+    }
+    
+    /**
+     * 指定されたデータでチャートを初期化する。
+     * dateがnullの場合、利用可能な日時を取得し「最新の日時が真ん中あたりに来る」ように調整する。
+     * 
+     */
+    public function init( processId:String, pair:String, scale:String, date:Date ):void {
+        
+        // 調整不要なデータは先に設定。(利用可能範囲の取得で少なくともprocessIDは必要。)
+        model.processId = processId;
+        model.pair = pair;
+        model.scale = scale;
+        
+        _updateEnableData( function( range:Object ):void {
+            model.range = range;
+            var date:Number =  model.range.last - Model.COUNT/2*model.scaleTime;
+            model.date = Util.createDate(date);
+
+            // チャートを更新
+            updateChartData( );
+            updateTradeData( );
+            updateProfitData( );
+            updateOutputList( );
+            // 利用可能データ更新イベントをキックして、スクロールバーを更新。
+            fire( Event.RANGE_CHANGED );
+        });
+    }
+    
+    /**
+     * すべてを更新する
+     */
+    public function updateAll():void {
+      updateChartData( );
+      updateTradeData( );
+      updateProfitData( );
+      updateEnableData( );
+      updateOutputList( );
+    }
+
+    /**
+     * ローソク足チャートを更新する
+     */
+    public function updateChartData():void {
+      rateService.list( model.pair, model.scale,
+          model.startDate.getTime()/1000, model.endDate.getTime()/1000,
+          function( datas:Array ):void {
+            model.rateDatas = model.createTimedDatas(datas, 5);
+            fire( Event.CANDLE_DATA_CHANGED );
+          }, function(error:*):void {
+            log(error); // TODO
+          } );
+    }
+    /**
+     * 取引データを更新する
+     */
+    public function updateTradeData( ):void {
+      tradeResultService.list( model.processId, model.scale,
+          model.startDate.getTime()/1000, model.endDate.getTime()/1000,
+          function( datas:Array ):void {
+            model.tradeDatas = model.createTimedDatas(datas, 10);
+            fire( Event.TRADE_DATA_CHANGED );
+          }, function(error:*):void {
+            log(error); // TODO
+          } );
+    }
+    /**
+     * 損益データを更新する
+     */
+    public function updateProfitData( ):void {
+      tradeResultService.list_profit_or_loss( model.processId, model.scale,
+          model.startDate.getTime()/1000, model.endDate.getTime()/1000,
+          function( datas:Array ):void {
+            model.profitDatas = model.createTimedDatas(datas, 4);
+            fire( Event.PROFIT_DATA_CHANGED );
+          }, function(error:*):void {
+            log(error); // TODO
+          } );
+    }
+
+
+    /**
+     * outputsデータ一覧を更新する
+     */
+    public function updateOutputList( ):void {
+        var names:Array = [];
+        outputService.list_outputs( model.processId,
+            function( datas:Object ):void {
+              model.graphs = datas;
+              fire( Event.OUTPUT_LIST_CHANGED );
+            }, function(error:*):void {
+              log(error); // TODO
+            } );
+    }
+
+    /**
+     * 表示可能な期間を更新する
+     */
+    public function updateEnableData( ):void {
+        _updateEnableData( function( range:Object ):void {
+            model.range = range;
+            fire( Event.RANGE_CHANGED );
+        });
+    }
+    /**
+     * 表示可能な期間を更新する
+     */
+    private function _updateEnableData( f:Function ):void {
+
+      // rmtの場合、サーバーから取得
+      if ( model.processId == "rmt" ) {
+          rateService.range( model.pair,
+              f, function(error:*):void {
+                log(error); // TODO
+              } );
+      } else {
+          // back_testの場合、指定されているはずの日時を使う。
+          processService.get( model.processId,
+              function( p:Object ):void {
+                var range:Object =  { 
+                  "first":p.start_date,
+                  "last":p.end_date 
+                };
+                f.call( null,  range );
+              }, function(error:*):void {
+                log(error); // TODO
+              } );
+      }
+    }
+    /**
+     * outputsデータを取得する
+     */
+    public function requestOutputDatas( names:Array, callback:Function ):void {
+        outputService.list_datas( model.processId, names, model.scale,
+            model.startDate.getTime()/1000, model.endDate.getTime()/1000,
+            function( datas:Object ):void {
+              callback.call( null, datas );
+            }, function(error:*):void {
+              log(error); // TODO
+            } );
+    }
+    /**
+     * 利用可能な通貨ペアの一覧を取得する
+     */
+    public function requestPairs( callback:Function ):void {
+        rateService.pairs( 
+            function( datas:Array ):void {
+              model.pairs = datas;
+              callback.call( null, datas );
+            }, function(error:*):void {
+              log(error); // TODO
+            } );
+    }
+    /**設定を記録する*/
+    public function save( name:String, value:Object ):void {
+        var so:SharedObject = SharedObject.getLocal("chartInfo");
+        so.data[name]  = value;
+        so.flush();
+    }
+  }
+
+}

data/swf/chart/fx/chart/ctrl/Event.as

@@ -0,0 +1,75 @@
+package fx.chart.ctrl {
+
+  import flash.events.*;
+  import fx.chart.model.*;
+
+  /**
+   * イベント
+   */
+  public class Event extends flash.events.Event {
+
+    /**
+     * ローソク足データがリロードされた
+     */
+    public static const CANDLE_DATA_CHANGED:String = "CANDLE_DATA_CHANGED";
+
+    /**
+     * トレードデータがリロードされた
+     */
+    public static const TRADE_DATA_CHANGED:String = "TRADE_DATA_CHANGED";
+
+    /**
+     * 損益データがリロードされた
+     */
+    public static const PROFIT_DATA_CHANGED:String = "PROFIT_DATA_CHANGED";
+
+    /**
+     * アウトプットデータがリロードされた
+     */
+    public static const OUTPUT_DATA_CHANGED:String = "OUTPUT_DATA_CHANGED";
+
+    /**
+     * プロセスIDが更新された
+     */
+    public static const PROCESS_ID_CHANGED:String = "PROCESS_ID_CHANGED";
+    /**
+     * スケールが更新された
+     */
+    public static const SCALE_CHANGED:String = "SCALE_CHANGED";
+
+    /**
+     * 範囲が更新された
+     */
+    public static const RANGE_CHANGED:String = "RANGE_CHANGED";
+
+    /**
+     * 表示時刻が更新された
+     */
+    public static const DATE_CHANGED:String = "DATE_CHANGED";
+
+    /**
+     * 出力データ一覧が更新された
+     */
+    public static const OUTPUT_LIST_CHANGED:String = "OUTPUT_LIST_CHANGED";
+
+    
+    /**
+     * リクエストが開始/終了された
+     */
+    public static const REQUEST_COUNT_CHANGED:String = "REQUEST_COUNT_CHANGED";
+    
+    /**
+     * モデル
+     */
+    public var model:Model;
+
+    /**
+     * コンストラクタ
+     */
+    public function Event(type:String, model:Model,
+      bubbles:Boolean=false, cancelable:Boolean = false) {
+      super( type, bubbles, cancelable );
+      this.model = model;
+    }
+  }
+}

data/swf/chart/fx/chart/model/Model.as

@@ -0,0 +1,228 @@
+package fx.chart.model {
+
+  import flash.net.*;
+  import fx.chart.*;
+  import fx.chart.ui.*;
+  import fx.chart.model.*;
+  import fx.util.*;
+
+  /**
+   * モデル
+   */
+  public class Model {
+    
+    /**設定情報*/
+    public var so:SharedObject = SharedObject.getLocal("chartInfo");
+  
+    /**スクロール可能範囲の左右のマージン*/
+    public static var RANGE_MARGIN:int = 20;
+
+    /**1画面で描画するローソク足の数*/
+    public static var COUNT:int = 118;
+      
+    /** プロセスID */
+    public var processId:String;
+
+    /** 利用可能な通貨ペア */
+    public var pairs:Array;
+    /** 現在表示している通貨ペア */
+    public var pair:String;
+    /** 現在のスケール */
+    private var _scale:String;
+    /** 現在のスケール */
+    public var scaleTime:int;
+    /** 中心日時 */
+    private var _date:Date;
+    /** 表示開始日時 */
+    private var _startDate:Date;
+    /** 表示終了日時 */
+    public var endDate:Date;
+    
+    /**
+     * 全体の開始日時と終了日時
+     *   rmtの場合、レートデータの存在期間
+     *   バックテストの場合バックテストの期間。
+     */
+    public var _range:Object;
+
+    /**
+     * グラフ情報のマップ
+     */
+    public var graphs:Object = {};
+  
+    /**
+     * 日時と座標のマネージャ
+     */
+    public var positionManager:PositionManager = new PositionManager();
+  
+  
+    /**
+     * 現在のスケールを取得する
+     */
+    public function get scale():String {
+      return _scale;
+    }
+    /**
+     * 現在のスケールを設定する
+     */
+    public function set scale(newData:String):void {
+      _scale = newData;
+      scaleTime = Util.parseScale( _scale );
+      if ( range ) { // スクロール可能範囲再設定し、更新する。
+          this.range = _range;
+      }
+      if ( date ) { // 日時を再設定し、開始/終了日時を更新する。
+        this.date = _date;
+      }
+    }
+    /**
+     * 日時を取得する
+     */
+    public function get date():Date {
+      return _date;
+    }
+    /**
+     * 日時を設定する
+     */
+    public function set date(newData:Date):void {
+      var tmp:Number = Math.floor(newData.getTime()/1000/scaleTime)*scaleTime;
+      if ( scaleTime ){
+        var start:Number = tmp-COUNT/2*scaleTime;
+        var end:Number = tmp+COUNT/2*scaleTime;
+        if ( _range != null && (_range.last  - _range.first) <= scaleTime*COUNT ) {
+            tmp = _range.first + (_range.last - _range.first ) / 2;
+        } else if ( _range != null && _range.first >= start ) { 
+            tmp = _range.first + scaleTime*COUNT/2;
+        } else if ( _range != null && _range.last <= end) {
+            tmp = _range.last - scaleTime*COUNT/2;
+        }
+        
+        start = tmp-COUNT/2*scaleTime;
+        end = tmp+COUNT/2*scaleTime;
+        this.startDate = Util.createDate(start);
+        this.endDate = Util.createDate(end);
+        _date = Util.createDate(tmp);
+      }
+      _date = Util.createDate(tmp);
+    }
+
+    /**
+     * 開始日時を取得する
+     */
+    public function get startDate():Date {
+      return _startDate;
+    }
+    /**
+     * 開始日時を設定する
+     */
+    public function set startDate(newData:Date):void {
+      _startDate = newData;
+      if ( scaleTime ){
+        positionManager.updateDate( scaleTime, _startDate );
+      }
+    }
+
+    /** レートデータ */
+    private var _rateDatas:TimedData;
+
+    /**
+     * レートデータを取得する
+     */
+    public function get rateDatas():TimedData {
+      return _rateDatas;
+    }
+    /**
+     * レートデータを設定する
+     */
+    public function set rateDatas(newData:TimedData):void {
+      _rateDatas = newData;
+
+      // データの最大値、最小値から描画する範囲を特定
+      var max:Number = 0;
+      var min:Number = Number.MAX_VALUE;
+      var i:int;
+      var datas:Array = _rateDatas.getDatas();
+      if ( datas.length <= 0 ) { return }
+      for (i=0; i < datas.length; i++) {
+        max = Math.max( max, datas[i][2] );
+        min = Math.min( min, datas[i][3] );
+      }
+      // マージンを上下に確保
+      if ( max == min ) {
+        var d:Number = max * 0.01;
+        min = max - d;
+        max = max + d;
+      } else {
+        max += (max - min ) * 0.1;
+        min -= (max - min ) * 0.1;
+      }
+      positionManager.updateRate( max, min );
+    }
+
+    /** トレートデータ */
+    public var tradeDatas:TimedData;
+
+    /** 損益データ */
+    private var _profitDatas:TimedData;
+    /**
+     * 損益データを取得する
+     */
+    public function get profitDatas():TimedData {
+      return _profitDatas;
+    }
+    /**
+     * 損益データを設定する
+     */
+    public function set profitDatas(newData:TimedData):void {
+      _profitDatas = newData;
+
+      // データの最大値、最小値から描画する範囲を特定
+      var max:Number = 0;
+      var min:Number = Number.MAX_VALUE;
+      var i:int;
+      var datas:Array = _profitDatas.getDatas();
+      if ( datas.length <= 0 ) { return }
+      for (i=0; i < datas.length; i++) {
+        max = Math.max( max, datas[i][1], datas[i][0] );
+        min = Math.min( min, datas[i][1], datas[i][0] );
+      }
+      // マージンを上下に確保
+      if ( max == min ) {
+        max = 1000;
+        min = -1000;
+      } else {
+        max += (max - min ) * 0.1;
+        min -= (max - min ) * 0.1;
+      }
+      positionManager.updateProfit( max, min );
+    }
+    
+    /**
+     * 表示範囲を取得する
+     */
+    public function get range():Object {
+      return _range;
+    }
+    /**
+     * 現在のスケールを設定する
+     */
+    public function set range(newRange:Object):void {
+      // マージンを追加。
+      _range = {
+          "first": newRange.first - RANGE_MARGIN*scaleTime,
+          "last":newRange.last + RANGE_MARGIN*scaleTime
+      };
+    }
+
+    /** アウトプットデータ */
+    private var _outputDatas:Object;
+
+    /**
+     * TimedDatasを生成する
+     */
+    public function createTimedDatas( datas:Array, timeKey:* ):TimedData {
+      return new TimedData( datas, this.scaleTime, timeKey );
+    }
+  }
+  
+}

data/swf/chart/fx/chart/model/TimedData.as

@@ -0,0 +1,40 @@
+package fx.chart.model {
+  
+  import fx.chart.model.*;
+  import fx.util.*;
+  
+  /**
+   * データ
+   */
+  public class TimedData {
+    
+    private var datas:Array;
+    private var dateMap:Object;
+    
+    /**
+     * コンストラクタ
+     */
+    public function TimedData(datas:Array, scaleTime:int, timeData:*):void {
+      this.datas = datas;
+      dateMap = {};
+      datas.forEach( function( item:*, index:int, arr:Array ):void {
+        var time:Number = int(item[timeData]/scaleTime)*scaleTime;
+        dateMap[time] = item;
+      } );
+    }
+    
+    /**
+     * 日時に対応する取引データを得る。見つからない場合null
+     */
+    public function getDataByDate( time:Number ):Array {
+      return dateMap[time];
+    }
+    
+    /**
+     * データを配列で取得する
+     */
+    public function getDatas( ):Array {
+      return datas;
+    }
+  }
+}