jiji 1.2.5

data/swf/chart/fx/chart/ui/AbstractChartUI.as

@@ -0,0 +1,59 @@
+package fx.chart.ui {
+  
+  import flash.display.*;
+  import mx.core.*;
+  import fx.chart.*;
+  import fx.chart.ctrl.*;
+  import fx.chart.model.*;
+  import fx.util.*;
+  import flash.text.*;
+  
+  /**
+   * チャートUIの抽象基底クラス
+   */
+  public class AbstractChartUI {
+    
+    /**
+     * コンストラクタ
+     */
+    public function AbstractChartUI(model:Model, 
+        controller:Controller, rc:RenderingContext) {
+      this.model = model;
+      this.ctrl = controller;
+      this.rc = rc;
+    }
+    
+    /**
+     * モデル
+     */
+    protected var model:Model;
+    
+    /**
+     * コントローラー
+     */
+    protected var ctrl:Controller;
+  
+    /**
+     * 描画コンテキスト
+     */
+    protected var rc:RenderingContext;
+    
+    /**
+     * テキストを作る。
+     */
+    protected function createText( str:String, parent:Sprite, 
+      format:TextFormat, x:int, y:int, width:int=100 ):TextField {
+      var text:TextField = new TextField();
+      text.selectable = false;
+      text.text = str;
+      text.width = width;
+      text.setTextFormat(format);
+      text.defaultTextFormat = format;
+      text.y = y;
+      text.x = x;
+      parent.addChild(text);
+      return text;
+    }
+  }
+
+}

data/swf/chart/fx/chart/ui/AbstractDrawChartUI.as

@@ -0,0 +1,63 @@
+package fx.chart.ui {
+
+  import flash.display.*;
+  import mx.core.*;
+  import fx.chart.*;
+  import fx.chart.ctrl.*;
+  import fx.chart.model.*;
+  import fx.util.*;
+
+  /**
+   * チャートUIの抽象基底クラス
+   */
+  public class AbstractDrawChartUI extends AbstractChartUI {
+
+    /**スプライト*/
+    protected var main:Sprite;
+    protected var axis:Sprite;
+    protected var lowAxis:Sprite;
+    protected var axisY:Sprite;
+    protected var lowAxisY:Sprite;
+    protected var all:Array;
+
+    /**
+     * コンストラクタ
+     */
+    public function AbstractDrawChartUI(model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+
+      // スプライト
+      main = new Sprite();
+      rc.layers.main.addChild( main );
+      axis = new Sprite();
+      rc.layers.axis.addChild( axis );
+      lowAxis = new Sprite();
+      rc.layers.lowAxis.addChild( lowAxis );
+      axisY = new Sprite();
+      rc.layers.axisY.addChild( axisY );
+      lowAxisY = new Sprite();
+      rc.layers.lowAxisY.addChild( lowAxisY );
+
+      all = [main,axis,lowAxis,axisY,lowAxisY];
+    }
+
+    /**
+     * 追加したスプライトを親のスプライトから取り除く。
+     */
+    public function destroy():void {
+      all.forEach( function(item:*,i:int,array:Array):void {
+        item.parent.removeChild( item );
+      });
+    }
+    /**
+     * スプライトの表示/非表示を切り替える。
+     */
+    public function setVisible( visible:Boolean ):void {
+      all.forEach( function(item:*,i:int,array:Array):void {
+        item.visible = visible;
+      });
+    }
+  }
+
+}

data/swf/chart/fx/chart/ui/Constants.as

@@ -0,0 +1,233 @@
+package fx.chart.ui {
+
+  import flash.text.*;
+
+  public class Constants {
+
+
+    /** 軸の色 */
+    public static const COLOR_AXIS:uint = 0x565656;
+    /** 軸のハイライト*/
+    public static const COLOR_AXIS_HI:uint = 0xF9F9F9;
+    /** 薄い軸の色*/
+    public static const COLOR_AXIS_RIGHT:uint = 0xd3d3d0;
+
+    /**背景色*/
+    public static const BACKGROUND_COLOR:uint = 0xE2E2E2;
+
+    /**
+     * ポインタのライン色
+     */
+    public static const COLOR_POINTER_LINE:uint = 0xFFFFFF;
+
+    /**
+     * 火のグラデーション
+     */
+    public static const COLOR_ROW_UP_HIGH:uint = 0xF8F8F5;
+    public static const COLOR_ROW_UP_LOW:uint = 0xF0F0F0;
+    public static const COLOR_ROW_DOWN_HIGH:uint = 0xa0a0bD;
+    public static const COLOR_ROW_DOWN_LOW:uint = 0xb8b8b5;
+
+    /**火の周りの色 */
+    public static const COLOR_CANDLE:uint = 0x898983;
+
+    /**
+     * 未確定損益グラフの色
+     */
+    public static const COLOR_UNFIXED:uint = 0xACA3E2;
+
+    /**
+     * 取引:+
+     */
+    public static const COLOR_UP:uint = 0xFE4072;//0xD65B7E;
+    /**
+     * 取引:-
+     */
+    public static const COLOR_DOWN:uint = 0x4072FF;//0x78A0D9;
+    /**
+     * 取引:同じ
+     */
+    public static const COLOR_DRAW:uint = 0x9283C5;//0x8C83c2;
+
+    public static const COLOR_UP_3:uint = 0xE35080;
+    public static const COLOR_UP_2:uint = 0xC46F8A;
+    public static const COLOR_UP_1:uint = 0xCDA5B1;
+    public static const COLOR_DOWN_1:uint = 0x6392F1;
+    public static const COLOR_DOWN_2:uint = 0x879DCD;
+    public static const COLOR_DOWN_3:uint = 0xB8C4DC;
+
+
+    /**フォント*/
+    public static const FONT:String = "Verdana"
+
+    /**
+     * テキストフォーマット:軸のテキスト
+     */
+    public static const TEXT_FORMAT_SCALE_Y:TextFormat =
+      new TextFormat(FONT, 10, COLOR_CANDLE);
+    TEXT_FORMAT_SCALE_Y.align = TextFormatAlign.RIGHT;
+    public static const TEXT_FORMAT_SCALE_X:TextFormat =
+      new TextFormat(FONT, 10, COLOR_CANDLE);
+    TEXT_FORMAT_SCALE_X.align = TextFormatAlign.CENTER;
+
+    /**
+     * テキストフォーマット:スクロール
+     */
+    public static const TEXT_FORMAT_SCROLL_LEFT:TextFormat =
+      new TextFormat(FONT, 10, COLOR_AXIS);
+    TEXT_FORMAT_SCROLL_LEFT.align = TextFormatAlign.LEFT;
+    public static const TEXT_FORMAT_SCROLL_RIGHT:TextFormat =
+      new TextFormat(FONT, 10, COLOR_AXIS);
+    TEXT_FORMAT_SCROLL_RIGHT.align = TextFormatAlign.RIGHT;
+
+
+    /**
+     * 情報ウインドウ
+     */
+    public static const TEXT_FORMAT_INFO_RATE_START:TextFormat
+      = new TextFormat(FONT, 25, 0x484845);
+    TEXT_FORMAT_INFO_RATE_START.align = TextFormatAlign.RIGHT;
+    public static const TEXT_FORMAT_INFO_RATE_END :TextFormat
+      = new TextFormat(FONT, 13, 0x484845);
+    TEXT_FORMAT_INFO_RATE_END.align = TextFormatAlign.RIGHT;
+
+    public static const TEXT_FORMAT_INFO_BASIC:TextFormat
+      = new TextFormat(FONT, 10, 0x888885);
+    TEXT_FORMAT_INFO_BASIC.align = TextFormatAlign.RIGHT;
+    public static const TEXT_FORMAT_INFO_BASIC_L:TextFormat
+      = new TextFormat(FONT, 10, 0x888885);
+    TEXT_FORMAT_INFO_BASIC_L.align = TextFormatAlign.LEFT;
+
+    public static const TEXT_FORMAT_INFO_LABEL:TextFormat
+      = new TextFormat(FONT, 10, 0x686865, false);
+    TEXT_FORMAT_INFO_BASIC.align = TextFormatAlign.RIGHT;
+    public static const TEXT_FORMAT_INFO_LABEL_L:TextFormat
+      = new TextFormat(FONT, 10, 0x686865, false);
+    TEXT_FORMAT_INFO_BASIC_L.align = TextFormatAlign.LEFT;
+
+    public static const TEXT_FORMAT_INFO_PROFIT_UP:TextFormat
+      = new TextFormat(FONT, 10, COLOR_UP);
+    TEXT_FORMAT_INFO_PROFIT_UP.align = TextFormatAlign.RIGHT;
+
+    public static const TEXT_FORMAT_INFO_PROFIT_DOWN:TextFormat
+      = new TextFormat(FONT, 10, COLOR_DOWN);
+    TEXT_FORMAT_INFO_PROFIT_DOWN.align = TextFormatAlign.RIGHT;
+
+    public static const TEXT_FORMAT_INFO_PROFIT_DRAW:TextFormat
+      = new TextFormat(FONT, 10, COLOR_DRAW);
+    TEXT_FORMAT_INFO_PROFIT_DRAW.align = TextFormatAlign.RIGHT;
+
+    /**
+     * 取引情報詳細
+     */
+    public static const TEXT_FORMAT_TINFO_PROFIT_UP:TextFormat
+      = new TextFormat(FONT, 18, COLOR_UP, false);
+    TEXT_FORMAT_TINFO_PROFIT_UP.align = TextFormatAlign.LEFT;
+    public static const TEXT_FORMAT_TINFO_PROFIT_DOWN:TextFormat
+      = new TextFormat(FONT, 18, COLOR_DOWN, false);
+    TEXT_FORMAT_TINFO_PROFIT_DOWN.align = TextFormatAlign.LEFT;
+    public static const TEXT_FORMAT_TINFO_PROFIT_DRAW:TextFormat
+      = new TextFormat(FONT, 18, COLOR_DRAW, false);
+    TEXT_FORMAT_TINFO_PROFIT_DRAW.align = TextFormatAlign.LEFT;
+
+    public static const TEXT_FORMAT_TINFO_INFO:TextFormat
+      = new TextFormat(FONT, 10, 0x888885, true);
+    TEXT_FORMAT_TINFO_INFO.align = TextFormatAlign.LEFT;
+
+
+    /**
+     * スクロール情報
+     */
+    public static const TEXT_FORMAT_PINFO:TextFormat
+      = new TextFormat(FONT, 10, 0x888885);
+    TEXT_FORMAT_PINFO.align = TextFormatAlign.LEFT;
+
+    /**
+     * ストライプ
+     */
+    [Embed(source="resource/stripe.gif")]
+    public static var BITMAP_STRIPE:Class;
+    [Embed(source="resource/stripe_b.gif")]
+    public static var BITMAP_STRIPE_BLUE:Class;
+    [Embed(source="resource/stripe_r.gif")]
+    public static var BITMAP_STRIPE_RED:Class;
+
+    /**
+     * アイコン
+     */
+    [Embed(source="resource/buy.gif")]
+    public static var ICON_BUY:Class;
+    [Embed(source="resource/sell.gif")]
+    public static var ICON_SELL:Class;
+    [Embed(source="resource/down.gif")]
+    public static var ICON_DOWN:Class;
+    [Embed(source="resource/up.gif")]
+    public static var ICON_UP:Class;
+    [Embed(source="resource/fixed.gif")]
+    public static var ICON_FIXED:Class;
+    [Embed(source="resource/unfixed.gif")]
+    public static var ICON_UNFIXED:Class;
+
+    [Embed(source="resource/max_label.gif")]
+    public static var ICON_MAX_LABEL:Class;
+    [Embed(source="resource/min_label.gif")]
+    public static var ICON_MIN_LABEL:Class;
+    [Embed(source="resource/diff_label.gif")]
+    public static var ICON_DIFF_LABEL:Class;
+
+    [Embed(source="resource/start_label.gif")]
+    public static var ICON_START_LABEL:Class;
+    [Embed(source="resource/end_label.gif")]
+    public static var ICON_END_LABEL:Class;
+
+    [Embed(source="resource/up_buy_1.gif")]
+    public static var ICON_TRADE_UP_BUY_1:Class;
+    [Embed(source="resource/up_buy_2.gif")]
+    public static var ICON_TRADE_UP_BUY_2:Class;
+    [Embed(source="resource/up_buy_3.gif")]
+    public static var ICON_TRADE_UP_BUY_3:Class;
+    [Embed(source="resource/up_sell_1.gif")]
+    public static var ICON_TRADE_UP_SELL_1:Class;
+    [Embed(source="resource/up_sell_2.gif")]
+    public static var ICON_TRADE_UP_SELL_2:Class;
+    [Embed(source="resource/up_sell_3.gif")]
+    public static var ICON_TRADE_UP_SELL_3:Class;
+
+    [Embed(source="resource/down_buy_1.gif")]
+    public static var ICON_TRADE_DOWN_BUY_1:Class;
+    [Embed(source="resource/down_buy_2.gif")]
+    public static var ICON_TRADE_DOWN_BUY_2:Class;
+    [Embed(source="resource/down_buy_3.gif")]
+    public static var ICON_TRADE_DOWN_BUY_3:Class;
+    [Embed(source="resource/down_sell_1.gif")]
+    public static var ICON_TRADE_DOWN_SELL_1:Class;
+    [Embed(source="resource/down_sell_2.gif")]
+    public static var ICON_TRADE_DOWN_SELL_2:Class;
+    [Embed(source="resource/down_sell_3.gif")]
+    public static var ICON_TRADE_DOWN_SELL_3:Class;
+
+    [Embed(source="resource/up_buy.gif")]
+     public static var ICON_TRADE_UP_BUY:Class;
+    [Embed(source="resource/up_sell.gif")]
+     public static var ICON_TRADE_UP_SELL:Class;
+    [Embed(source="resource/down_buy.gif")]
+     public static var ICON_TRADE_DOWN_BUY:Class;
+    [Embed(source="resource/down_sell.gif")]
+     public static var ICON_TRADE_DOWN_SELL:Class;
+    [Embed(source="resource/draw_buy.gif")]
+     public static var ICON_TRADE_DRAW_BUY:Class;
+    [Embed(source="resource/draw_sell.gif")]
+     public static var ICON_TRADE_DRAW_SELL:Class;
+    
+    [Embed(source="resource/scroll_info_handle.gif")]
+    public static var ICON_SCROLL_INFO_HANDLE:Class;
+
+    [Embed(source="resource/loading.gif")]
+    public static var ICON_LOADING:Class;
+
+    [Embed(source="resource/cursor_hand.gif")]
+    public static var CURSOR_HAND:Class;
+  }
+
+
+}

data/swf/chart/fx/chart/ui/InformationWindow.as

@@ -0,0 +1,228 @@
+package fx.chart.ui {
+
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import fx.chart.*;
+  import fx.util.*;
+  import flash.events.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.filters.*;
+
+  public class InformationWindow extends AbstractChartUI  {
+
+
+    private static const WIDTH:int = 214;
+    private static const HEIGHT:int = 140;
+
+    /**ウインドウ*/
+    private var window:Window;
+    private var infoLayer:Sprite;
+
+    /**テキストフィールド*/
+    private var textFields:Object = new Object();
+
+    /**アイコン*/
+    private var up:Bitmap;
+    private var down:Bitmap;
+
+    public function InformationWindow( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+
+      infoLayer = new Sprite();
+      infoLayer.name = "info";
+      rc.layers.window.addChild( infoLayer );
+
+      window = new Window( model,controller,rc,
+          infoLayer, WIDTH, HEIGHT);
+
+      var stageWidth:int = rc.stage.width;
+      var stageHeight:int = rc.stage.height;
+
+      var g:Graphics = window.window.graphics
+      g.lineStyle( 0, 0xD3D3D0, 1,
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      g.moveTo( 10, 64 );
+      g.lineTo( 135, 64 );
+      g.moveTo( 10, 95 );
+      g.lineTo( 135, 95 );
+      g.moveTo( 146, 10 );
+      g.lineTo( 146, 130 );
+
+      // 最初は非表示
+      window.window.visible = false;
+
+      //
+      textFields["rate_start"] = createTextField( 11,7,130,32,Constants.TEXT_FORMAT_INFO_RATE_START );
+      textFields["rate_end"]   = createTextField( 10,40,130,20,Constants.TEXT_FORMAT_INFO_RATE_END );
+
+      (["max","min","diff"]).forEach( function( item:*,i:int,arr:Array ):void{
+        textFields[item + "_value"] = createTextField( 153,21+i*29,70,15,Constants.TEXT_FORMAT_INFO_BASIC_L );
+        textFields[item + "_value"].text = "-";
+      } );
+      ([new Constants.ICON_MAX_LABEL(),
+        new Constants.ICON_MIN_LABEL(),
+        new Constants.ICON_DIFF_LABEL()]).forEach( function( item:*,i:int,arr:Array ):void{
+        item.x = 153;
+        item.y = 11+i*29;
+        window.window.addChild( item );
+      });
+
+
+      (["x","y"]).forEach( function( item:*,i:int,arr:Array ):void{
+        textFields[item] = createTextField( 10,65+i*13,130,15,Constants.TEXT_FORMAT_INFO_BASIC );
+      } );
+
+      (["fixed","unfixed"]).forEach( function( item:*,i:int,arr:Array ):void{
+        textFields[item] = createTextField( 60,99+i*15,80,16,Constants.TEXT_FORMAT_INFO_BASIC );
+      } );
+
+      down = new Constants.ICON_DOWN();
+      up = new Constants.ICON_UP();
+      ([down,up]).forEach( function( item:*,i:int,arr:Array ):void{
+        //item.filters = [new DropShadowFilter( 3.0, 45, 0x888885, 0.5)];
+        item.x = 9;
+        item.y = 9;
+        item.alpha = 0.85;
+        window.window.addChild( item );
+        item.visible = false;
+      });
+
+      var fix:Bitmap = new Constants.ICON_FIXED();
+      var unfix:Bitmap = new Constants.ICON_UNFIXED();
+      ([fix,unfix]).forEach( function( item:*,i:int,arr:Array ):void{
+        item.x = 11;
+        item.y = 101+i*16;
+        window.window.addChild( item );
+      } );
+    }
+    public function setPosition( x:int, y:int ):void {
+        var stageWidth:int = rc.stage.width;
+        var stageHeight:int = rc.stage.height;
+        if ( model.rateDatas &&
+            x >= rc.stage.candle.left+1 &&
+            x < rc.stage.candle.right &&
+            y > rc.stage.candle.top &&
+            y <= rc.stage.profit.bottom ) {
+    
+          window.window.visible = true;
+    
+          infoLayer.x = x > rc.stage.candle.right - WIDTH -10 ? x-15-WIDTH : x+15;
+          infoLayer.y = y > rc.stage.profit.bottom - HEIGHT -10 ? y-15-HEIGHT : y+15;
+    
+          var daten:Number = model.positionManager.toDate(x-rc.stage.candle.left-2);
+          daten = Math.ceil( daten / model.scaleTime ) * model.scaleTime;
+    
+          // x,y
+          var date:Date = new Date();
+          date.setTime( daten*1000 );
+          textFields["x"].text = Util.formatDate( date );
+          if ( y < rc.stage.candle.bottom ) {
+            var rate:Number = model.positionManager.toRate(
+                rc.stage.candle.bottom - y, rc.stage.candle.height);
+            var l:int = 5 - (rate == 0 ? 1 : Math.log(rate)*Math.LOG10E);
+            textFields["y"].text = rate.toFixed(l);
+          } else if ( y > rc.stage.profit.top ) {
+            var profit:Number = model.positionManager.toProfit(
+                rc.stage.profit.bottom - y, rc.stage.profit.height);
+            textFields["y"].text = Math.ceil(profit/100)*100;
+          } else {
+            textFields["y"].text = "-";
+          }
+    
+          // レート
+          updateRate( daten );
+    
+          // 収益
+          updateProfit(daten);
+    
+        } else {
+          window.window.visible = false;
+        }
+    }
+    
+    public function onMouseMove( ev:MouseEvent ):void {
+        setPosition(ev.stageX, ev.stageY)
+    }
+    private function updateRate( date:Number ):void {
+      if ( model.rateDatas ) {
+        var d:Array = model.rateDatas.getDataByDate( date );
+        if (d) {
+          var size:int = d[0] == 0 ? 1 : Math.ceil( Math.log(d[0])*Math.LOG10E );
+          var l:int = 5 - ( size <= 0 ? 1 : size ) ;
+          textFields["rate_start"].text = d[0].toFixed(l);
+          textFields["rate_end"].text = d[1].toFixed(l);
+
+          textFields["max_value"].text = d[2].toFixed(l);
+          textFields["min_value"].text = d[3].toFixed(l);
+          textFields["diff_value"].text = (d[2]-d[3]).toFixed(l);
+
+          if ( d[0]-d[1] > 0 ) {
+            down.visible=true;
+            up.visible=false;
+          } else {
+            down.visible=false;
+            up.visible=true;
+          }
+
+          return;
+        }
+      }
+      textFields["rate_start"].text = "-";
+      textFields["rate_end"].text = "-";
+
+      textFields["max_value"].text = "-";
+      textFields["min_value"].text = "-";
+      textFields["diff_value"].text = "-";
+
+      down.visible=false;
+      up.visible=false;
+    }
+
+    private function updateProfit( date:Number ):void {
+      if ( model.profitDatas ) {
+        var profit:Array = model.profitDatas.getDataByDate( date );
+        if (profit) {
+          textFields["unfixed"].text = int(profit[0]);
+          updateProfitColor( int(profit[0]), textFields["unfixed"] );
+          textFields["fixed"].text = int(profit[1]);
+          updateProfitColor( int(profit[1]), textFields["fixed"] );
+          return;
+        }
+      }
+      textFields["fixed"].text = "-";
+      updateProfitColor( 0, textFields["fixed"] );
+      textFields["unfixed"].text = "-";
+      updateProfitColor( 0, textFields["unfixed"] );
+    }
+    private function updateProfitColor( profit:Number, text:TextField ):void {
+      var f:TextFormat = null;
+      if (profit > 0) {
+        f = Constants.TEXT_FORMAT_INFO_PROFIT_UP;
+      } else if (profit < 0) {
+        f = Constants.TEXT_FORMAT_INFO_PROFIT_DOWN;
+      } else {
+        f = Constants.TEXT_FORMAT_INFO_PROFIT_DRAW;
+      }
+      text.setTextFormat( f );
+    }
+
+    private function createTextField( x:int, y:int,
+        width:int, height:int, format:TextFormat ):TextField {
+      var text:TextField = new TextField();
+      text.selectable = false;
+      text.width = width;
+      text.height = height;
+      text.defaultTextFormat = format;
+      text.y = y;
+      text.x = x;
+      text.text = "-";
+      window.window.addChild( text );
+      return text;
+    }
+
+  }
+
+}

data/swf/chart/fx/chart/ui/LayerManager.as

@@ -0,0 +1,95 @@
+package fx.chart.ui {
+
+  import flash.events.*;
+  import flash.display.*;
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+
+  /**
+   * レイヤーマネージャ
+   */
+  public class LayerManager {
+
+    public var window:Sprite;
+    public var ctrl:Sprite;
+    public var main:Sprite;
+    public var axis:Sprite;
+    public var axisY:Sprite;
+    public var pointer:Sprite;
+    public var lowAxis:Sprite;
+    public var lowAxisY:Sprite;
+  
+    private var stage:fx.chart.ui.Stage;
+    private var chartComponent:Sprite;
+
+    /**
+     * コンストラクタ
+     */
+    public function LayerManager(chartComponent:Sprite, stage:fx.chart.ui.Stage) {
+      
+      this.chartComponent = chartComponent;
+      this.stage = stage;
+      
+      // レイヤーを作成
+      lowAxisY = new Sprite();
+      chartComponent.addChild( lowAxisY );
+
+      lowAxis = new Sprite();
+      chartComponent.addChild( lowAxis );
+
+      pointer = new Sprite();
+      chartComponent.addChild( pointer );
+
+      main = new Sprite();
+      chartComponent.addChild( main );
+
+      axisY = new Sprite();
+      chartComponent.addChild( axisY );
+
+      axis = new Sprite();
+      chartComponent.addChild( axis );
+
+      ctrl = new Sprite();
+      chartComponent.addChild( ctrl );
+
+      window = new Sprite();
+      chartComponent.addChild( window );
+
+      // マスク
+      setChartMask(main);
+      setChartMask(axisY);
+      setChartMask(lowAxisY);
+    }
+    
+    /**
+     * スプライトにチャート領域のみを描画するマスクを設定する。
+     * @param target マスクを設定するスプライト
+     */
+    private function setChartMask( target:Sprite ):void {
+      // マスク
+      var mask:Sprite = new Sprite();
+      mask.graphics.beginFill(0x010101);
+      mask.graphics.drawRect( stage.candle.x, stage.candle.y, 
+          stage.candle.width, stage.height - fx.chart.ui.Stage.PADDING );
+      mask.graphics.endFill();
+      mask.alpha = 100;
+      this.chartComponent.addChild( mask );
+
+      // circleスプライトのマスクとしてmaskスプライトを設定
+      target.mask = mask;
+    }
+    
+    /**
+     * showで指定された名前を持つWindowだけ表示する。
+     */
+    public function setWindowVisible( show:Object ):void {
+      for ( var i:int =0; i < window.numChildren; i++ ) {
+        var w:DisplayObject = window.getChildAt( i );
+        w.visible = show[w.name];
+      }
+    }
+
+  }
+
+}