jiji 1.2.5

data/swf/chart/fx/chart/ui/Loading.as

@@ -0,0 +1,32 @@
+package fx.chart.ui {
+
+  import flash.display.*;
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import fx.chart.ui.*;
+  import flash.net.URLRequest;
+  import mx.managers.CursorManager;
+
+  /**
+   * ローディング
+   */
+  public class Loading extends AbstractChartUI {
+
+    public function Loading( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+    }
+
+    public function onRequestCountChanged( ev:* ):void {
+      try {
+          if ( ev.requestCount > 0 ) {
+            CursorManager.setBusyCursor();
+          } else {
+            CursorManager.removeAllCursors();
+          }
+      } catch ( ex:* ) {}
+    }
+  }
+
+}

data/swf/chart/fx/chart/ui/Pointer.as

@@ -0,0 +1,61 @@
+package fx.chart.ui {
+
+  import flash.events.*;
+  import flash.display.*;
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+
+  /**
+   * クロスポインタ
+   */
+  public class Pointer extends AbstractChartUI {
+
+    private var informationWindow:InformationWindow;
+    private var pointerLayerX:Sprite;
+    private var pointerLayerY:Sprite;
+
+
+    public function Pointer( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+
+      var pointerLayer:Sprite = rc.layers.pointer;
+
+      var stageWidth:int = rc.stage.width;
+      var stageHeight:int = rc.stage.height;
+
+      pointerLayerX = new Sprite();
+      pointerLayerX.graphics.lineStyle( 0, Constants.COLOR_POINTER_LINE, 1,
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      pointerLayerX.graphics.moveTo( 0, 0 );
+      pointerLayerX.graphics.lineTo( stageWidth, 0 );
+      //pointerLayerX.width = 10;
+
+      pointerLayerY = new Sprite();
+      pointerLayerY.graphics.lineStyle( 0, Constants.COLOR_POINTER_LINE, 1,
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      pointerLayerY.graphics.moveTo( 0, 0 );
+      pointerLayerY.graphics.lineTo( 0, stageHeight );
+      //pointerLayerY.height = 10;
+
+      pointerLayer.addChild( pointerLayerX );
+      pointerLayer.addChild( pointerLayerY );
+
+      // 情報ウインドウ
+      informationWindow = new InformationWindow(model,controller,rc);
+
+      // イベントをキャプチャ
+      pointerLayer.stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
+    }
+    public function setPosition( x:int, y:int ):void {
+        pointerLayerY.x = x;
+        pointerLayerX.y = y;
+        informationWindow.setPosition(x,y);
+    }
+    private function onMouseMove( ev:MouseEvent ):void {
+        setPosition( ev.stageX, ev.stageY );
+    }
+  }
+
+}

data/swf/chart/fx/chart/ui/RangeInfoWindow.as

@@ -0,0 +1,84 @@
+package fx.chart.ui {
+
+  import fx.chart.model.*;
+  import fx.chart.ctrl.Controller;
+  import fx.chart.*;
+  import fx.util.*;
+  import flash.events.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.filters.*;
+
+  public class RangeInfoWindow extends AbstractChartUI  {
+
+    private static const WIDTH:int = 170;
+    private static const HEIGHT:int = 45;
+
+    private var infoLayer:Sprite;
+    private var window:Window;
+
+    /**テキストフィールド*/
+    private var textFields:Object = new Object();
+
+    /**アイコン*/
+    private var sell:Bitmap;
+    private var buy:Bitmap;
+
+    public function RangeInfoWindow( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+
+      infoLayer = new Sprite();
+      infoLayer.name = "range";
+      rc.layers.window.addChild( infoLayer );
+      window = new Window( model,controller,rc,
+          infoLayer, WIDTH, HEIGHT );
+
+      var stageWidth:int = rc.stage.width;
+      var stageHeight:int = rc.stage.height;
+
+
+      // 最初は非表示
+      infoLayer.visible = false;
+
+      textFields["info"] = createTextField( 25,10,220,30,Constants.TEXT_FORMAT_PINFO );
+
+      var handle:Bitmap = new Constants.ICON_SCROLL_INFO_HANDLE();
+      handle.x = 10;
+      handle.y = 10;
+      handle.alpha = 90;
+      window.window.addChild( handle );
+
+      infoLayer.y = rc.stage.ctrl.top + 20;
+      infoLayer.x = rc.stage.ctrl.left;
+    }
+
+    public function update( start:Number, end:Number, x:Number ):void {
+      //infoLayer.x = x  x+30;
+      textFields["info"].text = formatDate(start) + "\n - " + formatDate(end);
+    }
+
+    private function formatDate( longtime:Number ):String {
+      var date:Date = new Date();
+      date.setTime( longtime*1000 );
+      return Util.formatDate( date, "YYYY/MM/DD JJ:NN" );
+    }
+
+    private function createTextField( x:int, y:int,
+        width:int, height:int, format:TextFormat ):TextField {
+      var text:TextField = new TextField();
+      text.selectable = false;
+      text.width = width;
+      //text.height = height;
+      text.defaultTextFormat = format;
+      text.y = y;
+      text.x = x;
+      text.text = "-";
+      window.window.addChild( text );
+      return text;
+    }
+
+  }
+
+}

data/swf/chart/fx/chart/ui/RenderingContext.as

@@ -0,0 +1,54 @@
+package fx.chart.ui {
+
+  import flash.display.Sprite;
+  import mx.core.*;
+  import fx.chart.*;
+  import fx.util.*;
+  import fx.chart.Chart;
+
+  /**
+   * 描画コンテキスト
+   */
+  public class RenderingContext {
+
+    /**
+     * コンストラクタ
+     */
+    public function RenderingContext(canvas:UIComponent) {
+      this.canvas = canvas;
+
+      chartComponent = new UIComponent();
+      chartComponent.width = canvas.stage.width;
+      chartComponent.height = canvas.stage.height;
+      canvas.addChild(chartComponent);
+
+      // ステージ
+      this.stage = new Stage(
+          canvas.stage.width, canvas.stage.height );
+
+      // レイヤーを作成
+      layers = new LayerManager( chartComponent, stage );
+
+    }
+
+    /**
+     * キャンバスコンテナ
+     */
+    public var canvas:UIComponent;
+
+    /**
+     * チャートコンポーネント(キャンバスに全面配置されるスプライト)
+     */
+    public var chartComponent:UIComponent;
+
+    /**
+     * レイヤー(チャートコンポーネント上のスプライト)
+     */
+    public var layers:LayerManager;
+
+    /**
+     * ステージ情報
+     */
+    public var stage:Stage;
+  }
+}

data/swf/chart/fx/chart/ui/ScaleSelector.as

@@ -0,0 +1,84 @@
+package fx.chart.ui {
+  
+  import flash.display.*;
+  import flash.text.*;
+  import flash.external.*;
+  import flash.events.*;
+  import mx.core.*;
+  import mx.controls.*;
+  import mx.collections.ArrayCollection;
+  import mx.events.*;
+  import fx.chart.model.Model;
+  import fx.chart.ctrl.Controller;
+  
+  /**
+   * 通貨ペアと表示倍率を設定するUI
+   */
+  public class ScaleSelector extends AbstractChartUI {
+    
+    private var pairSelector:ComboBox;
+    private var scaleSelector:ComboBox;
+  
+    public function ScaleSelector(model:Model, 
+        controller:Controller, rc:RenderingContext, pairs:Array ) {
+      super( model,controller,rc );
+      
+      pairSelector = new ComboBox();
+      var tmp:Array = [];
+      for (var i:int=0;i<pairs.length;i++) {
+          tmp[i] =  {label:pairs[i], data:pairs[i]};
+      }
+      pairSelector.dataProvider = new ArrayCollection(tmp);
+      pairSelector.width = 100;
+      pairSelector.x = rc.stage.ctrl.right - 200 - 5;
+      pairSelector.y = rc.stage.ctrl.top;
+      rc.canvas.addChild( pairSelector );
+      
+      scaleSelector = new ComboBox();
+      scaleSelector.dataProvider = new ArrayCollection([ 
+        {label:"1分足", data:"1m"}, 
+        {label:"5分足", data:"5m"}, 
+        {label:"10分足", data:"10m"}, 
+        {label:"30分足", data:"30m"}, 
+        {label:"1時間足", data:"1h"}, 
+        {label:"6時間足", data:"6h"}, 
+        {label:"日足", data:"1d"},  
+        {label:"2日足", data:"2d"},
+        {label:"5日足", data:"5d"}
+      ]);
+      scaleSelector.selectedIndex = 2; 
+      scaleSelector.width = 100;
+      scaleSelector.x = rc.stage.ctrl.right - 100;
+      scaleSelector.y = rc.stage.ctrl.top;
+      rc.canvas.addChild( scaleSelector );
+      
+      // イベントをキャプチャ
+      pairSelector.addEventListener(ListEvent.CHANGE, onPairChanged);
+      scaleSelector.addEventListener(ListEvent.CHANGE, onScaleChanged);
+      
+    }
+    /**
+     * コンボボックスの値を更新する(初期化時用/イベントの通知はされない)
+     */
+    public function init( pair:String, scale:String ):void {
+        setValue( scaleSelector, scale);
+        setValue( pairSelector, pair);
+    }
+    private function setValue( c:ComboBox, value:String ):void {
+        for ( var i:int=0;i<c.dataProvider.length; i++ ) {
+            if ( c.dataProvider.getItemAt(i).data == value ) {
+                c.selectedIndex = i;
+                break;
+            }
+        }
+    }
+    
+    private function onPairChanged( ev:ListEvent ):void {
+      ctrl.changePair(ev.currentTarget.selectedItem.data);
+    }
+    private function onScaleChanged( ev:Event ):void {
+      ctrl.changeScale(ev.currentTarget.selectedItem.data);
+    }
+    
+  }
+}

data/swf/chart/fx/chart/ui/Scroll.as

@@ -0,0 +1,241 @@
+package fx.chart.ui {
+
+  import flash.display.*;
+  import flash.text.*;
+  import flash.external.*;
+  import flash.events.*;
+  import mx.core.*;
+  import mx.controls.*;
+  import mx.collections.ArrayCollection;
+  import mx.managers.CursorManager;
+  import mx.events.*;
+  import flash.geom.*;
+
+  import fx.util.*;
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.Controller;
+
+  /**
+   * スクロール
+   */
+  public class Scroll extends AbstractChartUI {
+
+    private var scrollSprite:Sprite;
+    private var scroll:ScrollBar;
+
+    private var left:TextField;
+    private var right:TextField;
+
+    private var info:RangeInfoWindow;
+
+    /**
+     * ステージドラッグの開始位置
+     */
+    private var stageDrag:Boolean;
+    private var startPosition:Point;
+    private var scrollMax:int; // スクロール可能な最大ステップ数
+    private var scrollMin:int; // スクロール可能な最小ステップ数
+
+    /**
+     * ステージのドラッグで移動するレイヤー
+     */
+    private var moveLayers:Array;
+
+    public function Scroll(model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+
+      info = new RangeInfoWindow(model,controller,rc);
+
+      scrollSprite = new Sprite();
+      scrollSprite.x = rc.stage.ctrl.left;
+      scrollSprite.y = rc.stage.ctrl.top;
+      rc.layers.ctrl.addChild(scrollSprite);
+
+      // 期間ラベル
+      left = new TextField();
+      left.selectable = false;
+      left.text = "";
+      left.width = 150;
+      left.defaultTextFormat = Constants.TEXT_FORMAT_SCROLL_LEFT;
+      left.y = rc.stage.ctrl.top+10;
+      left.x = rc.stage.ctrl.left;
+      rc.layers.ctrl.addChild(left);
+
+      right = new TextField();
+      right.selectable = false;
+      right.text = "";
+      right.width = 150;
+      right.defaultTextFormat = Constants.TEXT_FORMAT_SCROLL_RIGHT;
+      right.y = rc.stage.ctrl.top+10;
+      right.x = rc.stage.ctrl.right -70 - 200 - 20 - 150;
+      rc.layers.ctrl.addChild(right);
+
+      // ステージのドラッグでのスクロールサポート
+      moveLayers = [ rc.layers.axisY, rc.layers.lowAxisY, rc.layers.main ];
+      var dragSpace:Sprite = new Sprite();
+      dragSpace.alpha = 0.01;
+      dragSpace.graphics.beginFill(Constants.BACKGROUND_COLOR);
+      dragSpace.graphics.drawRect( rc.stage.candle.x, rc.stage.candle.y,
+          rc.stage.candle.width, rc.stage.xAxis.top - rc.stage.candle.top );
+      dragSpace.graphics.endFill();
+      rc.layers.ctrl.addChild(dragSpace);
+
+      dragSpace.addEventListener(MouseEvent.MOUSE_DOWN, function(ev:MouseEvent):void {
+//        log( "start-drag" );
+//        log( "start: x=" + ev.stageX + ", y=" + ev.stageY );
+        if ( model.range == null ) return; // 範囲が未ロードの場合はドラッグ不可。
+        startPosition = new Point(ev.stageX, ev.stageY);
+
+        // スクロール可能範囲を割り出し
+        scrollMax = (model.startDate.getTime() /1000 - model.range.first) / model.scaleTime; // スクロール可能最小値から、現在の左端までのステップ
+        scrollMin = ( model.range.last - model.endDate.getTime() /1000) / model.scaleTime * -1;
+
+        CursorManager.setCursor( Constants.CURSOR_HAND, 2, -10, -10 );
+        rc.canvas.stage.addEventListener(MouseEvent.MOUSE_MOVE, move);
+        onScrollStart({});
+      });
+      rc.canvas.stage.addEventListener(MouseEvent.MOUSE_UP, function(event:MouseEvent):void {
+        endDrag(event);
+      });
+    }
+    private function endDrag(ev:MouseEvent):void {
+      if (startPosition!=null) {
+        CursorManager.removeAllCursors();
+        rc.canvas.stage.removeEventListener(MouseEvent.MOUSE_MOVE, move);
+        var step:Number = int((ev.stageX - startPosition.x) / 6);
+        var positionLeft:Number = 0;
+
+        // 範囲チェック
+        if ( scrollMax <= scrollMin  ) {
+          // 移動後の範囲が、表示可能範囲外
+          // スクロール不可
+          positionLeft = scroll.positionLeft;
+        } else if (  scrollMax <= step ) {
+          step = scrollMax;
+          positionLeft = 0;
+        }  else if ( scrollMin >= step ) {
+          step = scrollMin;
+          positionLeft = scroll.contentsWidth - scroll.viewWidth;
+        } else {
+          positionLeft = model.startDate.getTime() / 1000 - model.scaleTime * step - model.range.first;
+        }
+
+        var d:Date = new Date();
+        d.setTime( model.startDate.getTime() - model.scaleTime * 1000 * step );
+        scroll.scrollTo( positionLeft ); //d.getTime()/1000 - model.range.first); // スクロールバーを追従
+
+        onScrollEnd({positionLeft: d.getTime()/1000 - model.range.first });
+        startPosition = null;
+      }
+    }
+    private function move(ev:MouseEvent):void {
+      if (startPosition==null) {return;}
+      var step:Number = int((ev.stageX - startPosition.x) / 6);
+      var positionLeft:Number = 0;
+
+      // 範囲チェック
+      if ( scrollMax <= scrollMin  ) {
+        // 移動後の範囲が、表示可能範囲外
+        // スクロール不可
+//        step = 0;
+//        positionLeft = scroll.positionLeft;
+        return;
+      } else if (  scrollMax <= step ) {
+        step = scrollMax;
+        positionLeft = 0;
+      }  else if ( scrollMin >= step ) {
+        step = scrollMin;
+        positionLeft = scroll.contentsWidth - scroll.viewWidth;
+      } else {
+        positionLeft = model.startDate.getTime() / 1000 - model.scaleTime * step - model.range.first;
+      }
+
+      // レイヤーとスクロールバーを移動
+      scroll.scrollTo(positionLeft);
+      onScroll({positionLeft: positionLeft });
+
+//      log("xx:" + x);
+/*
+      moveLayers.forEach( function( l:*,i:Number,arr:Array ):void {
+        for( var j:int=0,n:int=l.numChildren;j<n;j++ ) {
+          l.getChildAt(j).x = x;
+        }
+      } );
+*/
+    }
+
+    public function update():void {
+      Util.clear(scrollSprite);
+      scroll = new ScrollBar( scrollSprite,
+          model.startDate.getTime()/1000 - model.range.first,
+          model.range.last-model.range.first,
+          model.scaleTime*Model.COUNT,
+          rc.stage.ctrl.width -70 -200-20 );
+
+      scroll.addEventListener( ScrollBar.SCROLL_START,
+          onScrollStart, this);
+      scroll.addEventListener( ScrollBar.SCROLL_END,
+          onScrollEnd, this);
+      scroll.addEventListener( ScrollBar.SCROLL,
+          onScroll, this);
+
+      left.text  = Util.formatDate(
+          Util.createDate( model.range.first ), "YYYY/MM/DD");
+      right.text = Util.formatDate(
+          Util.createDate( model.range.last  ), "YYYY/MM/DD");
+
+    }
+
+    public function onScaleChanged( ev:Event ):void {
+      update();
+    }
+    public function onRangeChanged( ev:Event ):void {
+      update();
+    }
+
+    public function onScrollStart( ev:* ):void {
+
+      var start:Number = model.startDate.getTime()/1000;
+
+      // 範囲情報ウインドウを更新
+      info.update(
+          start,
+          start + model.scaleTime*Model.COUNT,
+          scroll.slider ? scroll.slider.x : 0 );
+
+      // 情報系ウインドウの描画を不可視
+      // 範囲情報ウインドウを描画
+      rc.layers.setWindowVisible({"range":true});
+    }
+    public function onScrollEnd( ev:* ):void {
+      // 日時を更新
+      ctrl.changeDate( Util.createDate(
+          model.range.first + ev.positionLeft + model.scaleTime*Model.COUNT/2) );
+
+      // 情報系ウインドウの描画を元に戻す
+      rc.layers.setWindowVisible({"info":true});
+    }
+    public function onScroll( ev:* ):void {
+      // 範囲情報ウインドウを更新
+      info.update(
+          model.range.first + ev.positionLeft,
+          model.range.first + ev.positionLeft + model.scaleTime*Model.COUNT,
+          ev.x );
+
+      // レイヤーを移動
+//      log("ev.positionLeft:" + ev.positionLeft);
+//      log("model.startDate.getTime:" + model.startDate.getTime() / 1000);
+//      log("model.scaleTime:" + model.scaleTime);
+      var x:int = int(( model.startDate.getTime() / 1000 - model.range.first - ev.positionLeft) / model.scaleTime ) * 6 ;
+//      log("x:" + x);
+//      (model.startDate.getTime() /1000 - model.range.first) / model.scaleTime;
+      moveLayers.forEach( function( l:*,i:Number,arr:Array ):void {
+        for( var j:int=0,n:int=l.numChildren;j<n;j++ ) {
+          l.getChildAt(j).x = x;
+        }
+      } );
+    }
+  }
+}