houston-core 0.5.0.beta1

data/app/assets/javascripts/core/helpers.coffee

@@ -0,0 +1,18 @@
+if $.tablesorter
+  $.tablesorter.addParser
+    id: 'timestamp'
+    is: (s)-> false # don't auto-detect
+    format: (text, table, td)-> $(td).attr('data-timestamp')
+    type: 'text'
+
+  $.tablesorter.addParser
+    id: 'property'
+    is: (s)-> false # don't auto-detect
+    format: (text, table, td)-> +$(td).attr('data-position')
+    type: 'number'
+
+  $.tablesorter.addParser
+    id: 'attr'
+    is: (s)-> false # don't auto-detect
+    format: (text, table, td)-> $(td).attr('data-sort-by')
+    type: 'text'

data/app/assets/javascripts/core/jquery_extensions.coffee

@@ -0,0 +1,176 @@
+$.fn.extend
+  
+  pseudoHover: ->
+    $(@).addClass('unhovered').hover(
+      -> $(@).addClass('hover').removeClass('unhovered'),
+      -> $(@).removeClass('hover').addClass('unhovered'))
+  
+  appendView: (view)->
+    el = @append(view.el)
+    view.render()
+    el
+  
+  prependView: (view)->
+    el = @prepend(view.el)
+    view.render()
+    el
+  
+  serializeObject: ->
+    o = {}
+    a = @serializeArray()
+    endsInArrayBrackets = /\[\]$/
+    $.each a, ->
+      if o[@name] && endsInArrayBrackets.test(@name)
+        o[@name] = [o[@name]] unless o[@name].push
+        o[@name].push(@value || '')
+      else
+        o[@name] = @value || ''
+    o
+  
+  highlight: ->
+    $(@).effect('highlight', {}, 1500)
+  
+  reset: ->
+    $(@).each -> @reset()
+  
+  disable: ->
+    $(@).find('input[type="submit"], input[type="reset"], button').attr('disabled', 'disabled').end()
+  
+  enable: ->
+    $(@).find('input[type="submit"], input[type="reset"], button').removeAttr('disabled').end()
+  
+  getCursorPosition: ->
+    input = @get(0)
+    return unless input
+    if input.selectionStart # Standard-compliant browsers
+      input.selectionStart
+    else if document.selection # IE
+      input.focus()
+      sel = document.selection.createRange()
+      selLen = document.selection.createRange().text.length
+      sel.moveStart 'character', -input.value.length
+      sel.text.length - selLen
+  
+  appendAsAlert: ->
+    $alerts = $('#body .alert')
+    $newAlert = $(@)
+    if $alerts.length > 0
+      $('#body .alert').fadeOut
+        complete: ->
+          $(@).remove()
+          $newAlert.prependTo($('#body')).alert()
+    else
+      $newAlert.prependTo($('#body')).alert()
+  
+  putCursorAtEnd: ->
+    @each ->
+      $(@).focus()
+      
+      # If this function exists...
+      if @setSelectionRange
+        # ... then use it (Doesn't work in IE)
+        
+        # Double the length because Opera is inconsistent about whether a carriage return is one character or two. Sigh.
+        len = $(@).val().length * 2
+        
+        @setSelectionRange(len, len)
+      else
+        
+        # ... otherwise replace the contents with itself
+        # (Doesn't work in Google Chrome)
+        
+        $(@).val($(@).val())
+  
+  insertAtCursor: (text)->
+    textarea = @[0]
+    
+    # IE support
+    if document.selection
+      textarea.focus()
+      sel = document.selection.createRange()
+      sel.text = text
+    
+    # MOZILLA and others
+    else if textarea.selectionStart || textarea.selectionStart == '0'
+      startPos = textarea.selectionStart
+      endPos = textarea.selectionEnd
+      textarea.value = textarea.value.substring(0, startPos) + text + textarea.value.substring(endPos, textarea.value.length)
+      textarea.selectionStart = startPos + text.length
+      textarea.selectionEnd = startPos + text.length
+    
+    else
+      textarea.value += text
+  
+  supportImages: ->
+    $el = @
+    
+    $el.append '''
+      <div class="drag-and-drop">
+        Attach images by dragging &amp; dropping them or <a class="dz-selector">selecting them</a>.
+      </div>
+      <div class="upload-progress"></div>
+      <div class="upload-error"></div>
+    '''
+    
+    bucket = App.meta('s3-bucket')
+    $el.dropzone
+      maxFilesize: 13 # MB
+      clickable: '.dz-selector'
+      acceptedFiles: 'image/jpeg,image/png,image/gif'
+      url: "//#{bucket}.s3.amazonaws.com"
+      uploadprogress: (file, progress)->
+        $el.find('.upload-progress').html "Uploading #{file.name} (#{progress.toFixed(0)}% complete)"
+      
+      complete: ->
+        if @getUploadingFiles().length is 0 and @getQueuedFiles().length is 0
+          $el.removeClass('uploading')
+      
+      error: (file, errorMessage)->
+        $el.addClass('error')
+        $el.find('.upload-error').html """
+          <span class="message">#{errorMessage}</span>
+          <a class="dz-selector">Try again</a>"
+        """
+      
+      sending: (file, xhr, formData)=>
+        $el.removeClass('error').addClass('uploading')
+        $el.find('.upload-progress').html "Uploading #{file.name}..."
+        $.ajax
+          url: '/uploads/policies',
+          data: {name: file.name, size: file.size, type: file.type},
+          type: 'POST',
+          async: false, # because we need this response before dropzone can continue
+          success: (params)=>
+            src = "https://s3.amazonaws.com/#{bucket}/#{params.key}"
+            @.find('textarea').insertAtCursor "![#{file.name}](#{src})"
+            $.each params, (key, value)->
+              formData.append(key, value)
+
+
+
+$.extend
+
+  # Extend jQuery with functions for PUT and DELETE requests.
+  put: (url, data, callback, type)->
+    if jQuery.isFunction(data)
+      callback = data
+      data = {}
+    
+    data = data || {}
+    data['_method'] = 'put'
+    jQuery.post(url, data, callback, type)
+  
+  destroy: (url, data, callback, type)->
+    if jQuery.isFunction(data)
+      callback = data
+      data = {}
+
+    data = data || {}
+    data._method = 'delete'
+    jQuery.post(url, data, callback, type)
+
+
+
+$(document).ajaxSend (e, jqxhr, settings)->
+  return if settings.type is 'GET'
+  jqxhr.setRequestHeader 'X-CSRF-Token', App.meta('csrf-token')

data/app/assets/javascripts/dashboard.js

@@ -0,0 +1,23 @@
+// This is a manifest file that'll be compiled into application.js, which will include all the files
+// listed below.
+//
+// Any JavaScript/Coffee file within this directory, lib/assets/javascripts, vendor/assets/javascripts,
+// or vendor/assets/javascripts of plugins, if any, can be referenced here using a relative path.
+//
+// It's not advisable to add code directly here, but if you do, it'll appear at the bottom of the
+// compiled file.
+//
+// Read Sprockets README (https://github.com/sstephenson/sprockets#sprockets-directives) for details
+// about supported directives.
+//
+//= require_tree ./core
+//= require_tree ./dashboard
+//
+//  for Houston::Roadmap's dashboard
+//
+//= require ./app/views/_tickets_view
+//
+//  for Sprint Dashboard
+//
+//= require_tree ../templates/sprints
+//= require ./app/views/_show_sprint_view

data/app/assets/javascripts/dashboard/refresher.coffee

@@ -0,0 +1,120 @@
+class @Refresher
+  τ = 2 * Math.PI # http://tauday.com/tau-manifesto
+  
+  constructor: ->
+    @_rate = 1000 # 1 second
+    @_interval = 5 * 60 * 1000 # 5 minutes
+    @width = 42
+    @height = @width
+    @innerRadius = @width / 3
+    @outerRadius = @width / 2
+    @_container = 'body'
+  
+  rate: (@_rate)-> @
+  container: (@_container)-> @
+  interval: (@_interval)-> @
+  callback: (@_callback)-> @
+  
+  render: ->
+    # An arc function with all values bound except the endAngle. So, to compute an
+    # SVG path string for a given angle, we pass an object with an endAngle
+    # property to the `arc` function, and it will return the corresponding string.
+    @arc = d3.svg.arc()
+      .innerRadius(@innerRadius)
+      .outerRadius(@outerRadius)
+      .startAngle(0)
+
+    # Create the SVG container, and apply a transform such that the origin is the
+    # center of the canvas. This way, we don't need to position arcs individually.
+    svg = d3.select(@_container).append('svg')
+        .attr('width', @width)
+        .attr('height', @height)
+        .attr('class', 'refresher')
+      .append('g')
+        .attr('transform', "translate(#{@width / 2},#{@height / 2})")
+
+    # Add the background arc, from 0 to 100% (τ).
+    background = svg.append('path')
+      .datum(endAngle: τ)
+      .attr('class', 'refresher-track')
+      .attr('d', @arc)
+
+    # Add the foreground arc, currently showing 0%.
+    @foreground = svg.append('path')
+      .datum(endAngle: 0)
+      .attr('class', 'refresher-path')
+      .attr('d', @arc)
+
+    @tween = _.bind(@arcTween, @)
+    setInterval(_.bind(@tick, @), @_rate)
+    @start()
+
+  start: ->
+    @_startTime = +(new Date())
+    @_endTime = @_startTime + @_interval
+    @foreground
+      .datum(endAngle: 0)
+      .attr('d', @arc)
+      .transition()
+        .duration(@_rate)
+        .ease('linear')
+        .call(@tween, (@_rate / @_interval) * τ)
+
+  tick: ->
+    time = +(new Date())
+    if time > @_endTime
+      @_callback() if @_callback
+      @start()
+    else
+      percent = (time + @_rate - @_startTime) / @_interval
+      @foreground.transition()
+        .duration(@_rate)
+        .ease('linear')
+        .call(@tween, percent * τ)
+
+  # Creates a tween on the specified transition's 'd' attribute, transitioning
+  # any selected arcs from their current angle to the specified new angle.
+  arcTween: (transition, newAngle)->
+
+    # The function passed to attrTween is invoked for each selected element when
+    # the transition starts, and for each element returns the interpolator to use
+    # over the course of transition. This function is thus responsible for
+    # determining the starting angle of the transition (which is pulled from the
+    # element's bound datum, d.endAngle), and the ending angle (simply the
+    # newAngle argument to the enclosing function).
+    transition.attrTween 'd', (d)=>
+
+      # To interpolate between the two angles, we use the default d3.interpolate.
+      # (Internally, this maps to d3.interpolateNumber, since both of the
+      # arguments to d3.interpolate are numbers.) The returned function takes a
+      # single argument t and returns a number between the starting angle and the
+      # ending angle. When t = 0, it returns d.endAngle when t = 1, it returns
+      # newAngle and for 0 < t < 1 it returns an angle in-between.
+      interpolate = d3.interpolate(d.endAngle, newAngle)
+
+      # The return value of the attrTween is also a function: the function that
+      # we want to run for each tick of the transition. Because we used
+      # attrTween('d'), the return value of this last function will be set to the
+      # 'd' attribute at every tick. (It's also possible to use transition.tween
+      # to run arbitrary code for every tick, say if you want to set multiple
+      # attributes from a single function.) The argument t ranges from 0, at the
+      # start of the transition, to 1, at the end.
+      (t)=>
+
+        # Calculate the current arc angle based on the transition time, t. Since
+        # the t for the transition and the t for the interpolate both range from
+        # 0 to 1, we can pass t directly to the interpolator.
+    
+        # Note that the interpolated angle is written into the element's bound
+        # data object! This is important: it means that if the transition were
+        # interrupted, the data bound to the element would still be consistent
+        # with its appearance. Whenever we start a new arc transition, the
+        # correct starting angle can be inferred from the data.
+        d.endAngle = interpolate(t)
+
+        # Lastly, compute the arc path given the updated data! In effect, this
+        # transition uses data-space interpolation: the data is interpolated
+        # (that is, the end angle) rather than the path string itself.
+        # Interpolating the angles in polar coordinates, rather than the raw path
+        # string, produces valid intermediate arcs during the transition.
+        @arc(d)

data/app/assets/javascripts/vendor.js

@@ -0,0 +1,26 @@
+// This is a manifest file that'll be compiled into application.js, which will include all the files
+// listed below.
+//
+// Any JavaScript/Coffee file within this directory, lib/assets/javascripts, vendor/assets/javascripts,
+// or vendor/assets/javascripts of plugins, if any, can be referenced here using a relative path.
+//
+// It's not advisable to add code directly here, but if you do, it'll appear at the bottom of the
+// compiled file.
+//
+// Read Sprockets README (https://github.com/sstephenson/sprockets#sprockets-directives) for details
+// about supported directives.
+//
+//= require jquery-ui
+//= require bootstrap
+//= require jquery.pjax.js
+//= require jquery.tablesorter.js
+//= require jquery.autosize.js
+//= require jquery.timeago.js
+//= require mousetrap
+//= require nested_editor_for
+//= require sugar
+//= require Markdown.Converter
+//= require md5
+//= require neat
+//= require alertify
+//= require dropzone

data/app/assets/stylesheets/application.css

@@ -0,0 +1,14 @@
+/*
+ * This is a manifest file that'll be compiled into application.css, which will include all the files
+ * listed below.
+ *
+ * Any CSS and SCSS file within this directory, lib/assets/stylesheets, vendor/assets/stylesheets,
+ * or vendor/assets/stylesheets of plugins, if any, can be referenced here using a relative path.
+ *
+ * You're free to add application-wide styles to this file and they'll appear at the top of the
+ * compiled file, but it's generally better to create a new file per style scope.
+ *
+ *= require_self
+ *= require_tree ./core
+ *= require_tree ./application
+*/

data/app/assets/stylesheets/application/ansi.scss

@@ -0,0 +1,38 @@
+.ansi {
+  font-family: Monaco, Menlo, Consolas, "Courier New", monospace;
+  margin: 0 -20px;
+  padding: 20px 20px;
+
+  font-size: 13px;
+  line-height: 20px;
+  word-break: break-all;
+  word-wrap: break-word;
+  white-space: pre;
+  white-space: pre-wrap;
+  background-color: #33302c;
+  color: #989897;
+  
+  &, * {
+    &::selection { background: #474441; } // WebKit/Blink Browsers
+    &::-moz-selection { background: #474441; } // Gecko Browsers
+  }
+  
+  .ansi-bold { font-weight: bold; }
+  .ansi-underline { text-decoration: underline; }
+  .ansi-black { color: rgb(0, 35, 44); }
+  .ansi-red { color: #954c30; }
+  .ansi-green { color: #749c49; }
+  .ansi-yellow { color: #a9a049; }
+  .ansi-blue { color: #5c80a2; }
+  .ansi-magenta { color: #6c526c; }
+  .ansi-cyan { color: #688f8e; }
+  .ansi-white { color: #b8baba; }
+  .ansi-bold .ansi-black, .ansi-black .ansi-bold, .ansi-bright-black { color: rgb(66, 66, 66); }
+  .ansi-bold .ansi-red, .ansi-red .ansi-bold, .ansi-bright-red { color: #bb653d; }
+  .ansi-bold .ansi-green, .ansi-green .ansi-bold, .ansi-bright-green { color: #a8b265; }
+  .ansi-bold .ansi-yellow, .ansi-yellow .ansi-bold, .ansi-bright-yellow { color: #cfc266; }
+  .ansi-bold .ansi-blue, .ansi-blue .ansi-bold, .ansi-bright-blue { color: #7a9db0; }
+  .ansi-bold .ansi-magenta, .ansi-magenta .ansi-bold, .ansi-bright-magenta { color: #8b5c8a; }
+  .ansi-bold .ansi-cyan, .ansi-cyan .ansi-bold, .ansi-bright-cyan { color: #aac8ca; }
+  .ansi-bold .ansi-white, .ansi-white .ansi-bold, .ansi-bright-white { color: #d2d1cf; }
+}

data/app/assets/stylesheets/application/commit.scss

@@ -0,0 +1,6 @@
+.commit-profile {
+  
+  .avatar { float: left; margin: 0 14px 14px 0; }
+  h2 { font-weight: 100; margin-left: 110px; }
+  h4 { font-weight: 400; }
+}

data/app/assets/stylesheets/application/emoji.scss

@@ -0,0 +1,5 @@
+img.emoji {
+  height: 1.25em;
+  width: 1.25em;
+  vertical-align: middle;
+}

data/app/assets/stylesheets/application/exceptions.scss

@@ -0,0 +1,64 @@
+$completed-background: #E6F3E2;
+$completed-foreground: rgb(42, 133, 19);
+
+#exceptions {
+  .exception.has-ticket {
+    td {
+      background: $completed-background;
+      color: $completed-foreground;
+      a { color: $completed-foreground; }
+      .exception-comments { background: #DFECDC; }
+    }
+    
+    .fa-check-sign {
+      font-size: 19px;
+      color: #666;
+    }
+  }
+  &.hide-completed .exception.has-ticket { display: none; }
+  
+  .buttons { text-align: center; }
+  .exception-summary { max-width: 30em; }
+  .exception-message { word-break: break-all; }
+  .exception-where {
+    display: block;
+    font-size: 0.9em;
+    font-weight: 500;
+    font-style: italic;
+    color: #727272;
+  }
+  .exception-comments {
+    background: #f4f4f4;
+    padding: 3px 6px;
+    margin-top: 6px;
+  }
+  .table-striped tbody > tr:nth-child(odd) > td .exception-comments { background: #efefef; }
+  .exception-comment {
+    white-space: nowrap;
+    overflow: hidden;
+    text-overflow: ellipsis;
+    font-size: 0.9em;
+    color: #484848;
+    
+    p { display: inline; }
+  }
+  .exception-first, .exception-last {
+    white-space: nowrap;
+  }
+  .exception-commit {
+    display: block;
+    font-family: consolas, fixed;
+    font-size: 0.75em;
+    line-height: 14px;
+  }
+  .exception-release {
+    display: block;
+    font-size: 0.88em;
+    line-height: 10px;
+  }
+  .exception-ticket .ticket-number {
+//    font-size: 0.88em;
+    font-size: 1.5em;
+    font-weight: 100;
+  }
+}