houston-core 0.5.0.beta1

data/app/assets/javascripts/app/views/edit_ticket_view.coffee

@@ -0,0 +1,67 @@
+class @EditTicketView extends Backbone.View
+
+  initialize: ->
+    @ticket = @options.ticket
+
+  render: ->
+    @$el.find('.editable').pseudoHover()
+    @$summary = @$el.find('#ticket_summary')
+    @$description = @$el.find('#ticket_description')
+    $textarea = @$description.find('textarea')
+
+    $(window).resize =>
+      $textarea.css height: @$description.parent().height() - (61 + 31)
+    $textarea.css height: @$description.parent().height() - (61 + 31)
+
+    $('.uploader').supportImages()
+
+    @$el.find('.ticket-state').pseudoHover().click (e)=>
+      action = if $(e.target).hasClass('open') then 'close' else 'reopen'
+      @ticket[action]()
+        .success (attributes)->
+          $(e.target)
+            .removeClass('hover')
+            .toggleClass('open', !attributes.closedAt)
+            .toggleClass('closed', !!attributes.closedAt)
+
+    @$summary.find('.show').click (e)=>
+      $editable = $(e.target).closest('.editable')
+      $editable.addClass('in-edit')
+      $editable.find('input').val(@ticket.get 'summary').focus().select()
+      $editable.find('input').blur ->
+        $input = $(e.target)
+        $editable = $input.closest('.editable')
+        $editable.removeClass('in-edit')
+
+    @$description.find('.show').click (e)=>
+      $editable = $(e.target).closest('.editable')
+      $editable.addClass('in-edit')
+      $editable.find('textarea').val(@ticket.get 'description').focus().select()
+
+    @$summary.find('input').keydown (e)=>
+      if e.keyCode is 27
+        $input = $(e.target)
+        $editable = $input.closest('.editable')
+        $editable.removeClass('in-edit')
+      if e.keyCode is 13
+        $input = $(e.target)
+        @ticket.save summary: $input.val()
+
+        $editable = $input.closest('.editable')
+        $editable.removeClass('in-edit')
+        $editable.find('.show').html @ticket.get('summary')
+
+    @$description.find('button[type="reset"]').click (e)->
+      e.preventDefault()
+      $input = $(e.target)
+      $editable = $input.closest('.editable')
+      $editable.removeClass('in-edit')
+
+    @$description.find('button[type="submit"]').click (e)=>
+      e.preventDefault()
+      $textarea = @$description.find('textarea')
+      @ticket.save description: $textarea.val()
+
+      $editable = $textarea.closest('.editable')
+      $editable.removeClass('in-edit')
+      $editable.find('.show').html App.mdown(@ticket.get('description'))

data/app/assets/javascripts/app/views/find_or_create_ticket_view.coffee

@@ -0,0 +1,75 @@
+class @FindOrCreateTicketView extends Backbone.View
+  className: 'find-or-create-ticket'
+  
+  initialize: ->
+    @template = HandlebarsTemplates['tickets/find_or_create']
+    @typeaheadTemplate = HandlebarsTemplates['tickets/typeahead']
+    @tickets = @options.tickets
+    @addTicket = @options.addTicket
+    @createTicket = @options.createTicket
+    @ticketTracker = @options.ticketTracker
+  
+  render: ->
+    @$el.html @template()
+    
+    typeaheadTemplate = @typeaheadTemplate
+    view = @
+    $add_ticket = @$el.find('#find_or_create_ticket').attr('autocomplete', 'off').typeahead
+      source: @tickets
+      matcher: (item)->
+        ~item.summary.toLowerCase().indexOf(@query.toLowerCase()) ||
+        ~item.projectTitle.toLowerCase().indexOf(@query.toLowerCase()) ||
+        ~item.number.toString().toLowerCase().indexOf(@query.toLowerCase())
+
+      sorter: (items)->
+        view.suggestions = items
+        view.$el.toggleClass('no-suggestions', items.length is 0)
+        items # apply no sorting (return them in order of priority)
+
+      highlighter: (ticket)->
+        query = @query.replace(/[\-\[\]{}()*+?.,\\\^$|#\s]/g, '\\$&')
+        regex = new RegExp("(#{query})", 'ig')
+        ticket.summary.replace regex, ($1, match)-> "<strong>#{match}</strong>"
+        typeaheadTemplate
+          summary: ticket.summary.replace regex, ($1, match)-> "<strong>#{match}</strong>"
+          number: ticket.number.toString().replace regex, ($1, match)-> "<strong>#{match}</strong>"
+
+    .keyup -> view.$el.toggleClass('has-content', $(@).val().length > 0)
+
+    $add_ticket.data('typeahead').render = (tickets)->
+      items = $(tickets).map (i, item)=>
+        i = $(@options.item).attr('data-value', item.id)
+        i.find('a').html(@highlighter(item))
+        i[0]
+
+      items.first().addClass('active')
+      @$menu.html(items)
+      @
+
+    withFormFeedback = (callback)->
+      $add_ticket.prop 'disabled', true
+      callback()
+        .success ->
+          $add_ticket.prop('disabled', false).val('').focus()
+        .error (response)->
+          $add_ticket.prop('disabled', false).focus()
+          errors = Errors.fromResponse(response)
+          if errors.missingCredentials or errors.invalidCredentials
+            App.promptForCredentialsTo view.ticketTracker
+          else
+            errors.renderToAlert()
+
+    $add_ticket.data('typeahead').select = ->
+      @hide()
+
+      id = @$menu.find('.active').attr('data-value')
+      ticket = _.detect view.tickets, (ticket)-> +ticket.id == +id
+      withFormFeedback -> view.addTicket(ticket)
+
+    @$el.find('form').submit (e)=>
+      e.preventDefault()
+
+      $add_ticket.prop 'disabled', true
+      withFormFeedback => @createTicket($add_ticket.val())
+
+    $add_ticket.focus()

data/app/assets/javascripts/app/views/keyboard_shortcuts_modal.coffee

@@ -0,0 +1,42 @@
+class @KeyboardShortcutsModal
+  
+  constructor: ->
+    @template = HandlebarsTemplates['keyboard_shortcuts']
+    @shortcuts = [
+        keys: ['n', 't']
+        name: 'New Ticket'
+      , 
+        keys: ['R', 't']
+        name: 'Refresh Tickets'
+      
+      , 
+        keys: ['G']
+        name: 'Go to...'
+      
+      , 
+        keys: ['g', 'p']
+        name: 'Go to Projects'
+      , 
+        keys: ['g', 'q']
+        name: 'Go to Pull Requests'
+      , 
+        keys: ['g', 'i']
+        name: 'Go to ITSMs'
+      , 
+        keys: ['g', 't', 'r']
+        name: 'Go to Testing Report'
+      , 
+        keys: ['g', 'n', 't']
+        name: 'Go to New Ticket'
+      , 
+        keys: ['g', 'u']
+        name: 'Go to Users'
+    
+      , 
+        keys: ['?']
+        name: 'Keyboard shortcuts'
+    ]
+  
+  show: ->
+    $modal = $(@template(shortcuts: @shortcuts)).modal()
+    $modal.on 'hidden', -> $modal.remove()

data/app/assets/javascripts/app/views/new_ticket_modal.coffee

@@ -0,0 +1,24 @@
+class @NewTicketModal
+  
+  constructor: (options)->
+    @slug = options.slug
+    @color = options.color
+    @options = options
+    @template = HandlebarsTemplates['new_ticket/modal']
+  
+  show: ->
+    @$modal = $(@template(color: @color)).modal()
+    @$modal.on 'hidden', =>
+      @$modal.remove()
+      @options.onClose() if @options.onClose
+    
+    xhr = $.get "/projects/#{@slug}/tickets/new"
+    xhr.success (data)=>
+      options = _.extend(data, @options)
+      options.onCreate = ((ticket)=> @options.onCreate(ticket, @$modal)) if options.onCreate
+      view = new NewTicketView(options)
+      view.render()
+      
+      $('#reset_ticket').click (e)=>
+        e.preventDefault()
+        @$modal.modal('hide')

data/app/assets/javascripts/app/views/new_ticket_view.coffee

@@ -0,0 +1,207 @@
+class window.NewTicketView extends Backbone.View
+  
+  FEATURE_DESCRIPTION: '''
+### Make sure that
+ - 
+  '''
+
+  BUG_DESCRIPTION: '''
+### Steps to Test
+ - 
+
+### What happens
+ - 
+
+### What should happen
+ - 
+  '''
+  
+  # !todo: get these from Houston.config.ticket_types
+  TYPES: ['bug', 'feature', 'chore', 'enhancement']
+  
+  events:
+    'click #reset_ticket': 'resetNewTicket'
+    'click #create_ticket': 'createNewTicket'
+  
+  initialize: ->
+    @$el = $('#new_ticket_view')
+    @$el.html HandlebarsTemplates['new_ticket/form']()
+    @project = @options.project
+    @tickets = new Tickets(@options.tickets)
+    @LABELS = @options.labels
+    @TAGS = @TYPES.map (type)-> "[#{type}]"
+    @TAG_MATCHER = "\\[(#{@TYPES.join('|')})\\]"
+    @renderSuggestion = HandlebarsTemplates['new_ticket/suggestion']
+    @$suggestions = $('#ticket_suggestions')
+    @$summary = $('#ticket_summary')
+    @$summary.val "[#{@options.type}] " if @options.type
+    @lastSearch = ''
+    
+    if @options.antecedents
+      description = '### Antecedents\n' + (" - #{antecedent}" for antecedent in @options.antecedents).join("\n")
+      $('#ticket_description').val(description)
+      @showNewTicket(animate: false)
+    
+    Mousetrap.bindScoped '#ticket_summary, #ticket_description', 'mod+enter', (e)=>
+      @$el.find('#create_ticket').click() if @$el.find(':focus').length > 0
+  
+  render: ->
+    onTicketSummaryChange = _.bind(@onTicketSummaryChange, @)
+    @$summary.keydown (e)=>
+      if e.keyCode is 13
+        e.preventDefault()
+        @showNewTicket()
+        $('#ticket_description').focus()
+      if e.keyCode is 9
+        e.preventDefault()
+        @$summary.putCursorAtEnd()
+    @$summary.keyup onTicketSummaryChange
+    @$summary.change onTicketSummaryChange
+    $('#ticket_description').focus =>
+      @$el.attr('data-mode', 'description')
+    
+    $('.uploader').supportImages()
+    
+    view = @
+    
+    y = /\] *([^:]*)/
+    z = /^([^\]]*)(\]|$)/
+    
+    @$summary
+      .attr('autocomplete', 'off')
+      .typeahead
+        source: (query)->
+          pos = @$element.getCursorPosition()
+          a = query.indexOf(']')
+          b = query.indexOf(':')
+          
+          if a is -1 or pos <= a
+            @tquery = query.match(z)[1].toLowerCase()
+            @mode = 'type'
+            return view.TAGS
+          
+          else if a > 0 and (b is -1 or pos <= b)
+            @lquery = query.match(y)[1]
+            @lquery = new RegExp "\\b#{@lquery}", "i"
+            @mode = 'label'
+            return view.LABELS
+          
+          else if a > 0 and b > 0
+            @mode = 'summary'
+            return []
+          
+          else
+            @mode = ''
+            return []
+            
+        updater: (item)->
+          if @mode == 'type'
+            view.autocompleteDescriptionFor(item)
+            @$element.val().replace(/^[^\]]*(\] ?|$)?/, item + ' ')
+          else if @mode == 'label'
+            @$element.val().replace(/\] ?[^:]*(: ?|$)/, '] ' + item + ': ')
+            
+        matcher: (item)->
+          if @mode == 'type'
+            ~item.toLowerCase().indexOf(@tquery)
+          else if @mode == 'label'
+            @lquery.test(item)
+          else
+            false
+    
+    $('#ticket_summary').focus().putCursorAtEnd()
+    @onTicketSummaryChange()
+  
+  
+  onTicketSummaryChange: ->
+    return unless @$summary.is(':focus')
+    summary = @$summary.val()
+    if !///#{@TAG_MATCHER} ///.test(summary)
+      @$el.attr('data-mode', 'type')
+      @$suggestions.empty()
+    else if !///#{@TAG_MATCHER} (.*):///.test(summary)
+      @$el.attr('data-mode', 'label')
+      @$suggestions.empty()
+    else
+      @$el.attr('data-mode', 'summary')
+      md = summary.match(///#{@TAG_MATCHER} (.*)///)
+      if md
+        [_, type, summary] = md
+        @nextSearch = summary
+        @updateSuggestions()
+  
+  updateSuggestions: ->
+    unless @lastSearch is @nextSearch
+      @lastSearch = @nextSearch
+      results = @tickets.search(@nextSearch)
+      list = (@renderSuggestion(ticket.toJSON()) for ticket in results)
+      @$suggestions.empty().append list
+  
+
+  
+  
+  
+  resetNewTicket: (e)->
+    e?.preventDefault()
+    @$summary.val ''
+    @$suggestions.empty()
+    $('#ticket_description').val ''
+    @$el.attr('data-mode', 'type')
+    @hideNewTicket()
+    @$summary.focus()
+  
+  createNewTicket: (e)->
+    e?.preventDefault()
+    attributes = @$el.serializeObject()
+    
+    @$el.disable()
+    
+    xhr = $.post "/projects/#{@project.slug}/tickets", attributes
+    xhr.complete => @$el.enable()
+    
+    xhr.success (ticket)=>
+      @tickets.push(ticket)
+      @resetNewTicket()
+      alertify.success "Ticket <a href=\"#{ticket.ticketUrl}\" target=\"_blank\">##{ticket.number}</a> was created"
+      @$el.enable()
+      @options.onCreate(ticket) if @options.onCreate
+      $(document).trigger 'ticket:create', [ticket]
+    
+    xhr.error (response)=>
+      errors = Errors.fromResponse(response)
+      if errors.missingCredentials or errors.invalidCredentials
+        App.promptForCredentialsTo @project.ticketTrackerName
+      else if errors.oauthLocation
+        App.oauth(errors.oauthLocation)
+      else
+        errors.renderToAlert()
+
+
+
+  showNewTicket: (options)->
+    options ?= {}
+    animate = options.animate ? true
+    $('#ticket_suggestions').hide()
+    if animate
+      $('.new-ticket-full').slideDown 200, ->
+        $('#ticket_description').autosize()
+    else
+      $('.new-ticket-full').show()
+      $('#ticket_description').autosize()
+
+  hideNewTicket: ->
+    $('.new-ticket-full').slideUp 200, ->
+      $('#ticket_suggestions').show()
+
+
+
+  autocompleteDescriptionFor: (type)->
+    $('#ticket_description')
+      .val(@defaultDescriptionFor(type))
+      .trigger('autosize.resize')
+
+  defaultDescriptionFor: (type)->
+    switch type
+      when '[feature]' then @FEATURE_DESCRIPTION
+      when '[bug]' then @BUG_DESCRIPTION
+      else ''

data/app/assets/javascripts/app/views/problems_view.coffee

@@ -0,0 +1,114 @@
+class @ProblemsView extends Backbone.View
+  
+  initialize: ->
+    @project = @options.project
+    @problems = @options.problems
+    @template = HandlebarsTemplates['problems/index']
+    @renderProblem = HandlebarsTemplates['problems/show']
+    Handlebars.registerPartial 'problem', @renderProblem
+    $('#show_completed_exceptions').click _.bind(@toggleShowCompleted, @)
+
+  render: ->
+    @refresh()
+    
+    $('#problems').on 'click', 'tr', _.bind(@toggleCheckbox, @)
+    $('#problems').on 'click', ':checkbox', _.bind(@styleRow, @)
+    
+    $('#merge_exceptions').click _.bind(@mergeExceptions, @)
+    $('#unmerge_exceptions').click _.bind(@unmergeExceptions, @)
+    $('#delete_exceptions').click _.bind(@deleteExceptions, @)
+    
+    $('#exceptions table').tablesorter
+      headers:
+        2: {sorter: 'timestamp'}
+        3: {sorter: 'timestamp'}
+    
+    $('#exceptions').on 'click', '.btn-new-ticket', (e)=>
+      $button = $(e.target)
+      $button.attr('disabled', 'disabled')
+      $exception = $button.closest('.exception')
+      token = $exception.attr('data-token')
+      url = $exception.attr('data-url')
+      problem = _.find(@problems, (problem)-> problem.url == url)
+      return unless problem
+      App.showNewTicket
+        type: 'bug'
+        antecedents: ["Errbit: #{token}"]
+        onClose: ->
+          $button.removeAttr('disabled')
+        onCreate: (ticket, modal)=>
+          modal.modal('hide')
+          problem.ticketId = ticket.id
+          problem.ticketUrl = ticket.url
+          problem.ticketNumber = ticket.number
+          @refresh()
+  
+  refresh: ->
+    $('#problems').html @template(problems: @problems)
+    @updateProblemCount()
+  
+  updateProblemCount: ->
+    $('#problem_count').html $('.exception:not(.has-ticket)').length
+
+  toggleCheckbox: (e)->
+    return if _.include(['A', 'INPUT', 'BUTTON', 'TEXTAREA'], e.target.nodeName)
+    $exception = $(e.target).closest('.exception')
+    $checkbox = $exception.find(':checkbox')
+    $checkbox.prop('checked', !$checkbox.prop('checked'))
+    $exception.toggleClass('selected', $checkbox.is(':checked'))
+
+  styleRow: (e)->
+    $checkbox = $(e.target)
+    $exception = $checkbox.closest('.exception')
+    $exception.toggleClass('selected', $checkbox.is(':checked'))
+
+
+
+  mergeExceptions: ->
+    problems = @selectedProblems()
+    if problems.length < 2
+      @alert '#merge_exceptions', 'You must select at least two problems to merge'
+    else
+      xhr = $.post "/projects/#{@project}/exceptions/merge_several", problems: problems
+      xhr.success -> window.location.reload()
+      xhr.error (response)=> @alert('#merge_exceptions', response.responseText)
+
+  unmergeExceptions: ->
+    problems = @selectedProblems()
+    if problems.length < 2
+      @alert '#unmerge_exceptions', 'You must select at least one problem to unmerge'
+    else
+      xhr = $.post "/projects/#{@project}/exceptions/merge_several", problems: problems
+      xhr.success -> window.location.reload()
+      xhr.error (response)=> @alert('#unmerge_exceptions', response.responseText)
+
+  deleteExceptions: ->
+    problems = @selectedProblems()
+    if problems.length < 2
+      @alert '#delete_exceptions', 'You must select at least one problem to delete'
+    else
+      xhr = $.post "/projects/#{@project}/exceptions/merge_several", problems: problems
+      xhr.success -> window.location.reload()
+      xhr.error (response)=> @alert('#delete_exceptions', response.responseText)
+
+  selectedProblems: ->
+    $('#problems_form').serializeObject()['problems[]'] || []
+  
+  alert: (button, message)->
+    $(button)
+      .attr('data-content', message)
+      .attr('data-trigger', 'manual')
+      .attr('data-placement', 'top')
+      .popover('show')
+      .blur -> $(@).popover('hide')
+
+
+
+  toggleShowCompleted: (e)->
+    $button = $(e.target)
+    if $button.hasClass('active')
+      $button.removeClass('btn-success')
+      $('#exceptions').addClass('hide-completed')
+    else
+      $button.addClass('btn-success')
+      $('#exceptions').removeClass('hide-completed')