houston-core 0.5.0.beta1

data/app/assets/javascripts/app/stacked_bar_graph.coffee

@@ -0,0 +1,108 @@
+class Houston.StackedBarGraph
+  
+  constructor: ->
+    @_margin = {top: 0, right: 80, bottom: 40, left: 50}
+    @_width = 960
+    @_height = 260
+    @_data = []
+    @_legend = true
+    @_labels = []
+    @_colors = ['rgb(31, 119, 180)', 'rgb(174, 199, 232)', 'rgb(255, 127, 14)', 'rgb(255, 187, 120)', 'rgb(44, 160, 44)']
+    @_axes = ['x', 'y']
+  
+  legend: (@_legend)-> @
+  margin: (@_margin)-> @
+  width: (@_width)-> @
+  height: (@_height)-> @
+  selector: (@_selector)-> @ 
+  data: (@_data)-> @
+  labels: (@_labels)-> @
+  colors: (@_colors)-> @
+  range: (@_range)-> @
+  axes: (@_axes)-> @
+  yTicks: (@_yTicks)-> @
+  
+  render: ->
+    graphWidth = @_width - @_margin.left - @_margin.right
+    graphHeight = @_height - @_margin.top - @_margin.bottom
+    
+    formatDate = d3.time.format('%A')
+    
+    x = d3.scale.ordinal().rangeRoundBands([0, graphWidth], 0.15)
+    y = d3.scale.linear().range([graphHeight, 0])
+    
+    xAxis = d3.svg.axis()
+      .scale(x)
+      .orient('bottom')
+      .tickFormat(d3.time.format('%b %-d'))
+    
+    yAxis = d3.svg.axis()
+      .scale(y)
+      .orient('left')
+    yAxis.tickValues(@_yTicks) if @_yTicks
+    
+    color = d3.scale.ordinal().range(@_colors).domain(@_labels)
+    
+    stack = d3.layout.stack()
+      .values((d)-> d.values)
+    
+    data = stack [0...@_labels.length].map (i)=>
+      name: @_labels[i]
+      values: @_data.map (d)=>
+        name: @_labels[i]
+        date: new Date(d[0])
+        y: d[i + 1] ? 0
+    
+    x.domain _.map(data[0].values, (d)-> d.date)
+    max = d3.max(data[@_labels.length - 1].values, (d)-> d.y + d.y0)
+    max = d3.max([max, @_range[1]]) if @_range
+    y.domain [0, max]
+    
+    $(@_selector).empty()
+    svg = d3.select(@_selector).append('svg')
+        .attr('width', @_width)
+        .attr('height', @_height)
+      .append('g')
+        .attr('transform', "translate(#{@_margin.left},#{@_margin.top})")
+    
+    if 'x' in @_axes
+      svg.append('g')
+        .attr('class', 'x axis')
+        .attr('transform', "translate(0,#{graphHeight})")
+        .call(xAxis)
+    
+    if 'y' in @_axes
+      svg.append('g')
+        .attr('class', 'y axis')
+        .call(yAxis)
+    
+    section = svg.selectAll('.section')
+      .data(x.domain())
+    
+    section.enter()
+      .append('g')
+      .attr('class', 'section')
+      .attr('transform', (date)-> "translate(#{x(date)},0)")
+    
+    section.selectAll('rect')
+        .data (date, i)->
+          for bar in data
+            name: bar.name
+            y1: bar.values[i].y0 + bar.values[i].y
+            y0: bar.values[i].y0
+      .enter()
+        .append('rect')
+        .attr('class', 'bar')
+        .attr('width', x.rangeBand())
+        .attr('y', (d)-> y(d.y1))
+        .attr('height', (d)-> y(d.y0) - y(d.y1))
+        .style('fill', (d)-> color(d.name))
+    
+    if @_legend
+      $legend = $('<dl class="legend"></dl>').appendTo(@_selector)
+      for i in [0...@_labels.length]
+        label = @_labels[i]
+        color = @_colors[i]
+        $legend.append "<dt class=\"circle\" style=\"background: #{color}\"></dt><dd>#{label}</dd>"
+    
+    @

data/app/assets/javascripts/app/table_row_expander.coffee

@@ -0,0 +1,52 @@
+class @TableRowExpander
+  
+  setupForViews: (views)->
+    @expandedView = null
+    views.each (view)=>
+      view.on 'expanding', => @onViewExpanding(view)
+      
+      view.expand = _.bind ->
+          @trigger('expanding')
+          @$el.addClass('expanded in-transition')
+          @$expandedRow = @renderExpandedRow()
+          @$expandedRow.slideDown =>
+            @$el.removeClass('in-transition')
+            @trigger('expanded')
+        , view
+      
+      view.collapse = _.bind (speed)->
+          return unless @$expandedRow
+          
+          finish = =>
+            @$el.removeClass('expanded in-transition')
+            @$expandedRow.closest('tr').remove()
+            @$expandedRow = null
+          
+          if speed == 'fast'
+            finish()
+          else
+            @$el.addClass('in-transition')
+            @$expandedRow.slideUp(finish)
+        , view
+      
+      view.$el.click (e)=>
+        return if $(e.target).is('button, a, input')
+        @expandOrCollapseView(view)
+    
+    $('.table-sortable').bind 'sortStart', => @collapseExpandedView('fast')
+  
+  expandOrCollapseView: (view)->
+    return if view.$el.hasClass('in-transition')
+    return if view.$el.hasClass('deleting')
+
+    if view.$el.hasClass('expanded')
+      view.collapse()
+    else
+      view.expand()
+  
+  onViewExpanding: (view)->
+    @collapseExpandedView()
+    @expandedView = view
+  
+  collapseExpandedView: (speed)->
+    @expandedView.collapse(speed) if @expandedView

data/app/assets/javascripts/app/ticket_tracker_refresh.coffee

@@ -0,0 +1,73 @@
+$ ->
+  
+  refreshTickets = ->
+    return if $button.hasClass('working') or $button.hasClass('done')
+    
+    $button.addClass('working')
+    
+    alertify.log "Your project is being synced with #{$button.attr('data-tracker')}"
+    
+    xhr = $.post $button.attr('href')
+    xhr.complete => $button.removeClass('working')
+    xhr.success =>
+      alertify.success "Your project is up-to-date! <a href=\"#{window.location}\">Refresh</a> to see the latest tickets."
+      $button.addClass('done')
+    
+    xhr.error =>
+      alertify.error "Your project could not be synced with #{$button.attr('data-tracker')}"
+  
+  
+  showKeyboardShortcuts = ->
+    new KeyboardShortcutsModal().show()
+  
+  
+  $button = $('#sync_tickets_button')
+  $button.find('[data-toggle="tooltip"]').tooltip()
+  
+  Mousetrap.bind 'R t', -> $button.click()
+  $button.click (e)->
+    e.preventDefault()
+    refreshTickets()
+  
+  
+  Mousetrap.bind 'n t', -> $('#new_ticket_button').click()
+  $('#new_ticket_button').click (e)->
+    e.preventDefault()
+    App.showNewTicket()
+  
+  
+  Mousetrap.bind 'G', (e)->
+    e.preventDefault()
+    
+    renderItem = (item)-> HandlebarsTemplates["omnibar/#{item.type}"](item)
+    renderItems = (items)-> _.reduce items, ((html, item)-> html + renderItem(item)), ''
+    
+    $modal = $(HandlebarsTemplates['omnibar/modal']()).modal()
+    $modal.on 'hidden', => $modal.remove()
+    $('#omnibar').focus().putCursorAtEnd().typeahead
+      minLength: 2
+      source: (query, process)->
+        $.get '/omnibar', query: query, process
+        false # don't render anything now, wait for $.get to call process
+      updater: (url)->
+        $modal.remove() # remove the modal but not the backdrop
+        window.location.href = url
+      matcher: (item)-> true # they all match (the server did the matching)
+      sorter: (items)-> items # apply no sorting (return them in the order given)
+    $('#omnibar').data('typeahead').render = (items)->
+      @$menu.html(renderItems(items))
+      @$menu.find('li:first').addClass('active')
+      @
+    $('#omnibar').on 'keyup', (e)-> $modal.modal('hide') if e.keyCode is 27
+  
+  Mousetrap.bind 'g p', -> window.location = '/projects'
+  Mousetrap.bind 'g i', -> window.location = '/itsm/issues'
+  Mousetrap.bind 'g t r', -> window.location = '/testing_report'
+  Mousetrap.bind 'g n t', -> window.location = '/tickets/new'
+  Mousetrap.bind 'g u', -> window.location = '/users'
+  
+  
+  Mousetrap.bind '?', ->  $('#keyboard_shortcuts_button').click()
+  $('#keyboard_shortcuts_button').click (e)->
+    e.preventDefault()
+    showKeyboardShortcuts()

data/app/assets/javascripts/app/views/_show_sprint_view.coffee

@@ -0,0 +1,84 @@
+class @ShowSprintView extends Backbone.View
+  
+  initialize: ->
+    @sprintId = @options.sprintId
+    @sprintStart = @options.sprintStart
+    @template = HandlebarsTemplates['sprints/show']
+    @tasks = _.sortBy @options.sprintTasks, (task)-> task.projectTitle
+    super
+  
+  setStart: (@sprintStart)-> @
+  setTasks: (sprintTasks)->
+    @tasks = _.sortBy sprintTasks, (task)-> task.projectTitle
+    @
+  
+  render: ->
+    return @ unless @tasks
+    for task in @tasks
+      task.open = !task.completed
+    
+    @$el.html @template()
+    @renderBurndownChart(@tasks)
+  
+  renderBurndownChart: (tasks)->
+    
+    # The time range of the Sprint
+    today = new Date()
+    monday = @sprintStart
+    saturday = 2.days().before(monday)
+    days = (i.days().after(saturday) for i in [0..6])
+    
+    # Sum progress by day;
+    # Find the total amount of effort to accomplish
+    committedByDay = {}
+    completedByDay = {}
+    totalEffort = 0
+    for task in tasks
+      effort = +task.effort
+      if task.completed
+        day = App.truncateDate App.parseDate(task.completedAt)
+        effort = 0 if day < monday # this task was released before this sprint started!
+        
+        completedByDay[day] = (completedByDay[day] || 0) + effort
+        committedByDay[day] = (committedByDay[day] || 0) + effort unless task.firstCommitAt
+      
+      if task.committed
+        day = App.truncateDate App.parseDate(task.firstCommitAt)
+        effort = 0 if day < monday # this task was released before this sprint started!
+        
+        committedByDay[day] = (committedByDay[day] || 0) + effort
+      totalEffort += effort
+    
+    # for debugging
+    window.completedByDay = completedByDay
+    
+    # Transform into remaining effort by day:
+    # Iterate by day in case there are some days
+    # where no progress was made
+    toChartData = (progressByDay)->
+      remainingEffort = totalEffort
+      data = [
+        day: saturday
+        effort: Math.ceil(remainingEffort)
+      ]
+      for day in days
+        unless day > today
+          remainingEffort -= (progressByDay[day] || 0)
+          data.push
+            day: day
+            effort: Math.ceil(remainingEffort)
+      data
+    
+    committed = toChartData(committedByDay)
+    completed = toChartData(completedByDay)
+    toCommit = committed.last().effort
+    toComplete = completed.last().effort
+    
+    new Houston.BurndownChart()
+      .days(days)
+      .totalEffort(totalEffort)
+      .addLine('committed', committed)
+      .addLine('completed', completed)
+      .render()
+
+    $('body').toggleClass('green', totalEffort > 0 and (toCommit == 0 or toComplete == 0))

data/app/assets/javascripts/app/views/_tickets_view.coffee

@@ -0,0 +1,62 @@
+class @TicketsView extends Backbone.View
+  supportsSorting: true
+
+  initialize: ->
+    @tickets = @options.tickets
+    @project = @options.project
+    
+    if @supportsSorting
+      @$el.on 'click', 'th', (e)=>
+        @toggleSort $(e.target).closest('th')
+    
+    mouseDownPosition = {}
+    @$el.on 'mousedown', '[rel="ticket"]', (e)->
+      mouseDownPosition = {x: e.screenX, y: e.screenY}
+    
+    @$el.on 'click', '[rel="ticket"]', (e)=>
+      return if $(e.target).closest('a').length > 0
+      
+      e.preventDefault()
+      e.stopImmediatePropagation()
+      
+      # If a person is trying to highlight the text
+      # of this ticket, don't treat that as a click
+      dx = e.screenX - mouseDownPosition.x
+      dy = e.screenY - mouseDownPosition.y
+      d = Math.sqrt(Math.pow(dx, 2), Math.pow(dy, 2))
+      return if d > 12
+      
+      number = +$(e.target).closest('[rel="ticket"]').attr('data-number')
+      App.showTicket number, @project, @showTicketModal(number)
+    
+    if @options.infiniteScroll
+      new InfiniteScroll
+        load: ($what)=>
+          promise = new $.Deferred()
+          @offset += 50
+          promise.resolve @template
+            tickets: (ticket.toJSON() for ticket in @tickets.slice(@offset, @offset + 50))
+          promise
+
+  renderTickets: ->
+    @render()
+
+  showTicketModal: (number)->
+    {}
+
+  toggleSort: ($th)->
+    if $th.hasClass('sort-asc')
+      $th.removeClass('sort-asc').addClass('sort-desc')
+    else if $th.hasClass('sort-desc')
+      $th.removeClass('sort-desc').addClass('sort-asc')
+    else
+      @$el.find('.sort-asc, .sort-desc').removeClass('sort-asc sort-desc')
+      $th.addClass('sort-desc')
+    
+    attribute = $th.attr('data-attribute')
+    order = if $th.hasClass('sort-desc') then 'desc' else 'asc'
+    @performSort attribute, order
+
+  performSort: (attribute, order)->
+    @tickets = @tickets.orderBy(attribute, order)
+    @renderTickets()

data/app/assets/javascripts/app/views/all_tickets_view.coffee

@@ -0,0 +1,29 @@
+class @AllTicketsView extends @TicketsView
+  template: HandlebarsTemplates['tickets/index']
+
+  initialize: ->
+    super
+    @allTickets = @tickets
+    $('#tickets_filter')
+      .focus()
+      .keyup _.bind(@filterTickets, @)
+
+  render: ->
+    @$el.find('tbody').remove()
+    
+    @offset = 0
+    html = @template
+      tickets: (ticket.toJSON() for ticket in @tickets.slice(0, 50))
+    @$el.append(html)
+    @$el.find('.ticket').pseudoHover()
+
+  showTicketModal: (number)->
+    ticketNumbers: @tickets.pluck('number')
+
+  filterTickets: (e)->
+    search = $(e.target).val()
+    unless @lastSearch is search
+      @lastSearch = search
+      @tickets = if search then new Tickets(@allTickets.search(search)) else @allTickets
+      @render()
+

data/app/assets/javascripts/app/views/commit_view.coffee

@@ -0,0 +1,13 @@
+class window.CommitView extends Backbone.View
+  tagName: 'li'
+  className: 'commit'
+  
+  initialize: ->
+    @renderer = HandlebarsTemplates['commit']
+  
+  render: ->
+    $el = $(@el)
+    json = @model.toJSON()
+    json['message'] = json['message'].replace(/\[#(\d+)\]/g, '') # remove ticket numbers)
+    $el.html @renderer(json)
+    @

data/app/assets/javascripts/app/views/edit_sprint_view.coffee

@@ -0,0 +1,327 @@
+class @EditSprintView extends @ShowSprintView
+  
+  events:
+    'click .check-out-button': 'toggleCheckOut'
+    'click #show_completed_tasks': 'toggleShowCompleted'
+    'click #lock_sprint_button': 'confirmLockSprint'
+    'click .remove-task-button': 'removeTask'
+    'click .complete-task-button': 'toggleTaskCompleted'
+    'submit #add_task_form': 'submitAddTaskForm'
+  
+  initialize: ->
+    super
+    @sprintStart = @options.sprintStart
+    @sprintEnd = @options.sprintEnd
+    @locked = @options.sprintLocked || @options.sprintCompleted
+    @historical = @options.sprintCompleted
+    @template = HandlebarsTemplates['sprints/edit']
+    @typeaheadTemplate = HandlebarsTemplates['sprints/typeahead']
+    @openTasks = @options.openTasks
+    @sprintHistory = @options.sprintHistory
+    @sprintGraph = new Houston.StackedBarGraph()
+      .selector('#sprint_history')
+      .legend(false)
+      .labels(['Completed', 'Missed', 'Checked Out'])
+      .colors(['rgb(31, 180, 61)', 'rgb(200, 200, 200)', 'rgb(56, 173, 228)'])
+      .range([0, 60]) # <-- hard-coded range for effort; 60 is arbitrary
+      .axes([])
+      .width(80)
+      .height(40)
+      .margin(top: 0, left: 0, right: 0, bottom: 0)
+    
+  
+  render: ->
+    return @ unless @tasks
+    for task in @tasks
+      task.open = !task.completed
+      task.locked = @locked
+      task.historical = @historical
+    
+    html = @template
+      locked: @locked
+      historical: @historical
+      tasks: @tasks
+      sprintId: @sprintId
+    @$el.html html
+    
+    if @locked
+      @showAsLocked()
+    else
+      @$el.addClass 'edit-mode'
+      $('#add_task').focus()
+    
+    $('#average_effort').text d3.mean(@sprintHistory, (bar)-> bar[1]).toFixed(1)
+    
+    @renderBurndownChart(@tasks)
+    @updateTotalEffort()
+    
+    unless @historical
+      typeaheadTemplate = @typeaheadTemplate
+      view = @
+      $add_task = @$el.find('#add_task').attr('autocomplete', 'off').typeahead
+        source: @openTasks
+        matcher: (item)->
+          ~item.description.toLowerCase().indexOf(@query.toLowerCase()) ||
+          ~item.projectTitle.toLowerCase().indexOf(@query.toLowerCase()) ||
+          ~item.shorthand.toString().toLowerCase().indexOf(@query.toLowerCase())
+        
+        sorter: (items)-> items # apply no sorting (return them in order of priority)
+        
+        highlighter: (task)->
+          query = @query.replace(/[\-\[\]{}()*+?.,\\\^$|#\s]/g, '\\$&')
+          regex = new RegExp("(#{query})", 'ig')
+          task.description.replace regex, ($1, match)-> "<strong>#{match}</strong>"
+          typeaheadTemplate
+            sequence: task.extendedAttributes?.sequence
+            description: task.description.replace regex, ($1, match)-> "<strong>#{match}</strong>"
+            shorthand: task.shorthand.toString().replace regex, ($1, match)-> "<strong>#{match}</strong>"
+            projectTitle: task.projectTitle.replace regex, ($1, match)-> "<strong>#{match}</strong>"
+            projectColor: task.projectColor
+      
+      $add_task.data('typeahead').render = (tasks)->
+        items = $(tasks).map (i, item)=>
+          i = $(@options.item).attr('data-value', item.id)
+          i.find('a').html(@highlighter(item))
+          i[0]
+        
+        items.first().addClass('active')
+        @$menu.html(items)
+        @
+      
+      addTask = _.bind(@addTask, @)
+      $add_task.data('typeahead').select = ->
+        id = @$menu.find('.active').attr('data-value')
+        @$element.val('')
+        @hide()
+        addTask(id)
+    
+    
+    
+    $('.table-sortable').tablesorter()
+    @
+  
+  
+  
+  submitAddTaskForm: (e)->
+    e.preventDefault()
+  
+  addTask: (id)->
+    task = _.detect @openTasks, (task)-> +task.id == +id
+    if task && +task.effort <= 0
+      @promptForEffort(task).done(=> @addTask(id))
+      return
+    
+    $('#add_task_form').addClass('loading')
+    
+    $.post("/sprints/#{@sprintId}/tasks/#{id}")
+      .error (response)=>
+        $('#add_task_form').removeClass('loading')
+        errors = Errors.fromResponse(response)
+        errors.renderToAlert()
+      .success (task)=>
+        @showCompletedTasks() if !task.open
+        unless _.detect(@tasks, (_task)-> _task.id == task.id)
+          task.checkedOut = !!task.checkedOutBy
+          task.checkedOutByMe = task.checkedOutBy and (task.checkedOutBy.id is window.user.id)
+          @tasks.push task
+          @rerenderTasks()
+          @renderBurndownChart(@tasks)
+        $(".task[data-task-id=#{task.id}]").highlight()
+        $('#add_task_form').removeClass('loading')
+  
+  removeTask: (e)->
+    $button = $(e.target)
+    $task = $button.closest('.task')
+    id = +$task.attr('data-task-id')
+    $.destroy("/sprints/#{@sprintId}/tasks/#{id}")
+      .error (response)=>
+        $task.removeClass('deleting')
+        errors = Errors.fromResponse(response)
+        errors.renderToAlert()
+      .success (task)=>
+        @tasks = _.reject(@tasks, (task)-> task.id == id)
+        $task.remove()
+        @renderBurndownChart(@tasks)
+  
+  toggleTaskCompleted: (e)->
+    $button = $(e.target)
+    $task = $button.closest('.task')
+    id = +$task.attr('data-task-id')
+    task = _.findWhere @tasks, id: id
+    if task.completed
+      $.put "/tasks/#{id}/reopen"
+        .error => console.log 'error', arguments
+        .success (attrs)=>
+          task.completedAt = null
+          task.completed = false
+          task.open = true
+          @rerenderTasks()
+          @renderBurndownChart(@tasks)
+    else
+      $.put "/tasks/#{id}/complete" 
+        .error => console.log 'error', arguments
+        .success (attrs)=>
+          task.completedAt = attrs.completedAt
+          task.completed = true
+          task.open = false
+          @rerenderTasks()
+          @renderBurndownChart(@tasks)
+  
+  rerenderTasks: ->
+    template = HandlebarsTemplates['sprints/task']
+    $tasks = @$el.find('#tasks').empty()
+    for task in @tasks
+      task.open = !task.completed
+      task.locked = @locked
+      task.historical = @historical
+      $tasks.append template(task)
+  
+  promptForEffort: (task)->
+    promise = $.Deferred()
+    html = """
+    <form class="modal hide">
+      <div class="modal-header">
+        <button type="button" class="close" data-dismiss="modal" aria-hidden="true">&times;</button>
+        <h3>Estimate Task ##{task.shorthand}</h3>
+      </div>
+      <div class="modal-body">
+        <p>#{task.description}</p>
+        <div style="text-align: right">
+          <label for="task_effort">
+            Effort:
+            <input autofocus type="number" id="task_effort" class="ticket-effort" style="text-align: right; width: 80px;" />
+          </label>
+        </div>
+      </div>
+      <div class="modal-footer">
+        <button class="btn btn-default" type="reset" data-dismiss="modal">Close</button>
+        <button class="btn btn-primary" type="submit">Submit</button>
+      </div>
+    </form>
+    """
+    $modal = $(html).modal()
+    $modal.find('#task_effort').focus()
+    $modal.on 'hidden', ->
+      $modal.remove()
+      $('#add_task').focus()
+    $modal.on 'keypress', 'input[type="number"]', (e)->
+      return if e.keyCode in [13, 27] # <-- allow Enter and Escape
+      value = $(e.target).val() + String.fromCharCode(e.charCode)
+      e.preventDefault() unless /^\d+(\.\d{0,2})?$/.test(value)
+      e.preventDefault() if +value > 999.99
+    $modal.submit (e)->
+      e.preventDefault()
+      effort = +$('#task_effort').val()
+      xhr = $.put "/tasks/#{task.id}", effort: effort
+      xhr.success ->
+        task.effort = effort
+        promise.resolve()
+        $modal.modal('hide')
+      xhr.error ->
+        console.log('error', arguments)
+        $('#task_effort').focus()
+    promise
+  
+  
+  
+  toggleCheckOut: (e)->
+    $button = $(e.target)
+    $task = $button.closest('tr')
+    id = +$task.attr('data-task-id')
+    task = _.find @tasks, (task)-> task.id == id
+    
+    if $button.hasClass('active')
+      @checkIn($button, $task, id, task)
+    else
+      @checkOut($button, $task, id, task)
+  
+  checkIn: ($button, $task, id, task)->
+    $.destroy("/sprints/#{@sprintId}/tasks/#{id}/lock")
+      .success =>
+        task.checkedOutAt = null
+        task.checkedOutBy = null
+        task.checkedOut = false
+        task.checkedOutByMe = false
+        $button.removeClass('btn-danger').addClass('btn-info').html('Check out')
+        @updateTotalEffort()
+      .error (response)=>
+        errors = Errors.fromResponse(response)
+        errors.renderToAlert()
+  
+  checkOut: ($button, $task, id, task)->
+    $.post("/sprints/#{@sprintId}/tasks/#{id}/lock")
+      .success =>
+        task.checkedOutAt = new Date()
+        task.checkedOutBy =
+          id: window.user.id
+          name: window.user.get('name')
+          email: window.user.get('email')
+        task.checkedOut = true
+        task.checkedOutByMe = true
+        $button.removeClass('btn-info').addClass('btn-danger').html('Check in')
+        @updateTotalEffort()
+      .error (response)=>
+        errors = Errors.fromResponse(response)
+        errors.renderToAlert()
+
+  updateTotalEffort: ->
+    effort = 0
+    for task in @tasks when task.checkedOutBy?.id == window.user.id
+      effort += +task.effort
+    $('#total_effort').html(effort.toFixed(1))
+    @sprintGraph
+      .data(@sprintHistory.concat([[@sprintEnd, 0, 0, effort]]))
+      .render()
+
+  toggleShowCompleted: (e)->
+    $button = $(e.target)
+    if $button.hasClass('active')
+      $button.removeClass('btn-success')
+      @$el.addClass('hide-completed')
+    else
+      $button.addClass('btn-success')
+      @$el.removeClass('hide-completed')
+
+  showCompletedTasks: ->
+    $button = $('#show_completed_tasks')
+    $button.addClass('active')
+    $button.addClass('btn-success')
+    @$el.removeClass('hide-completed')
+
+
+  confirmLockSprint: ->
+    return if @locked
+    $modal = $("""
+    <div class="modal hide" tabindex="-1">
+      <div class="modal-header">
+        <button type="button" class="close" data-dismiss="modal" aria-hidden="true">&times;</button>
+        <h3>Lock Sprint</h3>
+      </div>
+      <div class="modal-body">
+        Once you lock a Sprint, you will be unable to add or remove tasks.
+      </div>
+      <div class="modal-footer">
+        <button class="btn" data-dismiss="modal">Back away slowly</button>
+        <button id="confirm_lock_sprint" class="btn btn-danger" data-dismiss="modal">
+          <i class="fa fa-lock" /> Lock It!
+        </button>
+      </div>
+    </div>
+    """).modal()
+    $modal.on 'hidden', -> $modal.remove()
+    $('#confirm_lock_sprint').click _.bind(@lockSprint, @)
+  
+  lockSprint: ->
+    $.put("/sprints/#{@sprintId}/lock")
+      .success =>
+        @locked = true
+        @showAsLocked()
+  
+  showAsLocked: ->
+    @$el.removeClass 'edit-mode'
+    $('#lock_sprint_button')
+      .attr('disabled', 'disabled')
+      .addClass('active')
+      .removeClass('btn-danger')
+      .html('<i class="fa fa-lock" /> Locked')
+    $('td.task-remove').remove()