houston-core 0.5.0.beta1

data/app/assets/javascripts/application.js

@@ -0,0 +1,18 @@
+// This is a manifest file that'll be compiled into application.js, which will include all the files
+// listed below.
+//
+// Any JavaScript/Coffee file within this directory, lib/assets/javascripts, vendor/assets/javascripts,
+// or vendor/assets/javascripts of plugins, if any, can be referenced here using a relative path.
+//
+// It's not advisable to add code directly here, but if you do, it'll appear at the bottom of the
+// compiled file.
+//
+// Read Sprockets README (https://github.com/sstephenson/sprockets#sprockets-directives) for details
+// about supported directives.
+//
+//= require_tree ./core
+//= require_tree ../templates
+//= require_tree ./app
+
+$.tablesorter.defaults.cssAsc = 'sort-asc';
+$.tablesorter.defaults.cssDesc = 'sort-desc';

data/app/assets/javascripts/core/app.coffee

@@ -0,0 +1,169 @@
+window.App = 
+  
+  meta: (name)->
+    $("meta[name=\"#{name}\"]").attr('content')
+  
+  serverDateFormat: d3.time.format('%Y-%m-%d')
+  
+  parseDate: (date)->
+    return date unless _.isString(date)
+    @serverDateFormat.parse date.slice(0, 10)
+  
+  checkRevision: (jqXHR)->
+    @clientRevision ||= App.meta('revision')
+    serverRevision = jqXHR.getResponseHeader('X-Revision')
+    if serverRevision
+      if (@clientRevision != serverRevision)
+        window.console.log("[App.checkRevision] reloading ('#{@clientRevision}' != '#{serverRevision}')")
+        window.location.reload()
+    else
+      window.console.log("[App.checkRevision] serverRevision is blank")
+  
+  relativeRoot: ->
+    relativeRoot = App.meta('relative_url_root')
+    relativeRoot = relativeRoot.substring(0, relativeRoot.length - 1) if /\/$/.test(relativeRoot)
+    relativeRoot
+  
+  mdown: (markdown)->
+    return '' unless markdown
+    converter = new Markdown.Converter()
+    html = converter.makeHtml(markdown)
+    App.emojify(html)
+
+  emojify: (string)->
+    string.replace /:([a-z0-9\+\-_]+):/, (match, $1)->
+      if _.contains(Emoji.names, $1)
+        "<img alt=\"#{$1}\" height=\"20\" width=\"20\" src=\"#{App.relativeRoot()}/images/emoji/#{$1}.png\" class=\"emoji\" />"
+      else
+        match
+  
+  formatTicketSummary: (message)->
+    message = Handlebars.Utils.escapeExpression(message)
+    [feature, sentence] = message.split(':', 2)
+    if sentence then "<b>#{feature}:</b>#{sentence}" else message
+  
+  formatPercent: (number)->
+    (number * 100).toFixed(0) + '%'
+  
+  showErrorMessage: (title, responseText)->
+    html = """
+    <div class="modal hide">
+      <div class="modal-header">
+        <button type="button" class="close" data-dismiss="modal" aria-hidden="true">&times;</button>
+        <h3>#{title}</h3>
+      </div>
+      <div class="modal-body">
+        #{responseText}
+      </div>
+      <div class="modal-footer">
+        <button type="button" data-dismiss="modal">Close</button>
+      </div>
+    </div>
+    """
+    $modal = $(html).modal()
+    $modal.on 'hidden', -> $(@).remove()
+  
+  uploadComplete: (id, args...)->
+    $(id).trigger('upload:complete', args)
+  
+  toggleFullScreen: ->
+    $body = $('body')
+    
+    $body.keypress (e)->
+      if e.which is 102 # f
+        $body.toggleClass('full-screen')
+        window.location.hash = $body.attr('class')
+        kanbanObj.setKanbanHeight() if window.kanbanObj # TMI: extract to event
+    
+    $body.keydown (e)->
+      if e.keyCode is 27
+        $body.removeClass('full-screen')
+        window.location.hash = ''
+        kanbanObj.setKanbanHeight() if window.kanbanObj # TMI: extract to event
+    
+    options = window.location.hash.substring(1).split(' ')
+    if _.include(options, 'full-screen')
+      $body.toggleClass('full-screen')
+      kanbanObj.setKanbanHeight() if window.kanbanObj # TMI: extract to events
+  
+  showNewTicket: (options)->
+    options ?= {}
+    $banner = $('.project-banner')
+    slug = $banner.attr('data-project-slug')
+    color = $banner.attr('data-project-color')
+    if slug and $('#new_ticket_modal').length is 0
+      new NewTicketModal(_.extend(options, slug: slug, color: color)).show()
+  
+  oauth: (url)->
+    window.location = url
+  
+  truncateDate: (date)->
+    return date unless date.setHours
+    date.setHours(0)
+    date.setMinutes(0)
+    date.setSeconds(0)
+    date.setMilliseconds(0)
+    date
+  
+  truncatedDate: (date)->
+    date = new Date(date.getTime())
+    App.truncateDate(date)
+  
+  showTicket: (number, project, options)->
+    project = project || $('.project-banner').attr('data-project-slug')
+    return false unless number and project
+    
+    options ||= {}
+    options.project = project
+    $context = options.$context || $('#tickets')
+    numbers = _.map($context.find('[rel="ticket"]:visible'), (el)-> +$(el).attr('data-number'))
+    options.ticketNumbers = numbers if numbers.length > 0
+    options.edit = window.user.canEditTickets() if window.user
+    new TicketModalView(options).show(number)
+  
+  promptForCredentialsTo: (service)->
+    html = """
+    <div class="modal hide fade">
+      <form class="form-horizontal" id="user_credentials_form">
+        <div class="modal-header">
+          <button type="button" class="close" data-dismiss="modal" aria-hidden="true">&times;</button>
+          <h3>Log in to #{service}</h3>
+        </div>
+        <div class="modal-body">
+          <div class="control-group">
+            <label class="control-label" for="user_credentials_login">Login</label>
+            <div class="controls">
+              <input type="text" id="user_credentials_login">
+            </div>
+          </div>
+          <div class="control-group">
+            <label class="control-label" for="user_credentials_password">Password</label>
+            <div class="controls">
+              <input type="password" id="user_credentials_password">
+            </div>
+          </div>
+        </div>
+        <div class="modal-footer">
+          <button type="submit" class="btn btn-primary">Sign in</button>
+        </div>
+      </form>
+    </div>
+    """
+    $modal = $(html).modal()
+    $modal.on 'hidden', -> $(@).remove()
+    $modal.on 'shown', (e)=>
+      $input = $modal.find('input[type="text"]:first').select()
+      $modal.find('button[type="submit"]').click (e)=>
+        e.preventDefault()
+        xhr = $.put '/credentials',
+          service: service
+          login: $modal.find('#user_credentials_login').val()
+          password: $modal.find('#user_credentials_password').val()
+        xhr.success ->
+          $modal.modal('hide')
+        xhr.error (response)->
+          $form = $('#user_credentials_form')
+          $form.find('.alert').remove()
+          Errors.fromResponse(response).renderToAlert().prependTo $form
+
+@Houston = @App

data/app/assets/javascripts/core/burndown_chart.coffee

@@ -0,0 +1,111 @@
+class Houston.BurndownChart
+  
+  constructor: ->
+    @_margin = {top: 40, right: 0, bottom: 24, left: 50}
+    @_selector = '#graph'
+    @_height = 260
+    @$el = $(@_selector)
+    @_totalEffort = 0
+    @_lines = {}
+    @_regressions = {}
+    $(window).resize (e)=>
+      @render() if e.target is window
+  
+  margin: (@_margin)-> @
+  height: (@_height)-> @
+  selector: (@_selector)-> @$el = $(@_selector); @
+  dateFormat: (@_dateFormat)-> @ 
+  days: (@days)-> @
+  totalEffort: (@_totalEffort)-> @
+  addLine: (slug, data)-> @_lines[slug] = data; @
+  addRegression: (slug, data)-> @_regressions[slug] = data; @
+  
+  render: ->
+    width = @$el.width() || 960
+    height = @_height
+    graphWidth = width - @_margin.left - @_margin.right
+    graphHeight = height - @_margin.top - @_margin.bottom
+    
+    totalEffort = @_totalEffort
+    unless totalEffort
+      for slug, data of @_lines
+        totalEffort = data[0].effort if data[0] and data[0].effort > totalEffort
+    
+    formatDate = @_dateFormat || d3.time.format('%A')
+    
+    [min, max] = d3.extent(@days)
+    x = d3.scale.ordinal().rangePoints([0, graphWidth], 0.75).domain(@days)
+    y = d3.scale.linear().range([graphHeight, 0]).domain([0, totalEffort])
+    rx = d3.scale.linear().range([x(min), x(max)]).domain([min, max])
+    
+    xAxis = d3.svg.axis()
+      .scale(x)
+      .orient('bottom')
+      .tickFormat((d)=> formatDate(new Date(d)))
+    
+    yAxis = d3.svg.axis()
+      .scale(y)
+      .orient('left')
+    
+    line = d3.svg.line()
+      .interpolate('linear')
+      .x((d)-> x(d.day))
+      .y((d)-> y(d.effort))
+    
+    @$el.empty()
+    svg = d3.select(@_selector).append('svg')
+        .attr('width', width)
+        .attr('height', height)
+      .append('g')
+        .attr('transform', "translate(#{@_margin.left},#{@_margin.top})")
+    
+    svg.append('g')
+      .attr('class', 'x axis')
+      .attr('transform', "translate(0,#{graphHeight})")
+      .call(xAxis)
+    
+    svg.append('g')
+        .attr('class', 'y axis')
+        .call(yAxis)
+      .append('text')
+        .attr('transform', 'rotate(-90)')
+        .attr('y', -45)
+        .attr('x', 160 - height)
+        .attr('dy', '.71em')
+        .attr('class', 'legend')
+        .style('text-anchor', 'end')
+        .text('Points Remaining')
+    
+    
+    
+    for slug, data of @_regressions
+      svg.append('line')
+        .attr('class', "regression regression-#{slug}")
+        .attr('x1', rx(data.x1))
+        .attr('y1', y(data.y1))
+        .attr('x2', rx(data.x2))
+        .attr('y2', y(data.y2))
+    
+    
+    
+    for slug, data of @_lines
+      svg.append('path')
+        .attr('class', "line line-#{slug}")
+        .attr('d', line(data))
+      
+      svg.selectAll("circle.circle-#{slug}")
+        .data(data)
+        .enter()
+        .append('circle')
+          .attr('class', "circle-#{slug}")
+          .attr('r', 5)
+          .attr('cx', (d)-> x(d.day))
+          .attr('cy', (d)-> y(d.effort))
+      
+      svg.selectAll(".effort-remaining.effort-#{slug}")
+        .data(data)
+        .enter()
+        .append('text')
+          .text((d) -> d.effort)
+          .attr('class', "effort-remaining effort-#{slug}")
+          .attr('transform', (d)-> "translate(#{x(d.day) + 5.5}, #{y(d.effort) - 10}) rotate(-75)")

data/app/assets/javascripts/core/core_ext/number.coffee

@@ -0,0 +1,48 @@
+class window.Duration
+  constructor: (@n, @units)->
+  after:  (date)-> date && Duration.transformDateBy(date, +@n, @units)
+  before: (date)-> date && Duration.transformDateBy(date, -@n, @units)
+  ago: -> @before(new Date())
+  fromNow: -> @after(new Date())
+  valueOf: ->
+    switch @units
+      when 'minutes' then @n * Duration.MINUTE
+      when 'hours' then @n * Duration.HOUR
+      when 'days' then @n * Duration.DAY
+      when 'weeks' then @n * Duration.WEEK
+      when 'months' then @n * Duration.AVGMONTH
+      when 'years' then @n * Duration.AVGYEAR
+
+Duration::from = Duration::after
+
+Duration.MINUTE = 60000
+Duration.HOUR = Duration.MINUTE * 60
+Duration.DAY = Duration.HOUR * 24
+Duration.WEEK = Duration.DAY * 7
+Duration.AVGMONTH = Duration.WEEK * 4.3452380952381
+Duration.AVGYEAR = Duration.DAY * 365
+Duration.transformDateBy = (date, n, units)->
+  [year, month, day] = [date.getFullYear(), date.getMonth(), date.getDate()]
+  switch units
+    when 'minutes' then new Date(date.getTime() + (n * Duration.MINUTE))
+    when 'hours' then new Date(date.getTime() + (n * Duration.HOUR))
+    when 'days' then new Date(year, month, (day + n))
+    when 'weeks' then new Date(year, month, (day + (n * 7)))
+    when 'months'
+      month = month + n
+      lastDayOfMonth = new Date(year, month + 1, 0).getDate()
+      new Date(year, month, Math.min(day, lastDayOfMonth))
+    when 'years' then new Date(year + n, month, day)
+
+Number::minutes  = ()-> new Duration(Number(@), 'minutes')
+Number::hours    = ()-> new Duration(Number(@), 'hours')
+Number::days     = ()-> new Duration(Number(@), 'days')
+Number::weeks    = ()-> new Duration(Number(@), 'weeks')
+Number::months   = ()-> new Duration(Number(@), 'months')
+Number::years    = ()-> new Duration(Number(@), 'years')
+Number::minutes  = Number::minutes
+Number::hours    = Number::hours
+Number::day      = Number::days
+Number::week     = Number::weeks
+Number::month    = Number::months
+Number::year     = Number::years

data/app/assets/javascripts/core/errors.coffee

@@ -0,0 +1,26 @@
+class window.Errors
+  
+  constructor: (response)->
+    if response.status == 401
+      if response.getResponseHeader('X-Credentials') == 'Missing Credentials'
+        @missingCredentials = true
+      else if response.getResponseHeader('X-Credentials') == 'Invalid Credentials'
+        @invalidCredentials = true
+      else if response.getResponseHeader('X-Credentials') == 'Oauth'
+        @oauthLocation = response.getResponseHeader('Location')
+      else
+        message = response.responseText ? "You are not authorized"
+        @errors = {base: [message]}
+    else
+      @errors = JSON.parse(response.responseText)
+  
+  renderToAlert: ->
+    sentences = []
+    for attribute, messages of @errors
+      if attribute == "base"
+        sentences.push messages[0]
+      else
+        sentences.push "#{attribute} #{messages[0]}"
+    alertify.error sentences.join(".\n")
+
+Errors.fromResponse = (response)-> new Errors(response)

data/app/assets/javascripts/core/handlebars_helpers.coffee

@@ -0,0 +1,164 @@
+Handlebars.registerHelper 'formatDuration', (seconds)->
+  if seconds < Duration.HOUR
+    minutes = Math.floor(seconds / Duration.MINUTE)
+    unit = if minutes == 1 then 'minute' else 'minutes'
+    "#{minutes} #{unit}"
+  else if seconds < Duration.DAY
+    hours = Math.floor(seconds / Duration.HOUR)
+    unit = if hours == 1 then 'hour' else 'hours'
+    "#{hours} #{unit}"
+  else
+    days = Math.floor(seconds / Duration.DAY)
+    unit = if days == 1 then 'day' else 'days'
+    "#{days} #{unit}"
+
+Handlebars.registerHelper 'formatDate', (timestamp)->
+  format = d3.time.format('%a %b %-d')
+  format Date.create(timestamp)
+
+Handlebars.registerHelper 'formatDateWithYear', (timestamp)->
+  return "" unless timestamp
+  format = d3.time.format('%b %-d <span class="year">%Y</span>')
+  format Date.create(timestamp)
+
+Handlebars.registerHelper 'formatDateWithYear2', (timestamp)->
+  return "" unless timestamp
+  format = d3.time.format('%b %-d, %Y')
+  format Date.create(timestamp)
+
+Handlebars.registerHelper 'formatTime', (timestamp)->
+  format = d3.time.format('%a %b %-d, %Y %-I:%M%p')
+  format Date.create(timestamp)
+    .replace(/[AP]M/, (str)-> str.toLowerCase()[0])
+
+Handlebars.registerHelper 'formatTimeAgo', (timestamp)->
+  $.timeago Date.create(timestamp)
+
+Handlebars.registerHelper 'markdown', (markdown)-> App.mdown(markdown)
+
+Handlebars.registerHelper 'emojify', (string)-> App.emojify(string)
+
+Handlebars.registerHelper 'classForAge', (seconds)->
+  if seconds < (6 * Duration.HOUR)
+    'infant'
+  else if seconds < (2 * Duration.DAY)
+    'child'
+  else if seconds < (7 * Duration.DAY)
+    'adult'
+  else if seconds < (4 * Duration.WEEK)
+    'senior'
+  else if seconds < (26 * Duration.WEEK)
+    'old'
+  else
+    'ancient'
+
+Handlebars.registerHelper 'radioButton', (object, id, name, value, selectedValue)->
+  id = "#{object}_#{id}_#{name}_#{value}"
+  input = "<input type=\"radio\" id=\"#{id}\" name=\"#{name}\" value=\"#{value}\""
+  input = input + ' checked="checked"' if value == selectedValue
+  "#{input} />"
+
+Handlebars.registerHelper 'formatTicketSummary', (message)->
+  App.formatTicketSummary(message)
+
+Handlebars.registerHelper 'linkToCommit', (commit)->
+  sha = commit.sha[0...8]
+  if commit.linkTo
+    "<a href=\"#{commit.linkTo}\" target=\"_blank\">#{sha}</a>"
+  else
+    sha
+
+Handlebars.registerHelper 'testerAvatar', (email, size, title)->
+  tester = window.testers.findByEmail(email)
+  gravatarUrl = "//www.gravatar.com/avatar/#{MD5(email.toLowerCase().trim())}?r=g&d=retro&s=#{size * 2}"
+  "<img src=\"#{gravatarUrl}\" width=\"#{size}\" height=\"#{size}\" rel=\"tooltip\" title=\"#{tester.get('name')}\" />"
+  
+Handlebars.registerHelper 'userAvatar', (size)->
+  user = window.user
+  gravatarUrl = "//www.gravatar.com/avatar/#{MD5(user.get('email').toLowerCase().trim())}?r=g&d=retro&s=#{size * 2}"
+  "<img src=\"#{gravatarUrl}\" width=\"#{size}\" height=\"#{size}\" rel=\"tooltip\" title=\"#{user.get('name')}\" />"
+  
+Handlebars.registerHelper 'avatar', (email, size, title)->
+  return "<img class=\"avatar avatar-empty\" width=\"#{size}\" height=\"#{size}\" />" unless email
+  gravatarUrl = "//www.gravatar.com/avatar/#{MD5(email.toLowerCase().trim())}?r=g&d=retro&s=#{size * 2}"
+  if title
+    "<img src=\"#{gravatarUrl}\" class=\"avatar\" width=\"#{size}\" height=\"#{size}\" rel=\"tooltip\" title=\"#{title}\" />"
+  else
+    "<img src=\"#{gravatarUrl}\" class=\"avatar\" width=\"#{size}\" height=\"#{size}\" />"
+  
+Handlebars.registerHelper 'ifEq', (v1, v2, block)->
+  if v1 == v2
+    block.fn(@)
+  else
+    block.inverse(@)
+
+Handlebars.registerHelper 'summarizeAntecedents', (antecedents)->
+  html = ''
+  for kind, antecedents of _.groupBy(antecedents, (antecedent)-> antecedent.kind)
+    html += "#{kind} <span class=\"badge\">#{antecedents.length}</span>"
+  html
+
+Handlebars.registerPartial 'sprintTask', (task)->
+  HandlebarsTemplates['sprints/task'](task)
+
+
+
+Handlebars.registerHelper 'timelineDateRange', (lastDate, date)->
+  return Handlebars.helpers.timelineDate(date) unless lastDate
+  days = (lastDate - date) / Duration.DAY
+  return Handlebars.helpers.timelineDateAfterGap(date) if days >= 3
+  
+  _.inject [0...days],
+    ((html, i)-> html + Handlebars.helpers.timelineDate((i + 1).days().before(lastDate)))
+  , ''
+  
+Handlebars.registerHelper 'timelineDate', (date)->
+  format = d3.time.format """
+  <div class="timeline-date">
+    <span class="weekday">%a</span>
+    <span class="month">%b</span>
+    <span class="day">%-d</span>
+    <span class="year">%Y</span>
+  </div>
+  """
+  format Date.create(date)
+  
+Handlebars.registerHelper 'timelineTime', (time)->
+  format = d3.time.format('<span class="timeline-event-time">%-I:%M%p</span>')
+  format Date.create(time)
+    .replace(/[AP]M/, (str)-> str.toLowerCase()[0])
+
+Handlebars.registerHelper 'timelineDateAfterGap', (date)->
+  '<div class="timeline-date-gap"></div>' + Handlebars.helpers.timelineDate(date)
+
+Handlebars.registerHelper 'timeline', (events, options)->
+  lastDate = null
+  events ?= []
+  if events.length > 0
+    html = '<div class="timeline">'
+    for event in events
+      date = App.truncateDate(Date.create(event.date || event.time))
+      html += Handlebars.helpers.timelineDateRange(lastDate, date)
+      html += options.fn(event)
+      lastDate = date
+    html += '</div>'
+  html
+
+Handlebars.registerHelper 'renderTaskWorker', (task)->
+  if task.checkedOutByMe and !task.historical and task.open
+    '<button class="btn btn-danger check-out-button active" data-toggle="button">Check in</button>'
+  else if task.checkedOutBy
+    Handlebars.helpers.avatar(task.checkedOutBy.email, 24, task.checkedOutBy.firstName) +
+     " #{task.checkedOutBy.firstName}"
+  else if task.open
+    '<button class="btn btn-info check-out-button" data-toggle="button">Check out</button>'
+
+Handlebars.registerHelper 'renderTaskStatus', (task)->
+  if task.released
+    '<i class="fa fa-paper-plane"></i> Released'
+  else if task.committed
+    '<span class="octicon octicon-git-commit"></span> Committed'
+  else if task.completed
+    if task.historical then 'Completed' else '<a class="complete-task-button"></a> Completed'
+  else
+    if task.historical then 'Open' else '<a class="complete-task-button"></a> Open'