houston-core 0.5.0.beta1

data/app/assets/javascripts/app/boot.coffee

@@ -0,0 +1,22 @@
+$ ->
+  
+  $('a[rel=popover]').popover()
+  $('.tooltip').tooltip()
+  $('a[rel=tooltip]').tooltip()
+  
+  $('[rel="tooltip"]').each ->
+    $el = $(@)
+    placement = $el.attr('data-tooltip-placement') || 'bottom'
+    $el.tooltip
+      placement: placement
+  
+  $('.project-banner').affix(offset: {top: 70})
+  
+  $('body').on 'click', '[rel="ticket"]', (e)->
+    return if $(e.target).closest('a').length > 0
+    
+    $link = $(@)
+    number = +$link.attr('data-number')
+    project = $link.attr('data-project')
+    $context = $link.closest('#tickets')
+    e.preventDefault() if App.showTicket(number, project, $context: $context)

data/app/assets/javascripts/app/emoji.coffee.erb

@@ -0,0 +1,2 @@
+window.Emoji =
+  names: <%= Emoji.all.map(&:name).to_json %>;

data/app/assets/javascripts/app/infinite_scroll.coffee

@@ -0,0 +1,32 @@
+class @InfiniteScroll
+  
+  constructor: (options)->
+    @$el = options.$el ? $('.infinite-scroll')
+    @offset = options.offset ? 50
+    @load = options.load
+    @success = options.success
+    @error = options.error
+    
+    @$window = $(window)
+    @$document = $(document)
+    @$window.scroll _.bind(@onScroll, @)
+  
+  onScroll: ->
+    return if @$el.hasClass('loading')
+    return unless @$el.is(':visible')
+    return unless @$window.scrollTop() >= (@$document.height() - @$window.height() - @offset)
+    
+    @loadMore()
+  
+  loadMore: ->
+    xhr = @load(@$el)
+    return unless xhr
+    
+    @$el.addClass('loading')
+    xhr.done (html)=>
+      @$el.removeClass('loading')
+      @$el.append(html)
+      @success() if @success
+    xhr.fail =>
+      @$el.removeClass('loading')
+      @error() if @error

data/app/assets/javascripts/app/models/commit.coffee

@@ -0,0 +1,9 @@
+class window.Commit extends Backbone.Model
+
+
+class window.Commits extends Backbone.Collection
+  model: Commit
+  
+  initialize: (models, options)->
+    super(models, options)
+    @ticket = options.ticket

data/app/assets/javascripts/app/models/release.coffee

@@ -0,0 +1,9 @@
+class window.Release extends Backbone.Model
+
+
+class window.Releases extends Backbone.Collection
+  model: Release
+  
+  initialize: (models, options)->
+    super(models, options)
+    @ticket = options.ticket

data/app/assets/javascripts/app/models/task.coffee

@@ -0,0 +1,5 @@
+class @Task extends Backbone.Model
+  urlRoot: '/tasks'
+  
+class @Tasks extends Backbone.Collection
+  model: Task

data/app/assets/javascripts/app/models/tester.coffee

@@ -0,0 +1,8 @@
+class window.Tester extends Backbone.Model
+
+
+class window.Testers extends Backbone.Collection
+  model: Tester
+  
+  findByEmail: (email)->
+    @find (tester)-> tester.get('email') == email

data/app/assets/javascripts/app/models/testing_note.coffee

@@ -0,0 +1,18 @@
+class window.TestingNote extends Backbone.Model
+  url: ->
+    if @isNew()
+      "#{App.relativeRoot()}/tickets/#{@get('ticketId')}/testing_notes"
+    else
+      "#{App.relativeRoot()}/tickets/#{@get('ticketId')}/testing_notes/#{@get('id')}"
+
+
+class window.TestingNotes extends Backbone.Collection
+  model: TestingNote
+  url: -> "#{App.relativeRoot()}/tickets/#{@ticket.get('id')}/testing_notes"
+  
+  initialize: (models, options)->
+    super(models, options)
+    @ticket = options.ticket
+  
+  since: (date)->
+    @filter (note)-> note.get('createdAt') > date

data/app/assets/javascripts/app/models/ticket.coffee

@@ -0,0 +1,165 @@
+class window.Ticket extends Backbone.Model
+  urlRoot: '/tickets'
+  
+  tasks: -> @_tasks ?= new Tasks(@get('tasks'))
+  
+  estimatedEffort: ->
+    return @get('effort') unless _.isUndefined(@attributes.effort)
+    effort = @tasks().reduce ((sum, task)-> sum + +task.get('effort')), 0
+    if effort == 0 then null else effort
+  
+  estimatedEffortCompleted: ->
+    effort = @tasks()
+      .select (task)-> task.get('completedAt')
+      .reduce ((sum, task)-> sum + +task.get('effort')), 0
+    if effort == 0 then null else effort
+  
+  severity: ->
+    seriousness = @get('seriousness')
+    likelihood = @get('likelihood')
+    clumsiness = @get('clumsiness')
+    return false unless seriousness && likelihood && clumsiness
+    (0.6 * seriousness + 0.3 * likelihood + 0.1 * clumsiness).toFixed(1)
+  
+  testingNotes: ->
+    @testingNotesCollection ||= new TestingNotes(@get('testingNotes'), ticket: @)
+  
+  releases: ->
+    @releasesCollection ||= new Releases(@get('releases'), ticket: @)
+  
+  commits: ->
+    @commitsCollection ||= new Commits(@get('commits'), ticket: @)
+  
+  activityStream: ->
+    @testingNotes().models.concat(@commits().models).sortBy (item)-> item.get('createdAt')
+  
+  
+  parse: (ticket)->
+    ticket.openedAt = new Date(ticket.openedAt) if ticket.openedAt
+    ticket.closedAt = new Date(ticket.closedAt) if ticket.closedAt
+    ticket.effort = +ticket.effort if ticket.effort
+    ticket
+  
+  
+  testerVerdicts: ->
+    verdictsByTester = @verdictsByTester(@testingNotesSinceLastRelease())
+    window.testers.map (tester)->
+      testerId: tester.id
+      email: tester.get('email')
+      verdict: verdictsByTester[tester.get('id')] ? 'pending'
+  
+  verdict: ->
+    verdicts = _.values(@verdictsByTester(@testingNotesSinceLastRelease()))
+    return 'Failing' if _.include verdicts, 'failing'
+    return 'Pending' if window.testers.length == 0
+    
+    minPassingVerdicts = @get('minPassingVerdicts') ? window.testers.length
+    passingVerdicts = _.filter(verdicts, (verdict)=> verdict == 'passing').length
+    return 'Passing' if passingVerdicts >= minPassingVerdicts
+    
+    'Pending'
+  
+  verdictsByTester: (notes)->
+    verdictsByTester = {}
+    notes.each (note)->
+      testerId = note.get('userId')
+      verdict = note.get('verdict')
+      if verdict == 'fails'
+        verdictsByTester[testerId] = 'failing'
+      else if verdict == 'works'
+        verdictsByTester[testerId] ?= 'passing'
+      else if verdict == 'badticket'
+        verdictsByTester[testerId] ?= 'badticket'
+      else if verdict == 'none'
+        verdictsByTester[testerId] ?= 'comment'
+    verdictsByTester
+    
+  testingNotesSinceLastRelease: ->
+    date = @get('lastReleaseAt')
+    if date then @testingNotes().since(date) else @testingNotes()
+  
+  
+  close: ->
+    url = "/projects/#{@get 'projectSlug'}/tickets/by_number/#{@get 'number'}/close"
+    $.post(url).success (attributes)=> @set attributes
+  
+  reopen: ->
+    url = "/projects/#{@get 'projectSlug'}/tickets/by_number/#{@get 'number'}/reopen"
+    $.post(url).success (attributes)=> @set attributes
+
+
+
+
+class window.Tickets extends Backbone.Collection
+  model: Ticket
+  
+  search: (summary)->
+    words = @getWords(summary)
+    # console.log(summary, '->', words)
+    
+    return [] if words.length == 0
+    
+    regexes = (new RegExp("\\b#{RegExp.escape(word)}", 'i') for word in words)
+    
+    results = []
+    for ticket in @models
+      wordsMatched = _.select(regexes, (rx)-> rx.test(ticket.get('summary'))).length
+      wordsMatched += _.select(regexes, (rx)-> rx.test(ticket.get('number'))).length
+      reporter = ticket.get('reporter')
+      wordsMatched += _.select(regexes, (rx)-> rx.test(reporter.name)).length if reporter
+      if wordsMatched > 0
+        ticket.wordsMatched = wordsMatched
+        results.push(ticket)
+    results.sort(@compareTickets).slice(0, 12)
+
+  compareTickets: (a, b)->
+    if a.wordsMatched > b.wordsMatched
+      -1
+    else if b.wordsMatched > a.wordsMatched
+      1
+    else if a.get('closed') && !b.get('closed')
+      1
+    else if b.get('closed') && !a.get('closed')
+      -1
+    else
+      0
+
+  IGNORED_WORDS: ['an', 'the',
+                  'if', 'when', 'then',
+                  'i', 'my',
+                  'and', 'or', 'but',
+                  'for', 'of', 'from',
+                  'should']
+
+  getWords: (string)->
+    words = (word.replace(/[:\|.,;!?]/, '') for word in string.split(' '))
+    _.select words, (word)=> @IGNORED_WORDS.indexOf(word) is -1
+
+  orderBy: (attribute, ascOrDesc)->
+    sortBy = @sorterFor(attribute)
+    [asc, desc] = if ascOrDesc == 'asc' then [1, -1] else [-1, 1]
+    tickets = @models.sort (a, b)->
+      [a, b] = [sortBy(a), sortBy(b)]
+      aIsNull = (a is '' or !a?)
+      bIsNull = (b is '' or !b?)
+      return  1 if aIsNull and !bIsNull
+      return -1 if bIsNull and !aIsNull
+      return 0 if a == b
+      if a > b then asc else desc
+    new @constructor(tickets)
+
+  sorterFor: (attribute)->
+    switch attribute
+      when 'effort'       then (ticket)-> ticket.estimatedEffort()
+      when 'severity'     then (ticket)-> ticket.severity()
+      when 'seriousness'  then (ticket)-> +ticket.get('seriousness')
+      when 'likelihood'   then (ticket)-> +ticket.get('likelihood')
+      when 'clumsiness'   then (ticket)-> +ticket.get('clumsiness')
+      when 'summary'      then (ticket)-> ticket.get('summary').toLowerCase().replace(/^\W/, '')
+      when 'openedAt'     then (ticket)-> ticket.get('openedAt')
+      when 'number'       then (ticket)-> ticket.get('number')
+      when 'antecedents'  then (ticket)->
+        len = ticket.get('antecedents').length
+        if len is 0 then null else len
+      when 'closedAt'     then (ticket)-> ticket.get('closedAt')
+      else throw "Tickets#sorterFor doesn't know how to sort #{attribute}!"

data/app/assets/javascripts/app/models/user.coffee

@@ -0,0 +1,3 @@
+class window.User extends Backbone.Model
+  
+  canEditTickets: -> @get('admin')

data/app/assets/javascripts/app/mousetrap-bind-scoped.js

@@ -0,0 +1,37 @@
+/**
+ * adds a bindScoped method to Mousetrap that allows you to
+ * bind specific keyboard shortcuts that will work only within
+ * certain context
+ * inside a text input field
+ *
+ * usage:
+ * Mousetrap.bindScoped('.some-class', 'ctrl+s', _saveChanges);
+ */
+Mousetrap = (function(Mousetrap) {
+    var _scopedCallbacks = {},
+        _originalStopCallback = Mousetrap.stopCallback;
+
+    Mousetrap.stopCallback = function(e, element, combo, sequence) {
+        var selector = _scopedCallbacks[combo] || _scopedCallbacks[sequence];
+        if (selector) {
+            return !$(element).is(selector);
+        }
+
+        return _originalStopCallback(e, element, combo);
+    };
+
+    Mousetrap.bindScoped = function(selector, keys, callback, action) {
+        Mousetrap.bind(keys, callback, action);
+
+        if (keys instanceof Array) {
+            for (var i = 0; i < keys.length; i++) {
+                _scopedCallbacks[keys[i]] = selector;
+            }
+            return;
+        }
+
+        _scopedCallbacks[keys] = selector;
+    };
+
+    return Mousetrap;
+}) (Mousetrap);

data/app/assets/javascripts/app/releases.coffee

@@ -0,0 +1,55 @@
+window.App.NewReleaseForm =
+  
+  init: (options)->
+    $nestedEditor = $('.changes-nested-editor')
+    $nestedEditor.find('.add-link, .delete-link').attr('tabindex', '-1')
+    $nestedEditor.delegate '.change-description input', 'keypress', (e)->
+      if e.keyCode == 13
+        e.preventDefault()
+        e.stopImmediatePropagation()
+        NestedEditorFor.addRow(NestedEditorFor.getFromEvent(e));
+    $nestedEditor.delegate '.change-description input', 'keyup', (e)->
+      if e.keyCode == 8 and $(this).val() == ''
+        e.preventDefault()
+        e.stopImmediatePropagation()
+        NestedEditorFor.deleteRow(NestedEditorFor.getFromEvent(e));      
+      if e.keyCode == 38
+        $(this).closest('.nested-row').prev().find('input').select()
+      if e.keyCode == 40
+        $(this).closest('.nested-row').next().find('input').select()
+    
+    ticketSummaries = []
+    ticketBySummary = {}
+    for ticket in options.tickets
+      summary = "[##{ticket.number}] #{ticket.summary}"
+      ticketSummaries.push summary
+      ticketBySummary[summary] = ticket
+    
+    addTicket = (ticket)->
+      return if $("#ticket_#{ticket.id}").length > 0
+      html = """
+      <tr id="ticket_#{ticket.id}">
+        <td class="release-ticket-check">
+          <input type="checkbox" id="release_ticket_#{ticket.id}" name="release[ticket_ids][]" value="#{ticket.id}" checked="checked" />
+        </td>
+        <td class="release-ticket-summary">
+          #{App.formatTicketSummary(ticket.summary)}
+        </td>
+        <td class="release-ticket-number">
+          <a href="#{ticket.ticketUrl}" target="_blank">##{ticket.number}
+        </td>
+      </tr>
+      """
+      $('#new_ticket_li').before(html)
+    
+    $('#release_tickets').delegate '.delete-link', 'click', (e)->
+      e.preventDefault()
+      $(@).closest('tr').remove()
+    
+    $('#new_ticket_field')
+      .typeahead
+        source: ticketSummaries
+        updater: (item)->
+          selectedTicket = ticketBySummary[item]
+          addTicket(selectedTicket) if selectedTicket
+          ''

data/app/assets/javascripts/app/stacked_area_graph.coffee

@@ -0,0 +1,113 @@
+class Houston.StackedAreaGraph
+  
+  constructor: ->
+    @_margin = {top: 10, right: 10, bottom: 25, left: 50}
+    @_width = 960
+    @_height = 260
+    @_data = []
+    @_labels = []
+    @_lines = []
+    @_colors = ['rgb(31, 119, 180)', 'rgb(174, 199, 232)', 'rgb(255, 127, 14)', 'rgb(255, 187, 120)', 'rgb(44, 160, 44)']
+    @_axes = ['x', 'y']
+  
+  margin: (@_margin)-> @
+  width: (@_width)-> @
+  height: (@_height)-> @
+  selector: (@_selector)-> @ 
+  data: (@_data)-> @
+  labels: (@_labels)-> @
+  colors: (@_colors)-> @
+  addLine: (line)-> @_lines.push(line); @
+  axes: (@_axes)-> @
+  domain: (@_domain)-> @
+      
+  
+  render: ->
+    graphWidth = @_width - @_margin.left - @_margin.right
+    graphHeight = @_height - @_margin.top - @_margin.bottom
+    
+    formatDate = d3.time.format('%A')
+    
+    @x = x = d3.time.scale().range([0, graphWidth])
+    @y = y = d3.scale.linear().range([graphHeight, 0])
+    
+    xAxis = d3.svg.axis()
+      .scale(x)
+      .orient('bottom')
+    
+    yAxis = d3.svg.axis()
+      .scale(y)
+      .orient('left')
+    
+    color = d3.scale.ordinal().range(@_colors).domain(@_labels)
+    
+    area = d3.svg.area()
+      .interpolate('linear')
+      .x((d)-> x(d.date))
+      .y0((d)-> y(d.y0))
+      .y1((d)-> y(d.y0 + d.y))
+    
+    line = d3.svg.area()
+      .interpolate('linear')
+      .x((d)-> x(d.date))
+      .y((d)-> y(d.y))
+    
+    stack = d3.layout.stack()
+      .values((d)-> d.values)
+    
+    data = stack [0...@_labels.length].map (i)=>
+      name: @_labels[i]
+      values: @_data.map (d)->
+        date: new Date(d[0])
+        y: d[i + 1]
+    
+    x.domain d3.extent(data[0].values, (d)-> d.date)
+    y.domain @_domain or [0, d3.max(data[@_labels.length - 1].values, (d)-> d.y + d.y0)]
+    
+    $(@_selector).empty()
+    svg = d3.select(@_selector).append('svg')
+        .attr('width', @_width)
+        .attr('height', @_height)
+      .append('g')
+        .attr('transform', "translate(#{@_margin.left},#{@_margin.top})")
+    
+    if 'x' in @_axes
+      svg.append('g')
+        .attr('class', 'x axis')
+        .attr('transform', "translate(0,#{graphHeight})")
+        .call(xAxis)
+    
+    if 'y' in @_axes
+      svg.append('g')
+        .attr('class', 'y axis')
+        .call(yAxis)
+    
+    section = svg.selectAll('.section').data(data)
+    
+    section.enter()
+      .append('g')
+      .attr('class', 'section')
+    
+    section.append('path')
+      .attr('class', 'area')
+      .attr('d', (d)-> area(d.values))
+      .style('fill', (d)-> color(d.name))
+    
+    for data in @_lines
+      point.date = new Date(point.date) for point in data
+      svg.append('path')
+        .attr('class', 'line')
+        .attr('d', line(data))
+        .attr('style', 'stroke: #f00; stroke-width: 2px')
+
+    $legend = $('<dl class="legend"></dl>').appendTo(@_selector)
+    for i in [0...@_labels.length]
+      label = @_labels[i]
+      color = @_colors[i]
+      $legend.append "<dt class=\"circle\" style=\"background: #{color}\"></dt><dd>#{label}</dd>"
+
+    # legend = svg.append("g")
+    #   .attr("class","legend")
+    #   .attr("transform","translate(50,30)")
+    #   .style("font-size","12px")
+    #   .call(d3.legend)