dango_generator 0.0.38

data/templates/as3/com/adobe/net/URIEncodingBitmap.as

@@ -0,0 +1,142 @@
+/*
+	Adobe Systems Incorporated(r) Source Code License Agreement
+	Copyright(c) 2005 Adobe Systems Incorporated. All rights reserved.
+	
+	Please read this Source Code License Agreement carefully before using
+	the source code.
+	
+	Adobe Systems Incorporated grants to you a perpetual, worldwide, non-exclusive, 
+	no-charge, royalty-free, irrevocable copyright license, to reproduce,
+	prepare derivative works of, publicly display, publicly perform, and
+	distribute this source code and such derivative works in source or 
+	object code form without any attribution requirements.  
+	
+	The name "Adobe Systems Incorporated" must not be used to endorse or promote products
+	derived from the source code without prior written permission.
+	
+	You agree to indemnify, hold harmless and defend Adobe Systems Incorporated from and
+	against any loss, damage, claims or lawsuits, including attorney's 
+	fees that arise or result from your use or distribution of the source 
+	code.
+	
+	THIS SOURCE CODE IS PROVIDED "AS IS" AND "WITH ALL FAULTS", WITHOUT 
+	ANY TECHNICAL SUPPORT OR ANY EXPRESSED OR IMPLIED WARRANTIES, INCLUDING,
+	BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+	FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  ALSO, THERE IS NO WARRANTY OF 
+	NON-INFRINGEMENT, TITLE OR QUIET ENJOYMENT.  IN NO EVENT SHALL MACROMEDIA
+	OR ITS SUPPLIERS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+	EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
+	PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+	OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
+	WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
+	OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOURCE CODE, EVEN IF
+	ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.net
+{
+	import flash.utils.ByteArray;
+	
+	/**
+	 * This class implements an efficient lookup table for URI
+	 * character escaping.  This class is only needed if you
+	 * create a derived class of URI to handle custom URI
+	 * syntax.  This class is used internally by URI.
+	 * 
+	 * @langversion ActionScript 3.0
+	 * @playerversion Flash 9.0* 
+	 */
+	public class URIEncodingBitmap extends ByteArray
+	{
+		/**
+		 * Constructor.  Creates an encoding bitmap using the given
+		 * string of characters as the set of characters that need
+		 * to be URI escaped.
+		 * 
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 9.0
+		 */
+		public function URIEncodingBitmap(charsToEscape:String) : void
+		{
+			var i:int;
+			var data:ByteArray = new ByteArray();
+			
+			// Initialize our 128 bits (16 bytes) to zero
+			for (i = 0; i < 16; i++)
+				this.writeByte(0);
+				
+			data.writeUTFBytes(charsToEscape);
+			data.position = 0;
+			
+			while (data.bytesAvailable)
+			{
+				var c:int = data.readByte();
+				
+				if (c > 0x7f)
+					continue;  // only escape low bytes
+					
+				var enc:int;
+				this.position = (c >> 3);
+				enc = this.readByte();
+				enc |= 1 << (c & 0x7);
+				this.position = (c >> 3);
+				this.writeByte(enc);
+			}
+		}
+		
+		/**
+		 * Based on the data table contained in this object, check
+		 * if the given character should be escaped.
+		 * 
+		 * @param char	the character to be escaped.  Only the first
+		 * character in the string is used.  Any other characters
+		 * are ignored.
+		 * 
+		 * @return	the integer value of the raw UTF8 character.  For
+		 * example, if '%' is given, the return value is 37 (0x25).
+		 * If the character given does not need to be escaped, the
+		 * return value is zero.
+		 * 
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 9.0 
+		 */
+		public function ShouldEscape(char:String) : int
+		{
+			var data:ByteArray = new ByteArray();
+			var c:int, mask:int;
+			
+			// write the character into a ByteArray so
+			// we can pull it out as a raw byte value.
+			data.writeUTFBytes(char);
+			data.position = 0;
+			c = data.readByte();
+			
+			if (c & 0x80)
+			{
+				// don't escape high byte characters.  It can make international
+				// URI's unreadable.  We just want to escape characters that would
+				// make URI syntax ambiguous.
+				return 0;
+			}
+			else if ((c < 0x1f) || (c == 0x7f))
+			{
+				// control characters must be escaped.
+				return c;
+			}
+			
+			this.position = (c >> 3);
+			mask = this.readByte();
+			
+			if (mask & (1 << (c & 0x7)))
+			{
+				// we need to escape this, return the numeric value
+				// of the character
+				return c;
+			}
+			else
+			{
+				return 0;
+			}
+		}
+	}
+}

data/templates/as3/com/adobe/net/proxies/RFC2817Socket.as

@@ -0,0 +1,204 @@
+/*
+	Adobe Systems Incorporated(r) Source Code License Agreement
+	Copyright(c) 2005 Adobe Systems Incorporated. All rights reserved.
+	
+	Please read this Source Code License Agreement carefully before using
+	the source code.
+	
+	Adobe Systems Incorporated grants to you a perpetual, worldwide, non-exclusive, 
+	no-charge, royalty-free, irrevocable copyright license, to reproduce,
+	prepare derivative works of, publicly display, publicly perform, and
+	distribute this source code and such derivative works in source or 
+	object code form without any attribution requirements.  
+	
+	The name "Adobe Systems Incorporated" must not be used to endorse or promote products
+	derived from the source code without prior written permission.
+	
+	You agree to indemnify, hold harmless and defend Adobe Systems Incorporated from and
+	against any loss, damage, claims or lawsuits, including attorney's 
+	fees that arise or result from your use or distribution of the source 
+	code.
+	
+	THIS SOURCE CODE IS PROVIDED "AS IS" AND "WITH ALL FAULTS", WITHOUT 
+	ANY TECHNICAL SUPPORT OR ANY EXPRESSED OR IMPLIED WARRANTIES, INCLUDING,
+	BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+	FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  ALSO, THERE IS NO WARRANTY OF 
+	NON-INFRINGEMENT, TITLE OR QUIET ENJOYMENT.  IN NO EVENT SHALL MACROMEDIA
+	OR ITS SUPPLIERS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+	EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, 
+	PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+	OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, 
+	WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR 
+	OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOURCE CODE, EVEN IF
+	ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+package com.adobe.net.proxies
+{
+	import flash.events.Event;
+	import flash.events.IOErrorEvent;
+	import flash.events.ProgressEvent;
+	import flash.net.Socket;
+
+	/**
+	 * This class allows TCP socket connections through HTTP proxies in accordance with
+	 * RFC 2817:
+	 * 
+	 * ftp://ftp.rfc-editor.org/in-notes/rfc2817.txt
+	 * 
+	 * It can also be used to make direct connections to a destination, as well. If you
+	 * pass the host and port into the constructor, no proxy will be used. You can also
+	 * call connect, passing in the host and the port, and if you didn't set the proxy
+	 * info, a direct connection will be made. A proxy is only used after you have called
+	 * the setProxyInfo function.
+	 * 
+	 * The connection to and negotiation with the proxy is completely hidden. All the
+	 * same events are thrown whether you are using a proxy or not, and the data you
+	 * receive from the target server will look exact as it would if you were connected
+	 * to it directly rather than through a proxy.
+	 * 
+	 * @author Christian Cantrell
+	 * 
+	 **/
+	public class RFC2817Socket
+		extends Socket
+	{
+		private var proxyHost:String = null;
+		private var host:String = null;
+		private var proxyPort:int = 0;
+		private var port:int = 0;
+		private var deferredEventHandlers:Object = new Object();
+		private var buffer:String = new String();
+
+		/**
+		 * Construct a new RFC2817Socket object. If you pass in the host and the port,
+		 * no proxy will be used. If you want to use a proxy, instantiate with no
+		 * arguments, call setProxyInfo, then call connect.
+		 **/
+		public function RFC2817Socket(host:String = null, port:int = 0)
+		{
+			if (host != null && port != 0)
+			{
+				super(host, port);
+			}
+		}
+		
+		/**
+		 * Set the proxy host and port number. Your connection will only proxied if
+		 * this function has been called.
+		 **/
+		public function setProxyInfo(host:String, port:int):void
+		{
+			this.proxyHost = host;
+			this.proxyPort = port;
+
+			var deferredSocketDataHandler:Object = this.deferredEventHandlers[ProgressEvent.SOCKET_DATA];
+			var deferredConnectHandler:Object = this.deferredEventHandlers[Event.CONNECT];
+
+			if (deferredSocketDataHandler != null)
+			{
+				super.removeEventListener(ProgressEvent.SOCKET_DATA, deferredSocketDataHandler.listener, deferredSocketDataHandler.useCapture);
+			}
+
+			if (deferredConnectHandler != null)
+			{
+				super.removeEventListener(Event.CONNECT, deferredConnectHandler.listener, deferredConnectHandler.useCapture);
+			}
+		}
+		
+		/**
+		 * Connect to the specified host over the specified port. If you want your
+		 * connection proxied, call the setProxyInfo function first.
+		 **/
+		public override function connect(host:String, port:int):void
+		{
+			if (this.proxyHost == null)
+			{
+				this.redirectConnectEvent();
+				this.redirectSocketDataEvent();
+				super.connect(host, port);
+			}
+			else
+			{
+				this.host = host;
+				this.port = port;
+				super.addEventListener(Event.CONNECT, this.onConnect);
+				super.addEventListener(ProgressEvent.SOCKET_DATA, this.onSocketData);
+				super.connect(this.proxyHost, this.proxyPort);
+			}
+		}
+
+		private function onConnect(event:Event):void
+		{
+			this.writeUTFBytes("CONNECT "+this.host+":"+this.port+" HTTP/1.1\n\n");
+			this.flush();
+			this.redirectConnectEvent();
+		}
+		
+		private function onSocketData(event:ProgressEvent):void
+		{
+			while (this.bytesAvailable != 0)
+			{
+				this.buffer += this.readUTFBytes(1);
+				if (this.buffer.search(/\r?\n\r?\n$/) != -1)
+				{
+					this.checkResponse(event);
+					break;
+				}
+			}
+		}
+		
+		private function checkResponse(event:ProgressEvent):void
+		{
+			var responseCode:String = this.buffer.substr(this.buffer.indexOf(" ")+1, 3);
+
+			if (responseCode.search(/^2/) == -1)
+			{
+				var ioError:IOErrorEvent = new IOErrorEvent(IOErrorEvent.IO_ERROR);
+				ioError.text = "Error connecting to the proxy ["+this.proxyHost+"] on port ["+this.proxyPort+"]: " + this.buffer;
+				this.dispatchEvent(ioError);
+			}
+			else
+			{
+				this.redirectSocketDataEvent();
+				this.dispatchEvent(new Event(Event.CONNECT));
+				if (this.bytesAvailable > 0)
+				{
+					this.dispatchEvent(event);
+				}
+			}
+			this.buffer = null;
+		}
+		
+		private function redirectConnectEvent():void
+		{
+			super.removeEventListener(Event.CONNECT, onConnect);
+			var deferredEventHandler:Object = this.deferredEventHandlers[Event.CONNECT];
+			if (deferredEventHandler != null)
+			{
+				super.addEventListener(Event.CONNECT, deferredEventHandler.listener, deferredEventHandler.useCapture, deferredEventHandler.priority, deferredEventHandler.useWeakReference);			
+			}
+		}
+		
+		private function redirectSocketDataEvent():void
+		{
+			super.removeEventListener(ProgressEvent.SOCKET_DATA, onSocketData);
+			var deferredEventHandler:Object = this.deferredEventHandlers[ProgressEvent.SOCKET_DATA];
+			if (deferredEventHandler != null)
+			{
+				super.addEventListener(ProgressEvent.SOCKET_DATA, deferredEventHandler.listener, deferredEventHandler.useCapture, deferredEventHandler.priority, deferredEventHandler.useWeakReference);			
+			}
+		}
+		
+		public override function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int=0.0, useWeakReference:Boolean=false):void
+		{
+			if (type == Event.CONNECT || type == ProgressEvent.SOCKET_DATA)
+			{
+				this.deferredEventHandlers[type] = {listener:listener,useCapture:useCapture, priority:priority, useWeakReference:useWeakReference};
+			}
+			else
+			{
+				super.addEventListener(type, listener, useCapture, priority, useWeakReference);
+			}
+		}
+	}
+}

data/templates/as3/com/adobe/serialization/json/JSON.as

@@ -0,0 +1,88 @@
+/*
+Adobe Systems Incorporated(r) Source Code License Agreement
+Copyright(c) 2005 Adobe Systems Incorporated. All rights reserved.
+	
+Please read this Source Code License Agreement carefully before using
+the source code.
+	
+Adobe Systems Incorporated grants to you a perpetual, worldwide, non-exclusive,
+no-charge, royalty-free, irrevocable copyright license, to reproduce,
+prepare derivative works of, publicly display, publicly perform, and
+distribute this source code and such derivative works in source or
+object code form without any attribution requirements.
+	
+The name "Adobe Systems Incorporated" must not be used to endorse or promote products
+derived from the source code without prior written permission.
+	
+You agree to indemnify, hold harmless and defend Adobe Systems Incorporated from and
+against any loss, damage, claims or lawsuits, including attorney's
+fees that arise or result from your use or distribution of the source
+code.
+	
+THIS SOURCE CODE IS PROVIDED "AS IS" AND "WITH ALL FAULTS", WITHOUT
+ANY TECHNICAL SUPPORT OR ANY EXPRESSED OR IMPLIED WARRANTIES, INCLUDING,
+BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+FOR A PARTICULAR PURPOSE ARE DISCLAIMED. ALSO, THERE IS NO WARRANTY OF
+NON-INFRINGEMENT, TITLE OR QUIET ENJOYMENT. IN NO EVENT SHALL MACROMEDIA
+OR ITS SUPPLIERS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOURCE CODE, EVEN IF
+ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.serialization.json {
+
+	/**
+	 * This class provides encoding and decoding of the JSON format.
+	 *
+	 * Example usage:
+	 * <code>
+	 * 		// create a JSON string from an internal object
+	 * 		JSON.encode( myObject );
+	 *
+	 *		// read a JSON string into an internal object
+	 *		var myObject:Object = JSON.decode( jsonString );
+	 *	</code>
+	 */
+	public class JSON {
+	
+	
+		/**
+		 * Encodes a object into a JSON string.
+		 *
+		 * @param o The object to create a JSON string for
+		 * @return the JSON string representing o
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 9.0
+		 * @tiptext
+		 */
+		public static function encode( o:Object ):String {
+			
+			var encoder:JSONEncoder = new JSONEncoder( o );
+			return encoder.getString();
+		
+		}
+		
+		/**
+		 * Decodes a JSON string into a native object.
+		 * 
+		 * @param s The JSON string representing the object
+		 * @return A native object as specified by s
+		 * @throw JSONParseError
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 9.0
+		 * @tiptext
+		 */
+		public static function decode( s:String ):* {
+			
+			var decoder:JSONDecoder = new JSONDecoder( s )
+			return decoder.getValue();
+			
+		}
+	
+	}
+
+}

data/templates/as3/com/adobe/serialization/json/JSONDecoder.as

@@ -0,0 +1,218 @@
+/*
+Adobe Systems Incorporated(r) Source Code License Agreement
+Copyright(c) 2005 Adobe Systems Incorporated. All rights reserved.
+	
+Please read this Source Code License Agreement carefully before using
+the source code.
+	
+Adobe Systems Incorporated grants to you a perpetual, worldwide, non-exclusive,
+no-charge, royalty-free, irrevocable copyright license, to reproduce,
+prepare derivative works of, publicly display, publicly perform, and
+distribute this source code and such derivative works in source or
+object code form without any attribution requirements.
+	
+The name "Adobe Systems Incorporated" must not be used to endorse or promote products
+derived from the source code without prior written permission.
+	
+You agree to indemnify, hold harmless and defend Adobe Systems Incorporated from and
+against any loss, damage, claims or lawsuits, including attorney's
+fees that arise or result from your use or distribution of the source
+code.
+	
+THIS SOURCE CODE IS PROVIDED "AS IS" AND "WITH ALL FAULTS", WITHOUT
+ANY TECHNICAL SUPPORT OR ANY EXPRESSED OR IMPLIED WARRANTIES, INCLUDING,
+BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+FOR A PARTICULAR PURPOSE ARE DISCLAIMED. ALSO, THERE IS NO WARRANTY OF
+NON-INFRINGEMENT, TITLE OR QUIET ENJOYMENT. IN NO EVENT SHALL MACROMEDIA
+OR ITS SUPPLIERS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOURCE CODE, EVEN IF
+ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+*/
+
+package com.adobe.serialization.json {
+
+	public class JSONDecoder {
+		
+		/** The value that will get parsed from the JSON string */
+		private var value:*;
+		
+		/** The tokenizer designated to read the JSON string */
+		private var tokenizer:JSONTokenizer;
+		
+		/** The current token from the tokenizer */
+		private var token:JSONToken;
+		
+		/**
+		 * Constructs a new JSONDecoder to parse a JSON string 
+		 * into a native object.
+		 *
+		 * @param s The JSON string to be converted
+		 *		into a native object
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 9.0
+		 * @tiptext
+		 */
+		public function JSONDecoder( s:String ) {
+			
+			tokenizer = new JSONTokenizer( s );
+			
+			nextToken();
+			value = parseValue();
+		}
+		
+		/**
+		 * Gets the internal object that was created by parsing
+		 * the JSON string passed to the constructor.
+		 *
+		 * @return The internal object representation of the JSON
+		 * 		string that was passed to the constructor
+		 * @langversion ActionScript 3.0
+		 * @playerversion Flash 9.0
+		 * @tiptext
+		 */
+		public function getValue():* {
+			return value;
+		}
+		
+		/**
+		 * Returns the next token from the tokenzier reading
+		 * the JSON string
+		 */
+		private function nextToken():JSONToken {
+			return token = tokenizer.getNextToken();
+		}
+		
+		/**
+		 * Attempt to parse an array
+		 */
+		private function parseArray():Array {
+			// create an array internally that we're going to attempt
+			// to parse from the tokenizer
+			var a:Array = new Array();
+			
+			// grab the next token from the tokenizer to move
+			// past the opening [
+			nextToken();
+			
+			// check to see if we have an empty array
+			if ( token.type == JSONTokenType.RIGHT_BRACKET ) {
+				// we're done reading the array, so return it
+				return a;
+			}
+			
+			// deal with elements of the array, and use an "infinite"
+			// loop because we could have any amount of elements
+			while ( true ) {
+				// read in the value and add it to the array
+				a.push ( parseValue() );
+			
+				// after the value there should be a ] or a ,
+				nextToken();
+				
+				if ( token.type == JSONTokenType.RIGHT_BRACKET ) {
+					// we're done reading the array, so return it
+					return a;
+				} else if ( token.type == JSONTokenType.COMMA ) {
+					// move past the comma and read another value
+					nextToken();
+				} else {
+					tokenizer.parseError( "Expecting ] or , but found " + token.value );
+				}
+			}
+            return null;
+		}
+		
+		/**
+		 * Attempt to parse an object
+		 */
+		private function parseObject():Object {
+			// create the object internally that we're going to
+			// attempt to parse from the tokenizer
+			var o:Object = new Object();
+						
+			// store the string part of an object member so
+			// that we can assign it a value in the object
+			var key:String
+			
+			// grab the next token from the tokenizer
+			nextToken();
+			
+			// check to see if we have an empty object
+			if ( token.type == JSONTokenType.RIGHT_BRACE ) {
+				// we're done reading the object, so return it
+				return o;
+			}
+			
+			// deal with members of the object, and use an "infinite"
+			// loop because we could have any amount of members
+			while ( true ) {
+			
+				if ( token.type == JSONTokenType.STRING ) {
+					// the string value we read is the key for the object
+					key = String( token.value );
+					
+					// move past the string to see what's next
+					nextToken();
+					
+					// after the string there should be a :
+					if ( token.type == JSONTokenType.COLON ) {
+						
+						// move past the : and read/assign a value for the key
+						nextToken();
+						o[key] = parseValue();	
+						
+						// move past the value to see what's next
+						nextToken();
+						
+						// after the value there's either a } or a ,
+						if ( token.type == JSONTokenType.RIGHT_BRACE ) {
+							// // we're done reading the object, so return it
+							return o;
+							
+						} else if ( token.type == JSONTokenType.COMMA ) {
+							// skip past the comma and read another member
+							nextToken();
+						} else {
+							tokenizer.parseError( "Expecting } or , but found " + token.value );
+						}
+					} else {
+						tokenizer.parseError( "Expecting : but found " + token.value );
+					}
+				} else {
+					tokenizer.parseError( "Expecting string but found " + token.value );
+				}
+			}
+            return null;
+		}
+		
+		/**
+		 * Attempt to parse a value
+		 */
+		private function parseValue():Object {
+					
+			switch ( token.type ) {
+				case JSONTokenType.LEFT_BRACE:
+					return parseObject();
+					
+				case JSONTokenType.LEFT_BRACKET:
+					return parseArray();
+					
+				case JSONTokenType.STRING:
+				case JSONTokenType.NUMBER:
+				case JSONTokenType.TRUE:
+				case JSONTokenType.FALSE:
+				case JSONTokenType.NULL:
+					return token.value;
+
+				default:
+					tokenizer.parseError( "Unexpected " + token.value );
+					
+			}
+            return null;
+		}
+	}
+}