cumulusci-plus 5.0.0__py3-none-any.whl

cumulusci/robotframework/tests/salesforce/performance.robot

@@ -0,0 +1,109 @@
+*** Settings ***
+
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         cumulusci.robotframework.Performance
+Test Teardown   Delete Session Records
+Force Tags      api  no-browser
+
+*** Test Cases ***
+
+Test Elapsed Time For Last Record
+    # This test uses contacts as if they were "jobs" because they are
+    # easy to insert. I don't currently have a better alternative
+    # for a job-like objects which is easy to create in a vanilla
+    # SF org. The underlying keyword only cares that it has two
+    # datetime fields.
+
+    ${contact_id} =  Salesforce Insert  Contact
+    ...         FirstName=Dummy1
+    ...         LastName=Dummy2
+    ...         EmailBouncedDate=2030-01-01T00:00:00
+
+    ${Elapsed}=     Elapsed Time For Last Record
+    ...             obj_name=Contact
+    ...             where=Id='${contact_id}'
+    ...             start_field=CreatedDate
+    ...             end_field=EmailBouncedDate
+    ...             order_by=EmailBouncedDate
+    Should Be True      ${Elapsed} >= 100_000
+
+    # This is an "earlier" record than the other
+    ${contact2_id} =  Salesforce Insert  Contact
+    ...         FirstName=Dummy1
+    ...         LastName=Dummy2
+    ...         EmailBouncedDate=2029-01-01T00:00:00
+
+    ${Elapsed_latest}=     Elapsed Time For Last Record
+    ...             obj_name=Contact
+    ...             start_field=CreatedDate
+    ...             end_field=EmailBouncedDate
+    ...             order_by=EmailBouncedDate
+
+    # The "latest" record should be the original
+    Should Be Equal         ${Elapsed}    ${Elapsed_latest}
+    Set Test Elapsed Time        ${Elapsed}
+
+
+Test Elapsed Time For Last Record - Failure No Record
+    Run Keyword and expect Error   *Matching record not found*
+    ...     Elapsed Time For Last Record
+    ...             obj_name=AsyncApexJob
+    ...             where=ApexClass.Name='BlahBlah'
+    ...             start_field=CreatedDate
+    ...             end_field=CompletedDate
+    ...             order_by=CompletedDate
+
+Test Elapsed Time For Last Record - Failure Bad Fields
+    ${contact_id} =  Salesforce Insert  Contact
+    ...         LastName=Dummy2
+    ...         EmailBouncedDate=2030-01-01T00:00:00
+    Run Keyword and Expect Error   *Date parse error*
+    ...     Elapsed Time For Last Record
+    ...             obj_name=Contact
+    ...             start_field=EmailBouncedDate
+    ...             end_field=LastName
+    ...             order_by=LastName
+
+    Run Keyword and Expect Error   *Date parse error*
+    ...     Elapsed Time For Last Record
+    ...             obj_name=Contact
+    ...             start_field=EmailBouncedDate
+    ...             end_field=FirstName     # None/NULL
+    ...             order_by=FirstName      # None/NULL
+
+Test Perf Set Elapsed Time
+    [Tags]  perf
+    Set Test Elapsed Time       11655.9   #  3:14:15.9
+
+Test Perf Set Elapsed Time Twice
+    [Tags]  perf
+    Set Test Elapsed Time       11655.9
+    Set Test Elapsed Time       53
+
+Test Perf Set Elapsed Time String
+    [Tags]  perf
+    Log                 A
+    Set Test Elapsed Time       5 hours   #  5:00:00
+
+Test Perf Measure Elapsed
+    [Setup]       Log             Before
+    [Teardown]    Log             After
+    Log                 B
+    Start Performance Timer
+    Sleep       1
+    Log         Noop
+    Stop Performance Timer
+
+Set Time and Also Metric
+    Start Performance Timer
+    Log         Noop
+    Stop Performance Timer
+    Set Test Metric   number of records  100
+
+Test Perf Measure Other Metric
+    Set Test Metric    Max_CPU_Percent    30
+
+Mismatched Stop Performance Timer
+    Run Keyword and Expect Error
+    ...         *Elapsed time clock was not*
+    ...         Stop Performance Timer

cumulusci/robotframework/tests/salesforce/playwright/javascript_keywords.robot

@@ -0,0 +1,33 @@
+*** Settings ***
+Resource  cumulusci/robotframework/SalesforcePlaywright.robot
+Library   Collections
+
+Suite Setup     Open test browser
+Suite Teardown  Close browser  ALL
+
+Force Tags      playwright
+
+*** Test Cases ***
+Validate cci context in javascript keyword
+    [Documentation]
+    ...  Verify that keywords written in javascript have access
+    ...  to some context information provided by the cumulusci
+    ...  node module
+
+    ${cci}=  Get library instance  cumulusci.robotframework.CumulusCI
+    ${expected org info}=  Create dictionary
+    ...  name          ${cci.org.name}
+    ...  instance_url  ${cci.org.instance_url}
+    ...  org_id        ${cci.org.org_id}
+
+    ${expected project_config info}=  Create dictionary
+    ...  repo_name     ${cci.project_config.repo_name}
+    ...  repo_root     ${cci.project_config.repo_root}
+
+    ${expected context}=  Create dictionary
+    ...  org             ${expected org info}
+    ...  project_config  ${expected project_config info}
+
+    ${context}=  get cci context
+
+    Dictionaries should be equal  ${context}  ${expected context}

cumulusci/robotframework/tests/salesforce/playwright/open_test_browser.robot

@@ -0,0 +1,48 @@
+*** Settings ***
+Documentation
+...  Tests for auto-detecting classic mode in a scratch org
+
+Resource  cumulusci/robotframework/SalesforcePlaywright.robot
+Library   cumulusci/robotframework/tests/salesforce/TestListener.py
+Library   Dialogs
+
+Suite Setup  Run keywords
+...  Get URLs for switching
+...  AND  Open test browser  wait=False
+...  AND  switch to classic
+...  AND  close browser  ALL
+
+Suite Teardown  Close Browser  ALL
+
+*** Keywords ***
+Switch to classic
+    Go to  ${switcher classic url}
+    Wait for elements state  a.switch-to-lightning  visible
+
+Switch to lightning
+    Go to  ${switcher lex url}
+    Wait until loading is complete
+
+Get urls for switching
+    ${org info}=  Get org info
+    set suite variable  ${switcher lex url}
+    ...  ${org info['instance_url']}/ltng/switcher?destination=lex
+    set suite variable  ${switcher classic url}
+    ...  ${org info['instance_url']}/ltng/switcher?destination=classic
+
+*** Test Cases ***
+Auto-switch to lightning
+    [Documentation]  Verify that if we land on a classic page that we auto-switch to lightning
+
+    [Setup]  Run keywords
+    ...  Close browser  ALL
+    ...  AND  Reset test listener message log
+
+    Open Test Browser  wait=True
+    take screenshot
+
+    # verify that we detected a classic page
+    Assert robot log  It appears we are on a classic page   WARN
+
+    # verify we landed on a lightning page
+    ${url}=  Get URL  $=  /lightning/setup/SetupOneHome/home

cumulusci/robotframework/tests/salesforce/playwright/playwright.robot

@@ -0,0 +1,24 @@
+*** Settings ***
+Resource         cumulusci/robotframework/SalesforcePlaywright.robot
+
+Suite Setup      Open test browser
+Suite Teardown   Delete records and close browser
+
+Force Tags       playwright
+
+*** Test Cases ***
+
+Go to user profile
+    Click    button:has-text("View profile")
+    Click    .profile-card-name .profile-link-label
+
+    Wait until loading is complete
+    Take screenshot
+
+Go to contacts home
+    Click            button:has-text("App Launcher")
+    Type text        input[placeholder='Search apps and items...']  Contacts
+    Click            one-app-launcher-menu-item:has-text("Contacts")
+
+    Wait until loading is complete
+    Take screenshot

cumulusci/robotframework/tests/salesforce/playwright/ui.robot

@@ -0,0 +1,32 @@
+** Settings ***
+Resource        cumulusci/robotframework/SalesforcePlaywright.robot
+Library         cumulusci/robotframework/tests/salesforce/TestListener.py
+
+Suite Setup     Open Test Browser
+Suite Teardown  Delete Records and Close Browser
+
+Force Tags      playwright
+
+*** Keywords ***
+Create Test Contact
+    [Arguments]      &{fields}
+    ${first_name} =  Get fake data  first_name
+    ${last_name} =   Get fake data  last_name
+    ${contact_id} =  Salesforce Insert  Contact
+    ...                FirstName=${first_name}
+    ...                LastName=${last_name}
+    ...                &{fields}
+    &{contact} =     Salesforce Get  Contact  ${contact_id}
+    [return]  &{contact}
+
+*** Test Cases ***
+Get Current Record Id
+    [Documentation]    Verify that `Get Current Record Id` returns the correct id
+
+    &{contact} =       Create Test Contact
+    Go To Record Home  ${contact}[Id]
+    # this fetches the ID from the URL; we expect that the keyword
+    # will return the ID of the record we just created and navigated
+    #  to
+    ${contact_id} =    Get Current Record Id
+    Should Be Equal    ${contact}[Id]  ${contact_id}

cumulusci/robotframework/tests/salesforce/populate.robot

@@ -0,0 +1,89 @@
+*** Settings ***
+Documentation
+...  This suite tests the `Populate Field` keyword.
+...  Specifically, it verifies that the keyword properly
+...  overwrites previous values. We had some bugs where
+...  new values were getting appended rather than replacing
+...  existing values.
+...
+...  This suite uses an opportunity, since the edit dialog
+...  has several different field types on it.
+
+Library   String
+Library   DateTime
+Resource  cumulusci/robotframework/Salesforce.robot
+
+Suite Setup     run keywords
+...  Open test browser
+...  Create opportunity
+Suite Teardown  Delete Records and Close Browser
+
+*** Keywords ***
+Create opportunity
+    [Documentation]
+    ...  Creates a test opportunity with a random name and a close
+    ...  date 30 days in the future. A reference to the created
+    ...  opportunity will be stored in the suite variable ${opportunity},
+    ...  and be return as the result of this keyword.
+
+    ${30 days from now}=  Get Current Date  increment=30 days  result_format=%Y-%m-%d
+    ${random}=  Generate random string  8  [NUMBERS]
+    ${opportunity_id}=    Salesforce Insert  Opportunity
+    ...                   Name=Test Opportunity ${random}
+    ...                   CloseDate=${30 days from now}
+    ...                   Amount=100000
+    ...                   Probability=42
+    ...                   StageName=Prospecting
+    ...                   Description=Clever description here
+    &{opportunity}=       Salesforce Get  Opportunity  ${opportunity_id}
+    set suite variable    ${opportunity}
+    [Return]  ${opportunity}
+
+Verify "populate field" replaces previous value
+    [Arguments]  ${field name}  ${new value}
+    [Documentation]
+    ...  Verify that a field has the expected value after calling 'populate field'
+    ...  This keyword will NOT cause the test to fail immediately, so that we can
+    ...  check multiple fields before the test completes
+
+    populate field      ${field name}    ${new value}
+    ${actual value}=    get field value  ${field name}
+
+    run keyword and continue on failure
+    ...  should be equal as strings  ${new value}  ${actual value}
+    ...  Expected modal field ${field name} to be '${new value}' but it was '${actual value}'
+
+*** Test cases ***
+Test Populate ability to clear a field
+    [Documentation]
+    ...  We've had problems with the populate keyword not always
+    ...  clearing the field before inserting text. This will try
+    ...  to set various fields to a new value and verify that the
+    ...  new value overwrites the old rather than append to it
+
+    [Setup]  run keywords
+    ...  go to object home     Opportunity
+    ...  AND  click link            ${opportunity['Name']}
+    ...  AND  click object button   Edit
+    ...  AND  wait until modal is open
+
+    ${60 days from now}=  Get Current Date  increment=60 days  result_format=%Y-%m-%d
+
+    ## currency / number
+    Verify "populate field" replaces previous value  Amount            90000
+
+    ## string
+    Verify "populate field" replaces previous value  Next Step         whatever
+
+    ## percentage / number
+    Verify "populate field" replaces previous value  Probability (%)   99
+
+    ## multi-line text field
+    Verify "populate field" replaces previous value  Description       yada yada yada
+
+    ## date field
+    # N.B. Close date is last because it pops up a date dialog. If there
+    # are more fields after, we have to wait for the dialog to be dismissed.
+    # This test is just easier if we modify the date last so we don't have to
+    # deal with that.
+    Verify "populate field" replaces previous value  Close Date        ${60 days from now}

cumulusci/robotframework/tests/salesforce/test_testlistener.py

@@ -0,0 +1,37 @@
+import pytest
+from TestListener import TestListener
+
+
+class TestTestListener:
+    @classmethod
+    def setup_class(cls):
+        cls.listener = TestListener()
+
+    def test_reset_test_listener_keyword_log(self):
+        """Verify the internal cache is reset by the reset keyword"""
+
+        # simulate what robot does when a keyword finishes executing
+        self.listener._end_keyword("log", {"status": "PASS", "args": tuple()})
+
+        self.listener.reset_test_listener_keyword_log()
+        assert len(self.listener.keyword_log) == 0
+
+    def test_reset_test_listener_message_log(self):
+        self.listener.message_log.append("Danger Will Robinson!")
+        self.listener.reset_test_listener_message_log()
+        assert len(self.listener.message_log) == 0
+
+    def test_assert_keyword_failure(self):
+        self.listener.reset_test_listener_keyword_log()
+        with pytest.raises(
+            Exception,
+            match=r"No keyword with name 'bogus' with args '\('arg1', 'arg2'\)' was found",
+        ):
+            self.listener.assert_keyword_status("PASS", "bogus", "arg1", "arg2")
+
+    def test_assert_keyword_pass(self):
+        # simulate what robot does when a keyword finishes executing
+        self.listener._end_keyword("log", {"status": "PASS", "args": tuple()})
+
+        # should not raise an exception
+        self.listener.assert_keyword_status("PASS", "log")