cumulusci-plus 5.0.0__py3-none-any.whl

cumulusci/robotframework/tests/salesforce/classic.robot

@@ -0,0 +1,51 @@
+*** Settings ***
+Documentation
+...  Tests for auto-detecting classic mode in a scratch org
+
+Resource  cumulusci/robotframework/Salesforce.robot
+Library   cumulusci/robotframework/tests/salesforce/TestListener.py
+
+Suite Setup  Run keywords
+...  Get URLs for switching
+...  AND  Open test browser  wait=False
+...  AND  Switch to classic
+
+Suite Teardown  Run keywords
+...  Switch to lightning
+...  AND  Close all browsers
+
+*** Keywords ***
+Get current user experience
+    log  not implemented yet
+
+Switch to classic
+    Go to  ${switcher classic url}
+    Wait for aura
+
+Switch to lightning
+    ${org info}=  Get org info
+    Go to  ${switcher lex url}
+    Wait for aura
+
+Get urls for switching
+    ${org info}=  Get org info
+    set suite variable  ${switcher lex url}
+    ...  ${org info['instance_url']}/ltng/switcher?destination=lex
+    set suite variable  ${switcher classic url}
+    ...  ${org info['instance_url']}/ltng/switcher?destination=classic
+
+*** Test Cases ***
+Auto-switch to lightning
+    [Setup]  Run keywords
+    ...  Close all browsers
+    ...  Reset test listener keyword log
+    ...  Reset test listener message log
+
+    Open Test Browser
+    Assert keyword status
+    ...  PASS
+    ...  cumulusci.robotframework.Salesforce.Wait Until Salesforce Is Ready
+    ...  timeout=180
+
+    Assert robot log  It appears we are on a classic page   WARN
+    capture page screenshot

cumulusci/robotframework/tests/salesforce/create_contact.robot

@@ -0,0 +1,59 @@
+*** Settings ***
+
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         cumulusci.robotframework.PageObjects
+
+Suite Setup     Open Test Browser
+Suite Teardown  Delete Records and Close Browser
+
+
+*** Test Cases ***
+
+Via API
+    ${first_name} =       Get fake data  first_name
+    ${last_name} =        Get fake data  last_name
+
+    ${contact_id} =       Salesforce Insert  Contact
+    ...                     FirstName=${first_name}
+    ...                     LastName=${last_name}
+
+    &{contact} =          Salesforce Get  Contact  ${contact_id}
+    Validate Contact      ${contact_id}  ${first_name}  ${last_name}
+
+Via UI
+    ${first_name} =       Get fake data  first_name
+    ${last_name} =        Get fake data  last_name
+
+    Go to page            Home  Contact
+    Click Object Button   New
+    Wait for modal        New  Contact
+
+    Populate Form
+    ...                   First Name=${first_name}
+    ...                   Last Name=${last_name}
+    Click Modal Button    Save
+
+    Wait Until Modal Is Closed
+
+    ${contact_id} =       Get Current Record Id
+    Store Session Record  Contact  ${contact_id}
+    Validate Contact      ${contact_id}  ${first_name}  ${last_name}
+
+
+*** Keywords ***
+
+Validate Contact
+    [Arguments]          ${contact_id}  ${first_name}  ${last_name}
+    [Documentation]
+    ...  Given a contact id, validate that the contact has the
+    ...  expected first and last name both through the detail page in
+    ...  the UI and via the API.
+
+    # Validate via UI
+    Go to page             Detail   Contact  ${contact_id}
+    Page Should Contain    ${first_name} ${last_name}
+
+    # Validate via API
+    &{contact} =     Salesforce Get  Contact  ${contact_id}
+    Should Be Equal  ${first_name}  ${contact}[FirstName]
+    Should Be Equal  ${last_name}  ${contact}[LastName]

cumulusci/robotframework/tests/salesforce/faker.robot

@@ -0,0 +1,68 @@
+*** Settings ***
+Resource  cumulusci/robotframework/Salesforce.robot
+Force Tags  no-browser
+
+*** Variables ***
+${ssn}    ${faker.ssn()}
+
+*** Test Cases ***
+Faker variable should exist
+    Variable should exist  \${faker}
+
+Faker extended variable syntax in variables table
+    Variable should exist  \${ssn}
+    Should match regexp    ${ssn}  \\d\\d\\d-\\d\\d-\\d\\d\\d\\d
+
+Faker keyword, no arguments
+    # Note, ssn is used because it's easily to validate that
+    # we got back data in the expected format. Hard to do with
+    # names and addresses since the whole point is to provide
+    # random fake data
+
+    [Setup]  Variable should not exist   \${data}
+    ${data}=  Get fake data  ssn
+    Should match regexp    ${data}  \\d\\d\\d-\\d\\d-\\d\\d\\d\\d
+
+Faker keyword, with arguments
+    [Setup]  Variable should not exist   \${data}
+
+    ${data}=  Get fake data  date  pattern=%Y,%m
+    Should match regexp  ${data}  \\d\\d\\d\\d,\\d\\d
+
+Faker variable, no arguments
+    [Setup]  Variable should not exist   \${data}
+
+    ${data}=  Set variable  ${faker.ssn()}
+    Should match regexp    ${ssn}  \\d\\d\\d-\\d\\d-\\d\\d\\d\\d
+
+Faker variable, with arguments
+    [Setup]  Variable should not exist   \${data}
+
+    ${data}=  Set variable  ${faker.date(pattern='%Y,%m')}
+    Should match regexp  ${data}  \\d\\d\\d\\d,\\d\\d
+
+Set faker locale
+    [Setup]  Variable should not exist   \${data}
+    [Teardown]  Set faker locale  en_US
+
+    Set faker locale  fr_FR
+    ${data}=  Get fake data  vat_id
+    Should match regexp  ${data}  ^FR.*
+
+    Set faker locale  it_IT
+    ${data}=  Get fake data  vat_id
+    Should match regexp  ${data}  ^IT.*
+
+Set faker locale exception
+    [Setup]  Variable should not exist   \${data}
+    [Teardown]  Set faker locale  en_US
+
+    Run keyword and expect error
+    ...  Unknown locale for fake data: 'bogus'
+    ...  Set faker locale  bogus
+
+Faker keyword, bad property
+    [Setup]  Variable should not exist   \${data}
+    Run keyword and expect error
+    ...  Unknown fake data request: 'bogus'
+    ...  Get fake data  bogus

cumulusci/robotframework/tests/salesforce/forms.robot

@@ -0,0 +1,172 @@
+*** Settings ***
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         cumulusci.robotframework.PageObjects
+Library         Dialogs
+
+Suite Setup     Run keywords
+...  Initialize Test Objects
+...  Open test browser
+Suite Teardown  Delete records and close browser
+Force tags      forms
+
+*** Variables ***
+${account name}   ACME Labs
+${campaign name}  The Big SPAM
+${DATA DIR}  ${{pathlib.Path($SUITE_SOURCE).parent}}
+
+*** Keywords ***
+Initialize test objects
+    [Documentation]  Create related objects used by this test
+
+    Require salesforce object  Account   name=${account name}
+    Require salesforce object  Campaign  name=${campaign name}
+
+Require Salesforce object
+    # We might want to make this available to everyone.
+    [Documentation]
+    ...  Create a salesforce object if it doesn't exist
+    ...
+    ...  Example:
+    ...
+    ...  | Require salesforce object  Account  name=ACME Labs  description=Created for test case
+
+    [Arguments]  ${object_type}  &{args}
+
+    ${result}=  salesforce query  ${object_type}  &{args}
+    # if we don't already have such an object, create one
+    Run keyword if  not $result
+    ...  Salesforce insert  ${object type}  &{args}
+    Run keyword if  not $result
+    ...  log  created object  DEBUG
+
+Go to My Email settings
+    [Documentation]
+    ...  Go directly to the My Email Settings page
+
+    &{org}=  Get org info
+    ${url}=  Set variable
+    ...  ${org['instance_url']}/lightning/settings/personal/EmailSettings/home
+    Go to  ${url}
+
+*** Test Cases ***
+Lightning based form
+    [Documentation]
+    ...  Sets all of the input fields for an opportunity, to make sure
+    ...  we at least support enough input field types to create an opportunity
+
+    [Setup]  Run keywords
+    ...  Go to page                  Home    Opportunity
+    ...  AND  Click Object Button    New
+    ...  AND  Wait for modal         New     Opportunity
+    [Teardown]   Click modal button  Cancel
+
+    Input form data
+    ...  Opportunity Name  The big one                             # required text field
+    ...  Account Name      ${Account Name}                         # lookup
+    ...  Amount            1b                                      # currency field
+    ...  Next Step         whatever                                # text field
+    ...  Close Date        4/01/2022                               # date field
+    ...  Private           checked                                 # checkbox
+    ...  Type              New Customer                            # combobox
+    ...  Stage             Prospecting                             # combobox
+    ...  Probability (%)   90                                      # percentage
+    ...  Description       this is a long description\nblah blah   # textarea
+    ...  Primary Campaign Source  ${Campaign Name}                 # lookup
+    ...  Lead Source       Purchased List                          # combobox
+
+    capture page screenshot
+
+Non-lightning based form - checkbox
+    [Documentation]
+    ...  Verify that we can check and uncheck standard html checkboxes
+    ...  e.g.: <input type="checkbox">
+
+    [Setup]  Run keywords
+    ...  Go to page                  Home    Campaign
+    ...  AND  Click Object Button    New
+    ...  AND  Wait for modal         New     Campaign
+    [Teardown]  Click modal button   Cancel
+
+    # first, let's make sure that the keyword returns an element
+    # that is a plain html input element
+    ${element}=      Get webelement       label:Active
+    Should be equal  ${element.tag_name}  input
+    ...  Expected to find an <input> element but did not.
+
+    # next, set the checkbox and assert it is checked
+    Input form data
+    ...  Active    checked
+    Checkbox should be selected      label:Active
+
+    # finally, unset it and assert it is unchecked
+    Input form data
+    ...  Active    unchecked
+    Checkbox should not be selected      label:Active
+
+Lightning based form - radiobutton
+    [Documentation]
+    ...  Verify we can set a lightning radiobutton by its label
+    [Setup]      Run keywords
+    ...  Go to page          Listing    Opportunity
+    ...  AND  Click element  sf:list_view_menu.button
+    ...  AND  Click element  sf:list_view_menu.item:New
+    ...  AND  Wait for modal  New  List View
+    [Teardown]   Click modal button  Cancel
+
+    Input form data
+    ...  Who sees this list view?::All users can see this list view    selected
+
+    # Using the label: locator returns a lightning-input element. We need to find
+    # the actual html input element to verify that it is checked. Ugly, but efficient.
+    ${element}=  Get webelement  label:All users can see this list view
+    Should be true  ${element.find_element_by_xpath(".//input").is_selected()}
+
+Non-lightning based form - radiobutton
+    [Documentation]  Verify we can set a plain non-lightning radiobutton
+
+    [Setup]     Run keywords
+    ...  Go to My Email Settings
+    ...  AND  Select frame                   //div[@class="setupcontent"]//iframe
+    ...  AND  Select radio button            use_external_email  1
+    ...  AND  Radio button should be set to  use_external_email  1
+    [Teardown]  Unselect frame
+
+    # The settings page is just about the only page I could find
+    # with old school non-lightning radiobuttons
+    # Thankfully, I can use built-in keywords to validate that
+    # the radiobuttons have actually bet set.
+
+    # then try to use our keyword to set it
+    Input form data
+    ...  Send through Salesforce  selected
+
+    # ... and then verify that it was set
+    Radio button should be set to  use_external_email  0
+
+Non-lightning based form - input and textarea
+    [Documentation]
+    ...  Fill in non-lightning input and textarea fields
+
+    [Setup]  Go to  file://${DATA DIR}/labels.html
+
+    Input form data
+    ...  Description  This is the description
+    ...  City         Oklahoma City
+
+    Textarea should contain   id=textarea-1  This is the description
+    Textfield should contain  id=input-3     Oklahoma City
+
+Fieldsets
+    [Documentation]
+    ...  Verify we can use fieldsets to disambiguate fields
+
+    [Setup]  Run keywords
+    ...  Go to page                  Home    Shipment
+    ...  AND  Click Object Button    New
+    ...  AND  Wait for modal         New     Shipment
+    [Teardown]   Click modal button  Cancel
+
+    Input form data
+    ...  Expected Delivery Date::Date  04/01/2021
+    # hmmm. This one isn't working. Too late in the evening to fixe it :-\
+    # ...  Actual Delivery Date::Date    04/02/2021

cumulusci/robotframework/tests/salesforce/label_locator.robot

@@ -0,0 +1,244 @@
+*** Settings ***
+Documentation
+...  Tests for the custom locator strategy "label:"
+...  These tests were created to catch the various ways form fields
+...  and labels are marked up on Salesforce pages.
+
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         OperatingSystem
+
+Suite Setup     Open test browser
+Suite Teardown  Delete records and close browser
+Test Teardown   Log failure conditions
+
+*** Variables ***
+
+${DATA DIR}  ${{pathlib.Path($SUITE_SOURCE).parent}}
+${TEST URL}  file://${DATA DIR}/labels.html
+
+
+*** Keywords ***
+
+Log failure conditions
+    [Documentation]
+    ...  Do some extra reporting when a test fails
+
+    Run keyword if test failed
+    ...  Run keywords
+    ...  Log Location
+    ...  Log Source
+    ...  Capture page screenshot
+
+Returned element should have id
+    [Documentation]
+    ...  This is the main assertion in a test case. It gets a webelement
+    ...  using the label: locator and asserts that the correct element is
+    ...  returned.
+    [Arguments]  ${expected id}  ${locator}
+    ${actual id}=  SeleniumLibrary.Get element attribute  ${locator}  id
+
+    Should be equal  ${actual id}  ${expected id}
+    ...  Expected the element id to be '${expected id}' but it was '${actual id}'
+    ...  values=False
+
+With HTML:
+    [Documentation]
+    ...  Inject html into our test document
+    ...  Input is one or more string arguments that will be joined
+    ...  and then inserted into the current document in a div
+    ...  with the id 'input-data'
+    [Arguments]  @{lines}
+
+    ${html}=  Catenate  SEPARATOR=${\n}  @{lines}
+    execute javascript
+    ...  ARGUMENTS
+    ...  ${HTML}
+    ...  JAVASCRIPT
+    ...  var element=document.querySelector('#test-data');
+    ...  element.innerHTML = arguments[0];
+
+
+*** Test Cases ***
+
+Label pointing to input
+    [Documentation]
+    ...  Verify we can find input elements
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='input-1'>Zipcode</label>
+    ...  <input id='input-1'>
+
+    Returned element should have id  input-1  label:Zipcode
+
+Label pointing to textarea
+    [Documentation]
+    ...  Verify we can find textarea elements
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='textarea-1'>Zipcode</label>
+    ...  <textarea id='textarea-1'>
+
+    Returned element should have id  textarea-1  label:Zipcode
+
+Label inside a lightning component
+    [Documentation]
+    ...  Verify we can find a lightning component
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <lightning-combobox id='combobox-1'>
+    ...      <label for='input-1'>Zipcode</label>
+    ...      <input id='input-1'>
+    ...  </lightning-combobox>
+
+    Returned element should have id  combobox-1  label:Zipcode
+
+Nested Lightning Components
+    [Documentation]
+    ...  Verify that the inner-most component is returned
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <lightning-picklist id='picklist-1'>
+    ...      <lightning-combobox id='combobox-1'>
+    ...          <label>Salutation</label>
+    ...      </lightning-combobox>
+    ...  <lightning-picklist>
+
+    Returned element should have id  combobox-1  label:Salutation
+
+Label with a single quote
+    [Documentation]
+    ...  Verify that labels with apostrophes don't trip us up
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='input-1'>foo'bar</label>
+    ...  <input id='input-1'>
+
+    Returned element should have id  input-1  label:foo'bar
+
+Simple label spread across multiple lines
+    [Documentation]
+    ...  Verify that label text spread across multiple lines is recognized
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='input-1'>
+    ...      Hello,
+    ...      world
+    ...  </label>
+    ...  <input id='input-1'>
+
+    Returned element should have id  input-1  label:Hello, world
+
+Label with leading and trailing whitespace
+    [Documentation]
+    ...  Verify that we aren't tripped up by leading or trailing spaces
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='input-1'> email </label>
+    ...  <input id='input-1'>
+
+    Returned element should have id  input-1  label:email
+
+Label with inner span BEFORE the label text, simulating a required field
+    [Documentation]
+    ...  Verify we can find a label when there's additional elements
+    ...  before the label text
+    ...
+    ...  Note: the assistiveText span is how some required fields are marked up
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='input-1'>
+    ...      <span class="assistiveText"> * </span>
+    ...      Company Name
+    ...  </label>
+    ...  <input id='input-1'>
+
+    Returned element should have id  input-1  label:Company Name
+
+Label with inner span AFTER the label text, simulating a required field
+    [Documentation]
+    ...  Verify we can find a label when there's additional elements
+    ...  after the label text
+    ...
+    ...  Note: the assistiveText span is how some required fields are marked up
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='input-1'>
+    ...      Street Address
+    ...      <span class="assistiveText"> * </span>
+    ...  </label>
+    ...  <input id='input-1'>
+
+    Returned element should have id  input-1  label:Street Address
+
+Label that doesn't exist yields an appropriate error
+    [Documentation]
+    ...  Verify we get an appropriate exception when we can't find the label
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='input-1'>
+    ...      Whatever
+    ...  </label>
+    ...  <input id='input-1'>
+
+    Run keyword and expect error
+    ...  Element with locator 'label:Bogus' not found.
+    ...  Get Webelement  label:Bogus
+
+Label where text is in a span
+    [Documentation]
+    ...  Verify that we can find a label when the text is in a span
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <label for='input-1'
+    ...      <span>Ship To Street</span>
+    ...  </label>
+    ...  <input id='input-1'>
+
+    Returned element should have id  input-1  label:Ship To Street
+
+Multiple identical labels in fieldsets
+    [Documentation]
+    ...  Verify that we can distinguish between similar labels
+    ...  in different fieldsets
+
+    [Setup]  Go to  ${TEST URL}
+
+    With HTML:
+    ...  <fieldset><div>Section 1</div>
+    ...      <label for='input-1'>
+    ...          Name
+    ...      </label>
+    ...      <input id='input-1'>
+    ...  </fieldset>
+    ...  <fieldset><div>Section 2</div>
+    ...      <label for='input-2'>
+    ...          Name
+    ...      </label>
+    ...      <input id='input-2'>
+    ...  </fieldset>
+
+    Returned element should have id  input-1  label:Section 1::Name
+    Returned element should have id  input-2  label:Section 2::Name
+

cumulusci/robotframework/tests/salesforce/labels.html

@@ -0,0 +1,33 @@
+<!DOCTYPE html>
+<html lang="en">
+    <head>
+        <title>Labels for testing</title>
+        <style>
+            #test-data {
+                margin: 10px;
+                border-left: 3px solid;
+                padding-left: 10px;
+            }
+        </style>
+    </head>
+    <body>
+        <h1>A simulated input form, yo.</h1>
+        <p>
+            While this has a couple of input elements, this file is primarily designed for
+            test cases to inject input fields into the div with an id of "test-data"
+        </p>
+
+        <div><label for="input-1">First Name</label><br /><input id="input-1" /></div>
+        <div><label for="input-2">Last Name</label><br /><input id="input-2" /></div>
+        <div id="test-data">
+            <!-- tests will dynamically add code here-->
+        </div>
+        <div><label for="input-3">City</label><br /><input id="input-3" /></div>
+        <div><label for="input-4">Street</label><br /><input id="input-4" /></div>
+        <div>
+            <label for="textarea-1">Description</label><br /><textarea
+                id="textarea-1"
+            ></textarea>
+        </div>
+    </body>
+</html>