cumulusci-plus 5.0.0__py3-none-any.whl

cumulusci/robotframework/tests/salesforce/locators.robot

@@ -0,0 +1,149 @@
+*** Settings ***
+
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         cumulusci/robotframework/tests/salesforce/TestListener.py
+Library         TestLibraryA.py
+Library         TestLibraryB.py
+Library         Dialogs
+
+Suite Setup     Open test browser
+Suite Teardown  Close all browsers
+
+*** Test Cases ***
+Locator strategy 'text'
+    [Documentation]
+    ...  Test that the 'text' location strategy has been added
+    [Setup]  Go to setup home
+
+    # Try to use the locator strategy on an element
+    # we know should be on the page.
+    Wait until page contains element     text:Mobile Publisher
+
+Locator strategy 'title'
+    [Documentation]
+    ...  Test that the 'title' location strategy has been added
+    [Setup]  Go to setup home
+
+    # Try to use the locator strategy on an element
+    # we know should be on the page.
+    Wait until page contains element     title:Object Manager
+
+Locator strategy 'label'
+    [Documentation]
+    ...  Test that the 'label' location strategy has been added
+    [Setup]  Run keywords
+    ...  Go To Object Home           Contact
+    ...  AND  Click Object Button    New
+    [Teardown]  Close Modal
+
+    # Try to use the locator strategy on an element
+    # we know should be on the page.
+    Wait until page contains element    label:Phone
+
+Keyword library locators
+    [Documentation]
+    ...  Test that we can use custom locators with Selenium keywords
+
+    ...  Both of the test libraries should have registered their own
+    ...  locators. This test makes sure both of them were registered
+    ...  and available for use.
+
+    [Setup]  Go to setup home
+
+    Wait until page contains element  A:breadcrumb: Home
+    Wait until page contains element  B:appname:Setup
+
+Invalid locator
+    [Documentation]
+    ...  Verify we give a reasonable error message if the locator
+    ...  isn't found
+
+    # Note: a:breadcrumb is valid, but it doesn't have a child
+    # locator named 'bogus'
+    Run keyword and expect error
+    ...  locator A:breadcrumb.bogus not found
+    ...  Page should not contain element  a:breadcrumb.bogus
+
+Not enough arguments in locator
+    [Documentation]
+    ...  Verify that we give a reasonable error message if a locator
+    ...  requires more arguments than it gets
+
+    # Note: a:breadcrumb requires an argument
+    Run keyword and expect error
+    ...  Not enough arguments were supplied
+    ...  Page should not contain element  a:breadcrumb
+
+
+Show translated locator in the log
+    [Documentation]
+    ...  Verify the translated locator appears in the log
+
+    Page should not contain element  A:something
+    assert robot log                 locator: 'A:something' => '//whatever'
+
+Page should not contain custom locator
+    [Documentation]
+    ...  Verify that a custom locator can be used in a context where
+    ...  the locator doesn't exist.
+    ...
+    ...  It used to be that the locator manager would itself throw
+    ...  an error if it couldn't find a locator. Now, it returns None
+    ...  so that the keyword can be responsible for deciding if an
+    ...  error should be thrown or not
+
+    # we know this locator doesn't exist, but the keyword should
+    # pass. Prior to the fix when this test was introduced, this would
+    # give an error
+
+    Page should not contain element  B:appname:Sorry Charlie
+
+
+Get Webelement (singlular)
+    [Documentation]
+    ...  A smoke test to verify that we can get an element with a custom locator
+    [Setup]  Go to setup home
+
+    ${element}=        Get webelement  A:breadcrumb:Home
+    # Different browsers return different classes of objects so we
+    # can't easily do a check for the returned object type that works
+    # for all browsers. We'll just have to assume that if the element
+    # isn't None then it's a web element
+    Should be true     $element is not None
+
+
+Get Webelements (plural) - no matching elements
+
+    [tags]   W-10187485
+
+    # this is a locator which shouldn't match anything on the page
+    ${locator}=   Get Locator  modal.button  Bogus
+    ${elements}=  Get webelements  ${locator}
+
+    # same locator, but using the custom locator strategy
+    ${elements_via_locator_manager}=  Get webelements  sf:modal.button:Bogus
+
+    # the two lists of elements should be identical. The bug reported
+    # in W-10187485 caused the locator strategy to return [None]
+    # instead of []. This verifies that we fixed that bug.
+    Should be equal  ${elements}  ${elements via locator manager}
+
+    # In addition to getting an empty list when trying to fetch
+    # non-existing elements, this verifies that we can use the
+    # locator in a negative test.
+    Page should not contain  sf:modal.button:Bogus
+
+Get Webelements (plural) with custom locator
+    [Setup]  Run keywords
+    ...  Go to object home  Contact
+    ...  AND  Click object button  New
+
+    # Get the web element with the xpath directly, then verify
+    # that Get Webelements returns a list with just that element
+    # when using the custom locator
+    ${element}=  Get webelement  //div[contains(@class,'uiModal')]//button[.='Save & New']
+    @{expected elements}=  Create list  ${element}
+
+    ${actual elements}=  Get webelements  sf:modal.button:Save & New
+
+    Should be equal  ${actual elements}  ${expected elements}

cumulusci/robotframework/tests/salesforce/pageobjects/base_pageobjects.robot

@@ -0,0 +1,100 @@
+*** Settings ***
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         Collections
+Library         cumulusci.robotframework.PageObjects
+...  ${CURDIR}/example_page_object.py
+
+Suite Setup     Run keywords
+...  Create test data
+...  AND  Open Test Browser
+Suite Teardown  Delete Records and Close Browser
+
+*** Keywords ***
+Create Test Data
+    [Documentation]
+    ...  Create a Contact for Connor MacLeod if there isn't one. If there's
+    ...  already more than one, it's a fatal error since some tests depend
+    ...  on their being only one.
+    ${result}=  Salesforce Query  Contact  Firstname=Connor  LastName=MacLeod
+    run keyword if  len($result) > 1
+    ...  Fatal Error  Expected to find only one contact named Connor MacLeod, found several
+    run keyword if  len($result) == 0
+    ...  Salesforce Insert  Contact  FirstName=Connor  LastName=MacLeod
+
+*** Test Cases ***
+HomePage
+    [Documentation]
+    ...  Verify we can go to the generic Home page
+    ...  (assuming we don't have an explicit TaskHomePage)
+    go to page  Home  Task
+    Current page should be  Home  Task
+
+DetailPage
+    [Documentation]
+    ...  Verify we can go to the generic Detail page
+    ...  (assuming we don't have an explicit TaskDetailPage)
+
+    Go to page  Detail  Contact  firstName=Connor  lastName=MacLeod
+    # It is assumed only one contact will match. If there are several,
+    # you might need to recreate your scratch org to clear out the duplicates
+    Current page should be  Detail  Contact  firstName=Connor  lastName=MacLeod
+
+DetailPage with no matches
+    [Documentation]
+    ...  Verify that we get an error if we try to go to a page for
+    ...  an object that doesn't exist.
+
+    run keyword and expect error  no Contact matches firstName=Nobody, lastName=Nobody
+    ...  Go to page  Detail  Contact  firstName=Nobody  lastName=Nobody
+
+DetailPage with more than one match
+    [Documentation]
+    ...  Verify that we get an error if we try to go to a detail
+    ...  page that matches more than a single record
+
+    [Setup]  run keywords
+    ...  Salesforce Insert  Contact  FirstName=John  LastName=Smith
+    ...  AND  Salesforce Insert  Contact  FirstName=John  LastName=Jones
+
+    ${records}=   Salesforce query  Contact  firstName=John
+    ${expected}=  get length  ${records}
+
+    run keyword and expect error  Query returned ${expected} objects
+    ...  Go to page  Detail  Contact  firstName=John
+
+NewModal
+    [Documentation]
+    ...  Verify that we can use the NewModal page object keywords
+
+    [Setup]  Go to page  Home  Contact
+    Click object button  New
+    Wait for modal      New  Contact
+    Close the modal
+
+NewModal - click modal button
+    [Documentation]
+    ...  Verify that we can use the NewModal 'click modal button' keyword
+
+    [Setup]  Run keywords
+    ...  Go to page  Home  Contact
+    ...  AND  Click object button  New
+    ...  AND  Wait for modal      New  Contact
+
+    Click modal button  Cancel
+    Wait until modal is closed
+
+NewModal - Modal errors
+    [Documentation]
+    ...  Verify that we can detect errors in the model
+    ...  with 'modal should contain errors' keyword (API < 51)
+    ...  or 'Modal should show edit error for fields' (API >= 51)
+
+    [Setup]  Run keywords
+    ...  Go to page  Home  Contact
+    ...  AND  Click object button  New
+    ...  AND  Wait for modal      New  Contact
+
+    Click modal button  Save
+    capture page screenshot
+    ${api}=   Get latest API version
+    Modal should show edit error for fields   Name

cumulusci/robotframework/tests/salesforce/pageobjects/example_page_object.py

@@ -0,0 +1,25 @@
+from cumulusci.robotframework.pageobjects import BasePage, pageobject
+
+
+@pageobject("About", "Blank")
+class AboutBlankPage(BasePage):
+    object_name = None
+
+    def _go_to_page(self):
+        self.selenium.go_to("about:blank")
+
+    def _is_current_page(self):
+        location = self.selenium.get_location()
+        if location != "about:blank":
+            raise Exception(
+                "Expected location to be 'about:blank' but it was '{}'".format(location)
+            )
+
+    def hello(self, message):
+        return "About:Blank Page says Hello, {}".format(message)
+
+    def keyword_one(self):
+        return "About:Blank keyword one"
+
+    def keyword_two(self):
+        return "About:Blank keyword two"

cumulusci/robotframework/tests/salesforce/pageobjects/listing_page.robot

@@ -0,0 +1,115 @@
+*** Settings ***
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         Collections
+Library         cumulusci.robotframework.PageObjects
+...  ${CURDIR}/example_page_object.py
+
+Suite Setup     Run keywords
+...  Create test data
+...  AND  Open Test Browser
+Suite Teardown  Delete Records and Close Browser
+
+*** Keywords ***
+Create Test Data
+    [Documentation]
+    ...  Create contacts used by tests in this suite
+
+    # Delete all cases, in case they are holding on to some contacts
+    ${records}=  Salesforce Query  Case
+    FOR  ${record}  IN  @{records}
+        Salesforce Delete  Case  ${record['Id']}
+    END
+
+    # Next, delete all existing contacts
+    ${records}=  Salesforce Query  Contact
+    FOR  ${record}  IN  @{records}
+        Salesforce Delete  Contact  ${record['Id']}
+    END
+
+    # Next, add the ones we need
+    Salesforce Insert  Contact  LastName=MacLeod  FirstName=Connor  Phone=555-123-1000
+    Salesforce Insert  Contact  LastName=Doe      Phone=555-123-1001
+    Salesforce Insert  Contact  LastName=Doe      Phone=555-123-1002
+
+Status info should contain
+    [Documentation]
+    ...  Verifies that the status info contains the given text
+    [Arguments]  ${expected}
+
+    ${text}=  Get text  sf:object_list.status_info
+    Should contain  ${text}  ${expected}
+    ...  msg=Element text '${text}' does not contain '${expected}'
+    ...  values=False
+
+*** Test Cases ***
+ListingPage - Smoke test
+    [Documentation]
+    ...  Verify we can go to the generic Listing page
+    ...  (assuming we don't have an explicit TaskListingPage)
+    Go to page              Listing  Task
+    Current page should be  Listing  Task
+
+ListingPage - Select Rows
+    [Documentation]
+    ...  Verify that the 'Select Rows' keyword works
+    [Setup]  Run keywords
+    ...  Go to page              Listing  Contact
+    ...  AND  wait until element is not visible   sf:spinner
+
+    Select rows  Doe
+    Status info should contain  2 items selected
+
+ListingPage - Select Rows when already selected
+    [Documentation]
+    ...  Verify that the 'Select Rows' keyword doesn't toggle
+    ...  already selected rows
+    [Setup]  Run keywords
+    ...  Go to page              Listing  Contact
+    ...  AND  wait until element is not visible   sf:spinner
+
+    Select rows  Doe
+    Status info should contain  2 items selected
+
+    Select rows  Doe
+    Status info should contain  2 items selected
+
+ListingPage - Select Rows - No matching rows
+    [Documentation]
+    ...  Verify that 'Select Rows' raises an appropriate error
+    ...  when no rows can be found
+    [Setup]  Run keywords
+    ...  Go to page              Listing  Contact
+    ...  AND  wait until element is not visible   sf:spinner
+
+    Run keyword and expect error
+    ...  No rows matched 'Bogus'
+    ...  Select rows  Bogus
+
+ListingPage - Deselect Rows
+    [Documentation]
+    ...  Verify that the 'Deselect Rows' keyword works
+    [Setup]  Run keywords
+    ...  Go to page              Listing  Contact
+    ...  AND  wait until element is not visible   sf:spinner
+
+    Select rows  Doe  Connor MacLeod
+    Status info should contain  3 items selected
+
+    # deselect via name column
+    Deselect rows  Doe
+    Status info should contain  1 item selected
+
+    # deselect one more via phone column
+    Deselect rows  555-123-1000
+    Status info should contain  3 items
+
+ListingPage - Deselect Rows - No matching rows
+    [Documentation]
+    ...  Verify that the 'Deselect Rows' keyword raises an appropriate error
+    [Setup]  Run keywords
+    ...  Go to page              Listing  Contact
+    ...  AND  wait until element is not visible   sf:spinner
+
+    Run keyword and expect error
+    ...  No rows matched 'Bogus'
+    ...  Select rows  Bogus

cumulusci/robotframework/tests/salesforce/pageobjects/objectmanager.robot

@@ -0,0 +1,74 @@
+*** Settings ***
+
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         cumulusci.robotframework.PageObjects
+Suite Setup     Run keywords  Open Test Browser
+Suite Teardown  Delete Records and Close Browser
+
+*** Keywords ***
+Create Custom Field In Object Manager
+    [Documentation]
+    ...  Reads key value pair arguments.
+    ...
+    ...  Navigates to Object Manager page and load fields and relationships for the specific object
+    ...  Runs keyword to create custom field
+    ...
+    ...  Example:
+    ...
+    ...  | Create custom field in object manager
+    ...  | ...  Object=Payment
+    ...  | ...  Field_Type=Formula
+    ...  | ...  Field_Name=Is Opportunity From Prior Year
+    ...  | ...  Formula=YEAR( npe01__Opportunity__r.CloseDate ) < YEAR( npe01__Payment_Date__c )
+
+    [Arguments]                                    &{fields}
+    Go To Page                                     ObjectManager                           ${fields}[Object]
+    Switch Tab To                                  Fields & Relationships
+    Create Custom Field                            &{fields}
+
+*** Test Cases ***
+
+Navigate To The Object Manager page For Specified Object
+    [Documentation]     Smoke Test For validating the behavior of navigating to the ObjectManager Page for a specified object
+
+    Go To Page                                             ObjectManager                              Contact
+    Current page should be                                 ObjectManager                              Contact
+
+
+Create Custom Lookup Field Using Object Manager
+    [Documentation]     To test the ability of creating a custom lookup field using object manager and verify field got created
+
+    Create Custom Field In Object Manager
+    ...                                                    Object=Contact
+    ...                                                    Field_Type=Lookup
+    ...                                                    Field_Name=Last Soft Credit Opportunity
+    ...                                                    Related_To=Opportunity
+    Go To Page                                             ObjectManager                               Contact
+    Switch Tab To                                          Fields & Relationships
+    Is Field Present                                       Last Soft Credit Opportunity
+    Delete Custom Field                                    Last Soft Credit Opportunity
+
+Create Custom Text Field Using Object Manager
+    [Documentation]     To test the ability of creating a custom text field using object manager and verify field got created
+
+    Create Custom Field In Object Manager
+    ...                                                    Object=Contact
+    ...                                                    Field_Type=Text
+    ...                                                    Field_Name=This Is A Text Field
+    Go To Page                                             ObjectManager                               Contact
+    Switch Tab To                                          Fields & Relationships
+    Is Field Present                                       This Is A Text Field
+    Delete Custom Field                                    This Is A Text Field
+
+
+Create Custom Currency Field Using Object Manager
+    [Documentation]     To test the ability of creating a custom currency field and verify field got created
+
+    Create Custom Field In Object Manager
+    ...                                                    Object=Account
+    ...                                                    Field_Type=Currency
+    ...                                                    Field_Name=This Year Payments on Past Year Pledges
+    Go To Page                                             ObjectManager                               Account
+    Switch Tab To                                          Fields & Relationships
+    Is Field Present                                       This Year Payments on Past Year Pledges
+    Delete Custom Field                                    This Year Payments on Past Year Pledges

cumulusci/robotframework/tests/salesforce/pageobjects/pageobjects.robot

@@ -0,0 +1,171 @@
+*** Settings ***
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         Collections
+Library         cumulusci.robotframework.PageObjects
+...  ${CURDIR}/example_page_object.py
+
+Suite Setup     Open Test Browser
+Suite Teardown  Delete Records and Close Browser
+
+*** Test Cases ***
+Load page object, using defined page object
+    [Documentation]
+    ...  If we can't do this, all hope is lost!
+    Load page object  About  Blank
+
+Go to page automatically loads page object
+    [Documentation]  Verify that 'go to page' automatically loads the page object
+    Go to page    About  Blank
+    ${pobj}=  log current page object
+    Should not be equal  ${pobj}  ${None}
+
+Go to page and current page should be, using defined page object
+    [Documentation]  Verify we can go to an implemented page object
+    Go to page              About  Blank
+    Current page should be  About  Blank
+
+Go to page, using generic page object
+    [Documentation]
+    ...  Verify we can go to a page object for which there is
+    ...  no explicit definition, but for which there is a generic
+    ...  (base) class.
+    Go to page    Listing  Contact
+    Current page should be  Listing  Contact
+
+Go to page, using multiple generic pages
+    [Documentation]
+    ...  Verify we can use multiple generic page objects in the same
+    ...  test. Earlier versions of the library had a bug that
+    ...  prevented this from working. What was happening is that we
+    ...  were giving the library a generic name like "DetailPage"
+    ...  rather than a name that included the object type such as
+    ...  "ContactDetailPage".
+
+    Go to page  Listing  Contact
+    Current page should be  Listing  Contact
+    Go to page  Listing  Task
+    Current page should be  Listing  Task
+    Go to page  Detail  Contact
+    Current page should be  Detail   Contact
+
+Get page object
+    [Documentation]
+    ...  Verify that we can call the `get page object` keyword and that
+    ...  it returns a page object
+    [Setup]  Load page object     About  Blank
+
+    ${pobj}=  Get page object  About  Blank
+    Should not be equal  ${pobj}  ${NONE}
+
+    @{keywords}=  Call method  ${pobj}  get_keyword_names
+
+    # The page object should have three keywords we defined, plus
+    # one from the base class
+    ${expected}=  Create list  hello  keyword_one  keyword_two  log_current_page_object
+    Lists should be equal  ${keywords}  ${expected}
+
+Call keyword of defined page object
+    [Documentation]
+    ...  Verify we can call a keyword in a defined page object
+    Load page object  About  Blank
+
+    # "Hello" is a keyword in AboutBlankPage
+    ${result}=  Hello  world
+    should be equal  ${result}  About:Blank Page says Hello, world
+
+Load page object, using generic page object
+    [Documentation]
+    ...  Verify that 'load page object' works when using a generic
+    ...  page object
+    Load page object  Listing  Contact
+
+Current page should be, using generic page object
+    [Documentation]
+    ...  Verify that 'current page should be' works when
+    ...  using a generic page object
+    [Setup]  Go to page  Listing  Task
+
+    log current page object
+    Current page should be  Listing  Task
+    Location should contain  /lightning/o/Task/list
+
+Current page should be throws appropriate error
+    [Documentation]
+    ...  Verifies the error that is thrown when 'current page should be'
+    ...  is false
+    [Setup]  load page object  Listing  Contact
+
+    ${location}=  get location
+    run keyword and expect error   Expected location to be 'about:blank' but it was '${location}'
+    ...  current page should be  About  Blank
+
+Error when no page object can be found
+    [Documentation]
+    ...  Verify we get an error if no page object exists, and
+    ...  there is no suitable base class
+
+    Run keyword and expect error
+    ...  Unable to find a page object for 'Foo Bar'
+    ...  Go to page  Foo  Bar
+
+Log page object keywords
+    [Documentation]  Verify that 'log page object keywords' doesn't throw an error
+    # All we're doing here is verifying it doesn't throw an error.
+    # Unfortunately there's no way to verify the robot log message
+    # was called (or is there...???)
+    [Setup]  Load Page Object  About  Blank
+
+    log page object keywords
+
+Load multiple page objects in library search order
+    [Documentation]
+    ...  Loading a page object inserts it at the start of the
+    ...  library search order. Verify that that happens properly.
+
+    # Note: the library search order persists for the life of a suite
+    # Therefore we need to reset it before running this test since
+    # other tests will be loading page objects
+    [Setup]  Set library search order  PageObjects
+
+    Go to page   About     Blank
+    Go to page   Home      Task
+    Go to page   Listing   Contact
+
+    # This should move HomeTask to the front. It should not
+    # end up in the search order twice.
+    Go to page   Home      Task
+
+    # Note: the order is a list of strings, not actual libraries.
+    ${actual_order}=       Set library search order
+    ${expected_order}=     Create list  TaskHomePage  ContactListingPage  AboutBlankPage  PageObjects
+    log  actual order: ${actual_order}
+    Lists should be equal  ${actual_order}  ${expected_order}
+
+Wait for page object
+    Go to page    Listing  Contact
+    Click object button  New
+
+    Wait for page object  New  Contact
+
+Wait for page object exception
+    [Documentation]  Verify we throw an error if page object isn't found
+    Go to page    Listing  Contact
+    Run keyword and expect error
+    ...  Unable to find a page object for 'BogusType BogusObject'
+    ...  Wait for page object  BogusType  BogusObject
+
+Wait for modal
+    [Documentation]  Verify that the 'wait for modal' keyword works
+    Go to page    Listing  Contact
+    Click object button  New
+
+    Wait for modal  New  Contact
+
+Wait for modal exception
+    [Documentation]  Verify we throw an error if page object isn't found
+    Go to page    Listing  Contact
+    Click object button  New
+
+    Run keyword and expect error
+    ...  Unable to find a page object for 'BogusType BogusObject'
+    ...  Wait for modal  BogusType  BogusObject