cumulusci-plus 5.0.0__py3-none-any.whl

cumulusci/robotframework/tests/cumulusci/base.robot

@@ -0,0 +1,40 @@
+*** Settings ***
+
+Resource  cumulusci/robotframework/CumulusCI.robot
+Force Tags  no-browser
+
+*** Test Cases ***
+
+Test Set Login Url 
+    Set Login Url
+    Variable Should Exist  ${LOGIN_URL}
+
+Test Login Url
+    ${login_url} =  Login Url
+    Should Contain  ${login_url}  secur/frontdoor.jsp?sid=
+
+Test Get Org Info
+    &{org_info} =  Get Org Info
+    Dictionary Should Contain Key  ${org_info}  org_id
+    Dictionary Should Contain Key  ${org_info}  username
+
+Test Get Namespace Prefix
+    ${ns} =  Get Namespace Prefix
+    Should Be Empty  ${ns}
+
+Test Run Task
+    Run Task  create_package
+
+Test Run Task With Options
+    Run Task  create_package  package=Test Package
+
+Test Run Task Missing
+    Run Keyword And Expect Error
+    ...  TaskNotFoundError: Task not found: does_not_exist
+    ...  Run Task  does_not_exist
+
+Test Run Task Class
+    Run Task Class  cumulusci.tasks.salesforce.CreatePackage
+
+Test Run Task Class With Options
+    Run Task Class  cumulusci.tasks.salesforce.CreatePackage  package=Test Package

cumulusci/robotframework/tests/cumulusci/bulkdata.robot

@@ -0,0 +1,38 @@
+*** Settings ***
+
+Resource       cumulusci/robotframework/Salesforce.robot
+Resource  cumulusci/robotframework/CumulusCI.robot
+
+Force Tags    bulkdata  no-browser
+
+*** Test Cases ***
+
+Test Run Bulk Data Deletion With Error
+
+    ${account_name} =  Get fake data  company
+    ${account_id} =  Salesforce Insert  Account
+    ...  Name=${account_name}
+    ...  BillingStreet=Granville Ave., SFDO
+
+    ${contract_id} =    Salesforce Insert  Contract
+    ...  AccountId=${account_id}
+
+    Salesforce Update    Contract    ${contract_id}
+    ...     status=Activated
+
+    ${opportunity} =    Salesforce Insert   Opportunity
+    ...  AccountId=${account_id}
+    ...  StageName=Prospecting
+    ...  Name=${account_name}
+    ...  CloseDate=2025-05-05
+
+    Run Keyword and Expect Error        *BulkDataException*
+    ...     Run Task Class   cumulusci.tasks.bulkdata.delete.DeleteData
+    ...         objects=Account
+    ...         where=BillingStreet='Granville Ave., SFDO'
+
+    Salesforce Delete   Contract     ${contract_id}
+
+    Run Task Class   cumulusci.tasks.bulkdata.delete.DeleteData
+    ...         objects=Account
+    ...         where=BillingStreet='Granville Ave., SFDO'

cumulusci/robotframework/tests/cumulusci/communities.robot

@@ -0,0 +1,57 @@
+*** Settings ***
+Resource  cumulusci/robotframework/CumulusCI.robot
+Library   Collections
+Force Tags  no-browser
+
+Suite Setup  run keywords
+     # Note: the first community name intentionally includes a unicode
+     # character to make sure we can handle it.
+...  Ensure community exists       Kōkua   kokua
+...  AND  Ensure community exists  Ohana   ohana
+
+*** Keywords ***
+Ensure community exists
+    [Arguments]      ${community name}  ${url prefix}
+    [Documentation]  Creates a community with the given name if it doesn't exist
+
+    ${passed}=  run keyword and return status
+    ...  get community info  ${community name}
+
+    run keyword if  not $passed  run task  create_community
+    ...  template=VF Template
+    ...  name=${community name}
+    ...  url_path_prefix=${url prefix}
+
+*** Test Cases ***
+Get community info for specific community
+    # we'll just spot-check a few keys. I don't see a point
+    # in testing them all, since the API is either going to
+    # return everything or nothing
+    ${info}=  get community info               Kōkua
+    Dictionary should contain key  ${info}     name
+    Dictionary should contain key  ${info}     loginUrl
+    Dictionary should contain key  ${info}     siteUrl
+    Should be equal  ${info['name']}           Kōkua
+    Should be equal  ${info['urlPathPrefix']}  kokua
+
+    # now get info for another community, to make sure
+    # it doesn't return the data from the previous community
+    ${info}=  get community info  Ohana
+    Should be equal  ${info['name']}  Ohana
+    Should be equal  ${info['urlPathPrefix']}  ohana
+
+Get community info for non-existing community throws error
+    [Documentation]  Verify that an unknown community name throws a reasonable error message
+    run keyword and expect error
+    ...  Unable to find community information for 'bōgusCommunity'
+    ...  get community info  bōgusCommunity
+
+Get community info with key
+    [Documentation]  Verify we can Fetch data for a single key
+    ${loginUrl}=  get community info  Kōkua  loginUrl
+    Should match regexp  ${loginUrl}  https://.*/kokua/login
+
+Get community info with unknown key throws error
+    [Documentation]  Verify that an unknown key throws a reasonable error message
+    run keyword and expect error  Invalid key 'bōgus'
+    ...  get community info  Kōkua  bōgus

cumulusci/robotframework/tests/cumulusci/datagen.robot

@@ -0,0 +1,84 @@
+*** Settings ***
+
+Resource       cumulusci/robotframework/Salesforce.robot
+Resource  cumulusci/robotframework/CumulusCI.robot
+
+Force Tags    bulkdata  no-browser
+
+*** Keywords ***
+Assert Row Count
+    [Arguments]     ${count}        ${object_name}      &{kwargs}
+
+    ${status}     ${result} =   Run Keyword And Ignore Error
+    ...           Salesforce Query  ${object_name}
+    ...           select=COUNT(Id)
+    ...           &{kwargs}
+
+    Run Keyword If      '${status}' != 'PASS'
+    ...           Log
+    ...           Salesforce query failed: probably timeout. ${object_name} ${result}
+    ...           console=True
+
+    Should Be Equal    PASS    ${status}
+
+    ${matching_records} =   Set Variable    ${result}[0][expr0]
+    Should Be Equal As Numbers        ${matching_records}     ${count}
+
+Attempt To Load Snowfakery
+    Import Library      snowfakery
+    Return From Keyword     True
+
+
+*** Test Cases ***
+
+Test Run Bulk Data Generation
+    Run Task Class   cumulusci.tasks.bulkdata.delete.DeleteData
+    ...         objects=Account
+    ...         where=BillingStreet='Baker St.'
+    Run Task Class   cumulusci.tasks.bulkdata.delete.DeleteData
+    ...         objects=Contact
+    ...         where=MailingStreet='Baker St.'
+    Run Task Class   cumulusci.tasks.bulkdata.generate_and_load_data.GenerateAndLoadData
+    ...     num_records=20
+    ...     mapping=cumulusci/tasks/bulkdata/tests/mapping_vanilla_sf.yml
+    ...     data_generation_task=cumulusci.tasks.bulkdata.tests.dummy_data_factory.GenerateDummyData
+    Assert Row Count  20  Account   BillingStreet=Baker St.
+    Assert Row Count  15  Contact  MailingStreet=Baker St.
+
+Test Batching
+    Run Task Class   cumulusci.tasks.bulkdata.delete.DeleteData
+    ...         objects=Account
+    ...         where=BillingStreet='Baker St.'
+    Run Task Class   cumulusci.tasks.bulkdata.delete.DeleteData
+    ...         objects=Contact
+    ...         where=MailingStreet='Baker St.'
+    Run Task Class   cumulusci.tasks.bulkdata.generate_and_load_data.GenerateAndLoadData
+    ...     num_records=20
+    ...     mapping=cumulusci/tasks/bulkdata/tests/mapping_vanilla_sf.yml
+    ...     batch_size=4
+    ...     data_generation_task=cumulusci.tasks.bulkdata.tests.dummy_data_factory.GenerateDummyData
+    Assert Row Count  20  Account   BillingStreet=Baker St.
+    Assert Row Count  15  Contact  MailingStreet=Baker St.
+
+Test Error Handling
+    Run Keyword and Expect Error    STARTS:TaskOptionsError
+    ...  Run Task Class   cumulusci.tasks.bulkdata.generate_and_load_data.GenerateAndLoadData
+    ...     num_records=20
+    ...     mapping=cumulusci/tasks/bulkdata/tests/mapping_vanilla_sf.yml
+    ...     batch_size=5
+    ...     database_url=sqlite:////tmp/foo.db
+
+
+
+Test Snowfakery
+    ${status}        ${retVal}=     Run Keyword And Ignore Error          Attempt To Load Snowfakery
+    Log     ${status}
+
+    Run Keyword Unless	    $status == 'PASS'       Log     Snowfakery is not available
+
+    Run Keyword If	    $status == 'PASS'       Run Task Class
+    ...     cumulusci.tasks.bulkdata.generate_and_load_data_from_yaml.GenerateAndLoadDataFromYaml
+    ...     num_records=20
+    ...     num_records_tablename=Account
+    ...     batch_size=5
+    ...     generator_yaml=cumulusci/tasks/bulkdata/tests/snowfakery/simple_snowfakery.recipe.yml

cumulusci/robotframework/tests/salesforce/TestLibraryA.py

@@ -0,0 +1,24 @@
+"""
+This is a library used by locators.robot for testing
+custom locator strategies
+"""
+from cumulusci.robotframework.locator_manager import (
+    register_locators,
+    translate_locator,
+)
+
+locators = {
+    # eg: A:breadcrumb:Home
+    "breadcrumb": "//span[contains(@class, 'breadcrumbDetail') and text()='{}']",
+    "something": "//whatever",
+}
+
+
+class TestLibraryA:
+    ROBOT_LIBRARY_SCOPE = "global"
+
+    def __init__(self):
+        register_locators("A", locators)
+
+    def translate_locator(self, prefix, locator):
+        return translate_locator(prefix, locator)

cumulusci/robotframework/tests/salesforce/TestLibraryB.py

@@ -0,0 +1,20 @@
+"""
+This is a library used by locators.robot for testing
+custom locator strategies
+"""
+from cumulusci.robotframework.locator_manager import (
+    register_locators,
+    translate_locator,
+)
+
+locators = {"appname": "//div[contains(@class, 'appName') and .='{}']"}
+
+
+class TestLibraryB:
+    ROBOT_LIBRARY_SCOPE = "global"
+
+    def __init__(self):
+        register_locators("B", locators)
+
+    def translate_locator(self, prefix, locator):
+        return translate_locator(prefix, locator)

cumulusci/robotframework/tests/salesforce/TestListener.py

@@ -0,0 +1,93 @@
+"""This hybrid library/listener can be used to verify messages that
+    have been logged and keywords have been called.
+
+    This works by listening for log messages and keywords via the
+    listener interface, and saving them in a cache. Keywords are
+    provided for doing assertions on called keywords and for resetting
+    the cache.
+
+    The keyword cache is reset for each test case to help keep it
+    from growing too large.
+
+"""
+import re
+
+
+class TestListener(object):
+    __test__ = False  # this class should be ignored by pytest
+    ROBOT_LIBRARY_SCOPE = "TEST SUITE"
+    ROBOT_LISTENER_API_VERSION = 2
+
+    def __init__(self):
+        self.ROBOT_LIBRARY_LISTENER = self
+        self.message_log = []
+        self.keyword_log = []
+        self.message_logging_enabled = True
+
+    def _log_message(self, message):
+        """Called whenever a message is added to the log"""
+        if self.message_logging_enabled:
+            self.message_log.append(message)
+
+    def _start_test(self, name, attrs):
+        self.reset_test_listener_keyword_log()
+
+    def _end_keyword(self, name, attrs):
+        attrs_subset = {name: attrs[name] for name in ("status", "args")}
+        self.keyword_log.append((name, attrs_subset))
+
+    def reset_test_listener_keyword_log(self):
+        """Reset the keyword cache
+
+        This can be used to reset the cache in the middle of a
+        testcase so that the 'Assert keyword Status' keyword will only
+        apply to keywords called from this point onwards.
+
+        """
+        self.keyword_log.clear()
+
+    def reset_test_listener_message_log(self):
+        self.message_log = []
+
+    def assert_keyword_status(self, expected_status, keyword_name, *args):
+        """Assert that all keyword with the given name and args have the given status
+
+        Keyword names need to be passed in as fully qualified names
+        exactly as they appear in the logs.
+
+        expected_status should be either PASS or FAIL
+
+        Example
+            Log  Hello, world
+            Assert keyword status  PASS  BuiltIn.log  Hello, world
+
+        """
+
+        keyword_was_found = False
+        for name, attrs in self.keyword_log:
+            if name == keyword_name and args == tuple(attrs["args"]):
+                keyword_was_found = True
+                if attrs["status"] != expected_status:
+                    message = (
+                        f"Status of keyword {keyword_name} with args {args} "
+                        f"expected to be {expected_status} but was {attrs['status']}"
+                    )
+                    raise AssertionError(message)
+        if not keyword_was_found:
+            raise AssertionError(
+                f"No keyword with name '{keyword_name}' with args '{args}' was found"
+            )
+
+    def assert_robot_log(self, message_pattern, log_level=None):
+        """Assert that a message matching the regex pattern was emitted"""
+        for message in self.message_log:
+            # note: message is a dictionary with the following keys:
+            # 'timestamp', 'message', 'level', 'html'
+            if re.search(message_pattern, message["message"], re.MULTILINE):
+                if log_level is None or message["level"] == log_level:
+                    return True
+        raise AssertionError(
+            "Could not find a robot log message matching the pattern '{}'".format(
+                message_pattern
+            )
+        )

cumulusci/robotframework/tests/salesforce/api.robot

@@ -0,0 +1,178 @@
+*** Settings ***
+
+Resource        cumulusci/robotframework/Salesforce.robot
+Suite Teardown  Delete Session Records
+Force Tags      api  no-browser
+
+*** Keywords ***
+
+Create Contact
+    ${first_name} =  Get fake data  first_name
+    ${last_name} =   Get fake data  last_name
+    ${contact_id} =  Salesforce Insert  Contact  FirstName=${first_name}  LastName=${last_name}
+    &{contact} =  Salesforce Get  Contact  ${contact_id}
+    [return]  &{contact}
+
+*** Test Cases ***
+
+Salesforce Delete
+    &{contact} =  Create Contact
+    Salesforce Delete  Contact  ${contact}[Id]
+    &{result} =  SOQL Query  Select Id from Contact WHERE Id = '${contact}[Id]'
+    Should Be Equal  ${result}[totalSize]  ${0}
+
+Salesforce Insert
+    ${first_name} =  Get fake data  first_name
+    ${last_name} =   Get fake data  last_name
+    ${contact_id} =  Salesforce Insert  Contact
+    ...  FirstName=${first_name}
+    ...  LastName=${last_name}
+    &{contact} =  Salesforce Get  Contact  ${contact_id}
+    Should Be Equal  ${contact}[FirstName]  ${first_name}
+    Should Be Equal  ${contact}[LastName]  ${last_name}
+
+Salesforce Update
+    &{contact} =  Create Contact
+    ${new_last_name} =  Get fake data  last_name
+    Salesforce Update  Contact  ${contact}[Id]  LastName=${new_last_name}
+    &{contact} =  Salesforce Get  Contact  ${contact}[Id]
+    Should Be Equal  ${contact}[LastName]  ${new_last_name}
+
+Salesforce Query
+    &{new_contact} =  Create Contact
+    @{records} =  Salesforce Query  Contact
+    ...              select=Id,FirstName,LastName
+    ...              Id=${new_contact}[Id]
+    &{contact} =  Get From List  ${records}  0
+    Should Be Equal  ${contact}[Id]  ${new_contact}[Id]
+    Should Be Equal  ${contact}[FirstName]  ${new_contact}[FirstName]
+    Should Be Equal  ${contact}[LastName]  ${new_contact}[LastName]
+
+Salesforce Query Where
+    &{new_contact} =  Create Contact
+    @{records} =  Salesforce Query  Contact
+    ...              select=Id,FirstName,LastName
+    ...              where=FirstName='${new_contact}[FirstName]' AND LastName='${new_contact}[LastName]'
+    &{contact} =  Get From List  ${records}  0
+    Should Be Equal  ${contact}[Id]  ${new_contact}[Id]
+    Should Be Equal  ${contact}[FirstName]  ${new_contact}[FirstName]
+    Should Be Equal  ${contact}[LastName]  ${new_contact}[LastName]
+
+Salesforce Query Where Plus Clauses
+    &{new_contact} =  Create Contact
+    @{records} =  Salesforce Query  Contact
+    ...              select=Id,FirstName,LastName
+    ...              where=LastName='${new_contact}[LastName]'
+    ...              FirstName=${new_contact}[FirstName]
+    &{contact} =  Get From List  ${records}  0
+    Should Be Equal  ${contact}[Id]  ${new_contact}[Id]
+    Should Be Equal  ${contact}[FirstName]  ${new_contact}[FirstName]
+    Should Be Equal  ${contact}[LastName]  ${new_contact}[LastName]
+
+Salesforce Query Where Not Equal
+    &{new_contact} =  Create Contact
+    @{records} =  Salesforce Query  Contact
+    ...              select=Id,FirstName,LastName
+    ...              where= LastName!='${new_contact}[LastName]'
+    ...              Id=${new_contact}[Id]
+    ${cnt}=    Get length    ${records}
+    Should Be Equal As Numbers   ${cnt}  0
+
+Salesforce Query Where Limit Order
+    &{anon_contact} =  Create Contact
+    &{anon_contact} =  Create Contact
+    ${contact_id} =  Salesforce Insert  Contact  FirstName=xyzzy   LastName=xyzzy
+    @{records} =    Salesforce Query  Contact
+    ...              select=Id,FirstName,LastName
+    ...              where= LastName!='xyzzy'
+    ...              order_by=LastName desc
+    ...              limit=2
+    ${cnt}=    Get length    ${records}
+    Should Be Equal As Numbers   ${cnt}  2
+
+
+SOQL Query - single line
+    &{new_contact} =  Create Contact
+    &{result} =  Soql Query  Select Id, FirstName, LastName from Contact WHERE Id = '${new_contact}[Id]'
+    @{records} =  Get From Dictionary  ${result}  records
+    &{contact} =  Get From List  ${records}  0
+    Should Be Equal  ${result}[totalSize]  ${1}
+    Should Be Equal  ${contact}[FirstName]  ${new_contact}[FirstName]
+    Should Be Equal  ${contact}[LastName]  ${new_contact}[LastName]
+
+SOQL Query - multiline
+    [Documentation]  Verify that a SOQL query can span multiple lines
+    [Tags]  W-10244357
+    &{contact1} =  Create Contact
+    &{contact2} =  Create Contact
+
+    &{result}=  SOQL Query
+    ...  SELECT Id, FirstName, LastName
+    ...  FROM   Contact
+    ...  WHERE  Id = '${contact1}[Id]'  OR  Id = '${contact2}[Id]'
+
+    Should Be Equal as numbers  ${result}[totalSize]  2
+
+Salesforce Delete Session Records
+    [Documentation]
+    ...  Verify that 'Delete Session Records' deletes all session records
+    ...  This verifies that we fixed a bug which resulted in some records
+    ...  not being deleted.
+
+    # We'll use this to uniquely identify all records created in this test
+    ${random string}=  Generate Random String
+
+    # First, make sure we have no records that match
+    @{query}=  Salesforce Query  Contact  LastName=${random string}
+    length should be  ${query}  0         Expected the query to return no records, but it returned ${query}
+
+    # Next, create some records
+    FOR  ${i}  IN RANGE  5
+        ${contact_id} =  Salesforce Insert  Contact
+        ...  FirstName=User-${i}
+        ...  LastName=${random string}
+    END
+    @{query}=  Salesforce Query    Contact  LastName=${random string}
+    length should be  ${query}  5  Expected the query to return five records, but it returned ${query}
+
+    # Now, call 'Delete Session Records' and verify all five were deleted
+    Delete Session Records
+    @{query}=  Salesforce Query  Contact
+    ...  LastName=${random string}
+    length should be  ${query}  0  Expected the query to return 0 records, but it returned ${query}
+
+Collection API Test
+    @{objects} =  Generate Test Data  Contact  20
+        ...  FirstName=User {{number}}
+        ...  LastName={{fake.last_name}}
+    @{records} =    Salesforce Collection Insert  ${objects}
+    FOR     ${record}   IN  @{records}
+        ${new_last_name} =  Get fake data  last_name
+        set to dictionary   ${record}   LastName    ${new_last_name}
+    END
+    Salesforce Collection Update    ${records}
+
+Collection API Errors Test
+    @{objects} =  Generate Test Data  Contact  20
+        ...  FirstName=User {{number}}
+        ...  LastName={{fake.last_name}}
+        ...  Xyzzy=qwertz
+    Run Keyword And Expect Error   *No such column*Xyzzy*   Salesforce Collection Insert  ${objects}
+
+    @{objects} =  Generate Test Data  Contact  20
+        ...  FirstName=User {{number}}
+        ...  LastName=
+    Run Keyword And Expect Error   Error*  Salesforce Collection Insert  ${objects}
+
+    @{objects} =  Generate Test Data  Contact  20
+        ...  FirstName=User {{number}}
+        ...  LastName={{fake.last_name}}
+    ${records} =     Salesforce Collection Insert  ${objects}
+    FOR     ${record}   IN  @{records}
+        set to dictionary   ${record}   Age    Iron
+    END
+    Run Keyword And Expect Error   *No such column*Age*   Salesforce Collection Update  ${objects}
+
+Get Version
+    ${version} =   Get Latest Api Version
+    Should Be True     ${version} > 46

cumulusci/robotframework/tests/salesforce/browsers.robot

@@ -0,0 +1,143 @@
+*** Settings ***
+
+Resource        cumulusci/robotframework/Salesforce.robot
+Library         TestListener.py
+Suite Teardown  Close all browsers
+
+
+*** Variables ***
+${DEFAULT WINDOW SIZE}  1280x1024
+
+*** Keywords ***
+Assert active browser count
+    [Documentation]   Assert that an expected number of browsers are active
+    [Arguments]       ${expected count}
+
+    @{browsers}=      get active browser ids
+    ${actual count}=  get length  ${browsers}
+    Length should be  ${browsers}  ${expected count}
+    ...  Expected to find ${expected count} open browsers, found ${actual count}
+
+Assert window size
+    [Documentation]
+    ...  Verify the actual window size is the expected size
+    ...  give or take a pixel or five.
+    [Arguments]  ${expected width}  ${expected height}
+
+    # On circleci, the browser size is sometimes off by a pixel. How rude!
+    # Since we don't so much care about the precise size as we do that
+    # we are able to change the size, we'll allow a tiny bit of wiggle room.
+    ${actual width}  ${actual height}=  Get window size
+    ${xdelta}=  evaluate  abs(int($actual_width)-int($expected_width))
+    ${ydelta}=  evaluate  abs(int($actual_height)-int($expected_height))
+    Run keyword if  $xdelta > 5 or $ydelta > 5
+    ...  Fail  Window size of ${actual width}x${actual height} is not close enough to expected ${expected width}x${expected height}
+
+*** Test Cases ***
+Open Test Browser Twice
+    [Documentation]  Verify that we can open two browsers in a single test
+    [Tags]  issue:1068
+    [Teardown]  Close all browsers
+
+    Assert active browser count  0
+    Open test browser
+    Open test browser  alias=browser2
+    Assert active browser count  2
+
+Browser aliases
+    [Documentation]  Verify that aliases are properly handled in Open Test Browser
+    [Tags]  issue:1068
+    [Teardown]  Close all browsers
+
+    # Open the default browser, go to a specific page and
+    # save the location
+    Open test browser  alias=browser1
+    Go to setup home
+    ${browser1 location}=  get location
+
+    # open a second browser to a different specific page
+    Open test browser  alias=browser2
+    Go to  about:blank
+
+    # Switch back to the first to verify that the location
+    # hasn't changed
+    Switch browser  browser1
+    Location should be  ${browser1 location}
+
+    # Go to a new location in the first browser,
+    Go to setup object manager
+
+    # ... and then verify the location of the second
+    # browser hasn't changed.
+    Switch browser  browser2
+    Location should be  about:blank
+
+
+Default browser size
+    [Documentation]  Verify that we automatically resize browser to minimum supported size
+    [Teardown]  Close all browsers
+
+    Open test browser
+    Assert window size  1280  1024
+
+Explicit browser size
+    [Documentation]  Verify we can set an explicit browser size when opening the window
+    [Teardown]  Close all browsers
+
+    Open test browser           size=1400x1200
+    Assert window size  1400  1200
+
+Open Test Browser calls Log Browser Capabilities
+    [Documentation]
+    ...  Verify that browser capabilities are logged when we call
+    ...  Open Test Browser
+    [Teardown]  Close all browsers
+
+    Reset test listener message log
+    Set test variable  ${BROWSER}  headlesschrome
+    Open test browser  alias=chrome
+    Assert robot log   selenium browser capabilities:  INFO
+    Assert robot log   browserName.*chrome
+
+    # Make sure we don't just log the capabilities of the
+    # first browser that was opened
+    Reset test listener message log
+    Set test variable  ${BROWSER}  headlessfirefox
+    Open test browser  alias=firefox
+    Assert robot log   selenium browser capabilities:  INFO
+    Assert robot log   browserName.*firefox
+
+
+Initializing selenium speed via global variable
+    [Documentation]
+    ...  Verify that the `Set Selenium Speed` is called when Open Test browser is called
+    [Setup]     Close all browsers
+    [Teardown]  Close all browsers
+
+    # First, verify that this variable has been initialized
+    # The default value is set in Salesforce.robot.
+    Variable should exist  ${SELENIUM_SPEED}
+
+    Open test browser
+    Assert keyword status  PASS  SeleniumLibrary.Set Selenium Speed  \${SELENIUM_SPEED}
+
+Select Window calls Switch Window
+    [Documentation]  Verify that 'Select Window' calls 'Switch Window'
+    ...              and also that it logs a deprecation warning
+    [Setup]          Run keywords
+    ...  Open test browser
+    ...  AND  go to setup home
+    ...  AND  execute javascript  window.open("about:blank", "window1")
+    [Teardown]       Close all browsers
+
+
+    Reset test listener message log
+    Select Window       window1
+    Assert robot log    'Select Window' is deprecated; use 'Switch Window' instead  WARN
+    location should be  about:blank
+
+    Reset test listener message log
+    Select Window       # defaults to the original window
+    Assert robot log    'Select Window' is deprecated; use 'Switch Window' instead  WARN
+    # let's make sure we actually are at the main window's location
+    Wait until location contains  /lightning/setup/SetupOneHome/home