w-mousekey 1.0.0

package/AutoHotkey_2.0.19/UX/ui-newscript.ahk

@@ -0,0 +1,296 @@
+#requires AutoHotkey v2.0
+
+#NoTrayIcon
+#SingleInstance Off
+
+#include inc\common.ahk
+#include inc\ui-base.ahk
+
+class NewScriptGui extends AutoHotkeyUxGui {
+    __new(path:="") {
+        super.__new("New Script")
+        
+        SplitPath path,, &dir,, &name
+        if this.ExplorerHwnd := WinActive("ahk_class CabinetWClass") {
+            this.Opt '+Owner' this.ExplorerHwnd
+            if dir = ""
+                dir := GetPathForExplorerWindow(this.ExplorerHwnd)
+        }
+        if dir = ""
+            dir := ConfigRead('New', 'DefaultDir', A_MyDocuments "\AutoHotkey")
+        
+        name := this.AddEdit('vName w272', name != "New AutoHotkey Script" ? name : "")
+        static EM_SETCUEBANNER := 0x1501
+        SendMessage(EM_SETCUEBANNER, true, StrPtr("Untitled"), name)
+        
+        static IconSize := SysGet(49) ; SM_CXSMICON
+        
+        static BrowseIcon := LoadPicture("imageres.dll", 'Icon-1025 w' IconSize, &imgtype)
+        this.AddIconButton('vBrowse x+0 yp-1 w28 hp+2', BrowseIcon, "&Browse")
+        .OnEvent('Click', 'Browse')
+        
+        this.AddEdit('vDir xm w300 r1 ReadOnly -TabStop', dir)
+        
+        static LVS_SHOWSELALWAYS := 8 ; Seems to have the opposite effect with Explorer theme, at least on Windows 11.
+        lv :=  this.AddListMenu("vLV xm w300 -" LVS_SHOWSELALWAYS, ["Name", "Desc", "Path", "Exec"])
+        lv.OnEvent('DoubleClick', 'DoubleClicked')
+        lv.OnEvent('ContextMenu', 'RightClicked')
+        
+        deft := GetDefaultTemplate()
+        lv.Add(deft = "" ? 'Select Focus' : '', "Empty", "Clean slate")
+        for ,t in this.Templates := GetScriptTemplates() {
+            if ConfigRead('New\HideTemplate', t.name, false)
+                continue
+            lv.Add(deft = t.name ? 'Select Focus' : '', t.name, t.desc)
+        }
+        
+        lv.AutoSize(8)
+        lv.GetPos(&x, &y, &w, &h)
+        
+        static DefaultsIcon := LoadPicture("imageres.dll", 'Icon-114 w' IconSize, &imgtype)
+        this.AddIconButton('vDefaults r1 w28 xm y' y + h + this.MarginY, DefaultsIcon, "&Defaults")
+        .OnEvent('Click', 'ChangeDefaults')
+        
+        this.AddButton('vCreate yp w75 x150', "&Create").OnEvent('Click', 'Confirm')
+        this.AddButton('vEdit Default yp wp xm+225', "&Edit").OnEvent('Click', 'Confirm')
+        if ConfigRead('New', 'DefaultButton', 'Edit') = 'Create'
+            this['Create'].Opt('Default')
+        
+        if this.ExplorerHwnd {
+            this.Show('AutoSize Hide')
+            WinGetPos(,, &gw, &gh, this)
+            WinGetPos(&x, &y, &ew, &eh)
+            WinMove(x + (ew - gw) // 2, y + (eh - gh) // 2,,, this)
+        }
+    }
+    
+    static __new() {
+        OnMessage(WM_KEYDOWN := 0x100, KeyDown)
+        KeyDown(wParam, lParam, nmsg, hwnd) {
+            static VK_UP := 0x26
+            static VK_DOWN := 0x28
+            if !(wParam = VK_UP || wParam = VK_DOWN)
+                return
+            gc := GuiCtrlFromHwnd(hwnd)
+            if gc.Gui is NewScriptGui && gc is Gui.Edit {
+                PostMessage nmsg, wParam, lParam, gc.Gui['LV']
+                return true
+            }
+        }
+    }
+    
+    Browse(*) {
+        path := this.FileSelect('S', this['Dir'].Value "\" this['Name'].Value, this.Title, "Script Files (*.ahk)")
+        if path = ""
+            return
+        SplitPath path, &name, &dir
+        this['Name'].Value := name
+        this['Dir'].Value := dir
+        this['LV'].Focus()
+    }
+    
+    ChangeDefaults(btn, *) {
+        lv := this["LV"]
+        
+        m := Menu()
+        m.Add "Default to Create", setDefBtn, "Radio"
+        m.Add "Default to Edit", setDefBtn, "Radio"
+        m.Add "Stay open", toggleStayOpen
+        if stayOpen := ConfigRead('New', 'StayOpen', false)
+            m.Check "Stay open"
+        m.Add
+        m.Add "Set folder as default", (*) => SetDefaultDir(this['Dir'].Value)
+        if this['Dir'].Value = GetDefaultDir()
+            m.Check "Set folder as default"
+        m.Add "Open templates folder", (*) => OpenTemplatesFolder()
+        
+        static DM_GETDEFID := 0x400
+        m.Check (1 + (SendMessage(DM_GETDEFID,,, this) & 0xFFFF = DllCall('GetDlgCtrlID', 'ptr', this['Edit'].Hwnd))) "&"
+        
+        this.Opt "-DPIScale"
+        btn.GetPos &x, &y, &w, &h
+        ;btn.Focus ; This would also apply the "default" style, which would not revert correctly.
+        ControlFocus btn
+        m.Show x, y + h
+        
+        setDefBtn(itemname, itempos, *) {
+            itemname := SubStr(itemname, 12)
+            this[itemname].Opt('Default')
+            ConfigWrite(itemname, 'New', 'DefaultButton')
+        }
+        toggleStayOpen(*) {
+            ConfigWrite(stayOpen := !stayOpen, 'New', 'StayOpen')
+        }
+    }
+    
+    Confirm(btn, *) {
+        lv := this['LV']
+        if !index := lv.GetNext()
+            return MsgBox("You need to select a template first.",, 'icon!')
+        t := index = 1 ? '' : this.Templates[lv.GetText(index)]
+        
+        stayOpen := GetKeyState('Ctrl') || ConfigRead('New', 'StayOpen', false)
+        
+        DirCreate dir := this['Dir'].Value
+        basename := this['Name'].Value
+        (basename != '') || basename := "Untitled"
+        SubStr(basename, -4) = ".ahk" && basename := SubStr(basename, 1, -4)
+        newPath := dir "\" basename ".ahk"
+        while FileExist(newPath)
+            newPath := dir "\" basename "-" A_Index ".ahk"
+        
+        if t && t.execute
+            RunWait Format('"{1}" "{2}" {3}', t.path, newPath, btn.Name), dir
+        else {
+            code := t = '' ? '' : FileRead(t.path)
+            code := RegExReplace(code, 'si)/\*\s+\[NewScriptTemplate\].*\*/\R?')
+            FileOpen(newPath, 'w', 'UTF-8').Write(code)
+        }
+        
+        if this.ExplorerHwnd && (xp := GetExplorerByHwnd(this.ExplorerHwnd))
+            || dir = A_Desktop && (xp := GetExplorerForDesktop()) {
+            SplitPath newPath, &basename
+            SelectExplorerItem xp, basename
+        }
+        else if btn.Name != 'Edit'
+            Run 'explorer /select,"' newPath '"'
+        
+        if btn.Name = 'Edit'
+            Run 'edit "' newPath '"'
+        
+        if !stayOpen
+            this.Hide
+    }
+    
+    RightClicked(lv, item, isRClick, x, y) {
+        if !item
+            return
+        t := item > 1 ? this.Templates[lv.GetText(item)] : {name: ''}
+        
+        m := Menu()
+        if item > 1 {
+            m.Add "&Edit template", (*) => EditTemplate(t)
+            m.Add "&Hide template", hideTemplate
+        }
+        m.Add "Set as &default", (*) => SetDefaultTemplate(t.name)
+        if t.name = GetDefaultTemplate()
+            m.Check "Set as &default"
+        m.Show x, y
+        
+        hideTemplate(*) {
+            ConfigWrite(true, 'New\HideTemplate', t.name)
+            lv.Delete item
+            static LVM_ARRANGE := 0x1016
+            SendMessage LVM_ARRANGE,,, lv ; Fill in any gap left by item (in Tile view).
+        }
+    }
+    
+    DoubleClicked(lv, row) {
+        if row
+            this.Confirm(this.GetDefaultButton())
+    }
+    
+    GetDefaultButton() {
+        static DM_GETDEFID := 0x400
+        hwnd := DllCall("GetDlgItem", "ptr", this.hwnd, "int", SendMessage(DM_GETDEFID,,, this) & 0xFFFF, "uint")
+        return hwnd && this[hwnd]
+    }
+}
+
+class NewScriptTemplate {
+    __new(path, name:="", description:="") {
+        this.path := path
+        if name = ""
+            SplitPath path,,,, &name
+        this.name := name
+        this.desc := IniRead(path, 'NewScriptTemplate', 'Description', description)
+        this.execute := false
+        switch IniRead(path, 'NewScriptTemplate', 'Execute', false) {
+        case true, "true": this.execute := true
+        }
+    }
+}
+
+OpenTemplatesFolder() {
+    dir := GetUserTemplateFolder(true)
+    if dir != ""
+        Run dir "\"
+}
+
+GetUserTemplateFolder(checkAndPrompt:=false) {
+    static dir := A_MyDocuments "\AutoHotkey\Templates"
+    if checkAndPrompt && !FileExist(dir) {
+        if MsgBox("User-created templates should be placed in the following folder, "
+                "which does not yet exist:`n`n" dir "`n`nCreate it now?",, "YesNo") = "No"
+            return
+        DirCreate dir
+    }
+    return dir
+}
+
+EditTemplate(t) {
+    dir := GetUserTemplateFolder(true)
+    if dir = ""
+        return
+    userPath := dir "\" t.name ".ahk"
+    if !FileExist(userPath) {
+        FileCopy t.path, userPath
+        t.path := userPath
+    }
+    Run 'edit "' userPath '"'
+}
+
+GetScriptTemplates() {
+    tmap := Map(), tmap.CaseSense := "off"
+    sources := [
+        A_ScriptDir "\Templates",
+        GetUserTemplateFolder()
+    ]
+    if FileExist(t := A_WinDir '\ShellNew\Template.ahk')
+        tmap["Legacy"] := NewScriptTemplate(t, "Legacy", "From " A_WinDir "\ShellNew")
+    for source in sources {
+        loop files source "\*.ahk" {
+            t := NewScriptTemplate(A_LoopFilePath)
+            tmap[t.name] := t
+        }
+    }
+    return tmap
+}
+
+SetDefaultTemplate(t) => ConfigWrite(t = "Empty" ? "" : t, 'New', 'DefaultTemplate')
+GetDefaultTemplate() => ConfigRead('New', 'DefaultTemplate', "")
+
+SetDefaultDir(dir) => ConfigWrite(dir, 'New', 'DefaultDir')
+GetDefaultDir() => ConfigRead('New', 'DefaultDir', A_MyDocuments "\AutoHotkey")
+
+SelectExplorerItem(e, name) {
+    sfv := e.Document
+    if fi := sfv.Folder.ParseName(name)
+        sfv.SelectItem(fi, 1|4|8|16)
+    return e
+}
+
+GetExplorerByHwnd(hwnd) {
+    for window in ComObject("Shell.Application").Windows
+        if window.hwnd = hwnd
+            return window
+}
+
+GetExplorerForDesktop() {
+    hwndBuf := Buffer(4, 0), hwndRef := ComValue(0x4003, hwndBuf.Ptr)
+    return ComObject("Shell.Application").Windows.FindWindowSW(0, "", 8, hwndRef, 1)
+}
+
+GetPathForExplorerWindow(hwnd) {
+    try return GetExplorerByHwnd(hwnd).Document.Folder.Self.Path
+}
+
+GetExplorerByPath(path) {
+    for window in ComObject("Shell.Application").Windows
+        try if window.Document.Folder.Self.Path = path
+            return window
+    return ""
+}
+
+if A_ScriptFullPath = A_LineFile
+    NewScriptGui.Show(A_Args.Length ? A_Args[1] : "")

package/AutoHotkey_2.0.19/UX/ui-setup.ahk

@@ -0,0 +1,175 @@
+; This script shows the initial setup GUI.
+; It is not intended for use after installation.
+#requires AutoHotkey v2.0
+
+#NoTrayIcon
+#SingleInstance Force
+
+#include inc\ui-base.ahk
+
+A_ScriptName := "AutoHotkey Setup"
+SetRegView 64
+InstallGui.Show()
+
+class InstallGui extends AutoHotkeyUxGui {
+    __new() {
+        super.__new(A_ScriptName, '-MinimizeBox -MaximizeBox')
+        
+        DllCall('uxtheme\SetWindowThemeAttribute', 'ptr', this.hwnd, 'int', 1 ; WTA_NONCLIENT
+            , 'int64*', 3 | (3<<32), 'int', 8) ; WTNCA_NODRAWCAPTION=1, WTNCA_NODRAWICON=2
+        
+        static TitleBack := 'BackgroundWhite'
+        static TitleFore := 'c3F627F'
+        static TotalWidth := 350
+        this.AddText('x0 y0 w' TotalWidth ' h84 ' TitleBack)
+        this.AddPicture('x32 y16 w32 h32 ' TitleBack, A_AhkPath)
+        this.SetFont('s12', 'Segoe UI')
+        this.AddText('x+20 yp+4 ' TitleFore ' ' TitleBack, "AutoHotkey v" A_AhkVersion)
+        this.SetFont('s9')
+        
+        ; SS_SUNKEN := 0x1000 ; 4096
+        this.AddText('x-4 y84 w' TotalWidth+4 ' h188 0x1000 -Background')
+        
+        this.AddText('xm yp+16', 'Install &to:')
+        dirEdit := this.AddEdit('vInstallDir w' TotalWidth - (2 * this.MarginX) - 88)
+        this.AddButton('vBrowseButton w80 x+8 yp-1', '&Browse')
+        .OnEvent('Click', 'Browse')
+        
+        rect := Buffer(16, 0)
+        DllCall('GetClientRect', 'ptr', dirEdit.hwnd, 'ptr', rect)
+        NumPut('int', 4, 'int', 2, rect)
+        ; DllCall('InflateRect', 'ptr', rect, 'int', 0, 'int', )
+        EM_SETRECT := 0xB3 ; 179
+        SendMessage 0xB3, 0, rect.ptr, dirEdit
+        
+        this.AddGroupBox('xm y+0 w' TotalWidth - (2 * this.MarginX) ' h44')
+        this.AddText('xp+8 yp+16', "Install mode:")
+        this.AddRadio('vModeAll x+m yp Checked', "&All users")
+        .OnEvent('Click', 'ModeChange')
+        this.AddRadio('vModeUser x+4', "&Current user")
+        .OnEvent('Click', 'ModeChange')
+        this.AddRadio('vModePortable x+4 Disabled', "Portable")
+        .OnEvent('Click', 'ModeChange')
+        
+        this.AddButton('vInstallButton x' (TotalWidth - 80) // 2 ' w80 y+36 Default', "&Install")
+        .OnEvent('Click', 'Install')
+        
+        this.ModeChange()
+        
+        this.MarginY := -1
+        this.Show('Hide w' TotalWidth)
+        this['InstallButton'].Focus()
+    }
+    
+    Browse(*) {
+        if ControlGetStyle(this['InstallDir']) & 0x800 { ; ES_READONLY
+            rootKey := this['ModeAll'].Value ? 'HKLM' : 'HKCU'
+            message := "Changing the installation directory is not recommended."
+            if InStr(RegRead(rootKey '\Software\AutoHotkey', 'Version', ''), '1.') = 1
+                message .= "`n`nThis installation package is designed to allow both v1 and v2 to be associated with .ahk files, but only if they are installed in the same directory."
+            message .= "`n`nExisting files will not be moved."
+            if MsgBox(message,, "OKCancel Icon!") != "OK"
+                return
+            this['InstallDir'].Opt('-ReadOnly')
+        }
+        dir := this.FileSelect('D', this['InstallDir'].Value '\', "Select installation directory")
+        if dir != '' {
+            this['InstallDir'].Value := dir
+            this.InstallDirChange()
+        }
+    }
+    
+    ModeChange(p*) {
+        if !this.CheckAlreadyInstalled(p.Length = 0, true) {
+            ; Ensure InstallDir makes sense for the new mode
+            installDir := this['InstallDir'].Value
+            if this['ModeAll'].Value {
+                if installDir = '' || installDir = InstallUtil.DefaultUserDir
+                    this['InstallDir'].Value := InstallUtil.DefaultAllDir, this['InstallDir'].Opt('-ReadOnly')
+            } else
+                if installDir = '' || IsInProgramFiles(installDir)
+                    this['InstallDir'].Value := InstallUtil.DefaultUserDir, this['InstallDir'].Opt('-ReadOnly')
+        }
+        this.UpdateShield()
+    }
+    
+    InstallDirChange(*) {
+        this.UpdateShield()
+    }
+    
+    UpdateShield() {
+        requireAdmin := this['ModeAll'].Value && !A_IsAdmin
+        SendMessage 0x160C, 0, requireAdmin, this['InstallButton'] ; BCM_SETSHIELD
+    }
+    
+    CheckAlreadyInstalled(setMode:=false, setDir:=false) {
+        for rootKey in setMode ? ['HKCU', 'HKLM'] : [this['ModeAll'].Value ? 'HKLM' : 'HKCU'] {
+            dir := RegRead(rootKey '\Software\AutoHotkey', 'InstallDir', '')
+            if dir != '' {
+                if setDir {
+                    this['InstallDir'].Value := dir
+                    this['InstallDir'].Opt('+ReadOnly')
+                }
+                if setMode
+                    this[A_Index = 1 ? 'ModeUser' : 'ModeAll'].Value := true
+                return dir
+            }
+        }
+        return ''
+    }
+    
+    Install(*) {
+        problem := ''
+        requireAdmin := this['ModeAll'].Value
+        installDir := this['InstallDir'].Value
+        buf := Buffer(260*2)
+        n := DllCall('GetFullPathName', 'str', installDir, 'uint', 260, 'ptr', buf, 'ptr', 0)
+        if !n || n > 259 {
+            MsgBox "Please enter a valid path.",, 'Icon!'
+            return
+        }
+        fullPath := StrGet(buf)
+        if installDir != fullPath {
+            problem .= '"' installDir '" resolves to "' fullPath '".`n`n'
+            installDir := fullPath
+        }
+        dir := this.CheckAlreadyInstalled()
+        if dir && dir != installDir
+            problem .= 'The existing installation in "' dir '" will not be moved or integrated with the new installation.`n`n'
+        if requireAdmin && !IsInProgramFiles(installDir) && dir != installDir
+            problem .= 'Enabling UI Access will not be possible because the installation directory is not a sub-directory of Program Files. Without UI Access, non-elevated scripts cannot interact with windows of elevated programs.`n`n'
+        if problem && MsgBox(problem,, 'OKCancel Default2 Icon!') = 'Cancel'
+            return
+        if A_IsCompiled && IsSet(Installation)
+            cmd := Format('"{1}" /to "{2}"', A_ScriptFullPath, installDir)
+        else
+            cmd := Format('"{1}" /script "{2}\install.ahk" /to "{3}"', A_AhkPath, A_ScriptDir, installDir)
+        if !requireAdmin
+            cmd .= ' /user'
+        else if !A_IsAdmin
+            cmd := '*RunAs ' cmd
+        try
+            Run cmd,,, &pid
+        catch as e {
+            if A_LastError != 1223 ; ERROR_CANCELLED
+                MsgBox e.Message "`n`n" e.Extra,, 'IconX'
+        } else {
+            this['InstallButton'].Enabled := false
+            this['InstallButton'].Text := "Installing..."
+            ProcessWaitClose pid
+            ExitApp
+        }
+    }
+}
+
+class InstallUtil {
+    static DefaultAllDir := (EnvGet('ProgramW6432') || A_ProgramFiles) '\AutoHotkey'
+    static DefaultUserDir := EnvGet('LocalAppData') '\Programs\AutoHotkey'
+    static DefaultDir := A_IsAdmin ? this.DefaultAllDir : this.DefaultUserDir
+}
+
+IsInProgramFiles(path) {
+    other := EnvGet(A_PtrSize=8 ? "ProgramFiles(x86)" : "ProgramW6432")
+    return InStr(path, A_ProgramFiles "\") = 1
+        || other && InStr(path, other "\") = 1
+}

package/AutoHotkey_2.0.19/UX/ui-uninstall.ahk

@@ -0,0 +1,68 @@
+; This script shows a GUI for uninstalling AutoHotkey or specific versions.
+#include inc\bounce-v1.ahk
+/* v1 stops here */
+#requires AutoHotkey v2.0
+
+#include inc\ui-base.ahk
+#include install.ahk
+
+#NoTrayIcon
+#SingleInstance Force
+
+A_ScriptName := "AutoHotkey Setup"
+SetRegView 64
+ModifySetupGui.Show()
+
+class ModifySetupGui extends AutoHotkeyUxGui {
+    __new() {
+        super.__new(A_ScriptName, '-MinimizeBox -MaximizeBox')
+        
+        this.inst := Installation()
+        this.inst.ResolveInstallDir()
+        versions := this.inst.GetComponents()
+
+        this.AddText(, "Remove which versions?")
+        iv := this.AddListView('vComponents Checked -Hdr R10 w248', ["Version"])
+        iv.OnEvent('ItemCheck', 'Checked')
+        for v, files in versions
+            iv.Add(files.HasProp('superseded') ? 'Check' : '', v)
+        
+        anyChecked := iv.GetNext(0, 'C')
+        this.AddButton('vRemoveAll w120 ' (anyChecked ? '' : 'Default'), "Remove &all")
+        .OnEvent('Click', 'ClickedRemove')
+        this.AddButton('vRemove w120 yp ' (anyChecked ? 'Default' : 'Disabled'), "Remove &checked")
+        .OnEvent('Click', 'ClickedRemove')
+        
+        if !this.inst.UserInstall && !A_IsAdmin {
+            SendMessage 0x160C,, true, 'Button1', this ; BCM_SETSHIELD := 0x160C
+            SendMessage 0x160C,, true, 'Button2', this
+        }
+    }
+    
+    ClickedRemove(btn, *) {
+        cmd := ''
+        if btn.Name = 'Remove' {
+            n := 0, iv := this['Components'], count := 0
+            while n := iv.GetNext(n, 'C')
+                cmd .= ',' iv.GetText(n), ++count
+            if count = iv.GetCount()
+                cmd := '' ; All are selected - do a full uninstall
+            else
+                cmd := ' "' SubStr(cmd, 2) '"'
+        }
+        cmd := Format('"{1}" "{2}\install.ahk" /uninstall{3}', A_AhkPath, A_ScriptDir, cmd)
+        if (!this.inst.UserInstall || A_Args.Length && A_Args[1] = '/elevate') && !A_IsAdmin
+            cmd := '*RunAs ' cmd
+        try {
+            Run cmd
+            ExitApp
+        }
+        catch as e
+            if !InStr(e.Message e.Extra, 'cancel')
+                throw e
+    }
+    
+    Checked(iv, *) {
+        this['Remove'].Enabled := iv.GetNext(0, 'C')
+    }
+}

package/AutoHotkey_2.0.19/WindowSpy.ahk

@@ -0,0 +1,2 @@
+#Requires AutoHotkey v2.0-beta
+#Include UX\WindowSpy.ahk