w-mousekey 1.0.0

package/AutoHotkey_2.0.19/UX/ui-dash.ahk

@@ -0,0 +1,200 @@
+; Dash: AutoHotkey's "main menu".
+; Run the script to show the GUI.
+#include inc\bounce-v1.ahk
+/* v1 stops here */
+#requires AutoHotkey v2.0
+
+#NoTrayIcon
+#SingleInstance Force
+
+#include inc\ui-base.ahk
+#include ui-launcherconfig.ahk
+#include ui-editor.ahk
+#include ui-newscript.ahk
+
+DashRegKey := 'HKCU\Software\AutoHotkey\Dash'
+
+class AutoHotkeyDashGui extends AutoHotkeyUxGui {
+    __new() {
+        super.__new("AutoHotkey Dash")
+        
+        lv := this.AddListMenu('vLV LV0x40 w250', ["Name", "Desc"])
+        lv.OnEvent("Click", "ItemClicked")
+        lv.OnEvent("ItemFocus", "ItemFocused")
+        lv.OnNotify(-155, "KeyPressed")
+        
+        this.AddButton("xp yp wp yp Hidden Default").OnEvent("Click", "EnterPressed")
+        
+        il := IL_Create(,, true)
+        lv.SetImageList(il, 0)
+        il2 := IL_Create(,, false)
+        lv.SetImageList(il2, 1)
+        addIcon(p*) =>(IL_Add(il, p*), IL_Add(il2, p*))
+        
+        lv.Add("Icon" addIcon(A_AhkPath, 2)
+            , "New script", "Create a script or manage templates")
+        lv.Add("Icon" addIcon("imageres.dll", -111)
+            , "Compile", "Open Ahk2Exe - convert .ahk to .exe")
+        lv.Add("Icon" addIcon("imageres.dll", -99)
+            , "Help files (F1)")
+        lv.Add("Icon" addIcon(A_ScriptDir '\inc\spy.ico', 1)
+            , "Window spy")
+        lv.Add("Icon" addIcon("imageres.dll", -116)
+            , "Launch settings", "Configure how .ahk files are opened")
+        lv.Add("Icon" addIcon("notepad.exe", 1)
+            , "Editor settings", "Set your default script editor")
+        ; lv.Add("Icon" addIcon("mmc.exe")
+        ;     , "Maintenance", "Repair settings or add/remove versions")
+        ; lv.Add(, "Auto-start", "Run scripts automatically at logon")
+        ; lv.Add(, "Downloads", "Get related tools")
+        
+        lv.AutoSize()
+        lv.GetPos(,,, &h)
+        
+        if !RegRead(DashRegKey, 'SuppressIntro', false) {
+            this.SetFont('s12')
+            this.AddText('yp x+m', "Welcome!")
+            this.SetFont('s9')
+            this.AddText('xp', "This is the Dash. It provides access to tools, settings and help files.")
+            this.AddText('xp', "To learn how to use AutoHotkey, refer to:")
+            this.AddLink('xp', "
+            (
+            `s   • <a href="Program.htm">Using the Program</a>
+                • <a href="howto/WriteHotkeys.htm">How to Write Hotkeys</a>
+                • <a href="howto/SendKeys.htm">How to Send Keystrokes</a>
+                • <a href="howto/RunPrograms.htm">How to Run Programs</a>
+                • <a href="howto/ManageWindows.htm">How to Manage Windows</a>
+                • <a href="index.htm#Quick_Reference">Quick Reference</a>
+            )").OnEvent('Click', 'LinkClicked')
+            
+            checkBox := this.AddCheckbox('Checked', "Show this info next time")
+            checkBox.GetPos(,,, &hc)
+            checkBox.Move(, h - hc)
+            checkBox.OnEvent('Click', 'SetIntroPref')
+        }
+        
+        this.Show("Hide h" (h + this.MarginY*2))
+    }
+    
+    LinkClicked(ctrl, id, href) {
+        if FileExist(chm := ROOT_DIR '\v2\AutoHotkey.chm')
+            Run 'hh.exe "ms-its:' chm '::docs/' href '"'
+        else
+            Run 'https://www.autohotkey.com/docs/v2/' href
+    }
+    
+    SetIntroPref(checkBox, *) {
+        if checkBox.Value { ; Show intro
+            try RegDelete(DashRegKey, 'SuppressIntro')
+        } else
+            RegWrite(true, 'REG_DWORD', DashRegKey, 'SuppressIntro')
+    }
+    
+    KeyPressed(lv, lParam) {
+        switch NumGet(lParam, A_PtrSize * 3, "Short") {
+        case 0x70: ; F1
+            ShowHelpFile()
+        }
+    }
+    
+    EnterPressed(*) {
+        lv := this["LV"]
+        this.ItemClicked(lv, lv.GetNext(,'F'))
+    }
+    
+    ItemClicked(lv, item) {
+        switch item && RegExReplace(lv.GetText(item), ' .*') {
+        case "New":
+            NewScriptGui.Show()
+        case "Compile":
+            if WinExist("Ahk2Exe ahk_class AutoHotkeyGUI")
+                WinActivate
+            else if FileExist(ROOT_DIR '\Compiler\Ahk2Exe.exe')
+                Run '"' ROOT_DIR '\Compiler\Ahk2Exe.exe"'
+            else
+                Run Format('"{1}" /script "{2}\install-ahk2exe.ahk"', A_AhkPath, A_ScriptDir)
+        case "Help":
+            ShowHelpFile()
+        case "Window":
+            try {
+                Run '"' A_MyDocuments '\AutoHotkey\WindowSpy.ahk"'
+                return
+            }
+            static AHK_FILE_WINDOWSPY := 0xFF7A ; 65402
+            static WM_COMMAND := 0x111 ; 273
+            SendMessage WM_COMMAND, AHK_FILE_WINDOWSPY, 0, A_ScriptHwnd
+            if WinWait("Window Spy ahk_class AutoHotkeyGUI",, 1)
+                WinActivate
+        case "Launch":
+            LauncherConfigGui.Show()
+        case "Editor":
+            DefaultEditorGui.Show()
+        }
+    }
+    
+    ItemFocused(lv, item) {
+        static WM_CHANGEUISTATE := 0x127 ; 295
+        SendMessage WM_CHANGEUISTATE, 0x10001, 0, lv
+    }
+}
+
+ShowHelpFile() {
+    SetWorkingDir ROOT_DIR
+    main := Map(), sub := Map()
+    other := Map(), other.CaseSense := "off"
+    hashes := ReadHashes('UX\installed-files.csv', item => item.Path ~= 'i)\.chm$')
+    Loop Files "*.chm", "FR" {
+        SplitPath A_LoopFilePath,, &dir,, &name
+        if name = "AutoHotkey" {
+            if !(f := hashes.Get(A_LoopFilePath, false))
+                continue
+            v := GetMajor(f.Version)
+            if !(cur := main.Get(v, false)) || VerCompare(cur.Version, f.Version) < 0
+                main[v] := f
+            sub[f.Version] := f
+        }
+        else
+            other[A_LoopFilePath] := name (dir != "" && name != dir ? " (" dir ")" : "")
+    }
+    
+    if sub.Count = 1 && other.Count = 0 {
+        for , f in main { ; Don't bother showing online options in this case.
+            Run f.Path
+            return
+        }   
+    }
+    
+    m := Menu()
+    if main.Count {
+        m.Add "Offline help", (*) => 0
+        m.Disable "1&"
+    }
+    for , f in main {
+        m.Add "v&" f.Version, openIt.Bind(f.Path)
+        sub.Delete(f.Version)
+    }
+    if sub.Count {
+        subm := Menu()
+        for , f in sub
+            subm.Insert "1&", "v" f.Version, openIt.Bind(f.Path)
+        m.Add "More", subm
+    }
+    
+    m.Add "Online help", (*) => 0
+    m.Disable "Online help"
+    prefix := main.Count ? "v" : "v&"
+    m.Add prefix "1.1", (*) => Run("https://www.autohotkey.com/docs/v1/")
+    m.Add prefix "2.0", (*) => Run("https://www.autohotkey.com/docs/v2/")
+    
+    if other.Count {
+        m.Add "Other files", (*) => 0
+        m.Disable "Other files"
+    }
+    for f, t in other
+        m.Add t, openIt.Bind(f)
+    
+    m.Show
+    openIt(f, *) => Run(f)
+}
+
+AutoHotkeyDashGui.Show()

package/AutoHotkey_2.0.19/UX/ui-editor.ahk

@@ -0,0 +1,238 @@
+; This script shows a GUI for setting the default .ahk editor.
+#requires AutoHotkey v2.0
+
+#NoTrayIcon
+#SingleInstance Off
+
+#include launcher.ahk
+#include inc\CommandLineToArgs.ahk
+
+class EditorSelectionGui extends AutoHotkeyUxGui {
+    __new(cmdLine) {
+        super.__new("Select an editor")
+        
+        lv := this.AddListMenu('vEds LV0x40 w300', ["Editor"])
+        this.IconList := il := IL_Create(,, true)
+        lv.SetImageList(il, 0)
+        for app in this.Apps := GetEditorApps() {
+            try
+                icon := IL_Add(il, app.exe)
+            catch
+                icon := -1
+            lv.Add('Icon' icon, app.name)
+        }
+        this.SelectEditorByCmd(cmdLine)
+        lv.AutoSize(8)
+        lv.GetPos(&x, &y, &w, &h)
+        x += w
+        y += h
+        
+        this.AddText('xm w' w ' y' y, "Command line")
+        this.AddEdit('xm wp r2 -WantReturn vCmd', cmdLine).OnEvent('Change', 'CmdChanged')
+        
+        this.AddText('xm h25 18 w' w)
+        this.AddPicture('x56 Icon-81 w16 yp+4', "imageres.dll")
+        this.AddLink('x76 yp-1', "<a>Editors with AutoHotkey support</a>")
+            .OnEvent('Click', 'ShowHelpEditors')
+        
+        this.AddButton('xm w80', "&Browse").OnEvent('Click', 'Browse')
+        this.AddButton('Default yp w80 x' x - 160 - this.MarginY, "&OK").OnEvent('Click', 'Confirm')
+        this.AddButton('yp w80 x' x - 80, "&Cancel").OnEvent('Click', (c, *) => c.Gui.Hide())
+        
+        this["Eds"].OnEvent("ItemFocus", "EditorSelected")
+        this.CmdChanged()
+    }
+    
+    ShowHelpEditors(*) {
+        if FileExist(chm := ROOT_DIR '\v2\AutoHotkey.chm')
+            Run 'hh.exe "ms-its:' chm '::docs/misc/Editors.htm"'
+        else
+            Run 'https://www.autohotkey.com/docs/v2/misc/Editors.htm'
+    }
+    
+    Browse(*) {
+        app := this.FileSelect(3,,, "Apps (*.exe; *.ahk)")
+        if app = ""
+            return
+        this['Cmd'].Value := this.GetAppCmd(app)
+        this.CmdChanged()
+    }
+    
+    GetAppCmd(app) {
+        SplitPath app,,, &ext
+        if ext != "ahk"
+            return Format('"{1}" "%l"', app)
+        lp := GetLaunchParameters(app, true)
+        if !lp.exe
+            return ""
+        ; Try to use a path that will work if the user installs a new version and removes this one
+        ; (rather than invoking the launcher every time the edit verb is executed).
+        adaptivePath := RegExReplace(lp.exe.Path, lp.v = 1 ? '\\v1[^\\]*(?=\\[^\\]*$)' : '\\v2\K[^\\]+(?=\\[^\\]*$)')
+        trace '![Launcher] ' adaptivePath
+        try
+            adaptiveExe := GetExeInfo(adaptivePath)
+        if !IsSet(adaptiveExe) || VerCompare(adaptiveExe.Version, lp.v) < 0
+            adaptivePath := ""
+        cmd := Format('"{}"', FileExist(adaptivePath) ? adaptivePath : lp.exe.Path)
+        for sw in lp.switches
+            cmd .= ' ' sw
+        return cmd .= Format(' "{}" "%l"', app)
+    }
+    
+    EditorSelected(lv, index) {
+        this['Cmd'].Value := this.Apps[index].cmd
+        this.CmdChanged()
+    }
+    
+    CmdChanged(ctrl:=unset, *) {
+        if IsSet(ctrl) && n := this['Eds'].GetNext()
+            this['Eds'].Modify(n, '-Select')
+        cmd := this['Cmd'].Value
+        this['OK'].Enabled := cmd != "" && FindExecutable(CommandLineToArgs(cmd)[1]) != ""
+    }
+    
+    SelectEditorByCmd(cmd) {
+        if cmd = ""
+            return
+        for app in this.Apps {
+            if app.cmd = cmd {
+                this['Eds'].Modify(A_Index, 'Focus Select')
+                return
+            }
+        }
+        ; App not in the list, so add it.
+        args := CommandLineToArgs(cmd)
+        try {
+            exe := GetExeInfo(FindExecutable(args.RemoveAt(1)))
+            app := {cmd: cmd, exe: exe.Path, name: exe.Description}
+            if SubStr(app.name, 1, 10) = "AutoHotkey" && (ahk := ahkArg(args)) {
+                ; The app itself appears to be a script, so show the script name.
+                app.name := ahk
+            }
+            this.Apps.Push(app)
+            try
+                icon := IL_Add(this.IconList, app.exe, IsSet(ahk) && ahk ? 2 : 1)
+            catch
+                icon := -1
+            this['Eds'].Add('Focus Select Icon' icon, app.name)
+        }
+        
+        ahkArg(args) {
+            for arg in args {
+                if SubStr(arg, 1, 1) = '/'
+                    continue
+                return SubStr(arg, -4) = '.ahk' ? arg : ''
+            }
+            return ''
+        }
+    }
+    
+    Confirm(*) {
+        this.Hide()
+        this.OnConfirm(this['Cmd'].Value)
+    }
+}
+
+class DefaultEditorGui extends EditorSelectionGui {
+    __new(scriptToEdit:=unset) {
+        cmd := RegRead('HKCR\AutoHotkeyScript\shell\edit\command',, '')
+        if InStr(cmd, A_LineFile)
+            cmd := ''
+        super.__new(cmd)
+        if IsSet(scriptToEdit)
+            this.ScriptToEdit := scriptToEdit
+    }
+    
+    OnConfirm(cmd) {
+        RegWrite(cmd, 'REG_SZ', 'HKCU\Software\Classes\AutoHotkeyScript\shell\edit\command')
+        if this.HasProp('ScriptToEdit')
+            Run('edit "' this.ScriptToEdit '"')
+    }
+}
+
+GetEditorApps() {
+    apps := []
+    apps.byName := Map(), apps.byName.CaseSense := 'off'
+    addAssoc(assoc, flag, src) {
+        static ASSOCSTR_COMMAND := 1
+        static ASSOCSTR_EXECUTABLE := 2
+        static ASSOCSTR_FRIENDLYAPPNAME := 4
+        try {
+            name := AssocQueryString(flag, ASSOCSTR_FRIENDLYAPPNAME, assoc)
+            exe := AssocQueryString(flag, ASSOCSTR_EXECUTABLE, assoc)
+        }
+        if !IsSet(exe) || name ~= 'i)^AutoHotkey|^Ahk2Exe'
+            return
+        try
+            cmd := AssocQueryString(flag, ASSOCSTR_COMMAND, assoc)
+        catch
+            cmd := '"' exe '" "%l"'
+        else if cmd = ""
+            return
+        if !(InStr(cmd, "%1") || InStr(cmd, "%l"))
+            cmd .= ' "%l"'
+        if name = "NOTEPAD.EXE"
+            name := "Notepad"
+        if apps.byName.Has(name)
+            return
+        app := {cmd: cmd, exe: exe, name: name}
+        apps.byName[name] := app
+        apps.Push(app)
+    }
+    addAppExe(app, src) {
+        static ASSOCF_INIT_BYEXENAME := 2 ; 0x2
+        addAssoc app, ASSOCF_INIT_BYEXENAME, src
+    }
+    addProgId(app, src) {
+        addAssoc app, 0, src
+    }
+    
+    for ext in ["ahk", "txt"] {
+        owl := "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\." ext "\OpenWithList"
+        mru := RegRead(owl, "MRUList", "")
+        Loop Parse mru {
+            if app := RegRead(owl, A_LoopField, "")
+                addAppExe app, "Explorer\." ext "\OWL"
+        }
+        Loop Reg "HKCR\." ext "\OpenWithProgIds", "V" {
+            addProgId A_LoopRegName, "HKCR\." ext "\OWPI"
+        }
+        Loop Reg "HKCR\." ext "\OpenWithList", "K" {
+            if !InStr(A_LoopRegName, "Ahk2Exe")
+                addAppExe A_LoopRegName, "HKCR\." ext "\OWL"
+        }
+    }
+    addAppExe "notepad.exe", "explicit"
+    return apps
+}
+
+; Return the path of an executable file, if given something that could be executed
+; in a shell verb (excluding args).  Although shell verb commands require an exe,
+; they do also look in \App Paths\, like ShellExecute, unlike CreateProcess.
+FindExecutable(name) {
+    if SubStr(name, -4) != ".exe"  ; For odd cases like 'notepad "%1"'
+        name .= ".exe"
+    if FileExist(name)
+        return name
+    if InStr(name, "\") || InStr(name, ":")
+        return ""
+    buf := Buffer(260*2)
+    if DllCall("shell32\FindExecutable", "str", name, "ptr", 0, "ptr", buf, "uint") > 32 ; "Returns a value greater than 32 if successful"
+        return StrGet(buf)
+    static AppPaths := '\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\'
+    path := RegRead('HKCU' AppPaths name,, '') || RegRead('HKLM' AppPaths name,, '')
+    ; The system permits quotes, and some applications are registered that way.
+    return StrReplace(path, '"')
+}
+
+AssocQueryString(flags, strtype, assoc) {
+    DllCall("shlwapi\AssocQueryStringW", "int", flags, "int", strtype, "wstr", assoc
+        , "ptr", 0, "ptr", 0, "uint*", &bufsize := 0, "hresult")
+    buf := Buffer(bufsize * 2)
+    DllCall("shlwapi\AssocQueryStringW", "int", flags, "int", strtype, "wstr", assoc
+        , "ptr", 0, "ptr", buf, "uint*", &bufsize, "hresult")
+    return StrGet(buf, "UTF-16")
+}
+
+if A_LineFile = A_ScriptFullPath
+    DefaultEditorGui.Show(A_Args*)

package/AutoHotkey_2.0.19/UX/ui-launcherconfig.ahk

@@ -0,0 +1,195 @@
+; This script shows a GUI for configuring the launcher.
+#requires AutoHotkey v2.0
+
+#NoTrayIcon
+
+#include inc\launcher-common.ahk
+#include inc\ui-base.ahk
+
+GetVersions() {
+    vmap := Map(1, Map(), 2, Map())
+    vmap.UIA := false ; Just detect whether any are present for now, to cover the most common cases (UIA supported by all or none).
+    for ,f in GetUsableAutoHotkeyExes() {
+        try {
+            vmap[GetMajor(f.Version)][f.Version] := true
+            if SubStr(f.Path, -8) = "_UIA.exe"
+                vmap.UIA := true
+        }
+        catch as e
+            trace "-[Launcher] " type(e) " checking file " A_LoopFileName ": " e.message
+    }
+    vmap[1] := [vmap[1]*]
+    vmap[2] := [vmap[2]*]
+    return vmap
+}
+
+class LauncherConfigGui extends AutoHotkeyUxGui {
+    __new() {
+        super.__new("AutoHotkey Launch Config")
+        
+        cmd := RegRead('HKCR\AutoHotkeyScript\shell\open\command',, '')
+        usingLauncher := InStr(cmd, 'UX\launcher.ahk') != 0
+        currentExe := !usingLauncher && RegExMatch(cmd, '^"(.*?)"(?= )', &m) ? m.1 : ""
+        try
+            if currentExe && GetExeInfo(currentExe).Description = "AutoHotkey Launcher" ; Support compiled launcher
+                usingLauncher := true, currentExe := ""
+        if InStr(currentExe, '\AutoHotkeyUX.exe')
+            currentExe := "" ; Don't default to AutoHotkeyUX.exe when disabling launcher
+        
+        versions := GetVersions()
+        
+        ; this.AddCheckbox("Checked", "Enable drag && drop on .ahk files")
+        
+        this.AddRadio('vUseLauncher Checked' usingLauncher, "Auto-detect version when launching script")
+        .OnEvent('Click', 'ChangedMode')
+        this.AddRadio('vUseSpecific Checked' (!usingLauncher), "Run all scripts with a specific interpreter")
+        .OnEvent('Click', 'ChangedMode')
+        
+        tab := this.AddTab('w0 h0 y+0 vTab -TabStop', ["Launcher", "Specific"])
+        
+        tab.UseTab(1)
+        this.AddText('xm yp+12 Section', "Preferred interpreter by major version")
+        this.AddDDL('vVersion1 y+3 w110 Choose1', ["Latest 1.x", versions[1]*])
+        .OnEvent('Change', "ChangedVersion")
+        this.AddComboBox('vBuild1 yp w150', ["Unicode 64-bit", "Unicode 32-bit", "ANSI 32-bit"])
+        .OnEvent('Change', 'ChangedBuild')
+        this.AddCheckBox('vUIA1 x+m yp+2 Disabled' (!versions.UIA), "UI Access")
+        .OnEvent('Click', 'ChangedUIA')
+        this.AddDDL('vVersion2 xs w110 Choose1', ["Latest 2.x", versions[2]*])
+        .OnEvent('Change', 'ChangedVersion')
+        this.AddComboBox('vBuild2 yp w150', ["64-bit", "32-bit"])
+        .OnEvent('Change', 'ChangedBuild')
+        this.AddCheckBox('vUIA2 x+m yp+2 Disabled' (!versions.UIA), "UI Access")
+        .OnEvent('Click', 'ChangedUIA')
+        this.AddText('xs y+m+8', "When detection fails")
+        this.AddDDL('vFallback y+3 w110 Choose3', ["Use v1.x", "Use v2.x", "Ask the user"])
+        .OnEvent('Change', "ChangedFallback")
+        this.AddCheckbox('vIdentify xs y+m+8 Checked', "Try to identify version based on syntax")
+        .OnEvent('Click', (c, *) => ConfigWrite(c.Value, 'Launcher', 'Identify'))
+        this.AddCheckbox('vLauncherUTF8 xs Checked', "Default to UTF-8 even for v1 scripts")
+        .OnEvent('Click', (c, *) => ConfigWrite(c.Value, 'Launcher\v1', 'UTF8'))
+        
+        tab.UseTab(2)
+        exeBox := this.AddEdit('vExePath xs ys w326 ReadOnly')
+        if currentExe
+            exeBox.Text := currentExe
+        else if FileExist(f := ROOT_DIR '\v2\AutoHotkey' (A_Is64bitOS ? '64' : '32') '.exe')
+            exeBox.Text := f
+        
+        static BrowseIcon := LoadPicture("imageres.dll", 'Icon-1025 w' SysGet(49), &imgtype)
+        this.AddIconButton('vBrowse x+0 yp-1 w28 hp+2', BrowseIcon, "&Browse")
+        .OnEvent('Click', 'BrowseForExe')
+        
+        this.AddCheckBox('vCustomUTF8 xm y+m+4 Hidden', "Default to UTF-8")
+        .OnEvent('Click', 'UpdateVerbs')
+        
+        tab.UseTab()
+        this.AddButton('vClose x292 w70 Default', "&Close")
+        .OnEvent('Click', (ctrl, *) => ctrl.Gui.Hide())
+        
+        ; size := 32 * A_ScreenDPI // 96
+        ; DllCall("comctl32\LoadIconWithScaleDown", "ptr", 0, "int", 32514, "int", size, "int", size, "ptr*", &icon:=0, "hresult")
+        ; help := this.AddButton('0x40 x322 ym w' 40 ' h' 40)
+        ; SendMessage(0xF7, 1, icon, help)
+        
+        tab.Choose(usingLauncher ? 1 : 2)
+        
+        Loop 2 {
+            section := 'Launcher\v' A_Index
+            v := ConfigRead(section, 'Version', '')
+            try this['Version' A_Index].Text := v || 'Latest ' A_Index '.x'
+            try this['Build' A_Index].Text := ConfigRead(section, 'Build', '')
+            try this['UIA' A_Index].Value := ConfigRead(section, 'UIA', false)
+            if this['Build' A_Index].Text = ""
+                ControlChooseIndex(1, this['Build' A_Index])
+        }
+        v := ConfigRead('Launcher', 'Fallback', '')
+        IsInteger(v) && this['Fallback'].Value := v
+        this['Identify'].Value := ConfigRead('Launcher', 'Identify', true)
+        this['LauncherUTF8'].Value := ConfigRead('Launcher\v1', 'UTF8', false)
+        
+        this.ChangedMode()
+        this.ChangedExe()
+    }
+    
+    ChangedMode(sourceCtrl:=false, *) {
+        usingLauncher := this['UseLauncher'].Value
+        this['Tab'].Choose(usingLauncher ? 1 : 2)
+        this[usingLauncher ? 'LauncherUTF8' : 'CustomUTF8'].GetPos(, &y1, , &h1)
+        this['Close'].GetPos(,,, &h2)
+        this['Close'].Move(, y1)
+        this.Show('h' (y1 + h2 + 10))
+        if sourceCtrl
+            this.UpdateVerbs()
+    }
+    
+    ChangedExe() {
+        exe := this['ExePath'].Text
+        if exe = ""
+            return
+        try
+            exeVersion := FileGetVersion(exe)
+        catch {
+            MsgBox "The selected EXE appears to be invalid.`n`nSpecifically: " exe,, 'Icon!'
+            return
+        }
+        if !this['CustomUTF8'].Visible && this['LauncherUTF8'].Value
+            this['CustomUTF8'].Value := true
+        this['CustomUTF8'].Visible := VerCompare(exeVersion, '2') < 0
+    }
+    
+    ChangedVersion(ctrl, *) =>
+        ConfigWrite(ctrl.Value = 1 ? '' : ctrl.Text, 'Launcher\v' SubStr(ctrl.Name, -1), 'Version')
+    
+    ChangedBuild(ctrl, *) =>
+        ConfigWrite(ctrl.Text, 'Launcher\v' SubStr(ctrl.Name, -1), 'Build')
+    
+    ChangedUIA(ctrl, *) =>
+        ConfigWrite(ctrl.Value, 'Launcher\v' SubStr(ctrl.Name, -1), 'UIA')
+    
+    ChangedFallback(ctrl, *) =>
+        ConfigWrite(ctrl.Value = 3 ? '' : ctrl.Value, 'Launcher', 'Fallback')
+    
+    BrowseForExe(*) {
+        exe := this.FileSelect('3', this['ExePath'].Text, "Select an AutoHotkey.exe", "EXE Files (*.exe)")
+        if exe = ""
+            return
+        this['ExePath'].Text := exe
+        this.ChangedExe()
+        this.UpdateVerbs()
+    }
+    
+    UpdateVerbs(*) {
+        ; FIXME: reg key and FriendlyAppName should be defined in only one place
+        static key := 'HKCU\Software\Classes\AutoHotkeyScript\Shell\'
+        if this['UseLauncher'].Value {
+            cmd := Format('"{1}" "{2}\launcher.ahk" "%1" %*', A_AhkPath, A_ScriptDir)
+            appname := "AutoHotkey Launcher"
+        } else {
+            exe := this['ExePath'].Text
+            if exe = ""
+                return
+            if !FileExist(exe)
+                throw
+            exe_uia := SubStr(exe, 1, -4) "_UIA.exe"
+            switches := this['CustomUTF8'].Visible && this['CustomUTF8'].Value ? '/cp65001 ' : ''
+            cmd := Format('"{1}" {2}"%1" %*', exe, switches)
+            ; Deleting FriendlyAppName from HKCU won't work if the installer uses HKLM,
+            ; so explicitly set it to the file's description
+            appname := GetExeInfo(exe).Description
+        }
+        RegWrite appname, 'REG_SZ', key 'Open', 'FriendlyAppName'
+        RegWrite cmd, 'REG_SZ', key 'Open\Command'
+        RegWrite cmd, 'REG_SZ', key 'RunAs\Command'
+        if RegRead('HKCR\AutoHotkeyScript\Shell\UIAccess\Command',, '') {
+            if IsSet(exe_uia) && FileExist(exe_uia)
+                cmd := StrReplace(cmd, exe, exe_uia)
+            else
+                cmd := Format('"{1}" "{2}\launcher.ahk" /runwith UIA "%1" %*', A_AhkPath, A_ScriptDir)
+            RegWrite cmd, 'REG_SZ', key 'UIAccess\Command'
+        }
+    }
+}
+
+if A_ScriptFullPath = A_LineFile
+    LauncherConfigGui.Show()