w-mousekey 1.0.0

package/.editorconfig

@@ -0,0 +1,9 @@
+root = true
+
+[*]
+charset = utf-8
+indent_style = space
+indent_size = 4
+end_of_line = lf
+insert_final_newline = true
+trim_trailing_whitespace = true

package/.eslintignore

@@ -0,0 +1,3 @@
+/build/
+/config/
+/dist/

package/.eslintrc.js

@@ -0,0 +1,55 @@
+module.exports = {
+    'env': {
+        'browser': true,
+        'es6': true,
+        'mocha': true
+    },
+    'extends': ['plugin:vue/base', 'plugin:vue/essential', 'standard'],
+    'plugins': [
+        'vue'
+    ],
+    'globals': {
+        'Atomics': 'readonly',
+        'SharedArrayBuffer': 'readonly'
+    },
+    'parser': 'vue-eslint-parser',
+    'parserOptions': {
+        'parser': '@babel/eslint-parser',
+        'ecmaVersion': 2019,
+        'sourceType': 'module',
+    },
+    'rules': {
+        'generator-star-spacing': 'off',
+        'no-debugger': process.env.NODE_ENV === 'production' ? 'error' : 'off',
+        'indent': ['error', 4],
+        'no-console': 'off',
+        'comma-dangle': ['error', {
+            'arrays': 'ignore',
+            'objects': 'ignore',
+            'imports': 'never',
+            'exports': 'never',
+            'functions': 'ignore'
+        }],
+        'no-multiple-empty-lines': ['error', { 'max': 2, 'maxEOF': 2 }],
+        //'space-before-function-paren': ['error', { 'anonymous': 'always', 'named': 'never' }],
+        'space-before-function-paren': 'off',
+        'spaced-comment': 'off',
+        'brace-style': ['error', 'stroustrup'],
+        'padded-blocks': 'off',
+        'no-constant-condition': 'off',
+        'camelcase': 'off',
+        'no-new': 'off',
+        'prefer-const': 'off',
+        'quote-props': ['error', 'consistent'],
+        'dot-notation': 'off',
+        'standard/no-callback-literal': 'off',
+        'quotes': ['error', 'single', { 'allowTemplateLiterals': true }],
+        'prefer-promise-reject-errors': 'off',
+        'no-unused-vars': ['error', { 'args': 'none', 'ignoreRestSiblings': true, 'argsIgnorePattern': '^_' }],
+        'node/no-callback-literal': 'off',
+        'prefer-regex-literals': 'off',
+        'array-callback-return': 'off',
+        'no-unreachable-loop': 'off',
+        'vue/multi-word-component-names': 'off',
+    }
+}

package/.jsdoc

@@ -0,0 +1,25 @@
+{
+    "tags": {
+        "allowUnknownTags": false
+    },
+    "source": {
+        "include": ["src/", "server/"],
+        "includePattern": ".+\\.(js(doc|x)?|mjs|vue)$",
+        "excludePattern": "(node_modules/|docs)"
+    },
+    "plugins": [
+        "plugins/markdown",
+        "node_modules/jsdoc-vuejs"
+    ],
+    "opts": {
+        "template": "node_modules/docdash",
+        "encoding": "utf8",
+        "destination": "docs/",
+        "recurse": true,
+        "verbose": true
+    },
+    "templates": {
+        "cleverLinks": false,
+        "monospaceLinks": false
+    }
+}

package/AutoHotkey_2.0.19/Install.cmd

@@ -0,0 +1,2 @@
+@echo off
+start "" "%~dp0AutoHotkey32.exe" "%~dp0UX\ui-setup.ahk"

package/AutoHotkey_2.0.19/UX/Templates/Minimal for v2.ahk

@@ -0,0 +1,6 @@
+/*
+[NewScriptTemplate]
+Description = Just #Requires v2.0
+*/
+#Requires AutoHotkey v2.0
+

package/AutoHotkey_2.0.19/UX/WindowSpy.ahk

@@ -0,0 +1,246 @@
+; 
+; Window Spy for AHKv2
+;
+
+#Requires AutoHotkey v2.0
+
+#NoTrayIcon
+#SingleInstance Ignore
+SetWorkingDir A_ScriptDir
+CoordMode "Pixel", "Screen"
+
+Global oGui
+
+WinSpyGui()
+
+WinSpyGui() {
+    Global oGui
+    
+    try TraySetIcon "inc\spy.ico"
+    DllCall("shell32\SetCurrentProcessExplicitAppUserModelID", "wstr", "AutoHotkey.WindowSpy")
+    
+    oGui := Gui("AlwaysOnTop Resize MinSize +DPIScale","Window Spy for AHKv2")
+    oGui.OnEvent("Close",WinSpyClose)
+    oGui.OnEvent("Size",WinSpySize)
+    
+    oGui.SetFont('s9', "Segoe UI")
+    
+    oGui.Add("Text",,"Window Title, Class and Process:")
+    oGui.Add("Checkbox","yp xp+200 w120 Right vCtrl_FollowMouse","Follow Mouse").Value := 1
+    oGui.Add("Edit","xm w320 r5 ReadOnly -Wrap vCtrl_Title")
+    oGui.Add("Text",,"Mouse Position:")
+    oGui.Add("Edit","w320 r4 ReadOnly vCtrl_MousePos")
+    oGui.Add("Text","w320 vCtrl_CtrlLabel",(txtFocusCtrl := "Focused Control") ":")
+    oGui.Add("Edit","w320 r4 ReadOnly vCtrl_Ctrl")
+    oGui.Add("Text",,"Active Window Position:")
+    oGui.Add("Edit","w320 r2 ReadOnly vCtrl_Pos")
+    oGui.Add("Text",,"Status Bar Text:")
+    oGui.Add("Edit","w320 r2 ReadOnly vCtrl_SBText")
+    oGui.Add("Checkbox","vCtrl_IsSlow","Slow TitleMatchMode")
+    oGui.Add("Text",,"Visible Text:")
+    oGui.Add("Edit","w320 r2 ReadOnly vCtrl_VisText")
+    oGui.Add("Text",,"All Text:")
+    oGui.Add("Edit","w320 r2 ReadOnly vCtrl_AllText")
+    oGui.Add("Text","w320 r1 vCtrl_Freeze",(txtNotFrozen := "(Hold Ctrl or Shift to suspend updates)"))
+    
+    oGui.Show("NoActivate")
+    WinGetClientPos(&x_temp, &y_temp2,,,"ahk_id " oGui.hwnd)
+    
+    ; oGui.horzMargin := x_temp*96//A_ScreenDPI - 320 ; now using oGui.MarginX
+    
+    oGui.txtNotFrozen := txtNotFrozen       ; create properties for futur use
+    oGui.txtFrozen    := "(Updates suspended)"
+    oGui.txtMouseCtrl := "Control Under Mouse Position"
+    oGui.txtFocusCtrl := txtFocusCtrl
+    
+    SetTimer Update, 250
+}
+
+WinSpySize(GuiObj, MinMax, Width, Height) {
+    Global oGui
+    
+    If !oGui.HasProp("txtNotFrozen") ; WinSpyGui() not done yet, return until it is
+        return
+    
+    SetTimer Update, (MinMax=0)?250:0 ; suspend updates on minimize
+    
+    ctrlW := Width - (oGui.MarginX * 2) ; ctrlW := Width - horzMargin
+    list := "Title,MousePos,Ctrl,Pos,SBText,VisText,AllText,Freeze"
+    Loop Parse list, ","
+        oGui["Ctrl_" A_LoopField].Move(,,ctrlW)
+}
+
+WinSpyClose(GuiObj) {
+    ExitApp
+}
+
+Update() { ; timer, no params
+    Try TryUpdate() ; Try
+}
+
+TryUpdate() {
+    Global oGui
+    
+    If !oGui.HasProp("txtNotFrozen") ; WinSpyGui() not done yet, return until it is
+        return
+    
+    Ctrl_FollowMouse := oGui["Ctrl_FollowMouse"].Value
+    CoordMode "Mouse", "Screen"
+    MouseGetPos &msX, &msY, &msWin, &msCtrl, 2 ; get ClassNN and hWindow
+    actWin := WinExist("A")
+    
+    if (Ctrl_FollowMouse) {
+        curWin := msWin, curCtrl := msCtrl
+        WinExist("ahk_id " curWin) ; updating LastWindowFound?
+    } else {
+        curWin := actWin
+        curCtrl := ControlGetFocus() ; get focused control hwnd from active win
+    }
+    curCtrlClassNN := ""
+    Try curCtrlClassNN := ControlGetClassNN(curCtrl)
+    
+    t1 := WinGetTitle(), t2 := WinGetClass()
+    if (curWin = oGui.hwnd || t2 = "MultitaskingViewFrame") { ; Our Gui || Alt-tab
+        UpdateText("Ctrl_Freeze", oGui.txtFrozen)
+        return
+    }
+    
+    UpdateText("Ctrl_Freeze", oGui.txtNotFrozen)
+    t3 := WinGetProcessName(), t4 := WinGetPID()
+    
+    WinDataText := t1 "`n" ; ZZZ
+                 . "ahk_class " t2 "`n"
+                 . "ahk_exe " t3 "`n"
+                 . "ahk_pid " t4 "`n"
+                 . "ahk_id " curWin
+    
+    UpdateText("Ctrl_Title", WinDataText)
+    CoordMode "Mouse", "Window"
+    MouseGetPos &mrX, &mrY
+    CoordMode "Mouse", "Client"
+    MouseGetPos &mcX, &mcY
+    mClr := PixelGetColor(msX,msY,"RGB")
+    mClr := SubStr(mClr, 3)
+    
+    mpText := "Screen:`t" msX ", " msY "`n"
+            . "Window:`t" mrX ", " mrY "`n"
+            . "Client:`t" mcX ", " mcY " (default)`n"
+            . "Color:`t" mClr " (Red=" SubStr(mClr, 1, 2) " Green=" SubStr(mClr, 3, 2) " Blue=" SubStr(mClr, 5) ")"
+    
+    UpdateText("Ctrl_MousePos", mpText)
+    
+    UpdateText("Ctrl_CtrlLabel", (Ctrl_FollowMouse ? oGui.txtMouseCtrl : oGui.txtFocusCtrl) ":")
+    
+    if (curCtrl) {
+        ctrlTxt := ControlGetText(curCtrl)
+        WinGetClientPos(&sX, &sY, &sW, &sH, curCtrl)
+        ControlGetPos &cX, &cY, &cW, &cH, curCtrl
+        
+        cText := "ClassNN:`t" curCtrlClassNN "`n"
+               . "Text:`t" textMangle(ctrlTxt) "`n"
+               . "Screen:`tx: " sX "`ty: " sY "`tw: " sW "`th: " sH "`n"
+               . "Client:`tx: " cX "`ty: " cY "`tw: " cW "`th: " cH
+    } else
+        cText := ""
+    
+    UpdateText("Ctrl_Ctrl", cText)
+    wX := "", wY := "", wW := "", wH := ""
+    WinGetPos &wX, &wY, &wW, &wH, "ahk_id " curWin
+    WinGetClientPos(&wcX, &wcY, &wcW, &wcH, "ahk_id " curWin)
+    
+    wText := "Screen:`tx: " wX "`ty: " wY "`tw: " wW "`th: " wH "`n"
+           . "Client:`tx: " wcX "`ty: " wcY "`tw: " wcW "`th: " wcH
+    
+    UpdateText("Ctrl_Pos", wText)
+    sbTxt := ""
+    
+    Loop {
+        ovi := ""
+        Try ovi := StatusBarGetText(A_Index)
+        if (ovi = "")
+            break
+        sbTxt .= "(" A_Index "):`t" textMangle(ovi) "`n"
+    }
+    
+    sbTxt := SubStr(sbTxt,1,-1) ; StringTrimRight, sbTxt, sbTxt, 1
+    UpdateText("Ctrl_SBText", sbTxt)
+    bSlow := oGui["Ctrl_IsSlow"].Value ; GuiControlGet, bSlow,, Ctrl_IsSlow
+    
+    if (bSlow) {
+        DetectHiddenText False
+        ovVisText := WinGetText() ; WinGetText, ovVisText
+        DetectHiddenText True
+        ovAllText := WinGetText() ; WinGetText, ovAllText
+    } else {
+        ovVisText := WinGetTextFast(false)
+        ovAllText := WinGetTextFast(true)
+    }
+    
+    UpdateText("Ctrl_VisText", ovVisText)
+    UpdateText("Ctrl_AllText", ovAllText)
+}
+
+; ===========================================================================================
+; WinGetText ALWAYS uses the "slow" mode - TitleMatchMode only affects
+; WinText/ExcludeText parameters. In "fast" mode, GetWindowText() is used
+; to retrieve the text of each control.
+; ===========================================================================================
+WinGetTextFast(detect_hidden) {    
+    controls := WinGetControlsHwnd()
+    
+    static WINDOW_TEXT_SIZE := 32767 ; Defined in AutoHotkey source.
+    
+    buf := Buffer(WINDOW_TEXT_SIZE * 2,0)
+    
+    text := ""
+    
+    Loop controls.Length {
+        hCtl := controls[A_Index]
+        if !detect_hidden && !DllCall("IsWindowVisible", "ptr", hCtl)
+            continue
+        if !DllCall("GetWindowText", "ptr", hCtl, "Ptr", buf.ptr, "int", WINDOW_TEXT_SIZE)
+            continue
+        
+        text .= StrGet(buf) "`r`n" ; text .= buf "`r`n"
+    }
+    return text
+}
+
+; ===========================================================================================
+; Unlike using a pure GuiControl, this function causes the text of the
+; controls to be updated only when the text has changed, preventing periodic
+; flickering (especially on older systems).
+; ===========================================================================================
+UpdateText(vCtl, NewText) {
+    Global oGui
+    static OldText := {}
+    ctl := oGui[vCtl], hCtl := Integer(ctl.hwnd)
+    
+    if (!oldText.HasProp(hCtl) Or OldText.%hCtl% != NewText) {
+        ctl.Value := NewText
+        OldText.%hCtl% := NewText
+    }
+}
+
+textMangle(x) {
+    elli := false
+    if (pos := InStr(x, "`n"))
+        x := SubStr(x, 1, pos-1), elli := true
+    else if (StrLen(x) > 40)
+        x := SubStr(x,1,40), elli := true
+    if elli
+        x .= " (...)"
+    return x
+}
+
+suspend_timer() {
+    Global oGui
+    SetTimer Update, 0
+    UpdateText("Ctrl_Freeze", oGui.txtFrozen)
+}
+
+~*Shift::
+~*Ctrl::suspend_timer()
+
+~*Ctrl up::
+~*Shift up::SetTimer Update, 250

package/AutoHotkey_2.0.19/UX/inc/CommandLineToArgs.ahk

@@ -0,0 +1,12 @@
+
+CommandLineToArgs(cmd) {
+    argv := DllCall("shell32\CommandLineToArgvW", "wstr", cmd, 'int*', &narg:=0, "ptr")
+    try {
+        args := []
+        Loop args.Capacity := narg
+            args.Push(StrGet(NumGet(argv, (A_Index-1)*A_PtrSize, "ptr"), "UTF-16"))
+    }
+    finally
+        DllCall("LocalFree", "ptr", argv)
+    return args
+}

package/AutoHotkey_2.0.19/UX/inc/CreateAppShortcut.ahk

@@ -0,0 +1,37 @@
+CreateAppShortcut(linkFile, p) {
+    ;target, args, description, aumid, uninst?
+    lnk := ComObject('{00021401-0000-0000-C000-000000000046}' ; CLSID_ShellLink
+                    ,'{000214F9-0000-0000-C000-000000000046}') ; IID_IShellLink
+    
+    ComCall(20, lnk, 'wstr', p.target)
+    ComCall(11, lnk, 'wstr', p.HasProp('args') ? p.args : "")
+    ComCall(7, lnk, 'wstr', p.desc)
+    if p.HasProp('icon')
+        ComCall(17, lnk, 'wstr', p.icon, 'int', p.HasProp('iconIndex') ? p.iconIndex : 0)
+    
+    ; Set the System.AppUserModel.ID property via IPropertyStore
+    props := ComObjQuery(lnk, '{886D8EEB-8CF2-4446-8D02-CDBA1DBDCF99}')
+    static PKEY_AppUserModel_ID               := PKEY('{9F4C2855-9F79-4B39-A8D0-E1D42DE1D5F3}',  5)
+    static PKEY_AppUserModel_UninstallCommand := PKEY('{9F4C2855-9F79-4B39-A8D0-E1D42DE1D5F3}', 37)
+    setProp PKEY_AppUserModel_ID, p.aumid
+    if p.HasProp('uninst')
+        setProp PKEY_AppUserModel_UninstallCommand, p.uninst
+    
+    ; Save via IPersistFile
+    pf := ComObjQuery(lnk, '{0000010B-0000-0000-C000-000000000046}')
+    ComCall(6, pf, 'wstr', linkFile, 'int', true)
+    
+    setProp(key, value) {
+        propvar := Buffer(24, 0), propref := ComValue(0x400C, propvar.ptr)
+        propref[] := String(value)
+        ComCall(6, props, 'ptr', key, 'ptr', propvar)
+        propref[] := 0
+    }
+    
+    PKEY(sguid, propID) {
+        pk := Buffer(20)
+        DllCall('ole32\IIDFromString', 'wstr', sguid, 'ptr', pk, 'hresult')
+        NumPut('int', propID, pk, 16)
+        return pk
+    }
+}

package/AutoHotkey_2.0.19/UX/inc/EnableUIAccess.ahk

@@ -0,0 +1,246 @@
+EnableUIAccess(ExePath) {
+    static CertName := "AutoHotkey"
+    hStore := DllCall("Crypt32\CertOpenStore", "ptr", 10 ; STORE_PROV_SYSTEM_W
+        , "uint", 0, "ptr", 0, "uint", 0x20000 ; SYSTEM_STORE_LOCAL_MACHINE
+        , "wstr", "Root", "ptr")
+    if !hStore
+        throw OSError()
+    store := CertStore(hStore)
+    ; Find or create certificate for signing.
+    cert := CertContext()
+    while (cert.ptr := DllCall("Crypt32\CertFindCertificateInStore", "ptr", hStore
+            , "uint", 0x10001 ; X509_ASN_ENCODING|PKCS_7_ASN_ENCODING
+            , "uint", 0, "uint", 0x80007 ; FIND_SUBJECT_STR
+            , "wstr", CertName, "ptr", cert.ptr, "ptr"))
+        && !(DllCall("Crypt32\CryptAcquireCertificatePrivateKey"
+            , "ptr", cert, "uint", 5 ; CRYPT_ACQUIRE_CACHE_FLAG|CRYPT_ACQUIRE_COMPARE_KEY_FLAG
+            , "ptr", 0, "ptr*", 0, "uint*", &keySpec:=0, "ptr", 0)
+            && (keySpec & 2)) { ; AT_SIGNATURE
+        ; Keep looking for a certificate with a private key.
+    }
+    if !cert.ptr
+        cert := EnableUIAccess_CreateCert(CertName, hStore)
+    ; Set uiAccess attribute in manifest.
+    EnableUIAccess_SetManifest(ExePath)
+    ; Sign the file (otherwise uiAccess attribute is ignored).
+    EnableUIAccess_SignFile(ExePath, cert, CertName)
+}
+
+EnableUIAccess_SetManifest(ExePath) {
+    xml := ComObject("Msxml2.DOMDocument")
+    xml.async := false
+    xml.setProperty("SelectionLanguage", "XPath")
+    xml.setProperty("SelectionNamespaces"
+        , "xmlns:v1='urn:schemas-microsoft-com:asm.v1' "
+        . "xmlns:v3='urn:schemas-microsoft-com:asm.v3'")
+    try
+        if !xml.loadXML(EnableUIAccess_ReadManifest(ExePath))
+            throw Error("Invalid manifest")
+    catch as e
+        throw Error("Error loading manifest from " ExePath,, e.Message "`n  @ " e.File ":" e.Line)
+    
+    
+    node := xml.selectSingleNode("/v1:assembly/v3:trustInfo/v3:security"
+                    . "/v3:requestedPrivileges/v3:requestedExecutionLevel")
+    if !node ; Not AutoHotkey?
+        throw Error("Manifest is missing required elements")
+    
+    node.setAttribute("uiAccess", "true")
+    xml := RTrim(xml.xml, "`r`n")
+    
+    data := Buffer(StrPut(xml, "utf-8") - 1)
+    StrPut(xml, data, "utf-8")
+    
+    if !(hupd := DllCall("BeginUpdateResource", "str", ExePath, "int", false))
+        throw OSError()
+    r := DllCall("UpdateResource", "ptr", hupd, "ptr", 24, "ptr", 1
+                    , "ushort", 1033, "ptr", data, "uint", data.size)
+
+    ; Retry loop to work around file locks (especially by antivirus)
+    for delay in [0, 100, 500, 1000, 3500] {
+        Sleep delay
+        if DllCall("EndUpdateResource", "ptr", hupd, "int", !r) || !r
+            return
+        if !(A_LastError = 5 || A_LastError = 110) ; ERROR_ACCESS_DENIED || ERROR_OPEN_FAILED
+            break
+    }
+    throw OSError(A_LastError, "EndUpdateResource")
+}
+
+EnableUIAccess_ReadManifest(ExePath) {
+	if !(hmod := DllCall("LoadLibraryEx", "str", ExePath, "ptr", 0, "uint", 2, "ptr"))
+		throw OSError()
+	try {
+		if !(hres := DllCall("FindResource", "ptr", hmod, "ptr", 1, "ptr", 24, "ptr"))
+			throw OSError()
+		size := DllCall("SizeofResource", "ptr", hmod, "ptr", hres, "uint")
+		if !(hglb := DllCall("LoadResource", "ptr", hmod, "ptr", hres, "ptr"))
+			throw OSError()
+		if !(pres := DllCall("LockResource", "ptr", hglb, "ptr"))
+			throw OSError()
+		return StrGet(pres, size, "utf-8")
+	}
+	finally
+		DllCall("FreeLibrary", "ptr", hmod)
+}
+
+EnableUIAccess_CreateCert(Name, hStore) {
+    ; Here Name is used as the key container name.
+    prov := CryptContext()
+    if !DllCall("Advapi32\CryptAcquireContext", "ptr*", prov
+        , "str", Name, "ptr", 0, "uint", 1, "uint", 0) { ; PROV_RSA_FULL=1, open existing=0
+        if !DllCall("Advapi32\CryptAcquireContext", "ptr*", prov
+            , "str", Name, "ptr", 0, "uint", 1, "uint", 8) ; PROV_RSA_FULL=1, CRYPT_NEWKEYSET=8
+            throw OSError()
+        if !DllCall("Advapi32\CryptGenKey", "ptr", prov
+                , "uint", 2, "uint", 0x4000001, "ptr*", CryptKey()) ; AT_SIGNATURE=2, EXPORTABLE=..01
+            throw OSError()
+    }
+
+    ; Here Name is used as the certificate subject and name.
+    Loop 2 {
+        if A_Index = 1
+            pbName := cbName := 0
+        else
+            bName := Buffer(cbName), pbName := bName.ptr
+        if !DllCall("Crypt32\CertStrToName", "uint", 1, "str", "CN=" Name
+            , "uint", 3, "ptr", 0, "ptr", pbName, "uint*", &cbName, "ptr", 0) ; X509_ASN_ENCODING=1, CERT_X500_NAME_STR=3
+            throw OSError()
+    }
+    cnb := Buffer(2*A_PtrSize), NumPut("ptr", cbName, "ptr", pbName, cnb)
+
+    ; Set expiry to 9999-01-01 12pm +0.
+    NumPut("short", 9999, "sort", 1, "short", 5, "short", 1, "short", 12, endTime := Buffer(16, 0))
+
+    StrPut("2.5.29.4", szOID_KEY_USAGE_RESTRICTION := Buffer(9),, "cp0")
+    StrPut("2.5.29.37", szOID_ENHANCED_KEY_USAGE := Buffer(10),, "cp0")
+    StrPut("1.3.6.1.5.5.7.3.3", szOID_PKIX_KP_CODE_SIGNING := Buffer(18),, "cp0")
+
+    ; CERT_KEY_USAGE_RESTRICTION_INFO key_usage;
+    key_usage := Buffer(6*A_PtrSize, 0)
+    NumPut('ptr', 0, 'ptr', 0, 'ptr', 1, 'ptr', key_usage.ptr + 5*A_PtrSize, 'ptr', 0
+        , 'uchar', (CERT_DATA_ENCIPHERMENT_KEY_USAGE := 0x10)
+                 | (CERT_DIGITAL_SIGNATURE_KEY_USAGE := 0x80), key_usage)
+
+    ; CERT_ENHKEY_USAGE enh_usage;
+    enh_usage := Buffer(3*A_PtrSize)
+    NumPut("ptr", 1, "ptr", enh_usage.ptr + 2*A_PtrSize, "ptr", szOID_PKIX_KP_CODE_SIGNING.ptr, enh_usage)
+
+    key_usage_data := EncodeObject(szOID_KEY_USAGE_RESTRICTION, key_usage)
+    enh_usage_data := EncodeObject(szOID_ENHANCED_KEY_USAGE, enh_usage)
+
+    EncodeObject(structType, structInfo) {
+        encoder := DllCall.Bind("Crypt32\CryptEncodeObject", "uint", X509_ASN_ENCODING := 1
+            , "ptr", structType, "ptr", structInfo)
+        if !encoder("ptr", 0, "uint*", &enc_size := 0)
+            throw OSError()
+        enc_data := Buffer(enc_size)
+        if !encoder("ptr", enc_data, "uint*", &enc_size)
+            throw OSError()
+        enc_data.Size := enc_size
+        return enc_data
+    }
+
+    ; CERT_EXTENSION extension[2]; CERT_EXTENSIONS extensions;
+    NumPut("ptr", szOID_KEY_USAGE_RESTRICTION.ptr, "ptr", true, "ptr", key_usage_data.size, "ptr", key_usage_data.ptr
+        ,  "ptr", szOID_ENHANCED_KEY_USAGE.ptr,    "ptr", true, "ptr", enh_usage_data.size, "ptr", enh_usage_data.ptr
+        , extension := Buffer(8*A_PtrSize))
+    NumPut("ptr", 2, "ptr", extension.ptr, extensions := Buffer(2*A_PtrSize))
+
+    if !hCert := DllCall("Crypt32\CertCreateSelfSignCertificate"
+        , "ptr", prov, "ptr", cnb, "uint", 0, "ptr", 0
+        , "ptr", 0, "ptr", 0, "ptr", endTime, "ptr", extensions, "ptr")
+        throw OSError()
+    cert := CertContext(hCert)
+
+    if !DllCall("Crypt32\CertAddCertificateContextToStore", "ptr", hStore
+        , "ptr", hCert, "uint", 1, "ptr", 0) ; STORE_ADD_NEW=1
+        throw OSError()
+
+    return cert
+}
+
+EnableUIAccess_DeleteCertAndKey(Name) {
+    ; This first call "acquires" the key container but also deletes it.
+    DllCall("Advapi32\CryptAcquireContext", "ptr*", 0, "str", Name
+        , "ptr", 0, "uint", 1, "uint", 16) ; PROV_RSA_FULL=1, CRYPT_DELETEKEYSET=16
+    if !hStore := DllCall("Crypt32\CertOpenStore", "ptr", 10 ; STORE_PROV_SYSTEM_W
+        , "uint", 0, "ptr", 0, "uint", 0x20000 ; SYSTEM_STORE_LOCAL_MACHINE
+        , "wstr", "Root", "ptr")
+		throw OSError()
+    store := CertStore(hStore)
+    deleted := 0
+    ; Multiple certificates might be created over time as keys become inaccessible.
+	while p := DllCall("Crypt32\CertFindCertificateInStore", "ptr", hStore
+        , "uint", 0x10001 ; X509_ASN_ENCODING|PKCS_7_ASN_ENCODING
+        , "uint", 0, "uint", 0x80007 ; FIND_SUBJECT_STR
+        , "wstr", Name, "ptr", 0, "ptr") {
+        if !DllCall("Crypt32\CertDeleteCertificateFromStore", "ptr", p)
+            throw OSError()                
+        deleted++
+    }
+	return deleted
+}
+
+class CryptPtrBase {
+    __new(p:=0) => this.ptr := p
+    __delete() => this.ptr && this.Dispose()
+}
+class CryptContext extends CryptPtrBase {
+    Dispose() => DllCall("Advapi32\CryptReleaseContext", "ptr", this, "uint", 0)
+}
+class CertContext extends CryptPtrBase {
+    Dispose() => DllCall("Crypt32\CertFreeCertificateContext", "ptr", this)
+}
+class CertStore extends CryptPtrBase {
+    Dispose() => DllCall("Crypt32\CertCloseStore", "ptr", this, "uint", 0)
+}
+class CryptKey extends CryptPtrBase {
+    Dispose() => DllCall("Advapi32\CryptDestroyKey", "ptr", this)
+}
+
+EnableUIAccess_SignFile(ExePath, CertCtx, Name) {
+    file_info := struct( ; SIGNER_FILE_INFO
+        "ptr", A_PtrSize*3, "ptr", StrPtr(ExePath))
+    dwIndex := Buffer(4, 0) ; DWORD
+    subject_info := struct( ; SIGNER_SUBJECT_INFO
+        "ptr", A_PtrSize*4, "ptr", dwIndex.ptr, "ptr", SIGNER_SUBJECT_FILE:=1,
+        "ptr", file_info.ptr)
+    cert_store_info := struct( ; SIGNER_CERT_STORE_INFO
+        "ptr", A_PtrSize*4, "ptr", CertCtx.ptr, "ptr", SIGNER_CERT_POLICY_CHAIN:=2)
+    cert_info := struct( ; SIGNER_CERT
+        "uint", 8+A_PtrSize*2, "uint", SIGNER_CERT_STORE:=2,
+        "ptr", cert_store_info.ptr)
+    authcode_attr := struct( ; SIGNER_ATTR_AUTHCODE
+        "uint", 8+A_PtrSize*3, "int", false, "ptr", true, "ptr", StrPtr(Name))
+    sig_info := struct( ; SIGNER_SIGNATURE_INFO
+        "uint", 8+A_PtrSize*4, "uint", CALG_SHA1:=0x8004,
+        "ptr", SIGNER_AUTHCODE_ATTR:=1, "ptr", authcode_attr.ptr)
+
+    DllCall("MSSign32\SignerSign"
+        , "ptr", subject_info, "ptr", cert_info, "ptr", sig_info
+        , "ptr", 0, "ptr", 0, "ptr", 0, "ptr", 0, "hresult")
+    
+    struct(args*) => (
+        args.Push(b := Buffer(args[2], 0)),
+        NumPut(args*),
+        b
+    )
+}
+
+; Verifies a signed executable file.  Returns 0 on success, or a standard OS error number.
+EnableUIAccess_Verify(ExePath) {
+    wfi := Buffer(4*A_PtrSize) ; WINTRUST_FILE_INFO
+    NumPut('ptr', wfi.size, 'ptr', StrPtr(ExePath), 'ptr', 0, 'ptr', 0, wfi)
+
+    ; WINTRUST_ACTION_GENERIC_VERIFY_V2
+    NumPut('int64', 0x11d0cd4400aac56b, 'int64', 0xee95c24fc000c28c, actionID := Buffer(16))
+
+    wtd := Buffer(9*A_PtrSize+16) ; WINTRUST_DATA
+    NumPut(
+        'ptr', wtd.Size, 'ptr', 0, 'ptr', 0, 'int', WTD_UI_NONE:=2, 'int', WTD_REVOKE_NONE:=0,
+        'ptr', WTD_CHOICE_FILE:=1, 'ptr', wfi.ptr, 'ptr', WTD_STATEACTION_VERIFY:=1,
+        'ptr', 0, 'ptr', 0, 'int', 0, 'int', 0, 'ptr', 0, wtd
+    )
+    return DllCall('wintrust\WinVerifyTrust', 'ptr', 0, 'ptr', actionID, 'ptr', wtd, 'int')
+}