w-mousekey 1.0.0

package/AutoHotkey_2.0.19/UX/inc/GetGitHubReleaseAssetURL.ahk

@@ -0,0 +1,26 @@
+GetGitHubReleaseAssetURL(repo, ext:='.zip', release:='latest') {
+    req := ComObject('Msxml2.XMLHTTP')
+    req.open('GET', 'https://api.github.com/repos/' repo '/releases/' release, false)
+    req.send()
+    if req.status != 200
+        throw Error(req.status ' - ' req.statusText, -1)
+    
+    res := JSON_parse(req.responseText)
+    try
+        assets := res.assets
+    catch PropertyError
+        throw Error(res.message, -1)
+    
+    loop assets.length {
+        asset := assets.%A_Index-1%
+        if SubStr(asset.name, -StrLen(ext)) = ext {
+            return asset.browser_download_url
+        }
+    }
+    
+    JSON_parse(str) {
+        htmlfile := ComObject('htmlfile')
+        htmlfile.write('<meta http-equiv="X-UA-Compatible" content="IE=edge">')
+        return htmlfile.parentWindow.JSON.parse(str)
+    }
+}

package/AutoHotkey_2.0.19/UX/inc/HashFile.ahk

@@ -0,0 +1,96 @@
+; HashFile by Deo
+; https://autohotkey.com/board/topic/66139-ahk-l-calculating-md5sha-checksum-from-file/
+; Modified for AutoHotkey v2 by lexikos.
+
+#Requires AutoHotkey v2.0-beta
+
+/*
+HASH types:
+1 - MD2
+2 - MD5
+3 - SHA
+4 - SHA256
+5 - SHA384
+6 - SHA512
+*/
+HashFile(filePath, hashType:=2)
+{
+	static PROV_RSA_AES := 24
+	static CRYPT_VERIFYCONTEXT := 0xF0000000
+	static BUFF_SIZE := 1024 * 1024 ; 1 MB
+	static HP_HASHVAL := 0x0002
+	static HP_HASHSIZE := 0x0004
+	
+    switch hashType {
+        case 1: hash_alg := (CALG_MD2 := 32769)
+        case 2: hash_alg := (CALG_MD5 := 32771)
+        case 3: hash_alg := (CALG_SHA := 32772)
+        case 4: hash_alg := (CALG_SHA_256 := 32780)
+        case 5: hash_alg := (CALG_SHA_384 := 32781)
+        case 6: hash_alg := (CALG_SHA_512 := 32782)
+        default: throw ValueError('Invalid hashType', -1, hashType)
+    }
+	
+	f := FileOpen(filePath, "r")
+    f.Pos := 0 ; Rewind in case of BOM.
+    
+    HCRYPTPROV() => {
+        ptr: 0,
+        __delete: this => this.ptr && DllCall("Advapi32\CryptReleaseContext", "Ptr", this, "UInt", 0)
+    }
+    
+	if !DllCall("Advapi32\CryptAcquireContextW"
+				, "Ptr*", hProv := HCRYPTPROV()
+				, "Uint", 0
+				, "Uint", 0
+				, "Uint", PROV_RSA_AES
+				, "UInt", CRYPT_VERIFYCONTEXT)
+		throw OSError()
+	
+    HCRYPTHASH() => {
+        ptr: 0,
+        __delete: this => this.ptr && DllCall("Advapi32\CryptDestroyHash", "Ptr", this)
+    }
+    
+	if !DllCall("Advapi32\CryptCreateHash"
+				, "Ptr", hProv
+				, "Uint", hash_alg
+				, "Uint", 0
+				, "Uint", 0
+				, "Ptr*", hHash := HCRYPTHASH())
+        throw OSError()
+	
+	read_buf := Buffer(BUFF_SIZE, 0)
+	
+	While (cbCount := f.RawRead(read_buf, BUFF_SIZE))
+	{
+		if !DllCall("Advapi32\CryptHashData"
+					, "Ptr", hHash
+					, "Ptr", read_buf
+					, "Uint", cbCount
+					, "Uint", 0)
+			throw OSError()
+	}
+	
+	if !DllCall("Advapi32\CryptGetHashParam"
+				, "Ptr", hHash
+				, "Uint", HP_HASHSIZE
+				, "Uint*", &HashLen := 0
+				, "Uint*", &HashLenSize := 4
+				, "UInt", 0) 
+        throw OSError()
+		
+    bHash := Buffer(HashLen, 0)
+	if !DllCall("Advapi32\CryptGetHashParam"
+				, "Ptr", hHash
+				, "Uint", HP_HASHVAL
+				, "Ptr", bHash
+				, "Uint*", &HashLen
+				, "UInt", 0 )
+        throw OSError()
+	
+	loop HashLen
+		HashVal .= Format('{:02x}', (NumGet(bHash, A_Index-1, "UChar")) & 0xff)
+	
+	return HashVal
+}

package/AutoHotkey_2.0.19/UX/inc/README.txt

@@ -0,0 +1,3 @@
+Scripts in this directory may be copied and used freely, but
+may be removed or modified without notice by any future release.
+Do not #include them directly; instead, create a copy.

package/AutoHotkey_2.0.19/UX/inc/ShellRun.ahk

@@ -0,0 +1,7 @@
+; For documentation about the parameters, refer to:
+;  https://learn.microsoft.com/en-us/windows/win32/shell/shell-shellexecute
+ShellRun(filePath, arguments?, directory?, operation?, show?) {
+    static VT_UI4 := 0x13, SWC_DESKTOP := ComValue(VT_UI4, 0x8)
+    ComObject("Shell.Application").Windows.Item(SWC_DESKTOP).Document.Application
+        .ShellExecute(filePath, arguments?, directory?, operation?, show?)
+}

package/AutoHotkey_2.0.19/UX/inc/bounce-v1.ahk

@@ -0,0 +1,3 @@
+; v1: includes the file from the script's directory.
+; v2: does nothing because the path is relative to this file.
+#include *i reload-v1.ahk

package/AutoHotkey_2.0.19/UX/inc/common.ahk

@@ -0,0 +1,21 @@
+A_AllowMainWindow := true
+if A_AhkPath != A_ScriptDir '\AutoHotkeyUX.exe' {
+    ; Standalone, compiled or test mode: locate InstallDir via registry
+    DirExist(ROOT_DIR := RegRead('HKCU\SOFTWARE\AutoHotkey', 'InstallDir', ""))
+        ||  (ROOT_DIR := RegRead('HKLM\SOFTWARE\AutoHotkey', 'InstallDir', ""))
+}
+if (ROOT_DIR ?? "") = "" || !DirExist(ROOT_DIR)
+    Loop Files A_ScriptDir '\..', 'D'
+        ROOT_DIR := A_LoopFileFullPath
+
+if !trace.Enabled := RegRead('HKCU\Software\AutoHotkey', 'Trace', false)
+    trace.DefineProp 'call', {call: (*) => ''}
+
+#include config.ahk
+
+trace(s) {
+    try
+        FileAppend s "`n", "*"
+    catch
+        OutputDebug s "`n"
+}

package/AutoHotkey_2.0.19/UX/inc/config.ahk

@@ -0,0 +1,13 @@
+
+; CONFIG_FILE_PATH := A_MyDocuments "\AutoHotkey\AutoHotkey.ini"
+CONFIG_KEY := 'HKCU\Software\AutoHotkey'
+
+ConfigRead(section, key, default) {
+    ; return IniRead(CONFIG_FILE_PATH, section, key, default)
+    return RegRead(CONFIG_KEY '\' section, key, default)
+}
+
+ConfigWrite(value, section, key) {
+    ; IniWrite(value, CONFIG_FILE_PATH, section, key)
+    RegWrite(value, 'REG_SZ', CONFIG_KEY '\' section, key)
+}

package/AutoHotkey_2.0.19/UX/inc/identify.ahk

@@ -0,0 +1,29 @@
+#include identify_regex.ahk
+
+IdentifyBySyntax(code) {
+    static identify_regex := get_identify_regex()
+    p := 1, count_1 := count_2 := 0, version := marks := ''
+    try while (p := RegExMatch(code, identify_regex, &m, p)) {
+        p += m.Len()
+        if SubStr(m.mark,1,1) = 'v' {
+            switch SubStr(m.mark,2,1) {   
+            case '1': count_1++
+            case '2': count_2++
+            }
+            if !InStr(marks, m.mark)
+                marks .= m.mark ' '
+        }
+    }
+    catch as e
+        return {v: 0, r: "error", err: e, pos: p}
+    if !(count_1 || count_2)
+        return {v: 0, r: "no tell-tale matches"}
+    ; Use a simple, cautious approach for now: select a version only if there were
+    ; matches for exactly one version.
+    if count_1 && count_2
+        return {v: 0, r: Format(
+            count_1 > count_2 ? "v1 {1}:{2} - {3}" : count_2 > count_1 ? "v2 {2}:{1} - {3}" : "? {1}:{2} - {3}",
+            count_1, count_2, Trim(marks)
+        )}
+    return {v: count_1 ? 1 : 2, r: Trim(marks)}
+}

package/AutoHotkey_2.0.19/UX/inc/identify_regex.ahk

@@ -0,0 +1,4 @@
+get_identify_regex() => '
+(
+(?(DEFINE)(?<line_comment>(?<![^ `t`r`n]);.*)(?<block_comment>(?m:^[ `t]*/\*(?:.*\R?)+?(?:[ `t]*\*/|.*\Z)))(?<eol>(?=[ `t]*+(?&line_comment)?(?m:$)))(?<tosol>(?:(?&eol).*\R|(?&block_comment))++)(?<toeol>(?:[^ `t`r`n]++|[ `t]*+(?!(?&eol)))*+)(?<contsec>[ `t]*+\((?i:Join[^ `t`r`n]*+|(?&line_comment)|[^ `t`r`n()]++|[ `t]++)*+\R(?:[ `t]*+(?!\)).*\R)*+[ `t]*+\))(?<solcont>[ `t]*+(?:,(?!::| +& )|[<>=/|^,?:\.+\-*&!~](?![^"'`r`n]*?(?:".*?::(?!.*?")|'.*?::(?!.*?')|::))|(?i:AND|OR)(?=[ `t])))(?<eolcont>(?&eol)(?:(?<ec_bad>(?<=:=)|(?<=[:,]))|(?<=[<>=/|^,?:\.+\-*&!~](?<!\+\+|--))|(?<=(?<![\w[:^ascii:]\.])(?i:OR|IS|AS|IN))|(?<=(?<![\w[:^ascii:]\.])(?i:AND|NOT))|(?<=(?<![\w[:^ascii:]\.])(?i:CONTAINS)))(?&tosol)(?:(?&contsec)|(?(ec_bad)|(*:v2-cle))))(?<v1_cont>(?&tosol)(?:(?&solcont)(?&subexp)|[ `t]*+,[ `t]*+(?=%)(?&pct)|(?&contsec)(?&ambig)))(?<v1_fin>(?:.*+(?&v1_cont))*.*+)(?<ambig>(?:(?&exp)|(?&v1_cont)|.*+)++(*:~))(?<pct>(?=%[ `t])(?:(?&subexp)(?&exp)|(?&v1_fin)(*:v1-pct)))(?<expm>(*:exp)(?&exp))(?<v1_lines>(?&toeol)(?:(?&tosol)(?:(?&solcont)|(?&contsec))(?&v1_lines))?)(?<otb>(?<![<>=/|^,?:\.*&!~])(?<!(?<!\+)\+)(?<!(?<!\-)\-)[ `t]*+\{(?&eol))(?<enclf>\R(?:(?&contsec)|(?!(?&solcont))(*:v2-cbe)|))(?<encex>(?:[, `t]++|(?&enclf)|(?&subexp)|(?&line_comment))*+)(?<v2_exm>%(?:[^,`r`n;\[\]{}()"%']*+|,(?![ `t]*+%)|(?&subexp))*+%(*:v2-pct)|=>(*:v2-fat))(?<subexp>(?:(?!(?&otb))(?&eolcont)?[ `t]*+(?:[^ `t;,`r`n=\[\]{}()"%']++|\((?&encex)\)|\[(?&encex)\]|\{(?&encex)\}|(?>"(?>[^"``\r\n]|``["'``])*+"|'(?>[^'``\r\n]|``["'``])*+'(*:v2-sq))|'(?&tosol)(?&contsec)'(*:v2-sq)|(?<!\.)%[\w[:^ascii:]]++%|(?&v2_exm)|=|(?&v1_cont)))++)(?<exp>(?:(?&subexp)|[ `t]*+,|(?&eol))++(?&otb)?))(?:[ `t]*+(?&line_comment)(*SKIP)(?!)|(?m:^)[ `t{}]*(?:(?m:^[ `t]*/\*(?:.*\R?)+?(?:[ `t]*\*/|.*\Z))(*SKIP)(?!)|(?:[<>*~$!^+#]*(?>\w+|[^ `t`r`n])|~?(?>\w+|[^ `t`r`n]) & ~?(?>\w+|[^ `t`r`n]))(?i:[ `t]+up)?::(?:[<>*~$!^+#]*(?>\w+|[^ `t`r`n])(?&eol)(*:remap?)|(?&eol)(?!(?&tosol)[ `t]*+(?:[\{#]|.*?::|[\w[:^ascii:]]++\())(*:v1-hk)|(*:hotkey))|(?(?=:[^\:`r`n]*[xX]):[[:alnum:]\?\*\- ]*:([^```r`n:]++|``.|:(?!:))*?::|:[[:alnum:]\?\*\- ]*:([^```r`n:]++|``.|:(?!:))*?::(?:(?&v1_cont)|.*))(*:hotstring)|[\w[:^ascii:]]++:(?=[ `t]*+(?:(?<![^ `t`r`n]);.*)?(?m:$))(*:label)|[^ ,```r`n]+(?<!:):(?=[ `t]*+(?:(?<![^ `t`r`n]);.*)?(?m:$))(*:v1-lbl)|#(?:\w+,|(?i:NoEnv|If|CommentFlag|Delimiter|DerefChar|EscapeChar))(?&v1_fin)(*:v1-dir)|#(?i:HotIf)(*:v2-dir)(?&exp)?|#(?i:Include(?:Again)?)[ `t]+(?&v1_fin)(*:dir)|#\w+(?![^ `t`r`n])(?&ambig)(*:dir?)|(?<=[{}])(*SKIP)(?!))|[ `t]*+(?:(?!(?:[\w[:^ascii:]<>=/|^,?:\.+\-*&!~ `t()\[\]{}%]++|(?>"(?>[^"``\r\n]|``["'``])*+"|'(?>[^'``\r\n]|``["'``])*+'(*:v2-sq))|['"].*)*+(?=[ `t]*+(?:(?<![^ `t`r`n]);.*)?(?m:$)))(?&v1_fin)(*:v1-char)|(?i:else|try|finally)(?![^ `t`r`n])[ `t]*+\{?(*SKIP)(?!)|(?i:return|for|while|until|throw|switch)[ `t]++(?&expm)|(?i:if|while|return|until|loop|goto)(?=\()(?&expm)|(?i:local|global|static)(?![\w[:^ascii:]#@$])(?:[ `t]++[\w[:^ascii:]]++(?:(?=\()(?&exp)(*:v2-kw)|[ `t]*+\{(?&eol)(*:v2-kw)|(?![ `t]*+=)(?&expm))|(?&eol)(*:assume)|(?&v1_fin)(*:v1-kw))|(?i:if)[ `t]++(?:(?>[\w[:^ascii:]#@$]++|%[\w[:^ascii:]#@$]++%)++(?:[ `t]++(?i:not[ `t]++)?(?i:in|contains|between)[ `t]++(?&v1_fin)(*:v1-if)|[ `t]*+(?:[<>]=?|!?=)(?&ambig))|(?&expm))|[\w[:^ascii:]]++(?:[ `t]*+=(?:>(?&ambig)|.*?\?.+?:.*(?&ambig)|(?&v1_fin)(*:v1-ass))|[\(\[](?=.*[\)\]][ `t`r`n]*\{)(?:[ `t]*+[\w[:^ascii:]]++[ `t]*+(?::=(?&subexp))?[ `t]*+,)*+[ `t]*+(?:(?i:ByRef)[ `t]++[\w[:^ascii:]](*:v1-ref)|&(*:v2-ref)|[\w[:^ascii:]]++[ `t]*+=(*:v1-def)|\*[ `t]*+[\)\]](*:v2-vfn)).*|(?=[\(\[\.\?]|[ `t]*+(?>[\:\+\-\*/\.\|&\^]|<<|>>|//)=)(?&expm)|,(?&v1_fin)(*:v1-cmd)|(?&eol)(?&ambig)|[ `t]++(?:[ `t]*+(?:\^|(?:(?!\{)[\w[:^ascii:]<>=/|^,?:\.+\-*&!~ `t()\[\]{}%]|(?>"(?>[^"``\r\n]|``["'``])*+"|'(?>[^'``\r\n]|``["'``])*+'(*:v2-sq)))*+\{[ `t]*+(?:\w+|.)(?:[ `t]++\w+)?[ `t]*+\})(?&v1_fin)(*:v1-send)|(?:[^`r`n,\[\]{}()"%']*+,[ `t]*+)*+(?&pct)|(?&ambig)(*:cmd?)))|(?:\+\+|--)(?&expm)|.(?&ambig)(*:!!)))
+)'

package/AutoHotkey_2.0.19/UX/inc/launcher-common.ahk

@@ -0,0 +1,78 @@
+
+#include common.ahk
+
+GetExeInfo(exe) {
+    if !(verSize := DllCall("version\GetFileVersionInfoSize", "str", exe, "uint*", 0, "uint"))
+        || !DllCall("version\GetFileVersionInfo", "str", exe, "uint", 0, "uint", verSize, "ptr", verInfo := Buffer(verSize))
+        throw OSError()
+    prop := {Path: exe}
+    static Properties := {
+        Version: 'FileVersion',
+        Description: 'FileDescription',
+        ProductName: 'ProductName'
+    }
+    for propName, infoName in Properties.OwnProps()
+        if DllCall("version\VerQueryValue", "ptr", verInfo, "str", "\StringFileInfo\040904b0\" infoName, "ptr*", &p:=0, "uint*", &len:=0)
+            prop.%propName% := StrGet(p, len)
+        else throw OSError()
+    if InStr(exe, '_UIA')
+        prop.Description .= ' UIA'
+    prop.Version := RegExReplace(prop.Version, 'i)-[a-z]{4,}\K(?=\d)|, ', '.') ; Hack-fix for erroneous version numbers (AutoHotkey_H v2.0-beta3-H...)
+    return prop
+}
+
+IsUsableAutoHotkey(exeinfo) {
+    return exeinfo.HasProp('Description')
+        && RegExMatch(exeinfo.Description, '^AutoHotkey.* (32|64)-bit', &m)
+        && (m.1 != '64' || A_Is64bitOS)
+        && !InStr(exeinfo.Path, '\AutoHotkeyUX.exe')
+}
+
+GetMajor(v) {
+    Loop Parse, v, '.-+'
+        return Integer(A_LoopField)
+    throw ValueError('Invalid version number', -1, v)
+}
+
+ReadHashes(path, filter?) {
+    filemap := Map(), filemap.CaseSense := 0
+    if !FileExist(path)
+        return filemap
+    csvfile := FileOpen(path, 'r')
+    props := StrSplit(csvfile.ReadLine(), ',')
+    while !csvfile.AtEOF {
+        item := {}
+        Loop Parse csvfile.ReadLine(), 'CSV'
+            item.%props[A_Index]% := A_LoopField
+        if IsSet(filter) && !filter(item)
+            continue
+        filemap[item.Path] := item
+    }
+    return filemap
+}
+
+GetUsableAutoHotkeyExes() {
+    static files
+    if IsSet(files) {
+        trace '![Launcher] returning hashes again'
+        return files
+    }
+    files := ReadHashes(ROOT_DIR '\UX\installed-files.csv',
+        item => IsUsableAutoHotkey(item) && (
+            item.Path ~= '^(?!\w:|\\\\)' && item.Path := ROOT_DIR '\' item.Path,
+            true
+        ))
+    if files.Count {
+        trace '![Launcher] returning hashes from cache'
+        return files
+    }
+    Loop Files ROOT_DIR '\AutoHotkey*.exe', 'R' {
+        try {
+            item := GetExeInfo(A_LoopFilePath)
+            if IsUsableAutoHotkey(item)
+                files[item.Path] := item
+        }
+    }
+    trace '![Launcher] returning hashes from filesystem'
+    return files
+}

package/AutoHotkey_2.0.19/UX/inc/ui-base.ahk

@@ -0,0 +1,129 @@
+class AutoHotkeyUxGui extends Gui {
+    __new(title, opt:='') {
+        super.__new(opt, title, this)
+        this.SetFont('s9', "Segoe UI")
+        this.OnEvent('Escape', 'Destroy')
+        this.OnEvent('Close', 'Destroy')
+    }
+    
+    AddListMenu(options:='', columns:=unset) {
+        IsSet(columns) || columns := []
+        c := this.AddListView(UxListMenu.DefaultOptions ' ' options, columns)
+        if !InStr(options, 'Theme')
+            DllCall("uxtheme\SetWindowTheme", "ptr", c.hwnd, "wstr", "Explorer", "ptr", 0)
+        static LVTVIM_TILESIZE := 1, LVTVIM_COLUMNS := 2, LVTVIM_LABELMARGIN := 4
+        static LVTVIF_AUTOSIZE := 0, LVTVIF_EXTENDED := 4, LVTVIF_FIXEDHEIGHT := 2
+            , LVTVIF_FIXEDSIZE := 3, LVTVIF_FIXEDWIDTH := 1
+        static LVM_SETTILEVIEWINFO := 0x10A2
+        tileviewinfo := Buffer(40, 0)
+        ControlGetPos(,, &w,, c)
+        pad := 2 * A_ScreenDPI // 96
+        NumPut(
+            'uint', 40, ; cbSize
+            'uint', LVTVIM_LABELMARGIN | LVTVIM_TILESIZE, ; dwMask
+            'uint', LVTVIF_FIXEDWIDTH, ; dwFlags
+            'int', w, 'int', 0, ; sizeTile
+            'int', 0, ; cLines
+            'int', pad, 'int', pad, 'int', pad, 'int', pad, ; rcLabelMargin
+            tileviewinfo
+        )
+        SendMessage LVM_SETTILEVIEWINFO,, tileviewinfo, c
+        c.base := UxListMenu.Prototype
+        return c
+    }
+    
+    AddIconButton(options, iconHandle, hiddenText:="") {
+        static BS_ICON := 0x40
+        static BS_CENTER := 0x300
+        static BS_VCENTER := 0xC00
+        btn := this.AddButton((BS_ICON | BS_CENTER | BS_VCENTER) ' ' options, hiddenText)
+        static BM_SETIMAGE := 0xF7
+        SendMessage(BM_SETIMAGE, 1, iconHandle, btn)
+        return btn
+    }
+    
+    FileSelect(p*) {
+        this.Opt '+OwnDialogs'
+        try
+            return FileSelect(p*)
+        finally
+            this.Opt '-OwnDialogs'
+    }
+    
+    static Show(p*) {
+        for w in WinGetList('ahk_pid ' ProcessExist())
+            if (g := GuiFromHwnd(w)) && g.base = this.Prototype
+                return g.Show()
+        inst := this(p*)
+        inst.Show()
+    }
+}
+
+class UxListMenu extends Gui.ListView {
+    static DefaultOptions := '-Multi Tile'
+        . ' R1'
+        . ' -E0x200' ; -WS_EX_CLIENTEDGE (remove border)
+        . ' LV0x14000'
+        . Format(' Background{:x}', DllCall("GetSysColor", "int", 15, "int")) ; COLOR_3DFACE
+    
+    Add(p*) {
+        i := super.Add(p*)
+        static LVM_SETTILEINFO := 0x10A4
+        static LVCFMT_FILL := 0x200000
+        static LVCFMT_WRAP := 0x400000
+        tileinfo := Buffer(8 + 3*A_PtrSize, 0)
+        col := Buffer(4)
+        colf := Buffer(4)
+        NumPut("int", 1, col)
+        NumPut("int", LVCFMT_FILL | LVCFMT_WRAP, colf)
+        NumPut("int", tileinfo.size, "int", i-1, "uptr", 1, "ptr", col.ptr, "ptr", colf.ptr, tileinfo)
+        SendMessage(LVM_SETTILEINFO, 0, tileinfo, this)
+        return i
+    }
+    
+    _SetTileWidth(w) {
+        static LVTVIM_TILESIZE := 1, LVTVIM_COLUMNS := 2, LVTVIM_LABELMARGIN := 4
+        static LVTVIF_AUTOSIZE := 0, LVTVIF_EXTENDED := 4, LVTVIF_FIXEDHEIGHT := 2
+            , LVTVIF_FIXEDSIZE := 3, LVTVIF_FIXEDWIDTH := 1
+        static LVM_SETTILEVIEWINFO := 0x10A2
+        tileviewinfo := Buffer(40, 0)
+        pad := 2 * A_ScreenDPI // 96
+        NumPut(
+            'uint', 40, ; cbSize
+            'uint', LVTVIM_LABELMARGIN | LVTVIM_TILESIZE, ; dwMask
+            'uint', LVTVIF_FIXEDWIDTH, ; dwFlags
+            'int', w, 'int', 0, ; sizeTile
+            'int', 0, ; cLines
+            'int', pad, 'int', pad, 'int', pad, 'int', pad, ; rcLabelMargin
+            tileviewinfo
+        )
+        SendMessage LVM_SETTILEVIEWINFO,, tileviewinfo, this
+    }
+    
+    AutoSize(maxItems:=20) {
+        static LVM_GETITEMRECT := 0x100E, LVIR_BOUNDS := 0
+        static SM_CXVSCROLL := 2
+        
+        itemCount := this.GetCount()
+        
+        ; Keep control width and adjust tile width to avoid horizontal scrollbar.
+        ControlGetPos(,, &w,, this)
+        if itemCount > maxItems
+            w -= SysGet(SM_CXVSCROLL)
+        this._SetTileWidth(w)
+        
+        ; Adjust control height to fit content.
+        rect := Buffer(16, 0)
+        NumPut('int', LVIR_BOUNDS, rect)
+        SendMessage(LVM_GETITEMRECT, Min(itemCount, maxItems) - 1, rect.ptr, this)
+        iy := NumGet(rect, 4, 'int')
+        iw := NumGet(rect, 8, 'int')
+        ih := NumGet(rect, 12, 'int') - iy
+        ; Result needs additional padding.  Testing showed the width returned was less
+        ; than what we set with LVM_SETTILEVIEWINFO.  The amount of padding needed to
+        ; avoid scrollbars appeared to be exactly the amount to bring it up to the size
+        ; we specified, so perhaps something similar is happening with the height.
+        h := NumGet(rect, 12, 'int') + 4
+        ControlMove(,,, h, this)
+    }
+}

package/AutoHotkey_2.0.19/UX/install-ahk2exe.ahk

@@ -0,0 +1,53 @@
+; Run this script to launch or download and install Ahk2Exe into A_ScriptDir '\..\Compiler'.
+#requires AutoHotkey v2.0
+
+#include install.ahk
+#include inc\GetGitHubReleaseAssetURL.ahk
+
+#SingleInstance Force
+InstallAhk2Exe
+
+InstallAhk2Exe() {
+    inst := Installation()
+    inst.ResolveInstallDir()  ; This sets inst.InstallDir and inst.UserInstall
+    
+    finalPath := inst.InstallDir '\Compiler\Ahk2Exe.exe'
+    if FileExist(finalPath) {
+        ShellRun finalPath
+        ExitApp
+    }
+    
+    if !A_Args.Length {
+        (inst.UserInstall) || SetTimer(() => (
+            WinExist('ahk_class #32770 ahk_pid ' ProcessExist()) &&
+            SendMessage(0x160C,, true, 'Button1') ; BCM_SETSHIELD := 0x160C
+        ), -25)
+        if MsgBox("Ahk2Exe is not installed, but we can download and install it for you.", "AutoHotkey", 'OkCancel') = 'Cancel'
+            ExitApp
+        if !A_IsAdmin && !inst.UserInstall {
+            Run Format('*RunAs "{1}" /restart /script "{2}" /Y', A_AhkPath, A_ScriptFullPath)
+            ExitApp
+        }
+    }
+    
+    tempDir := A_ScriptDir '\.staging' ; Avoid A_Temp for security reasons
+    DirCreate tempDir
+    SetWorkingDir tempDir
+    
+    TrayTip "Downloading Ahk2Exe", "AutoHotkey"
+    url := GetGitHubReleaseAssetURL('AutoHotkey/Ahk2Exe')
+    Download url, 'Ahk2Exe.zip'
+    
+    TrayTip "Installing Ahk2Exe", "AutoHotkey"
+    DirCopy 'Ahk2Exe.zip', 'Compiler', true
+    FileDelete 'Ahk2Exe.zip'
+    
+    inst.AddCompiler(tempDir '\Compiler')
+    inst.Apply()
+    
+    ; Working dir may have been changed
+    DirDelete tempDir '\Compiler', true
+    DirDelete tempDir
+    
+    ShellRun finalPath
+}

package/AutoHotkey_2.0.19/UX/install-version.ahk

@@ -0,0 +1,109 @@
+; Run this script to download and install an additional AutoHotkey version.
+; Specify the version as a single command line parameter.  If omitted or
+; incomplete like "1.1" or "2.0", the latest version will be downloaded.
+#requires AutoHotkey v2.0
+
+#include install.ahk
+
+A_ScriptName := "AutoHotkey"
+
+InstallAutoHotkey A_Args.Length ? A_Args[1] : '1.1'
+
+InstallAutoHotkey(version) {
+    abort(message, extra?) {
+        if IsSet(extra)
+            message .= "`n`nSpecifically: " SubStr(extra, 1, 100)
+        MsgBox message,, "Iconx"
+        ExitApp
+    }
+    
+    ; Determine base version, for download directory
+    baseVersion := RegExReplace(version, '^\d+(?:\.\d+)?\b\K.*')
+    if IsInteger(baseVersion)
+        baseVersion .= baseVersion = '1' ? '.1' : '.0'
+    else if !IsNumber(baseVersion)
+        abort "Invalid version.", version
+
+    ; If version number is not exact, try to determine the latest compatible version
+    if IsNumber(version) {
+        url := Format('https://www.autohotkey.com/download/{}/version.txt', baseVersion)
+        req := ComObject('Msxml2.XMLHTTP')
+        req.open('GET', url, false)
+        req.send()
+        if req.status != 200
+            throw Error(req.status ' - ' req.statusText, -1)
+        currentVersion := req.responseText
+        if !(currentVersion ~= '^\Q' baseVersion '\E\b')
+            abort "An error occurred while trying to identify the latest available version. The downloaded version.txt was invalid.", currentVersion
+        version := currentVersion
+    }
+
+    ; Only versions for which a zip is available are supported by this script.
+    ; 1.1.00.00 - 1.1.22.06 have no downloads available at the time of writing.
+    ; 1.1.22.07 - 1.1.24.01 have one zip per exe.
+    if VerCompare(version, '1.1') >= 0 && VerCompare(version, '1.1.24.02') < 0
+        abort "This version cannot be installed automatically.", version
+
+    inst := Installation()
+    inst.ResolveInstallDir()
+
+    if A_Args.Length < 2 && !A_IsAdmin && !inst.UserInstall {
+        ExitApp RunWait(Format('*RunAs "{1}" /force /script "{2}" {3} /Y', A_AhkPath, A_ScriptFullPath, version))
+    }
+
+    zipName := VerCompare(version, '1.1.24.02') < 0
+        ? 'AutoHotkey' StrReplace(version, '.') '.zip'
+        : 'AutoHotkey_' version '.zip'
+    url := Format('https://www.autohotkey.com/download/{}/{}', baseVersion, zipName)
+
+    try {
+        tempDir := inst.InstallDir '\.staging' ; Avoid A_Temp for security reasons
+        try {
+            DirCreate tempDir
+            SetWorkingDir tempDir
+        }
+        catch OSError as e
+            abort "An error occured while preparing the temporary directory.", e.Message
+
+        TrayTip "Downloading AutoHotkey v" version, "AutoHotkey"
+        try
+            Download url, tempDir '\' zipName
+        catch
+            abort "Download failed.`n`nURL: " url
+
+        TrayTip "Installing AutoHotkey v" version, "AutoHotkey"
+        inst.SourceDir := tempDir '\v' version
+        try
+            DirCopy tempDir '\' zipName, inst.SourceDir, true
+        catch
+            abort "Extraction failed."
+        finally
+        try
+            FileDelete zipName
+        catch
+            MsgBox 'Unable to delete temporary file "' tempDir '\' zipName '".',, "Icon!"
+        
+        try localUX := inst.Hashes['UX\install.ahk']
+        catch
+            localUX := {Version: ''}
+        try {
+            if VerCompare(localUX.Version, version) < 0
+                && FileExist(inst.SourceDir '\UX\install.ahk')
+                && FileExist(inst.SourceDir '\AutoHotkey32.exe') {
+                Run Format('"{1}\AutoHotkey32.exe" UX\install.ahk /to "{2}"', inst.SourceDir, inst.InstallDir), inst.SourceDir
+                ExitApp
+            }
+            else
+                inst.InstallExtraVersion
+        }
+        catch as e
+            abort "An error occurred during installation.", e.Message
+    }
+    finally {
+        try DirDelete tempDir '\v' version, true
+        try DirDelete tempDir
+    }
+
+    TrayTip
+    MsgBox "AutoHotkey v" version " is now installed."
+}