evomeme 0.1.9 → 0.1.10-beta.13

package/dist/stage-public/godot/appearance.gd

@@ -0,0 +1,170 @@
+## Shared by Stage native preview and exported game scene. GLB materials stay PBR.
+extends RefCounted
+
+static func vec(values: Array) -> Vector3:
+	return Vector3(float(values[0]), float(values[1]), float(values[2]))
+
+static func color(values: Array) -> Color:
+	return Color(float(values[0]), float(values[1]), float(values[2]), float(values[3]) if values.size() > 3 else 1.0)
+
+static func is_collision_only(node: Node) -> bool:
+	# Blender duplicate names append .001; Godot may normalize that to _001.
+	var source_name := str(node.name).to_lower().rstrip("0123456789").trim_suffix(".").trim_suffix("_")
+	return source_name.ends_with("-colonly") or source_name.ends_with("-convcolonly")
+
+static func hide_import_helpers(node: Node) -> void:
+	# GLTFDocument.generate_scene() does not run EditorSceneFormatImporter suffix
+	# processing. Collision-only meshes must not render or cast shadows in Stage.
+	# Imported game scenes already contain physics bodies instead of these meshes.
+	if node is MeshInstance3D:
+		if is_collision_only(node):
+			node.visible = false
+	for child in node.get_children(): hide_import_helpers(child)
+
+static func prepare_vertex_colors(node: Node, cache: Dictionary) -> void:
+	# Compatibility shades in sRGB and ignores vertex_color_is_srgb. glTF COLOR_0
+	# is linear, so encode a private mesh copy once. Keep indices, skinning, UVs,
+	# blend shapes and LODs intact by only updating the existing color bytes.
+	if node is MeshInstance3D and node.mesh is ArrayMesh and not node.mesh.get_meta("canonical_srgb_colors", false):
+		var source: ArrayMesh = node.mesh
+		var source_id := source.get_instance_id()
+		if cache.has(source_id):
+			node.mesh = cache[source_id]
+		else:
+			var converted: ArrayMesh = null
+			for surface in range(source.get_surface_count()):
+				if not (source.surface_get_format(surface) & Mesh.ARRAY_FORMAT_COLOR): continue
+				if converted == null: converted = source.duplicate()
+				var data := RenderingServer.mesh_get_surface(converted.get_rid(), surface)
+				var attributes: PackedByteArray = data.attribute_data
+				var stride := RenderingServer.mesh_surface_get_format_attribute_stride(data.format, data.vertex_count)
+				var offset := RenderingServer.mesh_surface_get_format_offset(data.format, data.vertex_count, Mesh.ARRAY_COLOR)
+				for vertex in range(data.vertex_count):
+					var at := offset + vertex * stride
+					var encoded := Color(attributes[at] / 255.0, attributes[at + 1] / 255.0, attributes[at + 2] / 255.0).linear_to_srgb()
+					attributes[at] = roundi(encoded.r * 255.0)
+					attributes[at + 1] = roundi(encoded.g * 255.0)
+					attributes[at + 2] = roundi(encoded.b * 255.0)
+				converted.surface_update_attribute_region(surface, 0, attributes)
+			if converted != null:
+				converted.set_meta("canonical_srgb_colors", true)
+				cache[source_id] = converted
+				node.mesh = converted
+	for child in node.get_children(): prepare_vertex_colors(child, cache)
+
+static func apply_materials(node: Node, overrides: Array, found: Dictionary) -> void:
+	if node is MeshInstance3D:
+		for surface in range(node.mesh.get_surface_count()):
+			var original = node.get_active_material(surface)
+			if original == null:
+				continue
+			# Honor glTF COLOR_0 without discarding textures. Compatibility uses
+			# an encoded private mesh; Forward+/Mobile retain the linear data.
+			var colors = node.mesh.surface_get_arrays(surface)[Mesh.ARRAY_COLOR]
+			if original is BaseMaterial3D and colors != null and colors.size() > 0:
+				original = original.duplicate()
+				original.vertex_color_use_as_albedo = true
+				original.vertex_color_is_srgb = node.mesh.get_meta("canonical_srgb_colors", false)
+				node.set_surface_override_material(surface, original)
+			for item in overrides:
+				if original.resource_name != str(item.material_name):
+					continue
+				found[item.material_name] = true
+				if not original is BaseMaterial3D:
+					push_error("Godot material override requires PBR: " + str(item.material_name))
+					continue
+				# Duplicate the material, preserving imported textures and alpha/culling.
+				var material = original.duplicate()
+				if item.has("roughness"): material.roughness = item.roughness
+				if item.has("metallic"): material.metallic = item.metallic
+				if item.has("albedo_srgb"): material.albedo_color = color(item.albedo_srgb)
+				if item.has("emission_srgb"):
+					material.emission_enabled = true
+					material.emission = color(item.emission_srgb)
+				if item.has("emission_energy"): material.emission_energy_multiplier = item.emission_energy
+				if item.has("double_sided"): material.cull_mode = BaseMaterial3D.CULL_DISABLED if item.double_sided else BaseMaterial3D.CULL_BACK
+				node.set_surface_override_material(surface, material)
+	for child in node.get_children(): apply_materials(child, overrides, found)
+
+static func apply(parent: Node3D, model: Node3D, profile: Dictionary, camera_data: Dictionary, key: String) -> Node3D:
+	if str(profile.get("schema", "")) != "evomeme.godot_scene_profile.v1":
+		push_error("Unsupported Godot appearance profile")
+		return null
+	for child in parent.get_children():
+		if child.get_meta("canonical_appearance_asset", "") == profile.asset_id:
+			if child.get_meta("canonical_appearance_key", "") == key: return child
+			parent.remove_child(child)
+			child.queue_free()
+	var found: Dictionary = {}
+	hide_import_helpers(model)
+	if RenderingServer.get_current_rendering_method() == "gl_compatibility":
+		prepare_vertex_colors(model, {})
+	apply_materials(model, profile.materials, found)
+	for item in profile.materials:
+		if not found.has(item.material_name):
+			push_error("Godot material not found: " + str(item.material_name))
+			return null
+	# Authored contract lights replace embedded glTF lights to avoid double lighting.
+	disable_embedded_lights(model)
+	var root := Node3D.new()
+	root.name = "CanonicalAppearance"
+	root.set_meta("canonical_appearance_asset", profile.asset_id)
+	root.set_meta("canonical_appearance_key", key)
+	for item in profile.lights:
+		var light: Light3D
+		match item.type:
+			"directional": light = DirectionalLight3D.new()
+			"omni":
+				light = OmniLight3D.new()
+				light.omni_range = item.range
+			"spot":
+				light = SpotLight3D.new()
+				light.spot_range = item.range
+				light.spot_angle = item.spot_angle_degrees
+		light.name = item.name
+		light.position = vec(item.position)
+		var q: Array = item.quaternion_xyzw
+		light.quaternion = Quaternion(q[0], q[1], q[2], q[3])
+		light.light_color = color(item.color_linear).linear_to_srgb()
+		light.light_energy = item.energy
+		light.shadow_enabled = item.shadow_enabled
+		root.add_child(light)
+	var settings: Dictionary = profile.environment
+	var environment := Environment.new()
+	environment.background_mode = Environment.BG_COLOR
+	environment.background_color = color(settings.background_srgb)
+	environment.ambient_light_source = Environment.AMBIENT_SOURCE_COLOR
+	# The profile supplies ambient color, not a Sky resource. Godot defaults to
+	# 100% sky contribution, which otherwise suppresses this color/energy pair.
+	environment.ambient_light_sky_contribution = 0.0
+	environment.ambient_light_color = color(settings.ambient_srgb)
+	environment.ambient_light_energy = settings.ambient_energy
+	environment.reflected_light_source = Environment.REFLECTION_SOURCE_DISABLED
+	environment.tonemap_mode = {"linear": Environment.TONE_MAPPER_LINEAR, "filmic": Environment.TONE_MAPPER_FILMIC, "aces": Environment.TONE_MAPPER_ACES}[settings.tonemapper]
+	environment.tonemap_exposure = settings.exposure
+	environment.fog_enabled = settings.fog.enabled
+	environment.fog_light_color = color(settings.fog.color_srgb)
+	environment.fog_density = settings.fog.density
+	var world := WorldEnvironment.new()
+	world.name = "ReviewedEnvironment"
+	world.environment = environment
+	root.add_child(world)
+	if not camera_data.is_empty():
+		var camera := Camera3D.new()
+		camera.name = "ReviewedCamera"
+		camera.keep_aspect = Camera3D.KEEP_HEIGHT
+		camera.fov = camera_data.fov
+		camera.near = camera_data.near
+		camera.far = camera_data.far
+		camera.position = vec(camera_data.position)
+		var q: Array = camera_data.quaternion
+		camera.quaternion = Quaternion(q[0], q[1], q[2], q[3])
+		camera.set_meta("canonical_camera_aspect", camera_data.aspect)
+		root.add_child(camera)
+		camera.current = true
+	parent.add_child(root)
+	return root
+
+static func disable_embedded_lights(node: Node) -> void:
+	if node is Light3D: node.visible = false
+	for child in node.get_children(): disable_embedded_lights(child)

package/dist/stage-public/godot/preview.gd

@@ -0,0 +1,79 @@
+## Render an isolated Stage preview. Never opens or modifies the user's game project.
+extends SceneTree
+const Appearance = preload("appearance.gd")
+
+func _initialize() -> void:
+	call_deferred("run")
+
+func run() -> void:
+	var args := OS.get_cmdline_user_args()
+	if args.size() != 1:
+		quit(2)
+		return
+	var request: Dictionary = JSON.parse_string(FileAccess.get_file_as_string(args[0]))
+	if RenderingServer.get_current_rendering_method() != str(request.profile.renderer):
+		push_error("Stage renderer does not match the requested profile")
+		quit(7)
+		return
+	var document := GLTFDocument.new()
+	var state := GLTFState.new()
+	var error := document.append_from_file(request.model, state)
+	if error != OK:
+		push_error("GLB import failed: %s" % error)
+		quit(3)
+		return
+	var model = document.generate_scene(state)
+	if not model is Node3D:
+		quit(4)
+		return
+	var world := Node3D.new()
+	root.add_child(world)
+	var aligned := Node3D.new()
+	world.add_child(aligned)
+	aligned.add_child(model)
+	var recipe: Dictionary = request.presentation.recipe
+	aligned.position = Appearance.vec(recipe.translation_metres)
+	aligned.scale = Appearance.vec(recipe.scale_xyz)
+	var q: Array = recipe.rotation_quaternion_xyzw
+	aligned.quaternion = Quaternion(q[0], q[1], q[2], q[3])
+	var appearance = Appearance.apply(world, aligned, request.profile, request.presentation.camera, request.profile_key)
+	if appearance == null:
+		quit(5)
+		return
+	var camera: Camera3D = appearance.get_node("ReviewedCamera")
+	root.size = Vector2i(request.width, request.height)
+	root.msaa_3d = Viewport.MSAA_4X
+	# Off-screen window is used because Godot's headless display has no GPU image.
+	if not request.get("validate_only", false):
+		DisplayServer.window_set_position(Vector2i(-16000, -16000))
+		for frame in range(5): await process_frame
+		await RenderingServer.frame_post_draw
+		var image := root.get_texture().get_image()
+		if image == null or image.is_empty() or image.save_png(request.output) != OK:
+			quit(6)
+			return
+	var material_values: Dictionary = {}
+	var hidden_import_helpers := 0
+	var visible_meshes := 0
+	var srgb_color_meshes := 0
+	for node in model.find_children("*", "MeshInstance3D", true, false):
+		if node.mesh.get_meta("canonical_srgb_colors", false): srgb_color_meshes += 1
+		if node.visible: visible_meshes += 1
+		elif Appearance.is_collision_only(node):
+			hidden_import_helpers += 1
+		for surface in range(node.mesh.get_surface_count()):
+			var material = node.get_active_material(surface)
+			if material is BaseMaterial3D:
+				material_values[material.resource_name] = {"roughness": material.roughness, "metallic": material.metallic,
+					"albedo": [material.albedo_color.r,material.albedo_color.g,material.albedo_color.b], "texture": material.albedo_texture != null}
+	var report := {"ok": true, "engine": "godot", "version": Engine.get_version_info().string, "renderer": RenderingServer.get_current_rendering_method(),
+		"profile_key": request.profile_key, "revision": request.revision, "presentation": request.presentation,
+		"lights": request.profile.lights.size(), "materials": state.materials.size(), "material_values": material_values,
+		"visible_meshes": visible_meshes, "hidden_import_helpers": hidden_import_helpers,
+		"srgb_color_meshes": srgb_color_meshes, "msaa_3d": root.msaa_3d,
+		"camera_position": [camera.position.x, camera.position.y, camera.position.z], "camera_fov": camera.fov,
+		"exposure": appearance.get_node("ReviewedEnvironment").environment.tonemap_exposure,
+		"ambient_sky_contribution": appearance.get_node("ReviewedEnvironment").environment.ambient_light_sky_contribution,
+		"ambient_energy": appearance.get_node("ReviewedEnvironment").environment.ambient_light_energy}
+	FileAccess.open(request.report, FileAccess.WRITE).store_string(JSON.stringify(report))
+	quit(0)

package/dist/stage-public/index.html

@@ -0,0 +1,141 @@
+<!doctype html>
+<html lang="zh-CN">
+  <head>
+    <meta charset="UTF-8" />
+    <meta name="viewport" content="width=device-width, initial-scale=1.0" />
+    <title>Stage · 默认 3D 展板</title>
+    <link rel="preconnect" href="https://fonts.googleapis.com" />
+    <link rel="preconnect" href="https://fonts.gstatic.com" crossorigin />
+    <link
+      href="https://fonts.googleapis.com/css2?family=IBM+Plex+Sans:wght@400;500;600;700&family=IBM+Plex+Mono:wght@400;500&display=swap"
+      rel="stylesheet"
+    />
+    <link rel="stylesheet" href="/styles.css" />
+    <script type="importmap">
+      {
+        "imports": {
+          "three": "https://unpkg.com/three@0.185.0/build/three.module.js",
+          "three/addons/": "https://unpkg.com/three@0.185.0/examples/jsm/"
+        }
+      }
+    </script>
+  </head>
+  <body>
+    <div class="shell">
+      <aside class="rail">
+        <header class="brand">
+          <p class="eyebrow">evomeme</p>
+          <h1>Stage</h1>
+          <p class="tagline">默认 3D 展板 · 预览 · 对齐 · 导出通用包</p>
+        </header>
+        <div class="rail-guide" id="empty-state">
+          <p>选择下方资产，或用 MCP / CLI 先创建 canonical 包</p>
+          <code>assets/canonical/&lt;asset_id&gt;/</code>
+        </div>
+        <button type="button" class="primary" id="refresh-btn">刷新列表</button>
+        <div class="list" id="package-list"></div>
+        <p class="hint" id="status">加载中…</p>
+      </aside>
+
+      <main class="stage">
+        <div id="viewport-frame">
+          <div id="viewport"></div>
+        </div>
+        <div class="gizmo-bar" id="gizmo-bar" hidden>
+          <span class="gizmo-label">轴向</span>
+          <button type="button" class="gizmo-btn active" data-gizmo="rotate" title="抓住轴环拖动旋转">旋转</button>
+          <button type="button" class="gizmo-btn" data-gizmo="translate" title="抓住轴线拖动平移">平移</button>
+          <button type="button" class="gizmo-btn" data-space="local" title="切换局部/世界坐标">局部</button>
+          <span class="gizmo-hint">拖轴时禁用轨道；旋转写入 yaw/pitch/roll</span>
+        </div>
+        <div class="gizmo-bar camera-bar" id="camera-bar" hidden>
+          <span class="gizmo-label">相机</span>
+          <button type="button" class="gizmo-btn active" data-camera="reference">reference</button>
+          <button type="button" class="gizmo-btn" data-camera="overview">overview</button>
+          <button type="button" class="gizmo-btn" data-camera="detail">detail</button>
+          <button type="button" class="gizmo-btn" data-camera="free">自由</button>
+          <span class="gizmo-hint">1.88 letterbox · 契约灯光/雾近似重建</span>
+        </div>
+      </main>
+
+      <aside class="inspector" id="inspector" hidden>
+        <header>
+          <h2 id="asset-title">资产</h2>
+          <p class="mono" id="asset-path"></p>
+        </header>
+
+        <label>
+          类型
+          <select id="field-type">
+            <option value="avatar">avatar</option>
+            <option value="character">character</option>
+            <option value="npc">npc</option>
+            <option value="prop">prop</option>
+            <option value="weapon">weapon</option>
+            <option value="vehicle">vehicle</option>
+            <option value="environment">environment</option>
+            <option value="static_mesh">static_mesh</option>
+            <option value="scene">scene</option>
+          </select>
+        </label>
+
+        <label>
+          朝向 forward_axis
+          <select id="field-forward">
+            <option value="+z">+z</option>
+            <option value="-z">-z</option>
+            <option value="+x">+x</option>
+            <option value="-x">-x</option>
+            <option value="+y">+y</option>
+            <option value="-y">-y</option>
+          </select>
+        </label>
+
+        <label>
+          pivot
+          <select id="field-pivot">
+            <option value="ground_center">ground_center</option>
+            <option value="origin">origin</option>
+            <option value="bounds_center">bounds_center</option>
+          </select>
+        </label>
+
+        <label>
+          尺度 scale_hint_metres
+          <input id="field-scale" type="number" min="0.01" step="0.01" placeholder="空=null，不按高度缩放" />
+        </label>
+
+        <label>
+          yaw 附加偏移 (°)
+          <input id="field-yaw" type="number" step="0.1" value="0" />
+        </label>
+
+        <label>
+          pitch 附加偏移 (°)
+          <input id="field-pitch" type="number" step="0.1" value="0" />
+        </label>
+
+        <label>
+          roll 附加偏移 (°)
+          <input id="field-roll" type="number" step="0.1" value="0" />
+        </label>
+
+        <label>
+          备注
+          <textarea id="field-notes" rows="3" placeholder="眼睛在 +Z 侧…"></textarea>
+        </label>
+
+        <div class="meta" id="runtime-meta"></div>
+
+        <div class="actions">
+          <button type="button" class="primary" id="save-btn">保存并对齐预览</button>
+          <button type="button" id="export-btn">导出通用包路径</button>
+        </div>
+        <p class="hint">
+          调整会写入 <code>asset.json</code>；导出目录可直接给 three.js / Godot 消费。不要在玩法里硬转旋转。
+        </p>
+      </aside>
+    </div>
+    <script type="module" src="/app.js"></script>
+  </body>
+</html>