@pkmn/engine 0.1.0-dev.d716e940 → 0.1.0-dev.d73cd76c

package/src/lib/bindings/node.zig

@@ -0,0 +1,117 @@
+const c = @import("napi");
+const js = @import("../common/js.zig");
+const pkmn = @import("../pkmn.zig");
+const std = @import("std");
+
+const assert = std.debug.assert;
+
+pub fn register(env: c.napi_env) c.napi_value {
+    const object = js.Object.init(env);
+    const properties = [_]c.napi_property_descriptor{
+        js.Property.init("options", .{ .value = options(env) }),
+        js.Property.init("bindings", .{ .value = bindings(env) }),
+    };
+    assert(c.napi_define_properties(env, object, properties.len, &properties) == c.napi_ok);
+    return object;
+}
+
+fn options(env: c.napi_env) c.napi_value {
+    const object = js.Object.init(env);
+    const properties = [_]c.napi_property_descriptor{
+        js.Property.init("showdown", .{ .value = js.Boolean.init(env, pkmn.options.showdown) }),
+        js.Property.init("log", .{ .value = js.Boolean.init(env, pkmn.options.log) }),
+        js.Property.init("chance", .{ .value = js.Boolean.init(env, pkmn.options.chance) }),
+        js.Property.init("calc", .{ .value = js.Boolean.init(env, pkmn.options.calc) }),
+    };
+    assert(c.napi_define_properties(env, object, properties.len, &properties) == c.napi_ok);
+    return object;
+}
+
+fn bindings(env: c.napi_env) c.napi_value {
+    const array = js.Array.init(env, .{ .length = 1 });
+    js.Array.set(env, array, 0, bind(env, pkmn.gen1));
+    return array;
+}
+
+fn bind(env: c.napi_env, gen: anytype) c.napi_value {
+    const choices_size: u32 = @intCast(gen.CHOICES_SIZE);
+    const logs_size: u32 = @intCast(gen.LOGS_SIZE);
+    const object = js.Object.init(env);
+    const properties = [_]c.napi_property_descriptor{
+        js.Property.init("CHOICES_SIZE", .{ .value = js.Number.init(env, choices_size) }),
+        js.Property.init("LOGS_SIZE", .{ .value = js.Number.init(env, logs_size) }),
+        js.Property.init("update", .{ .method = update(gen) }),
+        js.Property.init("choices", .{ .method = choices(gen) }),
+    };
+    assert(c.napi_define_properties(env, object, properties.len, &properties) == c.napi_ok);
+    return object;
+}
+
+fn update(gen: anytype) c.napi_callback {
+    return struct {
+        fn call(env: c.napi_env, info: c.napi_callback_info) callconv(.c) c.napi_value {
+            var argc: usize = 4;
+            var argv: [4]c.napi_value = undefined;
+            assert(c.napi_get_cb_info(env, info, &argc, &argv, null, null) == c.napi_ok);
+            assert(argc == 4);
+
+            var data: ?*anyopaque = undefined;
+            var len: usize = 0;
+            assert(c.napi_get_arraybuffer_info(env, argv[0], &data, &len) == c.napi_ok);
+            assert(len == @sizeOf(gen.Battle(gen.PRNG)));
+
+            var battle: *gen.Battle(gen.PRNG) = @ptrCast(@alignCast(data.?));
+            const c1: pkmn.Choice = @bitCast(js.Number.get(env, argv[1], u8));
+            const c2: pkmn.Choice = @bitCast(js.Number.get(env, argv[2], u8));
+
+            var vtype: c.napi_valuetype = undefined;
+            assert(c.napi_typeof(env, argv[3], &vtype) == c.napi_ok);
+            const result = switch (vtype) {
+                c.napi_undefined, c.napi_null => battle.update(c1, c2, &gen.NULL),
+                else => result: {
+                    assert(c.napi_get_arraybuffer_info(env, argv[3], &data, &len) == c.napi_ok);
+                    assert(len == gen.LOGS_SIZE);
+
+                    const buf = @as([*]u8, @ptrCast(data.?))[0..gen.LOGS_SIZE];
+                    var writer: pkmn.protocol.Writer = .{ .buffer = buf };
+                    // TODO: extract out
+                    var opts = pkmn.battle.options(
+                        pkmn.protocol.FixedLog{ .writer = &writer },
+                        gen.chance.NULL,
+                        gen.calc.NULL,
+                    );
+                    break :result battle.update(c1, c2, &opts);
+                },
+            } catch unreachable;
+
+            return js.Number.init(env, @as(u8, @bitCast(result)));
+        }
+    }.call;
+}
+
+fn choices(gen: anytype) c.napi_callback {
+    return struct {
+        fn call(env: c.napi_env, info: c.napi_callback_info) callconv(.c) c.napi_value {
+            var argc: usize = 4;
+            var argv: [4]c.napi_value = undefined;
+            assert(c.napi_get_cb_info(env, info, &argc, &argv, null, null) == c.napi_ok);
+            assert(argc == 4);
+
+            var data: ?*anyopaque = undefined;
+            var len: usize = 0;
+            assert(c.napi_get_arraybuffer_info(env, argv[0], &data, &len) == c.napi_ok);
+            assert(len == @sizeOf(gen.Battle(gen.PRNG)));
+
+            var battle: *gen.Battle(gen.PRNG) = @ptrCast(@alignCast(data.?));
+            const player: pkmn.Player = @enumFromInt(js.Number.get(env, argv[1], u8));
+            const request: pkmn.Choice.Type = @enumFromInt(js.Number.get(env, argv[2], u8));
+
+            assert(c.napi_get_arraybuffer_info(env, argv[3], &data, &len) == c.napi_ok);
+            assert(len == gen.CHOICES_SIZE);
+
+            const out = @as([*]pkmn.Choice, @ptrCast(data.?))[0..gen.CHOICES_SIZE];
+            const n = battle.choices(player, request, out);
+            return js.Number.init(env, @as(u8, @bitCast(n)));
+        }
+    }.call;
+}

package/src/lib/bindings/wasm.zig

@@ -0,0 +1,51 @@
+const pkmn = @import("../pkmn.zig");
+const std = @import("std");
+const util = @import("../common/util.zig");
+
+const assert = std.debug.assert;
+
+pub const options = pkmn.options;
+
+pub fn gen(comptime num: comptime_int) type {
+    const g = @field(pkmn, "gen" ++ std.fmt.comptimePrint("{d}", .{num}));
+    return struct {
+        pub const CHOICES_SIZE = size(g.CHOICES_SIZE);
+        pub const LOGS_SIZE = size(g.LOGS_SIZE);
+
+        pub fn update(
+            battle: *g.Battle(g.PRNG),
+            c1: pkmn.Choice,
+            c2: pkmn.Choice,
+            options_: ?[*]u8,
+        ) callconv(.c) pkmn.Result {
+            return (if (options_) |o| result: {
+                const buf = @as([*]u8, @ptrCast(o))[0..g.LOGS_SIZE];
+                var writer: pkmn.protocol.Writer = .{ .buffer = buf };
+                // TODO: extract out
+                var opts = pkmn.battle.options(
+                    pkmn.protocol.FixedLog{ .writer = &writer },
+                    g.chance.NULL,
+                    g.calc.NULL,
+                );
+                break :result battle.update(c1, c2, &opts);
+            } else battle.update(c1, c2, &g.NULL)) catch unreachable;
+        }
+
+        pub fn choices(
+            battle: *g.Battle(g.PRNG),
+            player: u8,
+            request: u8,
+            buf: [*]u8,
+        ) callconv(.c) u8 {
+            assert(player <= util.EnumFieldsLen(pkmn.Player));
+            assert(request <= util.EnumFieldsLen(pkmn.Choice.Type));
+
+            const n = CHOICES_SIZE;
+            return battle.choices(@enumFromInt(player), @enumFromInt(request), @ptrCast(buf[0..n]));
+        }
+    };
+}
+
+fn size(n: usize) u32 {
+    return std.math.ceilPowerOfTwo(u32, @as(u32, @intCast(n))) catch unreachable;
+}

package/src/lib/common/array.zig

@@ -0,0 +1,70 @@
+const std = @import("std");
+
+const expectEqual = std.testing.expectEqual;
+const assert = std.debug.assert;
+
+/// Helpers for working with bit-packed arrays of non-powers-of-2 types.
+/// NOTE: ziglang/zig#12547
+pub fn Array(comptime n: comptime_int, comptime U: type) type {
+    return struct {
+        const size = @bitSizeOf(U);
+        pub const T = @Int(.unsigned, size * n);
+
+        /// Returns the value stored at index `i` in the array `a`.
+        pub fn get(a: T, i: usize) U {
+            assert(i < n);
+            const shift = i * size;
+            const mask: T = (1 << size) - 1;
+            const result = (a >> @intCast(shift)) & mask;
+            return switch (@typeInfo(U)) {
+                .@"enum" => @enumFromInt(result),
+                .int => @intCast(result),
+                else => unreachable,
+            };
+        }
+
+        /// Sets the value at index `i` to `val` in the array `a`.
+        pub fn set(a: T, i: usize, val: U) T {
+            assert(i < n);
+            const v: T = switch (@typeInfo(U)) {
+                .@"enum" => @intFromEnum(val),
+                .int => @intCast(val),
+                else => unreachable,
+            };
+            const shift = i * size;
+            const mask: T = @as(T, @intCast((1 << size) - 1)) << @intCast(shift);
+            const result: T = a & ~mask;
+            return result | (v << @intCast(shift));
+        }
+    };
+}
+
+test Array {
+    const A = Array(5, u8);
+    var a: A.T = 0;
+    try expectEqual(u40, @TypeOf(a));
+
+    a = A.set(a, 4, 241);
+    try expectEqual(@as(u8, 241), A.get(a, 4));
+    a = A.set(a, 4, 1);
+    try expectEqual(@as(u8, 1), A.get(a, 4));
+
+    for (0..5) |i| a = A.set(a, i, @intCast(i));
+    for (0..5) |i| try expectEqual(@as(u8, @intCast(i)), A.get(a, i));
+
+    const Optional = @import("optional.zig").Optional;
+
+    const B = Array(4, Optional(bool));
+    var b: B.T = 0;
+    try expectEqual(u8, @TypeOf(b));
+
+    b = B.set(b, 2, .true);
+    try expectEqual(Optional(bool).None, B.get(b, 1));
+    try expectEqual(Optional(bool).true, B.get(b, 2));
+    try expectEqual(@as(u8, 0b00100000), b);
+    b = B.set(b, 2, .None);
+    b = B.set(b, 0, .false);
+    try expectEqual(Optional(bool).None, B.get(b, 2));
+    try expectEqual(Optional(bool).false, B.get(b, 0));
+    try expectEqual(@as(u8, 0b0000001), b);
+}

package/src/lib/common/battle.zig

@@ -0,0 +1,17 @@
+/// Stores state required by optional features to the engine that can be passed to a generation's
+/// `Battle.update` function. All generations generically support protocol logging (enabled via
+/// `-Dlog`), chance actions and probability tracking (enabled via `-Dchance`), and damage
+/// computation and chance overrides (`-Dcalc`), though the concrete types for these features are
+/// generation dependent.
+pub fn Options(comptime Log: type, comptime Chance: type, comptime Calc: type) type {
+    return struct { log: Log, chance: Chance, calc: Calc };
+}
+
+/// Helper to create a battle `Options` object with the provided `log`, `chance`, and `calc`.
+pub fn options(
+    log: anytype,
+    chance: anytype,
+    calc: anytype,
+) Options(@TypeOf(log), @TypeOf(chance), @TypeOf(calc)) {
+    return .{ .log = log, .chance = chance, .calc = calc };
+}

package/src/lib/common/data.zig

@@ -9,12 +9,12 @@ pub const Player = enum(u1) {
     P2,
 
     /// Returns a player's opponent.
-    pub inline fn foe(self: Player) Player {
-        return @intToEnum(Player, ~@enumToInt(self));
+    pub fn foe(self: Player) Player {
+        return @enumFromInt(~@intFromEnum(self));
     }
 
     /// Return's an identifier for the player's Pokémon at the one-indexed `id`.
-    pub inline fn ident(self: Player, id: u3) ID {
+    pub fn ident(self: Player, id: u3) ID {
         assert(id > 0 and id <= 6);
         return .{ .id = id, .player = self };
     }
@@ -22,42 +22,38 @@ pub const Player = enum(u1) {
 
 test Player {
     try expectEqual(Player.P2, Player.P1.foe());
-    try expectEqual(@as(u8, 0b0001), @bitCast(u8, Player.P1.ident(1)));
-    try expectEqual(@as(u8, 0b1101), @bitCast(u8, Player.P2.ident(5)));
+    try expectEqual(@as(u8, 0b0001), @as(u8, @bitCast(Player.P1.ident(1))));
+    try expectEqual(@as(u8, 0b1101), @as(u8, @bitCast(Player.P2.ident(5))));
 }
 
 /// An identifier for a specific Pokémon in battle.
-pub const ID = packed struct {
+pub const ID = packed struct(u8) {
     /// The one-indexed team slot of the Pokémon
     id: u3 = 0,
     /// The Pokémon's trainer.
     player: Player = .P1,
     _: u4 = 0,
 
-    comptime {
-        assert(@sizeOf(ID) == 1);
-    }
-
     /// Converts the identifier into a number.
-    pub inline fn int(self: ID) u4 {
-        return @intCast(u4, @bitCast(u8, self));
+    pub fn int(self: ID) u4 {
+        return @intCast(@as(u8, @bitCast(self)));
     }
 
     /// Decodes the identifier from a number.
-    pub inline fn from(id: u4) ID {
-        return @bitCast(ID, @as(u8, id));
+    pub fn from(id: u4) ID {
+        return @bitCast(@as(u8, id));
     }
 };
 
 test ID {
-    try expectEqual(@as(u8, 0b0001), @bitCast(u8, ID{ .player = .P1, .id = 1 }));
-    try expectEqual(@as(u8, 0b1101), @bitCast(u8, ID{ .player = .P2, .id = 5 }));
-    const id = ID{ .player = .P2, .id = 4 };
+    try expectEqual(@as(u8, 0b0001), @as(u8, @bitCast(ID{ .player = .P1, .id = 1 })));
+    try expectEqual(@as(u8, 0b1101), @as(u8, @bitCast(ID{ .player = .P2, .id = 5 })));
+    const id: ID = .{ .player = .P2, .id = 4 };
     try expectEqual(id, ID.from(id.int()));
 }
 
 /// A choice made by a player during battle.
-pub const Choice = packed struct {
+pub const Choice = packed struct(u8) {
     /// The choice type.
     type: Choice.Type = .Pass,
     /// The choice data:
@@ -73,10 +69,6 @@ pub const Choice = packed struct {
         Move,
         Switch,
     };
-
-    comptime {
-        assert(@sizeOf(Choice) == 1);
-    }
 };
 
 test Choice {
@@ -84,12 +76,12 @@ test Choice {
     const p2: Choice = .{ .type = .Switch, .data = 5 };
     try expectEqual(5, p2.data);
     try expectEqual(Choice.Type.Move, p1.type);
-    try expectEqual(0b0001_0001, @bitCast(u8, p1));
-    try expectEqual(0b0001_0110, @bitCast(u8, p2));
+    try expectEqual(@as(u8, 0b0001_0001), @as(u8, @bitCast(p1)));
+    try expectEqual(@as(u8, 0b0001_0110), @as(u8, @bitCast(p2)));
 }
 
 /// The result of the battle - all results other than 'None' should be considered terminal.
-pub const Result = packed struct {
+pub const Result = packed struct(u8) {
     /// The type of result from the perspective of Player 1.
     /// `Error` is not possible when in Pokémon Showdown compatibility mode.
     type: Result.Type = .None,
@@ -117,13 +109,9 @@ pub const Result = packed struct {
     pub const Error: Result = .{ .type = .Error };
     /// The default result.
     pub const Default: Result = .{ .p1 = .Move, .p2 = .Move };
-
-    comptime {
-        assert(@sizeOf(Result) == 1);
-    }
 };
 
 test Result {
-    try expectEqual(0b0101_0000, @bitCast(u8, Result.Default));
-    try expectEqual(0b1000_0000, @bitCast(u8, Result{ .p2 = .Switch }));
+    try expectEqual(@as(u8, 0b0101_0000), @as(u8, @bitCast(Result.Default)));
+    try expectEqual(@as(u8, 0b1000_0000), @as(u8, @bitCast(Result{ .p2 = .Switch })));
 }

package/src/lib/common/debug.zig

@@ -1,65 +1,90 @@
+const builtin = @import("builtin");
 const std = @import("std");
 
 const debug = std.debug;
-const io = std.io;
 
 pub fn print(value: anytype) void {
-    debug.getStderrMutex().lock();
-    defer debug.getStderrMutex().unlock();
-    const stderr = io.getStdErr().writer();
+    if (builtin.target.os.tag == .freestanding) return;
+
+    var buffer: [4096]u8 = undefined;
+    const stderr = debug.lockStderr(&buffer);
+    defer debug.unlockStderr();
+    var fw = stderr.file_writer;
 
     nosuspend {
-        stderr.writeAll("\x1b[41m") catch return;
-        switch (@typeInfo(@TypeOf(value))) {
-            .Struct => |info| {
-                if (info.is_tuple) {
-                    inline for (info.fields, 0..) |f, i| {
-                        inspect(@field(value, f.name));
-                        if (i < info.fields.len - 1) stderr.writeAll(" ") catch return;
+        fw.interface.writeAll("\x1b[41m") catch return;
+        if (@TypeOf(@src()) == @TypeOf(value)) {
+            fw.interface.print("{s} ({s}:{d}:{d})", .{
+                value.fn_name,
+                value.file,
+                value.line,
+                value.column,
+            }) catch return;
+        } else {
+            switch (@typeInfo(@TypeOf(value))) {
+                .@"struct" => |info| {
+                    if (info.is_tuple) {
+                        if (@hasField(@TypeOf(info), "fields")) {
+                            inline for (info.fields, 0..) |f, i| {
+                                inspect(fw, @field(value, f.name));
+                                if (i < info.fields.len - 1) {
+                                    fw.interface.writeAll(" ") catch return;
+                                }
+                            }
+                        } else {
+                            inline for (info.field_names, 0..) |name, i| {
+                                inspect(fw, @field(value, name));
+                                if (i < info.field_names.len - 1) {
+                                    fw.interface.writeAll(" ") catch return;
+                                }
+                            }
+                        }
+                    } else {
+                        inspect(fw, value);
                     }
-                } else {
-                    inspect(value);
-                }
-            },
-            else => inspect(value),
+                },
+                else => inspect(fw, value),
+            }
         }
-        stderr.writeAll("\x1b[K\x1b[0m\n") catch return;
+        fw.interface.writeAll("\x1b[K\x1b[0m\n") catch return;
     }
 }
 
-fn inspect(value: anytype) void {
-    const stderr = io.getStdErr().writer();
-
+fn inspect(w: anytype, value: anytype) void {
     nosuspend {
         const err = "Unable to format type '" ++ @typeName(@TypeOf(value)) ++ "'";
         switch (@typeInfo(@TypeOf(value))) {
-            .Array => |info| {
-                if (info.child == u8) return stderr.print("{s}", .{value}) catch return;
+            .array => |info| {
+                if (info.child == u8) return w.interface.print("{s}", .{value}) catch return;
                 @compileError(err);
             },
-            .Pointer => |ptr_info| switch (ptr_info.size) {
-                .One => switch (@typeInfo(ptr_info.child)) {
-                    .Array => |info| {
-                        if (info.child == u8) return stderr.print("{s}", .{value}) catch return;
+            .pointer => |ptr_info| switch (ptr_info.size) {
+                .one => switch (@typeInfo(ptr_info.child)) {
+                    .array => |info| {
+                        if (info.child == u8) {
+                            return w.interface.print("{s}", .{value}) catch return;
+                        }
                         @compileError(err);
                     },
-                    .Enum, .Union, .Struct => return inspect(value.*),
+                    .@"enum", .@"union", .@"struct" => return inspect(value.*),
                     else => @compileError(err),
                 },
-                .Many, .C => {
+                .many, .c => {
                     if (ptr_info.sentinel) |_| return inspect(std.mem.span(value));
                     if (ptr_info.child == u8) {
-                        return stderr.print("{s}", .{std.mem.span(value)}) catch return;
+                        return w.interface.print("{s}", .{std.mem.span(value)}) catch return;
                     }
                     @compileError(err);
                 },
-                .Slice => {
-                    if (ptr_info.child == u8) return stderr.print("{s}", .{value}) catch return;
+                .slice => {
+                    if (ptr_info.child == u8) {
+                        return w.interface.print("{s}", .{value}) catch return;
+                    }
                     @compileError(err);
                 },
             },
-            .Optional => stderr.print("{?}", .{value}) catch return,
-            else => stderr.print("{}", .{value}) catch return,
+            .optional => w.interface.print("{?}", .{value}) catch return,
+            else => w.interface.print("{}", .{value}) catch return,
         }
     }
 }

package/src/lib/common/js.zig

@@ -0,0 +1,114 @@
+const std = @import("std");
+const c = @import("napi");
+
+const assert = std.debug.assert;
+
+pub const Array = struct {
+    pub fn init(env: c.napi_env, o: struct { length: ?usize }) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_ok == if (o.length) |n|
+            c.napi_create_array_with_length(env, n, &result)
+        else
+            c.napi_create_array(env, &result));
+        return result;
+    }
+
+    pub fn set(env: c.napi_env, array: c.napi_value, index: u32, value: c.napi_value) void {
+        assert(c.napi_set_element(env, array, index, value) == c.napi_ok);
+    }
+};
+
+pub const Boolean = struct {
+    pub fn init(env: c.napi_env, value: bool) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_get_boolean(env, value, &result) == c.napi_ok);
+        return result;
+    }
+};
+
+pub const Number = struct {
+    pub fn init(env: c.napi_env, value: anytype) c.napi_value {
+        const T = @TypeOf(value);
+        var result: c.napi_value = undefined;
+        assert(c.napi_ok == switch (@typeInfo(T)) {
+            .int => |info| switch (info.bits) {
+                0...32 => switch (info.signedness) {
+                    .signed => c.napi_create_int32(env, @as(i32, value), &result),
+                    .unsigned => c.napi_create_uint32(env, @as(u32, value), &result),
+                },
+                33...52 => c.napi_create_int64(env, @as(i64, value), &result),
+                else => @compileError("int can't be represented as JS number"),
+            },
+            else => @compileError("expected number, got: " ++ @typeName(T)),
+        });
+        return result;
+    }
+
+    pub fn get(env: c.napi_env, value: c.napi_value, comptime T: type) T {
+        switch (@typeInfo(T)) {
+            .int => |info| switch (info.bits) {
+                0...32 => switch (info.signedness) {
+                    .signed => {
+                        var result: i32 = undefined;
+                        assert(c.napi_get_value_int32(env, value, &result) == c.napi_ok);
+                        return if (info.bits == 32) result else @intCast(result);
+                    },
+                    .unsigned => {
+                        var result: u32 = undefined;
+                        assert(c.napi_get_value_uint32(env, value, &result) == c.napi_ok);
+                        return if (info.bits == 32) result else @intCast(result);
+                    },
+                },
+                33...63 => {
+                    var result: i64 = undefined;
+                    assert(c.napi_get_value_int64(env, value, &result) == c.napi_ok);
+                    return @intCast(result);
+                },
+                else => {
+                    var result: i64 = undefined;
+                    assert(c.napi_get_value_int64(env, value, &result) == c.napi_ok);
+                    return switch (info.signedness) {
+                        .signed => value,
+                        .unsigned => if (0 <= value) @intCast(value) else unreachable,
+                    };
+                },
+            },
+            else => @compileError("expected number, got: " ++ @typeName(T)),
+        }
+    }
+};
+
+pub const Object = struct {
+    pub fn init(env: c.napi_env) c.napi_value {
+        var result: c.napi_value = undefined;
+        assert(c.napi_create_object(env, &result) == c.napi_ok);
+        return result;
+    }
+};
+
+pub const Property = union(enum) {
+    method: c.napi_callback,
+    value: c.napi_value,
+
+    pub fn init(comptime name: [:0]const u8, property: Property) c.napi_property_descriptor {
+        return .{
+            .utf8name = name,
+            .name = null,
+            .method = switch (property) {
+                .method => |m| m,
+                .value => null,
+            },
+            .getter = null,
+            .setter = null,
+            .value = switch (property) {
+                .method => null,
+                .value => |v| v,
+            },
+            .attributes = switch (property) {
+                .method => c.napi_default,
+                .value => c.napi_enumerable,
+            },
+            .data = null,
+        };
+    }
+};

package/src/lib/common/optional.zig

@@ -0,0 +1,71 @@
+const std = @import("std");
+
+const expect = std.testing.expect;
+const assert = std.debug.assert;
+
+/// Optimized optional representation which stores the empty None value as a sentinel.
+/// NOTE: ziglang/zig#104
+pub fn Optional(comptime T: type) type {
+    const names = if (@hasDecl(std.meta, "fieldNames"))
+        std.meta.fieldNames(switch (@typeInfo(T)) {
+            .bool => enum { false, true },
+            else => T,
+        })
+    else blk: {
+        const fields = std.meta.fields(switch (@typeInfo(T)) {
+            .bool => enum { false, true },
+            else => T,
+        });
+        var ns: [fields.len][:0]const u8 = undefined;
+        inline for (fields, 0..) |f, i| ns[i] = f.name;
+        break :blk &ns;
+    };
+
+    const TagType = std.math.IntFittingRange(0, names.len);
+    var fieldNames: [names.len + 1][]const u8 = undefined;
+    var fieldValues: [names.len + 1]TagType = undefined;
+
+    fieldNames[0] = "None";
+    fieldValues[0] = 0;
+
+    inline for (names, 1..) |name, i| {
+        assert(!std.mem.eql(u8, name, "None"));
+        fieldNames[i] = name;
+        fieldValues[i] = i;
+    }
+
+    return @Enum(TagType, .exhaustive, &fieldNames, &fieldValues);
+}
+
+test Optional {
+    try expect(@bitSizeOf(Optional(bool)) == 2);
+
+    const a: Optional(bool) = .true;
+    try expect(a != .None);
+    try expect(a == .true);
+    try expect(a != .false);
+
+    const b: Optional(bool) = .None;
+    try expect(b == .None);
+    try expect(b != .true);
+    try expect(b != .false);
+
+    const Player = @import("data.zig").Player;
+    try expect(@bitSizeOf(Optional(Player)) == 2);
+
+    const p: Optional(Player) = .P2;
+    try expect(p != .None);
+    try expect(p != .P1);
+    try expect(p == .P2);
+
+    const q: Optional(Player) = .None;
+    try expect(q == .None);
+    try expect(q != .P1);
+    try expect(q != .P2);
+
+    const Three = enum(u2) { A, B, C };
+    try expect(@bitSizeOf(Optional(Three)) == 2);
+
+    const Four = enum(u2) { A, B, C, D };
+    try expect(@bitSizeOf(Optional(Four)) == 3);
+}