@etherisc/gif-next 0.0.2-ebbe63d → 0.0.2-efdb520-159

package/contracts/types/UFixed.sol

@@ -0,0 +1,206 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {Math} from "@openzeppelin/contracts/utils/math/Math.sol";
+
+/// @dev UFixed is a fixed point number with 18 decimals precision.
+type UFixed is uint256;
+
+using {
+    addUFixed as +,
+    subUFixed as -,
+    mulUFixed as *,
+    divUFixed as /,
+    gtUFixed as >,
+    gteUFixed as >=,
+    ltUFixed as <,
+    lteUFixed as <=,
+    eqUFixed as ==,
+    UFixedMathLib.toInt
+} for UFixed global;
+
+function addUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    return UFixed.wrap(UFixed.unwrap(a) + UFixed.unwrap(b));
+}
+
+function subUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    require(a >= b, "ERROR:UFM-010:NEGATIVE_RESULT");
+    return UFixed.wrap(UFixed.unwrap(a) - UFixed.unwrap(b));
+}
+
+function mulUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    return
+        UFixed.wrap(Math.mulDiv(UFixed.unwrap(a), UFixed.unwrap(b), 10 ** 18));
+}
+
+function divUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    require(UFixed.unwrap(b) > 0, "ERROR:UFM-020:DIVISOR_ZERO");
+
+    return
+        UFixed.wrap(Math.mulDiv(UFixed.unwrap(a), 10 ** 18, UFixed.unwrap(b)));
+}
+
+function gtUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) > UFixed.unwrap(b);
+}
+
+function gteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) >= UFixed.unwrap(b);
+}
+
+function ltUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) < UFixed.unwrap(b);
+}
+
+function lteUFixed(UFixed a, UFixed b) pure returns (bool isGreaterThan) {
+    return UFixed.unwrap(a) <= UFixed.unwrap(b);
+}
+
+function eqUFixed(UFixed a, UFixed b) pure returns (bool isEqual) {
+    return UFixed.unwrap(a) == UFixed.unwrap(b);
+}
+
+function gtzUFixed(UFixed a) pure returns (bool isZero) {
+    return UFixed.unwrap(a) > 0;
+}
+
+function eqzUFixed(UFixed a) pure returns (bool isZero) {
+    return UFixed.unwrap(a) == 0;
+}
+
+function deltaUFixed(UFixed a, UFixed b) pure returns (UFixed) {
+    if (a > b) {
+        return a - b;
+    }
+
+    return b - a;
+}
+
+library UFixedMathLib {
+    enum Rounding {
+        /// @dev Round down - floor(value)
+        Down,
+        /// @dev Round up - ceil(value)
+        Up,
+        /// @dev Round half up - round(value)
+        HalfUp
+    }
+
+    int8 public constant EXP = 18;
+    uint256 public constant MULTIPLIER = 10 ** uint256(int256(EXP));
+    uint256 public constant MULTIPLIER_HALF = MULTIPLIER / 2;
+
+    /// @dev Converts the uint256 to a UFixed.
+    function toUFixed(uint256 a) public pure returns (UFixed) {
+        return UFixed.wrap(a * MULTIPLIER);
+    }
+
+    /// @dev Converts the uint256 to a UFixed with given exponent.
+    function toUFixed(uint256 a, int8 exp) public pure returns (UFixed) {
+        require(EXP + exp >= 0, "ERROR:FM-010:EXPONENT_TOO_SMALL");
+        require(EXP + exp <= 64, "ERROR:FM-011:EXPONENT_TOO_LARGE");
+
+        return UFixed.wrap(a * 10 ** uint8(EXP + exp));
+    }
+
+    /// @dev Default rounding mode used by ftoi is HalfUp
+    Rounding public constant ROUNDING_DEFAULT = Rounding.HalfUp;
+
+    /// @dev returns the decimals precision of the UFixed type
+    function decimals() public pure returns (uint256) {
+        return uint8(EXP);
+    }
+
+    /// @dev Converts a UFixed to a uint256.
+    function toInt(UFixed a) public pure returns (uint256) {
+        return toIntWithRounding(a, ROUNDING_DEFAULT);
+    }
+
+    /// @dev Converts a UFixed to a uint256 with given rounding mode.
+    function toIntWithRounding(UFixed a, Rounding rounding) public pure returns (uint256) {
+        if (rounding == Rounding.HalfUp) {
+            return
+                Math.mulDiv(
+                    UFixed.unwrap(a) + MULTIPLIER_HALF,
+                    1,
+                    MULTIPLIER,
+                    Math.Rounding.Down
+                );
+        } else if (rounding == Rounding.Down) {
+            return
+                Math.mulDiv(
+                    UFixed.unwrap(a),
+                    1,
+                    MULTIPLIER,
+                    Math.Rounding.Down
+                );
+        } else {
+            return
+                Math.mulDiv(UFixed.unwrap(a), 1, MULTIPLIER, Math.Rounding.Up);
+        }
+    }
+
+    /// @dev adds two UFixed numbers
+    function add(UFixed a, UFixed b) public pure returns (UFixed) {
+        return addUFixed(a, b);
+    }
+
+    /// @dev subtracts two UFixed numbers
+    function sub(UFixed a, UFixed b) public pure returns (UFixed) {
+        return subUFixed(a, b);
+    }
+
+    /// @dev multiplies two UFixed numbers
+    function mul(UFixed a, UFixed b) public pure returns (UFixed) {
+        return mulUFixed(a, b);
+    }
+
+    /// @dev divides two UFixed numbers
+    function div(UFixed a, UFixed b) public pure returns (UFixed) {
+        return divUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is greater than UFixed b
+    function gt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return gtUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is greater than or equal to UFixed b
+    function gte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return gteUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is less than UFixed b
+    function lt(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return ltUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is less than or equal to UFixed b
+    function lte(UFixed a, UFixed b) public pure returns (bool isGreaterThan) {
+        return lteUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is equal to UFixed b
+    function eq(UFixed a, UFixed b) public pure returns (bool isEqual) {
+        return eqUFixed(a, b);
+    }
+
+    /// @dev return true if UFixed a is not zero
+    function gtz(UFixed a) public pure returns (bool isZero) {
+        return gtzUFixed(a);
+    }
+
+    /// @dev return true if UFixed a is zero
+    function eqz(UFixed a) public pure returns (bool isZero) {
+        return eqzUFixed(a);
+    }
+
+    function zero() public pure returns (UFixed) {
+        return UFixed.wrap(0);
+    }
+
+    /// @dev return the absolute delta between two UFixed numbers
+    function delta(UFixed a, UFixed b) public pure returns (UFixed) {
+        return deltaUFixed(a, b);
+    }
+}

package/contracts/types/Version.sol

@@ -0,0 +1,91 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+type VersionPart is uint8;
+
+using {
+    versionPartGt as >,
+    versionPartEq as ==,
+    VersionPartLib.toInt
+}
+    for VersionPart global;
+
+function versionPartGt(VersionPart a, VersionPart b) pure returns(bool isGreaterThan) { return VersionPart.unwrap(a) > VersionPart.unwrap(b); }
+function versionPartEq(VersionPart a, VersionPart b) pure returns(bool isSame) { return VersionPart.unwrap(a) == VersionPart.unwrap(b); }
+function toVersionPart(uint8 versionPart) pure returns(VersionPart) { return VersionPart.wrap(versionPart); }
+
+library VersionPartLib {
+    function toInt(VersionPart x) external pure returns(uint) { return VersionPart.unwrap(x); }
+}
+
+type Version is uint24; // contains major,minor,patch version parts
+
+using {
+    versionGt as >,
+    versionEq as ==,
+    VersionLib.toInt,
+    VersionLib.toMajorPart,
+    VersionLib.toVersionParts
+}
+    for Version global;
+
+function versionGt(Version a, Version b) pure returns(bool isGreaterThan) { return Version.unwrap(a) > Version.unwrap(b); }
+function versionEq(Version a, Version b) pure returns(bool isSame) { return Version.unwrap(a) == Version.unwrap(b); }
+
+function toVersion(
+    VersionPart major,
+    VersionPart minor,
+    VersionPart patch
+)
+    pure
+    returns(Version)
+{
+    uint majorInt = major.toInt();
+    uint minorInt = minor.toInt();
+    uint patchInt = patch.toInt();
+
+    return Version.wrap(
+        uint24(
+            (majorInt << 16) + (minorInt << 8) + patchInt));
+}
+
+function zeroVersion() pure returns(Version) {
+    return toVersion(toVersionPart(0), toVersionPart(0), toVersionPart(0));
+}
+
+library VersionLib {
+    function toInt(Version version) external pure returns(uint) { return Version.unwrap(version); }
+
+    function toMajorPart(Version version)
+        external    
+        pure 
+        returns(VersionPart major)
+    { 
+        uint24 versionInt = Version.unwrap(version);
+        uint8 majorInt = uint8(versionInt >> 16);
+        return VersionPart.wrap(majorInt);
+    }
+
+    function toVersionParts(Version version)
+        external
+        pure
+        returns(
+            VersionPart major,
+            VersionPart minor,
+            VersionPart patch
+        )
+    {
+        uint24 versionInt = Version.unwrap(version);
+        uint8 majorInt = uint8(versionInt >> 16);
+
+        versionInt -= majorInt << 16;
+        uint8 minorInt = uint8(versionInt >> 8);
+        uint8 patchInt = uint8(versionInt - (minorInt << 8));
+
+        return (
+            toVersionPart(majorInt),
+            toVersionPart(minorInt),
+            toVersionPart(patchInt)
+        );
+    }
+}

package/package.json

@@ -1,14 +1,18 @@
 {
   "name": "@etherisc/gif-next",
-  "version": "0.0.2-ebbe63d",
+  "version": "0.0.2-efdb520-159",
   "description": "This is the repository for the next version of the Generic Insurance Framework (GIF) smart contracts. ",
   "main": "index.js",
   "scripts": {
-    "build": "hardhat compile",
-    "test": "hardhat test",
-    "ptest": "hardhat test --parallel",
-    "test-with-gas": "REPORT_GAS=true hardhat test",
-    "coverage": "hardhat coverage"
+    "build": "hh compile",
+    "test": "hh test",
+    "ptest": "hh test --parallel",
+    "test-with-gas": "REPORT_GAS=true hh test",
+    "coverage": "hh coverage",
+    "styleFix": "prettier --write --plugin=prettier-plugin-solidity 'contracts/**/*.sol' 'test_forge/**/*.t.sol'",
+    "styleCheck": "prettier --check --plugin=prettier-plugin-solidity 'contracts/**/*.sol' 'test_forge/**/*.t.sol'",
+    "lint": "solhint 'contracts/**/*.sol' 'test_forge/**/*.t.sol'",
+    "eslint": "eslint ."
   },
   "repository": {
     "type": "git",
@@ -25,12 +29,23 @@
   ],
   "homepage": "https://github.com/etherisc/gif-next#readme",
   "devDependencies": {
-    "@nomicfoundation/hardhat-foundry": "^1.0.3",
+    "@nomicfoundation/hardhat-foundry": "^1.1.1",
     "@nomicfoundation/hardhat-toolbox": "^3.0.0",
-    "hardhat": "^2.17.1"
+    "@nomicfoundation/hardhat-verify": "^1.1.1",
+    "@typescript-eslint/eslint-plugin": "^6.7.2",
+    "@typescript-eslint/parser": "^6.7.2",
+    "dotenv": "^16.3.1",
+    "eslint": "^8.50.0",
+    "hardhat": "^2.17.2",
+    "prettier": "^3.0.3",
+    "prettier-plugin-solidity": "^1.1.3",
+    "typescript": "^5"
   },
   "dependencies": {
     "@openzeppelin/contracts": "^4.9.3",
-    "@openzeppelin/contracts-upgradeable": "^4.9.3"
+    "@openzeppelin/contracts-upgradeable": "^4.9.3",
+    "abi-coder": "^5.0.0",
+    "ethers": "^6.7.1",
+    "winston": "^3.10.0"
   }
 }

package/artifacts/contracts/Dip.sol/DIP.dbg.json

@@ -1,4 +0,0 @@
-{
-  "_format": "hh-sol-dbg-1",
-  "buildInfo": "../../build-info/d6ddc31c8d0f29d05ebcf7dbd3184aca.json"
-}