@etherisc/gif-next 0.0.2-ebbe63d → 0.0.2-efdb520-159

package/contracts/components/IBaseComponent.sol

@@ -0,0 +1,19 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRegisterable} from "../shared/IRegisterable.sol";
+import {IInstanceLinked} from "../instance/IInstanceLinked.sol";
+
+interface IBaseComponent is IRegisterable, IInstanceLinked {
+
+    function lock() external;
+
+    function unlock() external;
+
+    function getToken() external view returns (IERC20Metadata token);
+
+    function getWallet() external view returns (address walletAddress);
+
+}

package/contracts/components/IPoolComponent.sol

@@ -0,0 +1,57 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../types/NftId.sol";
+import {Fee} from "../types/Fee.sol";
+import {UFixed} from "../types/UFixed.sol";
+import {IBaseComponent} from "./IBaseComponent.sol";
+
+interface IPoolComponent is IBaseComponent {
+
+    event LogUnderwrittenByPool(NftId policyNftId, uint256 collateralizationAmount, address pool);
+
+    /**
+     * @dev creates a new bundle for this pool.
+     */
+    function createBundle(
+        uint256 initialAmount,
+        uint256 lifetime,
+        bytes memory filter
+    ) external returns(NftId bundleNftId);
+
+    /** 
+     * @dev this is a callback function that is called by the product service when underwriting a policy.
+     * the pool has the option to check the details and object to underwriting by reverting.
+     * the function is only called for "active" pools that ask to be involved/notified
+     * by product related state changes.
+     */
+    function underwrite(
+        NftId policyNftId, 
+        bytes memory policyData,
+        bytes memory bundleFilter,
+        uint256 collateralizationAmount
+    ) external;
+
+    /**
+     * @dev returns true iff the policy application data in policyData matches
+     * with the bundle filter criteria encoded in bundleFilter. 
+     */
+    function policyMatchesBundle(
+        bytes memory policyData,
+        bytes memory bundleFilter
+    )
+        external
+        view
+        returns (bool isMatching);
+
+    function isVerifying() external view returns (bool verifying);
+
+    function getCollateralizationLevel() external view returns (UFixed collateralizationLevel);
+
+    function getStakingFee() external view returns (Fee memory stakingFee);
+
+    function getPerformanceFee()
+        external
+        view
+        returns (Fee memory performanceFee);
+}

package/contracts/components/IProductComponent.sol

@@ -0,0 +1,19 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../types/NftId.sol";
+import {Fee} from "../types/Fee.sol";
+import {IBaseComponent} from "./IBaseComponent.sol";
+
+interface IProductComponent is IBaseComponent {
+    function setFees(
+        Fee memory policyFee,
+        Fee memory processingFee
+    ) external;
+
+    function getPoolNftId() external view returns (NftId poolNftId);
+    
+    function getPolicyFee() external view returns (Fee memory policyFee);
+
+    function getProcessingFee() external view returns (Fee memory processingFee);
+}

package/contracts/components/Pool.sol

@@ -0,0 +1,174 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ObjectType, POOL} from "../types/ObjectType.sol";
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IPoolService} from "../instance/service/IPoolService.sol";
+import {NftId} from "../types/NftId.sol";
+import {Fee} from "../types/Fee.sol";
+import {UFixed} from "../types/UFixed.sol";
+import {IPoolComponent} from "./IPoolComponent.sol";
+import {BaseComponent} from "./BaseComponent.sol";
+
+contract Pool is BaseComponent, IPoolComponent {
+
+    bool internal _isVerifying;
+    UFixed internal _collateralizationLevel;
+
+    // may be used to interact with instance by derived contracts
+    IPoolService internal _poolService;
+
+    // only relevant to protect callback functions for "active" pools
+    IProductService private _productService;
+
+    modifier onlyPoolService() {
+        require(
+            msg.sender == address(_poolService), 
+            "ERROR:POL-001:NOT_POOL_SERVICE");
+        _;
+    }
+
+    modifier onlyProductService() {
+        require(
+            msg.sender == address(_productService), 
+            "ERROR:POL-002:NOT_PRODUCT_SERVICE");
+        _;
+    }
+
+    constructor(
+        address registry,
+        NftId instanceNftId,
+        // TODO refactor into tokenNftId
+        address token,
+        bool verifying,
+        UFixed collateralizationLevel
+    )
+        BaseComponent(registry, instanceNftId, token)
+    {
+        _isVerifying = verifying;
+        // TODO add validation
+        _collateralizationLevel = collateralizationLevel;
+
+        _poolService = _instance.getPoolService();
+        _productService = _instance.getProductService();
+    }
+
+    function createBundle(
+        uint256 initialAmount,
+        uint256 lifetime,
+        bytes memory filter
+    )
+        external
+        virtual override
+        returns(NftId bundleNftId)
+    {
+        address owner = msg.sender;
+        bundleNftId = _poolService.createBundle(
+            owner,
+            initialAmount,
+            lifetime,
+            filter
+        );
+
+        // TODO add logging
+    }
+
+    /**
+     * @dev see {IPool.underwrite}. 
+     * Default implementation that only writes a {LogUnderwrittenByPool} entry.
+     */
+    function underwrite(
+        NftId policyNftId, 
+        bytes memory policyData,
+        bytes memory bundleFilter,
+        uint256 collateralizationAmount
+    )
+        external
+        onlyProductService
+        virtual override 
+    {
+        _underwrite(policyNftId, policyData, bundleFilter, collateralizationAmount);
+    }
+
+    /**
+     * @dev see {IPoolComponent.policyMatchesBundle}. 
+     * Default implementation always returns true
+     */
+    function policyMatchesBundle(
+        bytes memory, // policyData
+        bytes memory // bundleFilter
+    )
+        public
+        view
+        virtual override
+        returns (bool isMatching)
+    {
+        return true;
+    }
+
+
+    function isVerifying() external view override returns (bool verifying) {
+        return _isVerifying;
+    }
+
+    function getCollateralizationLevel() external view override returns (UFixed collateralizationLevel) {
+        return _collateralizationLevel;
+    }
+
+    function _underwrite(
+        NftId policyNftId, 
+        bytes memory policyData,
+        bytes memory bundleFilter,
+        uint256 collateralizationAmount
+    )
+        internal 
+    {
+        require(
+            policyMatchesBundle(policyData, bundleFilter),
+            "ERROR:POL-020:POLICY_BUNDLE_MISMATCH"
+        );
+
+        emit LogUnderwrittenByPool(policyNftId, collateralizationAmount, address(this));
+    }
+
+    function _createBundle(
+        address bundleOwner,
+        uint256 amount,
+        uint256 lifetime, 
+        bytes calldata filter
+    )
+        internal
+        returns(NftId bundleNftId)
+    {
+        bundleNftId = _poolService.createBundle(
+            bundleOwner,
+            amount,
+            lifetime,
+            filter
+        );
+    }
+
+    // from pool component
+    function getStakingFee()
+        external
+        view
+        override
+        returns (Fee memory stakingFee)
+    {
+        return _instance.getPoolSetup(getNftId()).stakingFee;
+    }
+
+    function getPerformanceFee()
+        external
+        view
+        override
+        returns (Fee memory performanceFee)
+    {
+        return _instance.getPoolSetup(getNftId()).performanceFee;
+    }
+
+    // from registerable
+    function getType() public pure override returns (ObjectType) {
+        return POOL();
+    }
+}

package/contracts/components/Product.sol

@@ -0,0 +1,117 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IProductService} from "../instance/service/IProductService.sol";
+import {IProductComponent} from "./IProductComponent.sol";
+import {NftId} from "../types/NftId.sol";
+import {ObjectType, PRODUCT} from "../types/ObjectType.sol";
+import {Timestamp} from "../types/Timestamp.sol";
+import {Fee} from "../types/Fee.sol";
+import {BaseComponent} from "./BaseComponent.sol";
+
+contract Product is BaseComponent, IProductComponent {
+    IProductService private _productService;
+    address private _pool;
+
+    constructor(
+        address registry,
+        NftId instanceNftid,
+        address token,
+        address pool
+    ) BaseComponent(registry, instanceNftid, token) {
+        // TODO add validation
+        _productService = _instance.getProductService();
+        _pool = pool;
+    }
+
+    function _createApplication(
+        address applicationOwner,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    ) internal returns (NftId nftId) {
+        nftId = _productService.createApplication(
+            applicationOwner,
+            sumInsuredAmount,
+            premiumAmount,
+            lifetime,
+            bundleNftId
+        );
+    }
+
+    function _underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.underwrite(
+            policyNftId, 
+            requirePremiumPayment, 
+            activateAt);
+    }
+
+    function _collectPremium(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.collectPremium(
+            policyNftId, 
+            activateAt);
+    }
+
+    function _activate(
+        NftId policyNftId,
+        Timestamp activateAt
+    )
+        internal
+    {
+        _productService.activate(
+            policyNftId, 
+            activateAt);
+    }
+
+    function getPoolNftId() external view override returns (NftId poolNftId) {
+        return _registry.getNftId(_pool);
+    }
+
+    // from product component
+    function setFees(
+        Fee memory policyFee,
+        Fee memory processingFee
+    )
+        external
+        onlyOwner
+        override
+    {
+        _productService.setFees(policyFee, processingFee);
+    }
+
+
+    function getPolicyFee()
+        external
+        view
+        override
+        returns (Fee memory policyFee)
+    {
+        return _instance.getProductSetup(getNftId()).policyFee;
+    }
+
+    function getProcessingFee()
+        external
+        view
+        override
+        returns (Fee memory processingFee)
+    {
+        return _instance.getProductSetup(getNftId()).processingFee;
+    }
+
+    // from registerable
+    function getType() public pure override returns (ObjectType) {
+        return PRODUCT();
+    }
+}

package/contracts/experiment/errors/Require.sol

@@ -0,0 +1,38 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+contract Require {
+    error AsmallerThanB_S();
+    error AsmallerThanB_M(uint a);
+    error AsmallerThanB_L(uint a, uint b);
+
+    uint256 private _b;
+
+    constructor() {
+        _b = 42;
+    }
+
+    function isAlargerThanBRequire_S(
+        uint a
+    ) external view returns (bool isLarger) {
+        require(a > _b, "ERROR:ABC-001");
+
+        return true;
+    }
+
+    function isAlargerThanBRequire_M(
+        uint a
+    ) external view returns (bool isLarger) {
+        require(a > _b, "ERROR:ABC-002:A_IS_SMALLER");
+
+        return true;
+    }
+
+    function isAlargerThanBRequire_L(
+        uint a
+    ) external view returns (bool isLarger) {
+        require(a > _b, "ERROR:ABC-003:A_IS_SMALLER_THAN_B");
+
+        return true;
+    }
+}

package/contracts/experiment/errors/Revert.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+contract Revert {
+    error AsmallerThanB_S();
+    error AsmallerThanB_M(uint a);
+    error AsmallerThanB_L(uint a, uint b);
+
+    uint256 private _b;
+
+    constructor() {
+        _b = 42;
+    }
+
+    function isAlargerThanBRevert_S(
+        uint a
+    ) external view returns (bool isLarger) {
+        if (a <= _b) {
+            revert AsmallerThanB_S();
+        }
+
+        return true;
+    }
+
+    function isAlargerThanBRevert_M(
+        uint a
+    ) external view returns (bool isLarger) {
+        if (a <= _b) {
+            revert AsmallerThanB_M(a);
+        }
+
+        return true;
+    }
+
+    function isAlargerThanBRevert_L(
+        uint a
+    ) external view returns (bool isLarger) {
+        if (a <= _b) {
+            revert AsmallerThanB_L(a, _b);
+        }
+
+        return true;
+    }
+}

package/contracts/experiment/inheritance/A.sol

@@ -0,0 +1,53 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IA, ISharedA} from "./IA.sol";
+import {B} from "./B.sol";
+import {C} from "./C.sol";
+
+/* 
+
+# dependency graph
+
+   B <...+
+   ^     |
+   |     |
+   A --> C
+
+   - A is the main contract
+   - A provides functionality implemented by modules B and C
+   - B and C rely on functionality shared by A
+   - C accesses functionality of module B
+
+# chisel session
+
+import {A} from "./contracts/experiment/A.sol";
+A a = new A();
+uint(a.getA())
+uint(a.getB()))
+uint(a.getC())
+uint(a.getAfromB())
+uint(a.getAfromC())
+uint(a.getBfromC())
+a.setA(100);
+a.setB(10);
+a.setC(20);
+ */
+
+contract AShared is ISharedA {
+    uint256 private _x;
+
+    constructor() {
+        _x = 42;
+    }
+
+    function getA() external view override returns (uint256) {
+        return _x;
+    }
+
+    function setA(uint256 newA) external override {
+        _x = newA;
+    }
+}
+
+contract A is AShared, B, C, IA {}

package/contracts/experiment/inheritance/B.sol

@@ -0,0 +1,28 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ISharedA} from "./IA.sol";
+import {IB} from "./IB.sol";
+
+abstract contract B is ISharedA, IB {
+    // names of private variables can be re-used in inheritance
+    uint256 private _x;
+
+    constructor() {
+        _x = 1;
+    }
+
+    // access own state
+    function getB() external view override returns (uint256) {
+        return _x;
+    }
+
+    function setB(uint256 newB) external override {
+        _x = newB;
+    }
+
+    // access state from parent contract A
+    function getAfromB() external view override returns (uint256) {
+        return this.getA();
+    }
+}

package/contracts/experiment/inheritance/C.sol

@@ -0,0 +1,34 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ISharedA} from "./IA.sol";
+import {IB} from "./IB.sol";
+import {IC} from "./IC.sol";
+
+abstract contract C is ISharedA, IC {
+    uint256 private _x;
+
+    constructor() {
+        _x = 2;
+    }
+
+    // access own state
+    function getC() external view override returns (uint256) {
+        return _x;
+    }
+
+    function setC(uint256 newC) external override {
+        _x = newC;
+    }
+
+    // access state from parent contract A
+    function getAfromC() external view override returns (uint256) {
+        return this.getA();
+    }
+
+    // access state from other module B
+    function getBfromC() external view override returns (uint256) {
+        IB b = IB(address(this));
+        return b.getB();
+    }
+}

package/contracts/experiment/inheritance/IA.sol

@@ -0,0 +1,13 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IB} from "./IB.sol";
+import {IC} from "./IC.sol";
+
+interface ISharedA {
+    function getA() external view returns (uint256);
+
+    function setA(uint256 newA) external;
+}
+
+interface IA is ISharedA, IB, IC {}

package/contracts/experiment/inheritance/IB.sol

@@ -0,0 +1,10 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+interface IB {
+    function getAfromB() external view returns (uint256);
+
+    function getB() external view returns (uint256);
+
+    function setB(uint256 newA) external;
+}

package/contracts/experiment/inheritance/IC.sol

@@ -0,0 +1,12 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+interface IC {
+    function getAfromC() external view returns (uint256);
+
+    function getBfromC() external view returns (uint256);
+
+    function getC() external view returns (uint256);
+
+    function setC(uint256 newA) external;
+}

package/contracts/experiment/statemachine/Dummy.sol

@@ -0,0 +1,27 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {ObjectType} from "../../types/ObjectType.sol";
+import {StateId, toStateId, zeroStateId} from "../../types/StateId.sol";
+
+contract LifeCycleModule {
+    mapping(ObjectType objectType => StateId initialState)
+        private _initialState;
+
+    mapping(ObjectType objectType => mapping(StateId stateFrom => mapping(StateId stateTo => bool isValid)))
+        private _isValidTransition;
+
+    function getInitialState(
+        ObjectType objectType
+    ) external view returns (StateId) {
+        return _initialState[objectType];
+    }
+
+    function isValidTransition(
+        ObjectType objectType,
+        StateId fromId,
+        StateId toId
+    ) external view returns (bool) {
+        return _isValidTransition[objectType][fromId][toId];
+    }
+}

package/contracts/experiment/statemachine/ISM.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {StateId} from "../../types/StateId.sol";
+
+interface ISMEE {
+    error ErrorInitialStateUndefined();
+    error ErrorStartStateUndefined();
+    error ErrorNextStateUndefined();
+    error ErrorStateChangeInvalid(StateId currentStateId, StateId newStateId);
+
+    event LogInitialStateSet(StateId initialStateId);
+    event LogStateChanged(StateId oldStateId, StateId newStateId);
+}
+
+interface ISM is ISMEE {
+    function changeToState(StateId newStateId) external;
+
+    function isValidTransition(
+        StateId currentStateId,
+        StateId newStateId
+    ) external view returns (bool isValid);
+
+    function getState() external view returns (StateId currentStateId);
+}