@etherisc/gif-next 0.0.2-ebbe63d → 0.0.2-efdb520-159

package/contracts/instance/service/ComponentServiceBase.sol

@@ -0,0 +1,41 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {ObjectType, INSTANCE, PRODUCT, POOL} from "../../types/ObjectType.sol";
+import {NftId, NftIdLib} from "../../types/NftId.sol";
+
+import {ServiceBase} from "./ServiceBase.sol";
+
+abstract contract ComponentServiceBase is ServiceBase {
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        ServiceBase(registry, registryNftId)
+    {
+    }
+
+
+    function _getAndVerifyComponentInfoAndInstance(
+        ObjectType objectType
+    )
+        internal
+        view
+        returns(
+            IRegistry.ObjectInfo memory info, 
+            IInstance instance
+        )
+    {
+        NftId componentNftId = _registry.getNftId(msg.sender);
+        require(componentNftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
+
+        info = _registry.getObjectInfo(componentNftId);
+        require(info.objectType == objectType, "OBJECT_TYPE_INVALID");
+
+        address instanceAddress = _registry.getObjectInfo(info.parentNftId).objectAddress;
+        instance = IInstance(instanceAddress);
+    }
+}

package/contracts/instance/service/IComponentOwnerService.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {ObjectType} from "../../types/ObjectType.sol";
+import {RoleId} from "../../types/RoleId.sol";
+import {IBaseComponent} from "../../components/IBaseComponent.sol";
+import {IService} from "./IService.sol";
+
+// TODO rename to registry service
+interface IComponentOwnerService is IService {
+
+    function register(IBaseComponent component) external returns(NftId componentNftId);
+
+    // TODO move to product/pool services
+    function lock(IBaseComponent component) external;
+
+    // TODO move to product/pool services
+    function unlock(IBaseComponent component) external;
+
+    function getRoleForType(ObjectType cType) external pure returns (RoleId role);
+}

package/contracts/instance/service/IPoolService.sol

@@ -0,0 +1,30 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {Fee} from "../../types/Fee.sol";
+import {IService} from "./IService.sol";
+
+interface IPoolService is IService {
+    function setFees(
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external;
+
+    function createBundle(
+        address owner,
+        uint256 amount,
+        uint256 lifetime, 
+        bytes calldata filter
+    ) external returns(NftId bundleNftId);
+
+    // function fundBundle(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    // function defundBundle(NftId bundleNftId, uint256 amount) external returns(uint256 netAmount);
+
+    // function lockBundle(NftId bundleNftId) external;
+
+    // function unlockBundle(NftId bundleNftId) external;
+
+    // function closeBundle(NftId bundleNftId) external;
+}

package/contracts/instance/service/IProductService.sol

@@ -0,0 +1,58 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {NftId} from "../../types/NftId.sol";
+import {Timestamp} from "../../types/Timestamp.sol";
+import {UFixed} from "../../types/UFixed.sol";
+import {Fee} from "../../types/Fee.sol";
+import {IService} from "./IService.sol";
+
+interface IProductService is IService {
+    function setFees(
+        Fee memory policyFee,
+        Fee memory processingFee
+    ) external;
+
+    function createApplication(
+        address applicationOwner,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    ) external returns (NftId nftId);
+
+    // function revoke(unit256 nftId) external;
+
+    /**
+     * @dev underwrites the policy represented by {policyNftId}.
+     * optionally collects premiums and activates the policy.
+     * - premium payment is only attempted if requirePremiumPayment is set to true
+     * - activation is only done if activateAt is a non-zero timestamp
+     */
+    function underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    ) external;
+
+    // function decline(uint256 nftId) external;
+    // function expire(uint256 nftId) external;
+
+    function collectPremium(NftId nftId, Timestamp activateAt) external;
+
+    function activate(NftId nftId, Timestamp activateAt) external;
+
+
+    function close(NftId nftId) external;
+
+    // function createClaim(uint256 nftId, uint256 claimAmount) external;
+    // function confirmClaim(uint256 nftId, uint256 claimId, uint256 claimAmount) external;
+    // function declineClaim(uint256 nftId, uint256 claimId) external;
+    // function closeClaim(uint256 nftId, uint256 claimId) external;
+
+    function calculateRequiredCollateral(
+        UFixed collateralizationLevel, 
+        uint256 sumInsuredAmount
+    ) external pure returns(uint256 collateralAmount);
+
+}

package/contracts/instance/service/IService.sol

@@ -0,0 +1,15 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {VersionPart} from "../../types/Version.sol";
+
+import {IRegisterable} from "../../shared/IRegisterable.sol";
+import {IVersionable} from "../../shared/IVersionable.sol";
+
+interface IService is 
+    IRegisterable,
+    IVersionable
+{
+    function getName() external pure returns(string memory name);
+    function getMajorVersion() external view returns(VersionPart majorVersion);
+}

package/contracts/instance/service/PoolService.sol

@@ -0,0 +1,98 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {ITreasury, ITreasuryModule, TokenHandler} from "../../instance/module/treasury/ITreasury.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {NftId, NftIdLib} from "../../types/NftId.sol";
+import {POOL, BUNDLE} from "../../types/ObjectType.sol";
+import {Fee, feeIsZero} from "../../types/Fee.sol";
+import {Version, toVersion, toVersionPart} from "../../types/Version.sol";
+
+import {ComponentServiceBase} from "./ComponentServiceBase.sol";
+import {IPoolService} from "./IPoolService.sol";
+
+
+contract PoolService is ComponentServiceBase, IPoolService {
+    using NftIdLib for NftId;
+
+    string public constant NAME = "PoolService";
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    ) ComponentServiceBase(registry, registryNftId) // solhint-disable-next-line no-empty-blocks
+    {
+        _registerInterface(type(IPoolService).interfaceId);
+    }
+
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return toVersion(
+            toVersionPart(3),
+            toVersionPart(0),
+            toVersionPart(0));
+    }
+
+    function getName() external pure override returns(string memory name) {
+        return NAME;
+    }
+
+    function setFees(
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    )
+        external
+        override
+    {
+        (IRegistry.ObjectInfo memory info, IInstance instance) = _getAndVerifyComponentInfoAndInstance(POOL());
+        instance.setPoolFees(info.nftId, stakingFee, performanceFee);
+    }
+
+    function createBundle(
+        address owner, 
+        uint256 amount, 
+        uint256 lifetime, 
+        bytes calldata filter
+    )
+        external
+        override
+        returns(NftId bundleNftId)
+    {
+        (IRegistry.ObjectInfo memory info, IInstance instance) = _getAndVerifyComponentInfoAndInstance(POOL());
+
+        // register bundle with registry
+        NftId poolNftId = info.nftId;
+        bundleNftId = _registry.registerObjectForInstance(
+            poolNftId, 
+            BUNDLE(), 
+            owner,
+            "");
+
+        // create bundle info in instance
+        instance.createBundleInfo(
+            bundleNftId,
+            poolNftId,
+            amount,
+            lifetime,
+            filter);
+
+        // add bundle to pool in instance
+        instance.addBundleToPool(
+            bundleNftId,
+            poolNftId,
+            amount);
+
+        // TODO collect capital
+
+        // TODO add logging
+    }
+}

package/contracts/instance/service/ProductService.sol

@@ -0,0 +1,358 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IPoolComponent} from "../../components/IPoolComponent.sol";
+import {IInstance} from "../../instance/IInstance.sol";
+import {IPolicy, IPolicyModule} from "../module/policy/IPolicy.sol";
+import {IPool} from "../module/pool/IPoolModule.sol";
+import {IBundle} from "../module/bundle/IBundle.sol";
+import {IProductService} from "./IProductService.sol";
+import {ITreasury, ITreasuryModule, TokenHandler} from "../../instance/module/treasury/ITreasury.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {Timestamp, zeroTimestamp} from "../../types/Timestamp.sol";
+import {UFixed, UFixedMathLib} from "../../types/UFixed.sol";
+import {ObjectType, INSTANCE, PRODUCT, POLICY} from "../../types/ObjectType.sol";
+import {APPLIED, UNDERWRITTEN, ACTIVE} from "../../types/StateId.sol";
+import {NftId, NftIdLib} from "../../types/NftId.sol";
+import {Blocknumber, blockNumber} from "../../types/Blocknumber.sol";
+import {Fee, feeIsZero} from "../../types/Fee.sol";
+import {Version, toVersion, toVersionPart} from "../../types/Version.sol";
+
+import {ComponentServiceBase} from "./ComponentServiceBase.sol";
+import {IProductService} from "./IProductService.sol";
+
+// TODO or name this ProtectionService to have Product be something more generic (loan, savings account, ...)
+contract ProductService is ComponentServiceBase, IProductService {
+    using NftIdLib for NftId;
+
+    string public constant NAME = "ProductService";
+
+    event LogProductServiceSender(address sender);
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    ) ComponentServiceBase(registry, registryNftId) // solhint-disable-next-line no-empty-blocks
+    {
+        _registerInterface(type(IProductService).interfaceId);
+    }
+
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return toVersion(
+            toVersionPart(3),
+            toVersionPart(0),
+            toVersionPart(0));
+    }
+
+    function getName() external pure override returns(string memory name) {
+        return NAME;
+    }
+
+    function setFees(
+        Fee memory policyFee,
+        Fee memory processingFee
+    )
+        external
+        override
+    {
+        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        instance.setProductFees(productInfo.nftId, policyFee, processingFee);
+    }
+
+    function createApplication(
+        address applicationOwner,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    ) external override returns (NftId policyNftId) {
+        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+        NftId productNftId = productInfo.nftId;
+        // TODO add validations (see create bundle in pool service)
+
+        policyNftId = this.getRegistry().registerObjectForInstance(
+            productNftId,
+            POLICY(),
+            applicationOwner,
+            ""
+        );
+
+        instance.createApplication(
+            productNftId,
+            policyNftId,
+            sumInsuredAmount,
+            premiumAmount,
+            lifetime,
+            bundleNftId
+        );
+
+        // TODO add logging
+    }
+
+    function _getAndVerifyUnderwritingSetup(
+        IInstance instance,
+        IPolicy.PolicyInfo memory policyInfo
+    )
+        internal
+        view
+        returns (
+            ITreasury.ProductSetup memory productSetup,
+            IBundle.BundleInfo memory bundleInfo,
+            uint256 collateralAmount,
+            bool poolIsVerifying,
+            bytes memory bundleFilter
+        )
+    {
+        // check match between policy and bundle (via pool)
+        productSetup = instance.getProductSetup(policyInfo.productNftId);
+        bundleInfo = instance.getBundleInfo(policyInfo.bundleNftId);
+        require(bundleInfo.poolNftId == productSetup.poolNftId, "POLICY_BUNDLE_MISMATCH");
+
+        // calculate required collateral
+        NftId poolNftId = productSetup.poolNftId;
+        IPool.PoolInfo memory poolInfo = instance.getPoolInfo(poolNftId);
+
+        // obtain remaining return values
+        poolIsVerifying = poolInfo.isVerifying;
+        collateralAmount = calculateRequiredCollateral(poolInfo.collateralizationLevel, policyInfo.sumInsuredAmount);
+        bundleFilter = bundleInfo.filter;
+    }
+
+    function _lockCollateralInBundle(
+        IInstance instance,
+        IBundle.BundleInfo memory bundleInfo,
+        NftId policyNftId, 
+        uint256 collateralAmount
+    )
+        internal
+        returns (IBundle.BundleInfo memory)
+    {
+        bundleInfo.lockedAmount += collateralAmount;
+        bundleInfo.updatedIn = blockNumber();
+        instance.collateralizePolicy(bundleInfo.nftId, policyNftId, collateralAmount);
+        return bundleInfo;
+    }
+
+    function _underwriteByPool(
+        ITreasury.ProductSetup memory productSetup,
+        IPolicy.PolicyInfo memory policyInfo,
+        bytes memory bundleFilter,
+        uint256 collateralAmount
+    )
+        internal
+    {
+        address poolAddress = _registry.getObjectInfo(productSetup.poolNftId).objectAddress;
+        IPoolComponent pool = IPoolComponent(poolAddress);
+        pool.underwrite(
+            policyInfo.nftId, 
+            policyInfo.data, 
+            bundleFilter,
+            collateralAmount);
+    }
+
+
+    function underwrite(
+        NftId policyNftId,
+        bool requirePremiumPayment,
+        Timestamp activateAt
+    )
+        external 
+        override
+    {
+        // check caller is registered product
+        (
+            IRegistry.ObjectInfo memory productInfo, 
+            IInstance instance
+        ) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+
+        // check match between policy and calling product
+        NftId productNftId = productInfo.nftId;
+        IPolicy.PolicyInfo memory policyInfo = instance.getPolicyInfo(policyNftId);
+        require(policyInfo.productNftId == productNftId, "POLICY_PRODUCT_MISMATCH");
+        require(policyInfo.state == APPLIED(), "ERROR:PRS-021:STATE_NOT_APPLIED");
+
+        (
+            ITreasury.ProductSetup memory productSetup,
+            IBundle.BundleInfo memory bundleInfo,
+            uint256 collateralAmount,
+            bool poolIsVerifying,
+            bytes memory bundleFilter
+        ) = _getAndVerifyUnderwritingSetup(
+            instance,
+            policyInfo
+        );
+
+        // lock bundle collateral
+        bundleInfo = _lockCollateralInBundle(
+            instance,
+            bundleInfo,
+            policyNftId, 
+            collateralAmount);
+
+        // collect premium
+        if(requirePremiumPayment) {
+            uint256 netPremiumAmount = _processPremiumByTreasury(
+                instance, 
+                productSetup, 
+                policyNftId, 
+                policyInfo.premiumAmount);
+
+            policyInfo.premiumPaidAmount += policyInfo.premiumAmount;
+            bundleInfo.balanceAmount += netPremiumAmount;
+        }
+
+        // set policy state to underwritten
+        // TODO add require for state change
+        policyInfo.state = UNDERWRITTEN();
+        policyInfo.updatedIn = blockNumber();
+
+        // optional activation of policy
+        if(activateAt > zeroTimestamp()) {
+            policyInfo.activatedAt = activateAt;
+            policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
+
+            // TODO add require for state change
+            policyInfo.state = ACTIVE();
+        }
+
+        instance.setPolicyInfo(policyInfo);
+        instance.setBundleInfo(bundleInfo);
+
+        // integrate pool component
+        if(poolIsVerifying) {
+            _underwriteByPool(
+                productSetup,
+                policyInfo,
+                bundleFilter,
+                collateralAmount
+            );
+        }
+
+        // TODO add logging
+    }
+
+    function calculateRequiredCollateral(UFixed collateralizationLevel, uint256 sumInsuredAmount) public pure override returns(uint256 collateralAmount) {
+        UFixed sumInsuredUFixed = UFixedMathLib.toUFixed(sumInsuredAmount);
+        UFixed collateralUFixed =  collateralizationLevel * sumInsuredUFixed;
+        return collateralUFixed.toInt();
+    } 
+
+    function collectPremium(NftId policyNftId, Timestamp activateAt) external override {
+        // check caller is registered product
+        (IRegistry.ObjectInfo memory productInfo, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+
+        // perform actual token transfers
+        IPolicy.PolicyInfo memory policyInfo = instance.getPolicyInfo(policyNftId);
+        ITreasury.ProductSetup memory product = instance.getProductSetup(productInfo.nftId);
+
+        uint256 premiumAmount = policyInfo.premiumAmount;
+        _processPremiumByTreasury(instance, product, policyNftId, premiumAmount);
+
+        // policy level book keeping for premium paid
+        policyInfo.premiumPaidAmount += premiumAmount;
+        policyInfo.updatedIn = blockNumber();
+
+        // optional activation of policy
+        if(activateAt > zeroTimestamp()) {
+            require(
+                policyInfo.activatedAt.eqz(),
+                "ERROR:PRS-030:ALREADY_ACTIVATED");
+
+            policyInfo.activatedAt = activateAt;
+            policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
+
+            // TODO add require for state change
+            policyInfo.state = ACTIVE();
+        }
+
+        instance.setPolicyInfo(policyInfo);
+
+        // TODO add logging
+    }
+
+    function activate(NftId policyNftId, Timestamp activateAt) external override {
+        // check caller is registered product
+        (, IInstance instance) = _getAndVerifyComponentInfoAndInstance(PRODUCT());
+
+        IPolicy.PolicyInfo memory policyInfo = instance.getPolicyInfo(policyNftId);
+
+        require(
+            policyInfo.activatedAt.eqz(),
+            "ERROR:PRS-020:ALREADY_ACTIVATED");
+
+        policyInfo.activatedAt = activateAt;
+        policyInfo.expiredAt = activateAt.addSeconds(policyInfo.lifetime);
+
+        // TODO add require for state change
+        policyInfo.state = ACTIVE();
+
+        instance.setPolicyInfo(policyInfo);
+
+        // TODO add logging
+    }
+
+    function close(
+        NftId policyNftId
+    ) external override // solhint-disable-next-line no-empty-blocks
+    {
+
+    }
+
+    function _getPoolNftId(
+        IInstance instance,
+        NftId productNftId
+    )
+        internal
+        view
+        returns (NftId poolNftid)
+    {
+        return instance.getProductSetup(productNftId).poolNftId;
+    }
+
+    function _processPremiumByTreasury(
+        IInstance instance,
+        ITreasury.ProductSetup memory product,
+        NftId policyNftId,
+        uint256 premiumAmount
+    )
+        internal
+        returns (uint256 netPremiumAmount)
+    {
+        // process token transfer(s)
+        if(premiumAmount > 0) {
+            TokenHandler tokenHandler = product.tokenHandler;
+            address policyOwner = _registry.getOwner(policyNftId);
+            address poolWallet = instance.getPoolSetup(product.poolNftId).wallet;
+            netPremiumAmount = premiumAmount;
+            Fee memory policyFee = product.policyFee;
+
+            if (feeIsZero(policyFee)) {
+                tokenHandler.transfer(
+                    policyOwner,
+                    poolWallet,
+                    premiumAmount
+                );
+            } else {
+                (uint256 feeAmount, uint256 netAmount) = instance.calculateFeeAmount(
+                    premiumAmount,
+                    policyFee
+                );
+
+                tokenHandler.transfer(policyOwner, product.wallet, feeAmount);
+                tokenHandler.transfer(policyOwner, poolWallet, netAmount);
+                netPremiumAmount = netAmount;
+            }
+        }
+
+        // TODO add logging
+    }
+}

package/contracts/instance/service/ServiceBase.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+// import {IRegistry} from "../../registry/IRegistry.sol";
+// import {ITreasury, ITreasuryModule, TokenHandler} from "../../instance/module/treasury/ITreasury.sol";
+import {NftId, zeroNftId} from "../../types/NftId.sol";
+import {ObjectType, SERVICE} from "../../types/ObjectType.sol";
+import {Version, VersionPart, toVersion, toVersionPart} from "../../types/Version.sol";
+
+import {Registerable} from "../../shared/Registerable.sol";
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {IService} from "./IService.sol";
+
+abstract contract ServiceBase is 
+    Registerable,
+    Versionable,
+    IService
+{
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    )
+        Registerable(registry, registryNftId)
+        Versionable()
+    {
+        _registerInterface(type(IService).interfaceId);
+    }
+
+    function getMajorVersion() external view override returns(VersionPart majorVersion) {
+        return this.getVersion().toMajorPart();
+    }
+
+    function getType() external pure override returns (ObjectType) {
+        return SERVICE();
+    }
+}