@etherisc/gif-next 0.0.2-ebbe63d → 0.0.2-efdb520-159

package/contracts/instance/module/policy/PolicyModule.sol

@@ -0,0 +1,84 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+
+import {LifecycleModule} from "../../module/lifecycle/LifecycleModule.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPolicy, IPolicyModule} from "./IPolicy.sol";
+import {ObjectType, POLICY} from "../../../types/ObjectType.sol";
+import {APPLIED, ACTIVE, UNDERWRITTEN} from "../../../types/StateId.sol";
+import {NftId, NftIdLib} from "../../../types/NftId.sol";
+import {Timestamp, blockTimestamp, zeroTimestamp} from "../../../types/Timestamp.sol";
+import {Blocknumber, blockNumber} from "../../../types/Blocknumber.sol";
+
+import {LifecycleModule} from "../../module/lifecycle/LifecycleModule.sol";
+
+abstract contract PolicyModule is IPolicyModule {
+    using NftIdLib for NftId;
+
+    mapping(NftId nftId => PolicyInfo info) private _policyInfo;
+
+    LifecycleModule private _lifecycleModule;
+
+    // TODO find a better place to avoid dupliation
+    modifier onlyProductService2() {
+        require(
+            msg.sender == address(this.getProductService()),
+            "ERROR:POL-001:NOT_PRODUCT_SERVICE"
+        );
+        _;
+    }
+
+    constructor() {
+        _lifecycleModule = LifecycleModule(address(this));
+    }
+
+    function createApplication(
+        NftId productNftId,
+        NftId policyNftId,
+        uint256 sumInsuredAmount,
+        uint256 premiumAmount,
+        uint256 lifetime,
+        NftId bundleNftId
+    )
+        external
+        onlyProductService2
+        override
+    {
+        _policyInfo[policyNftId] = PolicyInfo(
+            policyNftId,
+            productNftId,
+            bundleNftId,
+            address(0), // beneficiary = policy nft holder
+            _lifecycleModule.getInitialState(POLICY()),
+            sumInsuredAmount,
+            premiumAmount,
+            0, // premium paid amount
+            lifetime, 
+            "", // data
+            blockTimestamp(), // createdAt
+            zeroTimestamp(), // activatedAt
+            zeroTimestamp(), // expiredAt
+            zeroTimestamp(), // closedAt
+            blockNumber() // updatedIn
+        );
+
+        // TODO add logging
+    }
+
+    function setPolicyInfo(PolicyInfo memory policyInfo)
+        external
+        override
+        onlyProductService2
+    {
+        _policyInfo[policyInfo.nftId] = policyInfo;
+    }
+
+    function getPolicyInfo(
+        NftId nftId
+    ) external view returns (PolicyInfo memory info) {
+        return _policyInfo[nftId];
+    }
+
+}

package/contracts/instance/module/pool/IPoolModule.sol

@@ -0,0 +1,41 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {NftId} from "../../../types/NftId.sol";
+import {UFixed} from "../../../types/UFixed.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+
+interface IPool {
+    struct PoolInfo {
+        NftId nftId;
+        bool isVerifying;
+        UFixed collateralizationLevel;
+    }
+}
+
+interface IPoolModule is IPool {
+
+    function registerPool(
+        NftId poolNftId, 
+        bool isVerifying, 
+        UFixed collateralizationLevel
+    ) external;
+
+    function addBundleToPool(
+        NftId bundleNftId,
+        NftId poolNftId,
+        uint256 amount
+    ) external;
+
+    function getPoolInfo(
+        NftId nftId
+    ) external view returns (PoolInfo memory info);
+
+    function getBundleCount(NftId poolNftId) external view returns (uint256 bundleCount);
+    function getBundleNftId(NftId poolNftId, uint256 index) external view returns (NftId bundleNftId);
+
+    // repeat service linked signatures to avoid linearization issues
+    function getPoolService() external returns(IPoolService);
+}

package/contracts/instance/module/pool/PoolModule.sol

@@ -0,0 +1,87 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IRegistry} from "../../../registry/IRegistry.sol";
+import {IProductService} from "../../service/IProductService.sol";
+import {IPoolService} from "../../service/IPoolService.sol";
+import {IPolicy, IPolicyModule} from "../../module/policy/IPolicy.sol";
+import {ITreasuryModule} from "../../module/treasury/ITreasury.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {LibNftIdSet} from "../../../types/NftIdSet.sol";
+import {StateId, APPLIED} from "../../../types/StateId.sol";
+import {UFixed} from "../../../types/UFixed.sol";
+
+import {IPoolModule} from "./IPoolModule.sol";
+
+abstract contract PoolModule is
+    IPoolModule
+{
+    using LibNftIdSet for LibNftIdSet.Set;
+
+    mapping(NftId poolNftId => PoolInfo info) private _poolInfo;
+    mapping(NftId poolNftId => LibNftIdSet.Set bundles) private _bundlesForPool;
+
+    modifier poolServiceCallingPool() {
+        require(
+            msg.sender == address(this.getPoolService()),
+            "ERROR:PL-001:NOT_POOL_SERVICE"
+        );
+        _;
+    }
+
+    function registerPool(
+        NftId nftId, 
+        bool isVerifying,
+        UFixed collateralizationRate
+    )
+        public
+        override
+    {
+        require(
+            _poolInfo[nftId].nftId.eqz(), 
+            "ERROR:PL-010:ALREADY_CREATED");
+
+        _poolInfo[nftId] = PoolInfo(
+            nftId,
+            isVerifying,
+            collateralizationRate
+        );
+
+        // TODO add logging
+    }
+
+    function addBundleToPool(
+        NftId bundleNftId,
+        NftId poolNftId,
+        uint256 // amount
+    )
+        external
+        override
+    {
+        LibNftIdSet.Set storage bundleSet = _bundlesForPool[poolNftId];
+        require(
+            !bundleSet.contains(bundleNftId),
+            "ERROR:PL-020:BUNDLE_ALREADY_ADDED");
+
+        bundleSet.add(bundleNftId);
+    }
+
+
+    function getPoolInfo(
+        NftId nftId
+    ) external view override returns (PoolInfo memory info) {
+        info = _poolInfo[nftId];
+    }
+
+
+    function getBundleCount(NftId poolNftId) external view override returns (uint256 bundleCount) {
+        return _bundlesForPool[poolNftId].getLength();
+    }
+
+
+    function getBundleNftId(NftId poolNftId, uint256 index) external view override returns (NftId bundleNftId) {
+        return _bundlesForPool[poolNftId].getElementAt(index);
+    }
+
+}

package/contracts/instance/module/product/IProductModule.sol

@@ -0,0 +1,6 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+interface IProductModule
+{
+}

package/contracts/instance/module/product/ProductModule.sol

@@ -0,0 +1,8 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IProductService} from "../../service/IProductService.sol";
+import {IProductModule} from "./IProductModule.sol";
+
+abstract contract ProductModule is IProductModule {
+}

package/contracts/instance/module/treasury/ITreasury.sol

@@ -0,0 +1,104 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {UFixed} from "../../../types/UFixed.sol";
+import {Fee} from "../../../types/Fee.sol";
+
+import {TokenHandler} from "./TokenHandler.sol";
+
+interface ITreasury {
+    // TODO add events
+    // TODO add errors
+
+    struct ProductSetup {
+        NftId productNftId;
+        NftId distributorNftId;
+        NftId poolNftId;
+        IERC20Metadata token;
+        TokenHandler tokenHandler;
+        address wallet;
+        Fee policyFee;
+        Fee processingFee;
+    }
+
+    struct DistributorSetup {
+        NftId distributorNftId;
+        address wallet;
+        Fee commissionFees;
+    }
+
+    struct PoolSetup {
+        NftId poolNftId;
+        address wallet;
+        Fee stakingFee;
+        Fee performanceFee;
+    }
+}
+
+interface ITreasuryModule is ITreasury {
+
+    function registerProduct(
+        NftId productNftId,
+        NftId distributorNftId,
+        NftId poolNftId,
+        IERC20Metadata token,
+        address wallet,
+        Fee memory policyFee,
+        Fee memory processingFee
+    ) external;
+
+    function setProductFees(
+        NftId productNftId,
+        Fee memory policyFee,
+        Fee memory processingFee
+    ) external;
+
+    function registerPool(
+        NftId poolNftId,
+        address wallet,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external;
+
+    function setPoolFees(
+        NftId poolNftId,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external;
+
+    function getTokenHandler(
+        NftId productNftId
+    ) external view returns (TokenHandler tokenHandler);
+
+    function getProductSetup(
+        NftId productNftId
+    ) external view returns (ProductSetup memory setup);
+
+    function getPoolSetup(
+        NftId poolNftId
+    ) external view returns (PoolSetup memory setup);
+
+    function calculateFeeAmount(
+        uint256 amount,
+        Fee memory fee
+    ) external pure returns (uint256 feeAmount, uint256 netAmount);
+
+    function getFee(
+        UFixed fractionalFee, 
+        uint256 fixedFee
+    ) external pure returns (Fee memory fee);
+
+    function getZeroFee() external pure returns (Fee memory fee);
+
+    function getUFixed(
+        uint256 a
+    ) external pure returns (UFixed);
+
+    function getUFixed(
+        uint256 a, 
+        int8 exp
+    ) external pure returns (UFixed);
+}

package/contracts/instance/module/treasury/TokenHandler.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+
+contract TokenHandler {
+    NftId private _productNftId;
+    IERC20Metadata private _token;
+
+    constructor(
+        NftId productNftId,
+        address token
+    )
+    {
+        _productNftId = productNftId;
+        _token = IERC20Metadata(token);
+    }
+
+    // TODO add logging
+    function transfer(
+        address from,
+        address to,
+        uint256 amount
+    )
+        external // TODO add authz (only treasury/instance/product/pool/ service)
+    {
+        // TODO switch to oz safeTransferFrom
+        _token.transferFrom(from, to, amount);
+    }
+
+    function getProductNftId()
+        external
+        view
+        returns(NftId)
+    {
+        return _productNftId;
+    }
+
+    function getToken()
+        external
+        view
+        returns(IERC20Metadata)
+    {
+        return _token;
+    }
+}

package/contracts/instance/module/treasury/TreasuryModule.sol

@@ -0,0 +1,148 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {NftId} from "../../../types/NftId.sol";
+import {Fee, feeIsZero, toFee, zeroFee} from "../../../types/Fee.sol";
+import {UFixed, UFixedMathLib} from "../../../types/UFixed.sol";
+import {TokenHandler} from "./TokenHandler.sol";
+import {ITreasuryModule} from "./ITreasury.sol";
+
+abstract contract TreasuryModule is ITreasuryModule {
+    mapping(NftId productNftId => ProductSetup setup) private _productSetup;
+    mapping(NftId distributorNftId => DistributorSetup setup)
+        private _distributorSetup;
+    mapping(NftId poolNftId => PoolSetup setup) private _poolSetup;
+
+    function registerProduct(
+        NftId productNftId,
+        NftId distributorNftId,
+        NftId poolNftId,
+        IERC20Metadata token,
+        address wallet,
+        Fee memory policyFee,
+        Fee memory processingFee
+    ) external override // TODO add authz (only component module)
+    {
+        // TODO add validation
+
+        // deploy product specific handler contract
+        TokenHandler tokenHandler = new TokenHandler(productNftId, address(token));
+
+        _productSetup[productNftId] = ProductSetup(
+            productNftId,
+            distributorNftId,
+            poolNftId,
+            token,
+            tokenHandler,
+            wallet,
+            policyFee,
+            processingFee
+        );
+
+        // TODO add logging
+    }
+
+    function setProductFees(
+        NftId productNftId,
+        Fee memory policyFee,
+        Fee memory processingFee
+    ) external override // TODO add authz (only component owner service)
+    {
+        // TODO add validation
+
+        ProductSetup storage setup = _productSetup[productNftId];
+        setup.policyFee = policyFee;
+        setup.processingFee = processingFee;
+
+        // TODO add logging
+    }
+
+    function registerPool(
+        NftId poolNftId,
+        address wallet,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external override // TODO add authz (only component module)
+    {
+        // TODO add validation
+
+        _poolSetup[poolNftId] = PoolSetup(
+            poolNftId,
+            wallet,
+            stakingFee,
+            performanceFee
+        );
+
+        // TODO add logging
+    }
+
+    function setPoolFees(
+        NftId poolNftId,
+        Fee memory stakingFee,
+        Fee memory performanceFee
+    ) external override // TODO add authz (only component owner service)
+    {
+        // TODO add validation
+
+        PoolSetup storage setup = _poolSetup[poolNftId];
+        setup.stakingFee = stakingFee;
+        setup.performanceFee = performanceFee;
+
+        // TODO add logging
+    }
+
+    function getTokenHandler(
+        NftId productNftId
+    ) external view override returns (TokenHandler tokenHandler) {
+        return _productSetup[productNftId].tokenHandler;
+    }
+
+    function getProductSetup(
+        NftId productNftId
+    ) external view override returns (ProductSetup memory setup) {
+        return _productSetup[productNftId];
+    }
+
+    function getPoolSetup(
+        NftId poolNftId
+    ) external view override returns (PoolSetup memory setup) {
+        return _poolSetup[poolNftId];
+    }
+
+    function calculateFeeAmount(
+        uint256 amount,
+        Fee memory fee
+    ) public pure override returns (uint256 feeAmount, uint256 netAmount) {
+        UFixed fractionalAmount = UFixedMathLib.toUFixed(amount) *
+            fee.fractionalFee;
+        feeAmount = fractionalAmount.toInt() + fee.fixedFee;
+        netAmount = amount - feeAmount;
+    }
+
+    function getFee(
+        UFixed fractionalFee, 
+        uint256 fixedFee
+    ) external pure override returns (Fee memory fee) {
+        return toFee(fractionalFee, fixedFee);
+    }
+
+    function getZeroFee() external pure override returns (Fee memory fee) {
+        return zeroFee();
+    }
+
+    function getUFixed(
+        uint256 a
+    ) external pure override returns (UFixed) {
+        return UFixedMathLib.toUFixed(a);
+    }
+
+    function getUFixed(
+        uint256 a, 
+        int8 exp
+    ) external pure returns (UFixed)
+    {
+        return UFixedMathLib.toUFixed(a, exp);
+    }
+}

package/contracts/instance/service/ComponentOwnerService.sol

@@ -0,0 +1,174 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.19;
+
+import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
+
+import {IRegistry} from "../../registry/IRegistry.sol";
+import {IInstance} from "../IInstance.sol";
+
+import {LifecycleModule} from "../module/lifecycle/LifecycleModule.sol";
+import {ITreasuryModule} from "../module/treasury/ITreasury.sol";
+import {TreasuryModule} from "../module/treasury/TreasuryModule.sol";
+import {IComponent, IComponentModule} from "../module/component/IComponent.sol";
+import {IBaseComponent} from "../../components/IBaseComponent.sol";
+import {IPoolComponent} from "../../components/IPoolComponent.sol";
+
+import {IVersionable} from "../../shared/IVersionable.sol";
+import {Versionable} from "../../shared/Versionable.sol";
+
+import {RoleId, PRODUCT_OWNER_ROLE, POOL_OWNER_ROLE, ORACLE_OWNER_ROLE} from "../../types/RoleId.sol";
+import {ObjectType, PRODUCT, ORACLE, POOL} from "../../types/ObjectType.sol";
+import {StateId, ACTIVE, PAUSED} from "../../types/StateId.sol";
+import {NftId, NftIdLib, zeroNftId} from "../../types/NftId.sol";
+import {Fee, zeroFee} from "../../types/Fee.sol";
+import {Version, toVersion, toVersionPart} from "../../types/Version.sol";
+
+import {IProductComponent} from "../../components/IProductComponent.sol";
+import {ServiceBase} from "./ServiceBase.sol";
+import {IComponentOwnerService} from "./IComponentOwnerService.sol";
+
+contract ComponentOwnerService is
+    ServiceBase,
+    IComponentOwnerService
+{
+    using NftIdLib for NftId;
+
+    string public constant NAME = "ComponentOwnerService";
+
+    modifier onlyRegisteredComponent(IBaseComponent component) {
+        NftId nftId = _registry.getNftId(address(component));
+        require(nftId.gtz(), "ERROR:COS-001:COMPONENT_UNKNOWN");
+        _;
+    }
+
+    constructor(
+        address registry,
+        NftId registryNftId
+    ) ServiceBase(registry, registryNftId) // solhint-disable-next-line no-empty-blocks
+    {
+
+    }
+
+    function getVersion()
+        public 
+        pure 
+        virtual override (IVersionable, Versionable)
+        returns(Version)
+    {
+        return toVersion(
+            toVersionPart(3),
+            toVersionPart(0),
+            toVersionPart(0));
+    }
+
+    function getName() external pure override returns(string memory name) {
+        return NAME;
+    }
+
+    function getRoleForType(
+        ObjectType cType
+    ) public pure override returns (RoleId role) {
+        if (cType == PRODUCT()) {
+            return PRODUCT_OWNER_ROLE();
+        }
+        if (cType == POOL()) {
+            return POOL_OWNER_ROLE();
+        }
+        if (cType == ORACLE()) {
+            return ORACLE_OWNER_ROLE();
+        }
+    }
+
+    function register(
+        IBaseComponent component
+    ) external override returns (NftId nftId) {
+        address initialOwner = component.getOwner();
+        require(
+            msg.sender == address(component),
+            "ERROR:COS-003:NOT_COMPONENT"
+        );
+
+        IInstance instance = component.getInstance();
+        ObjectType objectType = component.getType();
+        RoleId typeRole = getRoleForType(objectType);
+        require(
+            instance.hasRole(typeRole, initialOwner),
+            "ERROR:CMP-004:TYPE_ROLE_MISSING"
+        );
+
+        nftId = _registry.register(address(component));
+        IERC20Metadata token = component.getToken();
+
+        instance.registerComponent(
+            nftId,
+            objectType,
+            token);
+
+        address wallet = component.getWallet();
+
+        // component type specific registration actions
+        if (component.getType() == PRODUCT()) {
+            IProductComponent product = IProductComponent(address(component));
+            NftId poolNftId = product.getPoolNftId();
+            require(poolNftId.gtz(), "ERROR:CMP-005:POOL_UNKNOWN");
+            // validate pool token and product token are same
+
+            // register with tresury
+            // implement and add validation
+            NftId distributorNftId = zeroNftId();
+            instance.registerProduct(
+                nftId,
+                distributorNftId,
+                poolNftId,
+                token,
+                wallet,
+                product.getPolicyFee(),
+                product.getProcessingFee()
+            );
+        } else if (component.getType() == POOL()) {
+            IPoolComponent pool = IPoolComponent(address(component));
+
+            // register with pool
+            instance.registerPool(
+                nftId,
+                pool.isVerifying(),
+                pool.getCollateralizationLevel());
+
+            // register with tresury
+            instance.registerPool(
+                nftId,
+                wallet,
+                pool.getStakingFee(),
+                pool.getPerformanceFee());
+        }
+        // TODO add distribution
+    }
+
+    function lock(
+        IBaseComponent component
+    ) external override onlyRegisteredComponent(component) {
+        IInstance instance = component.getInstance();
+        IComponent.ComponentInfo memory info = instance.getComponentInfo(
+            component.getNftId()
+        );
+        require(info.nftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
+
+        info.state = PAUSED();
+        // setComponentInfo checks for valid state changes
+        instance.setComponentInfo(info);
+    }
+
+    function unlock(
+        IBaseComponent component
+    ) external override onlyRegisteredComponent(component) {
+        IInstance instance = component.getInstance();
+        IComponent.ComponentInfo memory info = instance.getComponentInfo(
+            component.getNftId()
+        );
+        require(info.nftId.gtz(), "ERROR_COMPONENT_UNKNOWN");
+
+        info.state = ACTIVE();
+        // setComponentInfo checks for valid state changes
+        instance.setComponentInfo(info);
+    }
+}