@cpp.js/package-gdal 1.0.0-beta.20

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindShapelib.cmake

@@ -0,0 +1,69 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst:
+# FindShapelib
+# -----------
+#
+# Copyright (c) 2018, Hiroshi Miura <miurahr@linux.com>
+#
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_Shapelib QUIET shapelib)
+endif()
+
+find_path(Shapelib_INCLUDE_DIR
+          NAMES shapefil.h
+          HINTS ${PC_Shapelib_INCLUDE_DIRS})
+
+if(Shapelib_INCLUDE_DIR)
+    if(PC_Shapelib_VERSION)
+        set(Shapelib_VERSION ${PC_Shapelib_VERSION})
+    else()
+        file(READ ${Shapelib_INCLUDE_DIR}/shapefil.h _shapefil_h_contents)
+        string(REGEX MATCH "Id: shapefil.h,v ([0-9.]+)" Shapelib_H_VERSION "${_shapefil_h_contents}")
+        string(REGEX MATCH "([0-9].[0-9][0-9])" Shapelib_H_VERSION "${Shapelib_H_VERSION}")
+        # shapefil.h 1.26 = release 1.2.10
+        # shapefil.h 1.52 = release 1.3.0
+        # shapefil.h 1.55 = release 1.4.0, 1.4.1
+        if(Shapelib_H_VERSION VERSION_LESS 1.26)
+            message(WARNING "Shapelib version detection failed")
+        elseif(Shapelib_H_VERSION VERSION_LESS 1.52)
+            set(Shapelib_VERSION 1.2.10)
+        elseif(Shapelib_H_VERSION VERSION_LESS 1.55)
+            set(Shapelib_VERSION 1.3.0)
+        else()
+            set(Shapelib_VERSION 1.4.0)
+        endif()
+    endif()
+endif()
+
+if(MSVC)
+    set(Shapelib_LIBNAME shapelib)
+else()
+    set(Shapelib_LIBNAME shp)
+endif()
+
+find_library(Shapelib_LIBRARY NAMES ${Shapelib_LIBNAME})
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Shapelib
+                                  FOUND_VAR Shapelib_FOUND
+                                  REQUIRED_VARS Shapelib_INCLUDE_DIR Shapelib_LIBRARY
+                                  VERSION_VAR Shapelib_VERSION
+)
+
+mark_as_advanced(Shapelib_INCLUDE_DIR Shapelib_LIBRARY)
+
+if(Shapelib_FOUND)
+    set(Shapelib_INCLUDE_DIRS "${Shapelib_INCLUDE_DIR}")
+    set(Shapelib_LIBRARIES "${Shapelib_LIBRARY}")
+    if(NOT TARGET SHAPELIB::shp)
+        add_library(SHAPELIB::shp UNKNOWN IMPORTED)
+        set_target_properties(SHAPELIB::shp PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${Shapelib_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES C
+                              IMPORTED_LOCATION "${Shapelib_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindSpatialindex.cmake

@@ -0,0 +1,18 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# - Find Spatialindex
+#
+# Once run this will define:
+#
+# SPATIALINDEX_FOUND       = system has Spatialindex lib
+# SPATIALINDEX_LIBRARY     = full path to the Spatialindex library
+# SPATIALINDEX_INCLUDE_DIR = where to find headers
+#
+
+find_path(SPATIALINDEX_INCLUDE_DIR NAMES SpatialIndex.h PATH_SUFFIXES spatialindex)
+find_library(SPATIALINDEX_LIBRARY NAMES spatialindex_i spatialindex)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Spatialindex FOUND_VAR SPATIALINDEX_FOUND
+                                  REQUIRED_VARS SPATIALINDEX_LIBRARY MYSQL_SPATIALINDEX_DIR)

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindTEIGHA.cmake

@@ -0,0 +1,242 @@
+# Find TEIGHA
+# ~~~~~~~~~
+#
+# Copyright (c) 2017,2018, Hiroshi Miura <miurahr@linux.com>
+# Copyright (c) 2021 Even Rouault <even.rouault@spatialys.com>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+#
+# If it's found it sets TEIGHA_FOUND to TRUE
+# and following variables are set:
+#    TEIGHA_INCLUDE_DIR
+#    TEIGHA_LIBRARIES
+#
+#  Before call here user should set TEIGHA_ROOT variable (and possibly TEIGHA_PLATFORM as well)
+
+if(NOT TEIGHA_ROOT)
+    return()
+endif()
+
+if(NOT EXISTS "${TEIGHA_ROOT}")
+    message(FATAL_ERROR "TEIGHA_ROOT=${TEIGHA_ROOT} does not exist")
+endif()
+
+if(NOT TEIGHA_PLATFORM)
+    if(NOT EXISTS "${TEIGHA_ROOT}/lib")
+        message(FATAL_ERROR "TEIGHA_ROOT=${TEIGHA_ROOT} should point to a directory with a lib/ subdirectory")
+    endif()
+    file(GLOB TEIGHA_PLATFORM RELATIVE "${TEIGHA_ROOT}/lib" "${TEIGHA_ROOT}/lib/*")
+    list(LENGTH TEIGHA_PLATFORM TEIGHA_PLATFORM_LIST_LENGTH)
+    if(NOT TEIGHA_PLATFORM_LIST_LENGTH EQUAL "1")
+        message(FATAL_ERROR "TEIGHA_ROOT=${TEIGHA_ROOT}/lib has several directories. You should also set the TEIGHA_PLATFORM variable to the subdirectory of interest")
+    endif()
+endif()
+
+set(TEIGHA_INCLUDE_SUBDIRS_NAMES
+    ${TEIGHA_INCLUDE_SUBDIRS_NAMES}
+    Core/Include
+    Core/Extensions/ExServices
+    Core/Examples/Common
+    ThirdParty/activation
+    KernelBase/Include
+    Kernel/Include
+    Kernel/Extensions/ExServices
+    Drawing/Include
+    Drawing/Extensions/ExServices
+    Dgn/include
+    Dgn/Extensions/ExServices)
+set(TEIGHA_INCLUDE_DIRS)
+foreach(_TEIGHA_INCLUDE_SUBDIR IN LISTS TEIGHA_INCLUDE_SUBDIRS_NAMES)
+    if(EXISTS "${TEIGHA_ROOT}/${_TEIGHA_INCLUDE_SUBDIR}")
+        list(APPEND TEIGHA_INCLUDE_DIRS "${TEIGHA_ROOT}/${_TEIGHA_INCLUDE_SUBDIR}")
+    endif()
+endforeach()
+
+if(DEFINED TEIGHA_ACTIVATION_FILE_DIRECTORY)
+    list(APPEND TEIGHA_INCLUDE_DIRS "${TEIGHA_ACTIVATION_FILE_DIRECTORY}")
+else()
+    file(GLOB _od_activation_info "${TEIGHA_ROOT}/OdActivationInfo")
+    if(_od_activation_info)
+        list(LENGTH _od_activation_info _od_activation_info_length)
+        if(_od_activation_info_length EQUAL 1)
+            get_filename_component(TEIGHA_ACTIVATION_FILE_DIRECTORY "${_od_activation_info}" DIRECTORY)
+            list(APPEND TEIGHA_INCLUDE_DIRS "${TEIGHA_ACTIVATION_FILE_DIRECTORY}")
+        else()
+            message(FATAL_ERROR "Several OdActivationInfo files found under ${TEIGHA_ROOT}. Point to one of them by setting TEIGHA_ACTIVATION_FILE_DIRECTORY")
+        endif()
+    else()
+        message(WARNING "No OdActivationInfo file found under ${TEIGHA_ROOT}. You'll likely need to point to one by setting TEIGHA_ACTIVATION_FILE_DIRECTORY")
+    endif()
+endif()
+
+set(TEIGHA_LIBRARIES)
+
+if(EXISTS "${TEIGHA_ROOT}/bin/${TEIGHA_PLATFORM}/TG_Db.tx")
+    # Linux shared libs
+    list(APPEND TEIGHA_LIBRARIES_NAMES
+        "bin/${TEIGHA_PLATFORM}/TG_Db.tx"
+        "bin/${TEIGHA_PLATFORM}/TD_DbEntities.tx"
+        "lib/${TEIGHA_PLATFORM}/libTD_DrawingsExamplesCommon.a"
+        "lib/${TEIGHA_PLATFORM}/libTG_ExamplesCommon.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_ExamplesCommon.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_Key.a"
+        "bin/${TEIGHA_PLATFORM}/libTD_Db.so"
+        "bin/${TEIGHA_PLATFORM}/libTD_DbCore.so"
+        "bin/${TEIGHA_PLATFORM}/libTD_DbRoot.so"
+        "bin/${TEIGHA_PLATFORM}/libTD_Gi.so"
+        "bin/${TEIGHA_PLATFORM}/libTD_SpatialIndex.so"
+        "bin/${TEIGHA_PLATFORM}/libTD_Root.so"
+        "bin/${TEIGHA_PLATFORM}/libTD_Ge.so"
+        "bin/${TEIGHA_PLATFORM}/libTD_Zlib.so"
+        "bin/${TEIGHA_PLATFORM}/libTD_Alloc.so"
+        "bin/${TEIGHA_PLATFORM}/liboless.so"
+        "bin/${TEIGHA_PLATFORM}/liblibcrypto.so"
+        )
+elseif (EXISTS "${TEIGHA_ROOT}/lib/${TEIGHA_PLATFORM}/libTG_Db.a")
+    # Linux static libs
+    list(APPEND TEIGHA_LIBRARIES_NAMES
+        "lib/${TEIGHA_PLATFORM}/libTD_Db.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_DbCore.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_DbEntities.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_DrawingsExamplesCommon.a"
+        "lib/${TEIGHA_PLATFORM}/libTG_Db.a"
+        "lib/${TEIGHA_PLATFORM}/libTG_ExamplesCommon.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_Alloc.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_DbRoot.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_ExamplesCommon.a"
+        "lib/${TEIGHA_PLATFORM}/libWinBitmap.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_Gi.a"
+        "lib/${TEIGHA_PLATFORM}/libtinyxml.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_Zlib.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_SpatialIndex.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_DgnImport.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_DgnUnderlay.a"
+        "lib/${TEIGHA_PLATFORM}/libModelerGeometry.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_BrepRenderer.a"
+        "lib/${TEIGHA_PLATFORM}/libRecomputeDimBlock.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_AcisBuilder.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_Br.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_Gs.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_Ge.a"
+        "lib/${TEIGHA_PLATFORM}/libTD_Root.a"
+        "lib/${TEIGHA_PLATFORM}/liboless.a"
+        "lib/${TEIGHA_PLATFORM}/liblibcrypto.a"
+        "lib/${TEIGHA_PLATFORM}/libsisl.a"
+        #"lib/${TEIGHA_PLATFORM}/libFreeType.a"  # System one added later
+        #"lib/${TEIGHA_PLATFORM}/libzlib.a"      # System one added later
+        )
+elseif (EXISTS "${TEIGHA_ROOT}/lib/${TEIGHA_PLATFORM}/TD_DrawingsExamplesCommon.lib")
+    # Windows ODA 2021
+    set(TD_DRAWINGS_LIBDIR "lib/${TEIGHA_PLATFORM}")
+    set(TD_KERNEL_LIBDIR   "lib/${TEIGHA_PLATFORM}")
+    list(APPEND TEIGHA_LIBRARIES_NAMES
+        "${TD_DRAWINGS_LIBDIR}/TD_Db.lib"
+        "${TD_DRAWINGS_LIBDIR}/TD_DbCore.lib"
+        "${TD_DRAWINGS_LIBDIR}/TD_DbEntities.lib"
+        "${TD_DRAWINGS_LIBDIR}/TD_DrawingsExamplesCommon.lib"
+        "${TD_DRAWINGS_LIBDIR}/TG_Db.lib"
+        "${TD_DRAWINGS_LIBDIR}/TG_ExamplesCommon.lib"
+        "${TD_KERNEL_LIBDIR}/TD_Alloc.lib"
+        "${TD_KERNEL_LIBDIR}/TD_DbRoot.lib"
+        "${TD_KERNEL_LIBDIR}/TD_ExamplesCommon.lib"
+        "${TD_KERNEL_LIBDIR}/TD_Ge.lib"
+        "${TD_KERNEL_LIBDIR}/TD_Root.lib")
+    if (EXISTS "${TEIGHA_ROOT}/exe/${TEIGHA_PLATFORM}/oless.dll")
+    # Dynamic libs
+    list(APPEND TEIGHA_LIBRARIES_NAMES
+        "${TD_DRAWINGS_LIBDIR}/TD_Key.lib")
+    else()
+    # Static libs
+    list(APPEND TEIGHA_LIBRARIES_NAMES
+        "${TD_KERNEL_LIBDIR}/TD_Gi.lib"
+        "${TD_KERNEL_LIBDIR}/tinyxml.lib"
+        "${TD_KERNEL_LIBDIR}/TD_Zlib.lib"
+        "${TD_DRAWINGS_LIBDIR}/TD_DbIO.lib"
+        "${TD_DRAWINGS_LIBDIR}/ISM.lib"
+        "${TD_DRAWINGS_LIBDIR}/WipeOut.lib"
+        "${TD_DRAWINGS_LIBDIR}/RText.lib"
+        "${TD_DRAWINGS_LIBDIR}/ATEXT.lib"
+        "${TD_DRAWINGS_LIBDIR}/SCENEOE.lib"
+        "${TD_DRAWINGS_LIBDIR}/ACCAMERA.lib"
+        "${TD_DRAWINGS_LIBDIR}/AcMPolygonObj15.lib"
+        "${TD_KERNEL_LIBDIR}/TD_Gs.lib"
+        "${TD_KERNEL_LIBDIR}/TD_SpatialIndex.lib"
+        "${TD_KERNEL_LIBDIR}/oless.lib"
+        "${TD_KERNEL_LIBDIR}/UTF.lib"
+        "${TD_KERNEL_LIBDIR}/WinBitmap.lib"
+        "${TD_KERNEL_LIBDIR}/OdBrepModeler.lib"
+        "${TD_KERNEL_LIBDIR}/TD_Br.lib"
+        "${TD_KERNEL_LIBDIR}/TD_AcisBuilder.lib"
+        "${TD_KERNEL_LIBDIR}/TD_BrepBuilder.lib"
+        "${TD_KERNEL_LIBDIR}/TD_BrepBuilderFiller.lib"
+        "${TD_KERNEL_LIBDIR}/TD_BrepRenderer.lib"
+        "${TD_DRAWINGS_LIBDIR}/ModelerGeometry.lib"
+        "${TD_DRAWINGS_LIBDIR}/RecomputeDimBlock.lib")
+    list(APPEND TEIGHA_LIBRARIES crypt32.lib
+                                 secur32.lib
+                                 user32.lib
+                                 gdi32.lib
+                                 ole32.lib)
+    endif()
+elseif (EXISTS "${TEIGHA_ROOT}/lib/${TEIGHA_PLATFORM}/TD_Key.lib")
+    # Windows Teigha 4.2.2 shared libs
+    list(APPEND TEIGHA_LIBRARIES_NAMES
+         "lib/${TEIGHA_PLATFORM}/TD_Key.lib"
+         "lib/${TEIGHA_PLATFORM}/TD_ExamplesCommon.lib"
+         "lib/${TEIGHA_PLATFORM}/TD_Db.lib"
+         "lib/${TEIGHA_PLATFORM}/TD_DbRoot.lib"
+         "lib/${TEIGHA_PLATFORM}/TD_Root.lib"
+         "lib/${TEIGHA_PLATFORM}/TD_Ge.lib"
+         "lib/${TEIGHA_PLATFORM}/TD_Alloc.lib"
+         "lib/${TEIGHA_PLATFORM}/TG_Db.lib"
+         "lib/${TEIGHA_PLATFORM}/TG_ExamplesCommon.lib")
+else()
+    # TODO ODA 2021.2 shared and static libs to migrate from nmake.opt
+    message(FATAL_ERROR "Teigha/ODA library layout not handled currently")
+endif()
+
+foreach(_TEIGHA_LIBRARY IN LISTS TEIGHA_LIBRARIES_NAMES)
+    if(EXISTS "${TEIGHA_ROOT}/${_TEIGHA_LIBRARY}")
+        list(APPEND TEIGHA_LIBRARIES "${TEIGHA_ROOT}/${_TEIGHA_LIBRARY}")
+    endif()
+endforeach()
+
+if(WIN32)
+    list(APPEND TEIGHA_LIBRARIES advapi32.lib)
+endif()
+if (EXISTS "${TEIGHA_ROOT}/lib/${TEIGHA_PLATFORM}/libTG_Db.a")
+    find_library(FREETYPE_LIBRARY NAMES freetype)
+    mark_as_advanced(FREETYPE_LIBRARY)
+    list(APPEND TEIGHA_LIBRARIES ${FREETYPE_LIBRARY})
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(TEIGHA
+                                  FOUND_VAR TEIGHA_FOUND
+                                  REQUIRED_VARS TEIGHA_LIBRARIES TEIGHA_INCLUDE_DIRS)
+if(TEIGHA_FOUND)
+    if(NOT TARGET TEIGHA::TEIGHA)
+        set(INCR 1)
+        set(TEIGHA_TARGETS)
+        foreach(_TEIGHA_LIBRARY IN LISTS TEIGHA_LIBRARIES)
+            add_library(TEIGHA::TEIGHA_${INCR} UNKNOWN IMPORTED)
+            set_target_properties(TEIGHA::TEIGHA_${INCR} PROPERTIES
+                                  IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                  IMPORTED_LOCATION "${_TEIGHA_LIBRARY}")
+            list(APPEND TEIGHA_TARGETS TEIGHA::TEIGHA_${INCR})
+            math(EXPR INCR "${INCR}+1")
+        endforeach()
+        if (EXISTS "${TEIGHA_ROOT}/lib/${TEIGHA_PLATFORM}/libTG_Db.a")
+            find_library(FREETYPE_LIBRARY NAMES freetype)
+            list(APPEND TEIGHA_TARGETS ZLIB::ZLIB)
+        endif()
+        add_library(TEIGHA::TEIGHA INTERFACE IMPORTED)
+        set_target_properties(TEIGHA::TEIGHA PROPERTIES
+                     INTERFACE_INCLUDE_DIRECTORIES "${TEIGHA_INCLUDE_DIRS}"
+                     INTERFACE_LINK_LIBRARIES "${TEIGHA_TARGETS}")
+        if(EXISTS "${TEIGHA_ROOT}/bin/${TEIGHA_PLATFORM}/liboless.so" OR EXISTS "${TEIGHA_ROOT}/exe/${TEIGHA_PLATFORM}/oless.dll")
+            set_property(TARGET TEIGHA::TEIGHA APPEND PROPERTY
+                         INTERFACE_COMPILE_DEFINITIONS "_TOOLKIT_IN_DLL_")
+        endif()
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindWebP.cmake

@@ -0,0 +1,38 @@
+# - Try to find the WebP library
+#
+# Once done this will define
+#
+#  WEBP_FOUND - System has libgta
+#  WEBP_INCLUDE_DIR - The libgta include directory
+#  WEBP_LIBRARIES - The libraries needed to use libgta
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_WEBP QUIET libwebp)
+    set(WEBP_VERSION_STRING ${PC_WEBP_VERSION})
+endif()
+
+find_path(WEBP_INCLUDE_DIR webp/encode.h HINTS ${PC_WEBP_INCLUDE_DIRS})
+
+find_library(WEBP_LIBRARY NAMES webp libwebp HINTS ${PC_WEBP_LIBRARY_DIRS})
+
+mark_as_advanced(WEBP_INCLUDE_DIR WEBP_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(WebP
+                                  FOUND_VAR WEBP_FOUND
+                                  REQUIRED_VARS WEBP_LIBRARY WEBP_INCLUDE_DIR
+                                  VERSION_VAR WEBP_VERSION_STRING
+)
+
+if(WEBP_FOUND)
+    set(WEBP_LIBRARIES "${WEBP_LIBRARY}")
+    set(WEBP_INCLUDE_DIRS "${WEBP_INCLUDE_DIR}")
+    if(NOT TARGET WEBP::WebP)
+        add_library(WEBP::WebP UNKNOWN IMPORTED)
+        set_target_properties(WEBP::WebP PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${WEBP_INCLUDE_DIRS}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${WEBP_LIBRARIES}")
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindZSTD.cmake

@@ -0,0 +1,95 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying file COPYING-CMAKE-SCRIPTS or
+# https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindZSTD
+--------
+
+Find the ZSTD library
+
+Zstandard C/C++ library is built with CMake. So this find module
+should be removed when ZStandard library export cmake config files
+as distribution. Unfortunately ZStandard does not export it,
+we need to prepare find module.
+see. https://gitlab.kitware.com/cmake/cmake/-/issues/19405
+
+IMPORTED targets
+^^^^^^^^^^^^^^^^
+
+This module defines the following :prop_tgt:`IMPORTED` target: ``ZSTD::zstd``
+
+Result variables
+^^^^^^^^^^^^^^^^
+
+This module will set the following variables if found:
+
+``ZSTD_INCLUDE_DIRS`` - where to find zstd.h, etc.
+``ZSTD_LIBRARIES`` - the libraries to link against to use ZSTD.
+``ZSTD_VERSION`` - version of the ZSTD library found
+``ZSTD_FOUND`` - TRUE if found
+
+::
+
+  ``ZSTD_VERSION_MAJOR``  - The major version of zstd
+  ``ZSTD_VERSION_MINOR``  - The minor version of zstd
+  ``ZSTD_VERSION_RELEASE``  - The release version of zstd
+
+#]=======================================================================]
+
+find_package(PkgConfig)
+pkg_check_modules(PC_ZSTD QUIET libzstd)
+
+find_path(
+  ZSTD_INCLUDE_DIR
+  NAMES zstd.h
+  PATHS ${PC_ZSTD_INCLUDE_DIRS}
+)
+find_library(
+  ZSTD_LIBRARY
+  NAMES zstd zstd_static NAMES_PER_DIR
+  PATHS ${PC_ZSTD_LIBRARY_DIRS}
+)
+
+# Extract version information from the header file
+if(EXISTS "${ZSTD_INCLUDE_DIR}/zstd.h")
+  file(STRINGS "${ZSTD_INCLUDE_DIR}/zstd.h"
+       _ZSTD_VERSION_MAJOR REGEX "^#define ZSTD_VERSION_MAJOR")
+  string(REGEX MATCH "[0-9]+" ZSTD_VERSION_MAJOR ${_ZSTD_VERSION_MAJOR})
+  file(STRINGS "${ZSTD_INCLUDE_DIR}/zstd.h"
+       _ZSTD_VERSION_MINOR REGEX "^#define ZSTD_VERSION_MINOR")
+  string(REGEX MATCH "[0-9]+" ZSTD_VERSION_MINOR ${_ZSTD_VERSION_MINOR} )
+  file(STRINGS "${ZSTD_INCLUDE_DIR}/zstd.h"
+       _ZSTD_VERSION_RELEASE REGEX "^#define ZSTD_VERSION_RELEASE")
+  string(REGEX MATCH "[0-9]+" ZSTD_VERSION_RELEASE ${_ZSTD_VERSION_RELEASE} )
+  set(ZSTD_VERSION ${ZSTD_VERSION_MAJOR}.${ZSTD_VERSION_MINOR}.${ZSTD_VERSION_RELEASE})
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(
+  ZSTD
+  FOUND_VAR ZSTD_FOUND
+  REQUIRED_VARS ZSTD_LIBRARY ZSTD_INCLUDE_DIR
+  VERSION_VAR ZSTD_VERSION
+  HANDLE_COMPONENTS)
+mark_as_advanced(ZSTD_INCLUDE_DIR ZSTD_LIBRARY)
+
+include(FeatureSummary)
+set_package_properties(
+  ZSTD PROPERTIES
+  DESCRIPTION "Zstandard - Fast real-time compression algorithm"
+  URL "https://github.com/facebook/zstd")
+
+if(ZSTD_FOUND)
+  set(ZSTD_INCLUDE_DIRS "${ZSTD_INCLUDE_DIR}")
+  set(ZSTD_LIBRARIES "${ZSTD_LIBRARY}")
+  set(ZSTD_DEFINITIONS ${PC_ZSTD_CFLAGS_OTHER})
+  set(ZSTD_TARGET ZSTD::zstd)
+  if(NOT TARGET ${ZSTD_TARGET})
+    add_library(${ZSTD_TARGET} UNKNOWN IMPORTED)
+    set_target_properties(${ZSTD_TARGET} PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${ZSTD_INCLUDE_DIR}")
+    if(EXISTS "${ZSTD_LIBRARY}")
+      set_target_properties(${ZSTD_TARGET} PROPERTIES IMPORTED_LINK_INTERFACE_LANGUAGES "CXX"
+        IMPORTED_LOCATION "${ZSTD_LIBRARY}")
+    endif()
+  endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/thirdparty/DotnetImports.props.in

@@ -0,0 +1,7 @@
+<Project>
+    <PropertyGroup>
+        <OutDir>${_DN_OUTPUT_PATH}/</OutDir>
+        <DOTNET_PACKAGE_VERSION>${_DN_VERSION}</DOTNET_PACKAGE_VERSION>
+        ${_DN_CUSTOM_BUILDPROPS}
+    </PropertyGroup>
+</Project>

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/thirdparty/FindCSharp.cmake

@@ -0,0 +1,72 @@
+#
+# A CMake Module for finding and using C# (.NET and Mono).
+#
+#The following variables are consumed:
+#   CSHARP_MONO - set to yes to force the use of Mono. Default is look for .NET first
+#
+# The following variables are set:
+#   CSHARP_FOUND - set to ON if C# is found
+#   CSHARP_USE_FILE - the path to the C# use file
+#   CSHARP_TYPE - the type of the C# compiler (eg. ".NET" or "Mono")
+#   CSHARP_VERSION - the version of the C# compiler (eg. "v4.0" or "2.10.2")
+#   CSHARP_COMPILER - the path to the C# compiler executable (eg. "C:/Windows/Microsoft.NET/Framework/v4.0.30319/csc.exe" or "/usr/bin/gmcs")
+#   CSHARP_INTERPRETER - the path to interpreter needed to run CSharp executables
+#   CSHARP_PLATFORM - the C# target platform
+#   CSHARP_SDK - the SDK commandline switch (empty for .NET, for Mono eg. "/sdk:2" or "/sdk:4")
+#
+# This file is based on the work of GDCM:
+#   http://gdcm.svn.sf.net/viewvc/gdcm/trunk/CMake/FindCSharp.cmake
+# Copyright (c) 2006-2010 Mathieu Malaterre <mathieu.malaterre@gmail.com>
+#
+
+# Make sure find package macros are included
+include( FindPackageHandleStandardArgs )
+
+unset( CSHARP_COMPILER CACHE )
+unset( CSHARP_INTERPRETER CACHE )
+unset( CSHARP_TYPE CACHE )
+unset( CSHARP_VERSION CACHE )
+unset( CSHARP_FOUND CACHE )
+
+# By default use anycpu platform, allow the user to override
+set( CSHARP_PLATFORM "anycpu" CACHE STRING "C# target platform: x86, x64, anycpu, or itanium" )
+if( NOT ${CSHARP_PLATFORM} MATCHES "x86|x64|anycpu|itanium" )
+  message( FATAL_ERROR "The C# target platform '${CSHARP_PLATFORM}' is not valid. Please enter one of the following: x86, x64, anycpu, or itanium" )
+endif( )
+
+if( CSHARP_MONO )
+  find_package( Mono )
+else()
+  find_package( Dotnet )
+  if( NOT DOTNET_FOUND )
+    find_package( Mono )
+  endif()
+endif()
+
+if( DOTNET_FOUND )
+  set( CSHARP_TYPE ".NET" CACHE STRING "Using the .NET compiler" )
+  set( CSHARP_VERSION ${DOTNET_VERSION} CACHE STRING "C# .NET compiler version" FORCE )
+  set( CSHARP_COMPILER ${DOTNET_EXE} CACHE STRING "Full path to .NET compiler" FORCE )
+  set( CSHARP_INTERPRETER "" CACHE INTERNAL "Interpreter not required for .NET" FORCE )
+elseif( CSHARP_MONO_FOUND )
+  set( CSHARP_TYPE "Mono" CACHE STRING "Using the Mono compiler" )
+  set( CSHARP_VERSION ${CSHARP_MONO_VERSION} CACHE STRING "C# Mono compiler version" FORCE )
+  set( CSHARP_COMPILER ${CSHARP_MONO_COMPILER_${CSHARP_MONO_VERSION}} CACHE STRING "Full path to Mono compiler" FORCE )
+  set( CSHARP_INTERPRETER ${CSHARP_MONO_INTERPRETER_${CSHARP_MONO_VERSION}} CACHE STRING "Full path to Mono interpreter" FORCE )
+endif( )
+
+# Handle WIN32 specific issues
+if ( WIN32 )
+  if ( CSHARP_COMPILER MATCHES "bat" )
+    set( CSHARP_COMPILER "call ${CSHARP_COMPILER}" )
+  endif ( )
+endif( )
+
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(CSharp DEFAULT_MSG CSHARP_TYPE CSHARP_VERSION CSHARP_COMPILER)
+
+mark_as_advanced( CSHARP_TYPE CSHARP_VERSION CSHARP_COMPILER CSHARP_INTERPRETER CSHARP_PLATFORM CSHARP_SDK )
+
+# Set the USE_FILE path
+# http://public.kitware.com/Bug/view.php?id=7757
+get_filename_component( current_list_path ${CMAKE_CURRENT_LIST_FILE} PATH )
+set( CSHARP_USE_FILE ${current_list_path}/UseCSharp.cmake )