@cpp.js/package-gdal 1.0.0-beta.20

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindPoppler.cmake

@@ -0,0 +1,182 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindPoppler
+--------
+
+Find the Poppler headers and libraries.
+
+This is a component-based find module, which makes use of the COMPONENTS
+and OPTIONAL_COMPONENTS arguments to find_package.  The following components
+are available::
+
+  Cpp  Qt5  Qt4  Glib
+
+Copyright (c) 2017,2019, Hiroshi Miura <miurahr@linux.com>
+Copyright (c) 2015, Alex Richardson <arichardson.kde@gmail.com>
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``Poppler::Poppler``, if
+curl has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``Poppler_FOUND``
+  True if Poppler found.
+
+``Poppler_INCLUDE_DIRS``
+  where to find poppler/poppler-config.h, etc.
+
+``Poppler_LIBRARIES``
+  List of libraries when using Poppler.
+
+``Poppler_VERSION_STRING``
+  The version of Poppler found.
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+  pkg_check_modules(PC_Poppler QUIET poppler)
+  if(PC_Poppler_VERSION)
+    set(Poppler_VERSION_STRING ${PC_Poppler_VERSION})
+  endif()
+endif()
+find_path(Poppler_INCLUDE_DIR NAMES "poppler-config.h" "cpp/poppler-version.h" "qt5/poppler-qt5.h" "qt4/poppler-qt4.h"
+          "glib/poppler.h"
+          HINTS ${PC_Poppler_INCLUDE_DIRS}
+          PATH_SUFFIXES poppler)
+
+find_library(Poppler_LIBRARY NAMES poppler HINTS ${PC_Poppler_LIBRARY_DIRS})
+
+set(Poppler_known_components Cpp Qt4 Qt5 Glib )
+foreach(_comp IN LISTS Poppler_known_components)
+  string(TOLOWER "${_comp}" _lc_comp)
+  set(Poppler_${_comp}_pkg_config "poppler-${_lc_comp}")
+  set(Poppler_${_comp}_lib "poppler-${_lc_comp}")
+  set(Poppler_${_comp}_header_subdir "poppler/${_lc_comp}")
+endforeach()
+set(Poppler_known_components Core ${Poppler_known_components})
+
+# poppler-config.h header is only installed with --enable-xpdf-headers
+# fall back to using any header from a submodule with a path to make it work in that case too
+set(Poppler_Cpp_header "poppler-version.h")
+set(Poppler_Qt5_header "poppler-qt5.h")
+set(Poppler_Qt4_header "poppler-qt4.h")
+set(Poppler_Glib_header "poppler.h")
+
+foreach(_comp IN LISTS Poppler_FIND_COMPONENTS)
+  set(Poppler_${_comp}_FOUND FALSE)
+endforeach()
+
+foreach(_comp IN LISTS Poppler_known_components)
+  list(FIND Poppler_FIND_COMPONENTS "${_comp}" _nextcomp)
+  if(_nextcomp GREATER -1)
+    find_path(Poppler_${_comp}_INCLUDE_DIR
+              NAMES ${Poppler_${_comp}_header}
+              PATH_SUFFIXES poppler
+              HINTS ${PC_Poppler_${_comp}_INCLUDE_DIRS})
+    find_library(Poppler_${_comp}_LIBRARY
+            NAMES ${Poppler_${_comp}_lib}
+            HINTS ${PC_Poppler_${_comp}_LIBRARY_DIRS})
+  endif()
+endforeach()
+
+if(NOT Poppler_VERSION_STRING)
+  find_file(Poppler_VERSION_HEADER
+            NAMES "poppler-config.h" "cpp/poppler-version.h"
+            HINTS ${Poppler_INCLUDE_DIR}
+            PATH_SUFFIXES poppler
+            )
+  #if(Poppler_VERSION_HEADER)
+  #  file(READ ${Poppler_VERSION_HEADER} _poppler_version_header_contents)
+  #  string(REGEX REPLACE
+  #         "^.*[ \t]+POPPLER_VERSION_MAJOR[ \t]+([0-9]+).*$"
+  #         "\\1"
+  #         Poppler_VERSION_MAJOR
+  #         "${_poppler_version_header_contents}"
+  #         )
+  #  string(REGEX REPLACE
+  #         "^.*[ \t]+POPPLER_VERSION_MINOR[ \t]+([0-9]+).*$"
+  #         "\\1"
+  #         Poppler_VERSION_MINOR
+  #         "${_poppler_version_header_contents}"
+  #         )
+  #  string(REGEX REPLACE
+  #         "^.*[ \t]+POPPLER_VERSION_MICRO[ \t]+([0-9]+).*$"
+  #         "\\1"
+  #         Poppler_VERSION_MICRO
+  #         "${_poppler_version_header_contents}"
+  #         )
+  #  unset(_poppler_version_header_contents)
+  #  set(Poppler_VERSION_STRING "${Poppler_VERSION_MAJOR}.${Poppler_VERSION_MINOR}.${Poppler_VERSION_MICRO}")
+  #endif()
+  if(Poppler_VERSION_HEADER)
+    file(STRINGS "${Poppler_VERSION_HEADER}" _poppler_version_str REGEX "^#define[\t ]+POPPLER_VERSION[\t ]+\".*\"")
+    string(REGEX REPLACE "^#define[\t ]+POPPLER_VERSION[\t ]+\"([^\"]*)\".*" "\\1" Poppler_VERSION_STRING "${_poppler_version_str}")
+    if(NOT ${Poppler_VERSION_STRING} MATCHES "[0-9]+\\.[0-9]+\\.[0-9]+")
+      message(WARNING "POPPLER_VERSION (${Poppler_VERSION_STRING}) doesn't match *.*.* form")
+    endif()
+    unset(_poppler_version_str)
+  endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Poppler
+                                  FOUND_VAR Poppler_FOUND
+                                  REQUIRED_VARS Poppler_LIBRARY Poppler_INCLUDE_DIR
+                                  VERSION_VAR  Poppler_VERSION_STRING
+                                  HANDLE_COMPONENTS)
+mark_as_advanced(Poppler_INCLUDE_DIR Poppler_LIBRARY)
+
+if(Poppler_FOUND)
+  if (NOT EXISTS "${Poppler_INCLUDE_DIR}/Object.h")
+    message(WARNING "Poppler private headers not found. Make sure you build Poppler with -DENABLE_UNSTABLE_API_ABI_HEADERS")
+    unset(Poppler_FOUND)
+    unset(POPPLER_FOUND)
+  endif()
+endif()
+
+if(Poppler_FOUND)
+  set(Poppler_INCLUDE_DIRS "${Poppler_INCLUDE_DIR}")
+  if(Poppler_INCLUDE_DIR MATCHES ".*/poppler" OR Poppler_INCLUDE_DIR MATCHES ".*\\poppler")
+      # poppler/splash/SplashBitmap.h unfortunately has a #include "poppler/GfxState.h"
+      # which obliges us to add the parent directory of Poppler_INCLUDE_DIR
+      get_filename_component(_poppler_upper_include_dir "${Poppler_INCLUDE_DIR}" DIRECTORY)
+      list(APPEND Poppler_INCLUDE_DIRS "${_poppler_upper_include_dir}")
+  endif()
+  set(Poppler_LIBRARIES "${Poppler_LIBRARY}")
+  if(NOT TARGET Poppler::Poppler)
+    add_library(Poppler::Poppler UNKNOWN IMPORTED)
+    set(POPPLER_EXTRA_TARGETS)
+    foreach(_lib IN LISTS POPPLER_EXTRA_LIBRARIES)
+        add_library(Poppler::Poppler_${INCR} UNKNOWN IMPORTED)
+        set_target_properties(Poppler::Poppler_${INCR} PROPERTIES
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${_lib}")
+        list(APPEND POPPLER_EXTRA_TARGETS Poppler::Poppler_${INCR})
+        math(EXPR INCR "${INCR}+1")
+    endforeach()
+    set_target_properties(Poppler::Poppler PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${Poppler_INCLUDE_DIRS}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                          INTERFACE_LINK_LIBRARIES "${POPPLER_EXTRA_TARGETS}"
+                          IMPORTED_LOCATION "${Poppler_LIBRARY}")
+    foreach(tgt IN LISTS Poppler_known_components)
+      add_library(Poppler::${tgt} UNKNOWN IMPORTED)
+      set_target_properties(Poppler::${tgt} PROPERTIES
+                            INTERFACE_INCLUDE_DIRECTORIES "${Poppler_${tgt}_INCLUDE_DIR}"
+                            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                            IMPORTED_LOCATION "${POPPLER_${tgt}_LIBRARY}")
+    endforeach()
+  endif()
+endif()
+
+include(FeatureSummary)
+set_package_properties(Poppler PROPERTIES
+                       DESCRIPTION "A PDF rendering library" URL "http://poppler.freedesktop.org")

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindQHULL.cmake

@@ -0,0 +1,43 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# Find QHULL library
+# ~~~~~~~~~
+#
+# Copyright (c) 2017,2018, Hiroshi Miura <miurahr@linux.com>
+#
+# Input variables:
+#    QHULL_PACKAGE_NAME: name (or list of names) of the pkg-config package, typically qhull_r or qhullstatic_r
+#
+# If it's found it sets QHULL_FOUND to TRUE
+# and following variables are set:
+#    QHULL_INCLUDE_DIR
+#    QHULL_LIBRARY
+#
+
+set(QHULL_PACKAGE_NAME "qhull_r;qhullstatic_r" CACHE STRING "Names of the pkg-config package, typically qhull_r or qhullstatic_r")
+mark_as_advanced(QHULL_PACKAGE_NAME)
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_search_module(PC_QHULL QUIET ${QHULL_PACKAGE_NAME})
+endif()
+
+find_path(QHULL_INCLUDE_DIR libqhull_r/libqhull_r.h
+          HINTS ${PC_QHULL_INCLUDE_DIRS})
+
+if(PC_QHULL_FOUND)
+  set(_library_name "${PC_QHULL_LIBRARIES}")
+else()
+  set(_library_name qhull_r qhullstatic_r)
+endif()
+find_library(QHULL_LIBRARY NAMES ${_library_name}
+             HINTS ${PC_QHULL_LIBRARY_DIRS})
+unset(_library_name)
+
+mark_as_advanced(QHULL_INCLUDE_DIR QHULL_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(QHULL
+    REQUIRED_VARS QHULL_LIBRARY QHULL_INCLUDE_DIR)

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindRASTERLITE2.cmake

@@ -0,0 +1,85 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindRASTERLITE2
+--------------
+
+CMake module to search for RasterLite2 library
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``RASTERLITE2::RASTERLITE2``, if
+RasterLite2 has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``RASTERLITE2_FOUND``
+  True if RasterLite2 found.
+
+``RASTERLITE2_INCLUDE_DIRS``
+  where to find rasterlite2, etc.
+
+``RASTERLITE2_LIBRARIES``
+  List of libraries when using RasterLite2.
+
+``RASTERLITE2_VERSION_STRING``
+  The version of RasterLite2 found.
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_RASTERLITE2 QUIET rasterlite2)
+    set(RASTERLITE2_VERSION_STRING ${PC_RASTERLITE2_VERSION})
+endif()
+
+find_path(RASTERLITE2_INCLUDE_DIR
+          NAMES rasterlite2/rasterlite2.h
+          HINTS ${RASTERLITE2_ROOT} ${PC_RASTERLITE2_INCLUDE_DIRS}
+          PATH_SUFFIXES include)
+find_library(RASTERLITE2_LIBRARY
+             NAMES rasterlite2
+             HINTS ${RASTERLITE2_ROOT} ${PC_RASTERLITE2_LIBRARY_DIRS}
+             PATH_SUFFIXES lib)
+mark_as_advanced(RASTERLITE2_LIBRARY RASTERLITE2_INCLUDE_DIR)
+
+if(NOT RASTERLITE2_VERSION_STRING AND RASTERLITE2_INCLUDE_DIR AND RASTERLITE2_LIBRARY)
+  include(CMakePushCheckState)
+  cmake_push_check_state(RESET)
+  file(WRITE "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/get_rasterlite2_version.c"
+          "#include <stdio.h>\n#include \"rasterlite2/rasterlite2.h\"\n
+          int main(int argc, void *argv) { const char *version = rl2_version(); printf(\"%s\", version); }\n")
+  set(CMAKE_REQUIRED_INCLUDES "${RASTERLITE2_INCLUDE_DIR}")
+  try_run(RL2_EXITCODE RL2_COMPILED ${PROJECT_BINARY_DIR} ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/get_rasterlite2_version.c
+      LINK_LIBRARIES  ${RASTERLITE2_LIBRARY}
+      CMAKE_FLAGS "-DCMAKE_SKIP_RPATH:BOOL=${CMAKE_SKIP_RPATH}" "-DINCLUDE_DIRECTORIES:STRING=${RASTERLITE2_INCLUDE_DIR}"
+      RUN_OUTPUT_VARIABLE RL2_OUTPUT)
+  if(RL2_COMPILED AND RL2_EXITCODE EQUAL 0)
+    set(RASTERLITE2_VERSION_STRING "${RL2_OUTPUT}")
+  endif()
+  unset(RL2_EXITCODE)
+  unset(RL2_COMPILED)
+  unset(RL2_OUTPUT)
+  cmake_pop_check_state()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(RASTERLITE2
+                                  FOUND_VAR RASTERLITE2_FOUND
+                                  REQUIRED_VARS RASTERLITE2_LIBRARY RASTERLITE2_INCLUDE_DIR
+                                  VERSION_VAR RASTERLITE2_VERSION_STRING)
+if(RASTERLITE2_FOUND)
+    set(RASTERLITE2_LIBRARIES "${RASTERLITE2_LIBRARY}")
+    set(RASTERLITE2_INCLUDE_DIRS "${RASTERLITE2_INCLUDE_DIR}")
+    if(NOT TARGET RASTERLITE2::RASTERLITE2)
+        add_library(RASTERLITE2::RASTERLITE2 UNKNOWN IMPORTED)
+        set_target_properties(RASTERLITE2::RASTERLITE2 PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${RASTERLITE2_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${RASTERLITE2_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindSFCGAL.cmake

@@ -0,0 +1,87 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# FindSFCGAL
+# ~~~~~~~~~
+# Copyright (C) 2017-2018, Hiroshi Miura
+#
+
+find_program(SFCGAL_CONFIG sfcgal-config DOC "SFCGAL config command")
+mark_as_advanced(SFCGAL_CONFIG)
+
+if(SFCGAL_CONFIG)
+    execute_process(COMMAND ${SFCGAL_CONFIG} --prefix
+                    OUTPUT_VARIABLE SC_SFCGAL_PREFIX
+                    ERROR_QUIET
+                    OUTPUT_STRIP_TRAILING_WHITESPACE)
+    execute_process(COMMAND ${SFCGAL_CONFIG} --version
+                    OUTPUT_VARIABLE SC_SFCGAL_VERSION_STRING
+                    ERROR_QUIET
+                    OUTPUT_STRIP_TRAILING_WHITESPACE)
+    execute_process(COMMAND ${SFCGAL_CONFIG} --ldflags
+                    OUTPUT_VARIABLE SC_SFCGAL_LDFLAGS
+                    ERROR_QUIET
+                    OUTPUT_STRIP_TRAILING_WHITESPACE)
+    string(REGEX REPLACE "^-L(.*)$" "\\1" SC_SFCGAL_LIBDIR "${SC_SFCGAL_LDFLAGS}")
+    if(SC_SFCGAL_VERSION_STRING)
+        set(SFCGAL_VERSION_STRING ${SC_SFCGAL_VERSION_STRING})
+    endif()
+endif()
+
+find_path(SFCGAL_INCLUDE_DIR SFCGAL/Kernel.h
+          HINTS ${SC_SFCGAL_PREFIX}
+          PATHS ${SFCGAL_ROOT}
+          PATH_SUFFIXES include Include
+          )
+
+if(SFCGAL_INCLUDE_DIR)
+    if(NOT SFCGAL_VERSION_STRING)
+        if(EXISTS "${SFCGAL_INCLUDE_DIR}/SFCGAL/version.h")
+            file(STRINGS "${SFCGAL_INCLUDE_DIR}/SFCGAL/version.h" sfcgal_version_str REGEX "^#define[\t ]+SFCGAL_VERSION[\t ]+\".*\"")
+            string(REGEX REPLACE "^#define[\t ]+SFCGAL_VERSION[\t ]+\"([^\"]*)\".*" "\\1" SFCGAL_VERSION_STRING "${sfcgal_version_str}")
+            if(${SFCGAL_VERSION_STRING} MATCHES "[0-9]+\\.[0-9]+\\.[0-9]+")
+                string(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+" "\\1" SFCGAL_VERSION_MAJOR "${SFCGAL_VERSION_STRING}")
+                string(REGEX REPLACE "^[0-9]+\\.([0-9])+\\.[0-9]+" "\\1" SFCGAL_VERSION_MINOR "${SFCGAL_VERSION_STRING}")
+                string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+)" "\\1" SFCGAL_VERSION_PATCH "${SFCGAL_VERSION_STRING}")
+            else()
+                message(WARNING "SFCGAL_VERSION (${SFCGAL_VERSION_STRING}) doesn't match *.*.* form")
+            endif()
+            unset(sfcgal_version_str)
+        else()
+            message(WARNING "Failed toget SFCGAL version, header file not found.")
+        endif()
+    endif()
+endif()
+
+find_library(SFCGAL_LIBRARY_RELEASE NAMES SFCGAL
+             HINTS ${SC_SFCGAL_LIBDIR}
+             PATH ${SFCGAL_ROOT}
+             PATH_SUFFIXES lib Lib
+             )
+find_library(SFCGAL_LIBRARY_DEBUG NAMES SFCGALd
+             HINTS ${SC_SFCGAL_LIBDIR}
+             PATH ${SFCGAL_ROOT}
+             PATH_SUFFIXES lib Lib
+             )
+include(SelectLibraryConfigurations)
+select_library_configurations(SFCGAL)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SFCGAL
+                                  FOUND_VAR SFCGAL_FOUND
+                                  REQUIRED_VARS SFCGAL_LIBRARY SFCGAL_INCLUDE_DIR
+                                  VERSION_VAR SFCGAL_VERSION_STRING
+                                  )
+mark_as_advanced(SFCGAL_INCLUDE_DIR SFCGAL_LIBRARY)
+
+if(SFCGAL_FOUND)
+    set(SFCGAL_LIBRARIES ${SFCGAL_LIBRARY})
+    set(SFCGAL_INCLUDE_DIRS "${SFCGAL_INCLUDE_DIR}")
+    if(NOT TARGET SFCGAL::SFCGAL)
+        add_library(SFCGAL::SFCGAL UNKNOWN IMPORTED)
+        set_target_properties(SFCGAL::SFCGAL PROPERTIES
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${SFCGAL_LIBRARY}"
+                              INTERFACE_INCLUDE_DIRECTORIES "${SFCGAL_INCLUDE_DIR}")
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindSPATIALITE.cmake

@@ -0,0 +1,73 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindSPATIALITE
+--------------
+
+CMake module to search for SpatiaLite library
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``SPATIALITE::SPATIALITE``, if
+Spatialite has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``SPATIALITE_FOUND``
+  True if Spatialite found.
+
+``SPATIALITE_INCLUDE_DIRS``
+  where to find Spatialite.h, etc.
+
+``SPATIALITE_LIBRARIES``
+  List of libraries when using Spatialite.
+
+``SPATIALITE_VERSION_STRING``
+  The version of Spatialite found.
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_SPATIALITE QUIET spatialite)
+    set(SPATIALITE_VERSION_STRING ${PC_SPATIALITE_VERSION})
+endif()
+
+find_path(SPATIALITE_INCLUDE_DIR
+          NAMES spatialite.h
+          HINTS ${SPATIALITE_ROOT} ${PC_SPATIALITE_INCLUDE_DIRS}
+          PATH_SUFFIXES include)
+find_library(SPATIALITE_LIBRARY
+             NAMES spatialite_i spatialite
+             HINTS ${SPATIALITE_ROOT} ${PC_SPATIALITE_LIBRARY_DIRS}
+             PATH_SUFFIXES lib)
+mark_as_advanced(SPATIALITE_LIBRARY SPATIALITE_INCLUDE_DIR)
+
+if(SPATIALITE_LIBRARY AND SPATIALITE_INCLUDE_DIR
+   AND NOT SPATIALITE_VERSION_STRING)
+    file(STRINGS "${SPATIALITE_INCLUDE_DIR}/spatialite.h" _spatialite_h_ver
+         REGEX "^[ \t]version[ \t]([0-9]+\\.[0-9]+)[,.].*")
+    string(REGEX REPLACE "[ \t]version[ \t]([0-9]+\\.[0-9]+)[,.].*" "\\1" _spatialite_h_ver "${_spatialite_h_ver}")
+    set(SPATIALITE_VERSION_STRING "${_spatialite_h_ver}")
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SPATIALITE
+                                  FOUND_VAR SPATIALITE_FOUND
+                                  REQUIRED_VARS SPATIALITE_LIBRARY SPATIALITE_INCLUDE_DIR
+                                  VERSION_VAR SPATIALITE_VERSION_STRING)
+if(SPATIALITE_FOUND)
+    set(SPATIALITE_LIBRARIES "${SPATIALITE_LIBRARY}")
+    set(SPATIALITE_INCLUDE_DIRS "${SPATIALITE_INCLUDE_DIR}")
+    if(NOT TARGET SPATIALITE::SPATIALITE)
+        add_library(SPATIALITE::SPATIALITE UNKNOWN IMPORTED)
+        set_target_properties(SPATIALITE::SPATIALITE PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${SPATIALITE_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${SPATIALITE_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindSQLite3.cmake

@@ -0,0 +1,190 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindSQLite3
+-----------
+Find the SQLite libraries, v3
+IMPORTED targets
+^^^^^^^^^^^^^^^^
+This module defines the following :prop_tgt:`IMPORTED` target:
+``SQLite::SQLite3``
+Result variables
+^^^^^^^^^^^^^^^^
+This module will set the following variables if found:
+``SQLite3_INCLUDE_DIRS``
+  where to find sqlite3.h, etc.
+``SQLite3_LIBRARIES``
+  the libraries to link against to use SQLite3.
+``SQLite3_VERSION``
+  version of the SQLite3 library found
+``SQLite3_FOUND``
+  TRUE if found
+
+  Copyright (c) 2008 Andreas Schneider <mail@cynapses.org>
+  Copyright (c) 2016 NextGIS <info@nextgis.com>
+  Copyright (c) 2018,2021 Hiroshi Miura
+  Copyright (c) 2019 Chuck Atkins
+#]=======================================================================]
+include (CMakePushCheckState)
+# Accept upper case variant for SQLite3_INCLUDE_DIR
+if(SQLITE3_INCLUDE_DIR)
+  if(SQLite3_INCLUDE_DIR AND NOT "${SQLite3_INCLUDE_DIR}" STREQUAL "${SQLITE3_INCLUDE_DIR}")
+    message(FATAL_ERROR "Both SQLite3_INCLUDE_DIR and SQLITE3_INCLUDE_DIR are defined, but not at same value")
+  endif()
+  set(SQLite3_INCLUDE_DIR "${SQLITE3_INCLUDE_DIR}" CACHE STRING "Path to a file" FORCE)
+  unset(SQLITE3_INCLUDE_DIR CACHE)
+endif()
+
+# Accept upper case variant for SQLite3_LIBRARY
+if(SQLITE3_LIBRARY)
+  if(SQLite3_LIBRARY AND NOT "${SQLite3_LIBRARY}" STREQUAL "${SQLITE3_LIBRARY}")
+    message(FATAL_ERROR "Both SQLite3_LIBRARY and SQLITE3_LIBRARY are defined, but not at same value")
+  endif()
+  set(SQLite3_LIBRARY "${SQLITE3_LIBRARY}" CACHE FILEPATH "Path to a library" FORCE)
+  unset(SQLITE3_LIBRARY CACHE)
+endif()
+
+if(SQLite3_INCLUDE_DIR AND SQLite3_LIBRARY)
+  set(SQLite3_FIND_QUIETLY TRUE)
+else()
+  find_package(PkgConfig QUIET)
+  if(PKG_CONFIG_FOUND)
+      pkg_check_modules(PC_SQLITE3 QUIET sqlite3)
+  endif()
+
+  find_path(SQLite3_INCLUDE_DIR
+            NAMES  sqlite3.h
+            HINTS ${PC_SQLITE3_INCLUDE_DIRS})
+  find_library(SQLite3_LIBRARY
+               NAMES sqlite3 sqlite3_i
+               HINTS ${PC_SQLITE3_LIBRARY_DIRS})
+endif()
+
+# Extract version information from the header file
+if(SQLite3_INCLUDE_DIR)
+    file(STRINGS ${SQLite3_INCLUDE_DIR}/sqlite3.h _ver_line
+         REGEX "^#define SQLITE_VERSION  *\"[0-9]+\\.[0-9]+\\.[0-9]+\""
+         LIMIT_COUNT 1)
+    string(REGEX MATCH "[0-9]+\\.[0-9]+\\.[0-9]+"
+           SQLite3_VERSION "${_ver_line}")
+    unset(_ver_line)
+endif()
+
+if(SQLite3_INCLUDE_DIR AND SQLite3_LIBRARY)
+    include(CheckSymbolExists)
+    cmake_push_check_state(RESET)
+    # check column metadata
+    set(CMAKE_REQUIRED_INCLUDES ${SQLite3_INCLUDE_DIR})
+    if( ${SQLite3_LIBRARY} MATCHES "libsqlite3.a")
+      if(PC_SQLITE3_STATIC_LDFLAGS)
+        set(CMAKE_REQUIRED_LIBRARIES ${PC_SQLITE3_STATIC_LDFLAGS})
+      else()
+        # Manually try likely additional private libraries
+        set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY})
+        check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        if(NOT SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN CACHE)
+            set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY} -lz)
+            check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        endif()
+        if(NOT SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN CACHE)
+            set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY} -lm)
+            check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        endif()
+        if(NOT SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN CACHE)
+            set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY} -lz -lm)
+            check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        endif()
+        if(NOT SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN CACHE)
+            set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY} -lz -lm -lpthread -ldl)
+            check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        endif()
+      endif()
+    else()
+        set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY})
+    endif()
+
+    # Trick to force CMake to re-run if SQLite3_LIBRARY changes
+    # Useful in development situations when switching/refreshing the library
+    set_property(
+        DIRECTORY
+        APPEND
+        PROPERTY CMAKE_CONFIGURE_DEPENDS "${SQLite3_LIBRARY}"
+    )
+    # Invalidate cached variables if SQLite3_LIBRARY changes
+    file(TIMESTAMP "${SQLite3_LIBRARY}" SQLite3_LIBRARY_TIMESTAMP)
+    if( SQLite3_LIBRARY_TIMESTAMP_OLD_VAL AND
+        NOT "${SQLite3_LIBRARY_TIMESTAMP_OLD_VAL}" STREQUAL "${SQLite3_LIBRARY_TIMESTAMP}")
+        get_cmake_property(_cache_variables CACHE_VARIABLES)
+        foreach(opt IN LISTS _cache_variables)
+            if ("${opt}" MATCHES "SQLite3_HAS_")
+                message(STATUS "Invalidating ${opt}")
+                unset(${opt} CACHE)
+            endif()
+        endforeach()
+    endif()
+    set(SQLite3_LIBRARY_TIMESTAMP_OLD_VAL "${SQLite3_LIBRARY_TIMESTAMP}" CACHE INTERNAL "Old value of option SQLite3_LIBRARY_TIMESTAMP")
+
+    check_symbol_exists(sqlite3_mutex_alloc sqlite3.h SQLite3_HAS_MUTEX_ALLOC)
+    check_symbol_exists(sqlite3_column_table_name sqlite3.h SQLite3_HAS_COLUMN_METADATA)
+    check_symbol_exists(sqlite3_rtree_query_callback sqlite3.h SQLite3_HAS_RTREE)
+    check_symbol_exists(sqlite3_load_extension sqlite3.h SQLite3_HAS_LOAD_EXTENSION)
+    # https://www.sqlite.org/compile.html recommends to build with -DSQLITE_OMIT_PROGRESS_CALLBACK
+    # "for applications that are able to use them"... This is sometimes wrongly
+    # understood as recommended in all situations.
+    check_symbol_exists(sqlite3_progress_handler sqlite3.h SQLite3_HAS_PROGRESS_HANDLER)
+
+    if (MSVC)
+        set(CMAKE_REQUIRED_FLAGS "/WX")
+      else ()
+        set(CMAKE_REQUIRED_FLAGS "-Werror")
+      endif ()
+    set(SQLITE3_AUTO_EXTENSION_CHECK
+        "#include <sqlite3.h>
+         int main(){
+          return sqlite3_auto_extension ((void (*)(void)) 0);
+         }")
+    if(CMAKE_C_COMPILER_LOADED)
+        check_c_source_compiles("${SQLITE3_AUTO_EXTENSION_CHECK}" SQLite3_HAS_NON_DEPRECATED_AUTO_EXTENSION)
+    elseif(CMAKE_CXX_COMPILER_LOADED)
+        check_cxx_source_compiles("${SQLITE3_AUTO_EXTENSION_CHECK}" SQLite3_HAS_NON_DEPRECATED_AUTO_EXTENSION)
+    else()
+        message(AUTHOR_WARNING "C and CXX languages not enabled: Skipping detection of sqlite3_auto_extension.")
+    endif()
+    cmake_pop_check_state()
+endif()
+mark_as_advanced(SQLite3_LIBRARY SQLite3_INCLUDE_DIR SQLite3_HAS_COLUMN_METADATA SQLite3_HAS_RTREE SQLite3_HAS_LOAD_EXTENSION)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SQLite3
+                                  FOUND_VAR SQLite3_FOUND
+                                  REQUIRED_VARS SQLite3_LIBRARY SQLite3_INCLUDE_DIR
+                                  VERSION_VAR SQLite3_VERSION)
+
+if(SQLite3_FOUND)
+  set(SQLite3_LIBRARIES ${SQLite3_LIBRARY})
+  set(SQLite3_INCLUDE_DIRS ${SQLite3_INCLUDE_DIR})
+  if(NOT TARGET SQLite::SQLite3)
+    add_library(SQLite::SQLite3 UNKNOWN IMPORTED)
+    set_target_properties(SQLite::SQLite3 PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${SQLite3_INCLUDE_DIRS}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                          IMPORTED_LOCATION "${SQLite3_LIBRARY}")
+    if(SQLite3_HAS_COLUMN_METADATA)
+        set_property(TARGET SQLite::SQLite3 APPEND PROPERTY
+                     INTERFACE_COMPILE_DEFINITIONS "SQLite3_HAS_COLUMN_METADATA")
+    endif()
+    if(SQLite3_HAS_RTREE)
+        set_property(TARGET SQLite::SQLite3 APPEND PROPERTY
+                     INTERFACE_COMPILE_DEFINITIONS "SQLite3_HAS_RTREE")
+    endif()
+  endif()
+endif()