@cpp.js/package-gdal 1.0.0-beta.20

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindOpenJPEG.cmake

@@ -0,0 +1,124 @@
+###
+# File:  FindOpenJPEG.cmake
+#
+
+function(transform_version _numerical_result _version_major _version_minor _version_patch)
+  set(factor 100)
+  if(_version_minor GREATER 99)
+      set(factor 1000)
+  endif()
+  if(_verion_patch GREATER 99)
+      set(factor 1000)
+  endif()
+  math(EXPR _internal_numerical_result
+          "${_version_major}*${factor}*${factor} + ${_version_minor}*${factor} + ${_version_patch}"
+          )
+  set(${_numerical_result} ${_internal_numerical_result} PARENT_SCOPE)
+endfunction()
+
+
+# - Find OpenJPEG
+# Find the OpenJPEG includes and library
+#
+# IMPORTED Target
+#      OPENJPEG::OpenJPEG
+#
+# This module defines
+#  OPENJPEG_INCLUDE_DIR, where to find openjpeg.h, etc.
+#  OPENJPEG_LIBRARIES, the libraries needed to use OpenJPEG.
+#  OPENJPEG_FOUND, If false, do not try to use OpenJPEG.
+# also defined, but not for general use are
+#  OPENJPEG_LIBRARY, where to find the OpenJPEG library.
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_OPENJPEG QUIET libopenjp2)
+    set(OpenJPEG_VERSION_STRING ${PC_OPENJPEG_VERSION})
+endif()
+
+
+find_path(OPENJPEG_INCLUDE_DIR opj_config.h
+          PATH_SUFFIXES
+              openjpeg-2.5
+              openjpeg-2.4
+              openjpeg-2.3
+              openjpeg-2.2
+              openjpeg-2.1
+              openjpeg-2.0
+          HINTS ${PC_OPENJPEG_INCLUDE_DIRS}
+          DOC "Location of OpenJPEG Headers"
+)
+
+find_library(OPENJPEG_LIBRARY
+             NAMES openjp2
+             HINTS ${PC_OPENJPEG_LIBRARY_DIRS}
+             )
+mark_as_advanced(OPENJPEG_LIBRARY OPENJPEG_INCLUDE_DIR)
+
+if(OPENJPEG_INCLUDE_DIR)
+    if(OpenJPEG_VERSION_STRING)
+        string(REGEX MATCH "([0-9]+).([0-9]+).([0-9]+)" OPJ_VERSION ${OpenJPEG_VERSION_STRING})
+        if(OPJ_VERSION)
+            transform_version(OPENJPEG_VERSION_NUM ${CMAKE_MATCH_1} ${CMAKE_MATCH_2} ${CMAKE_MATCH_3})
+        else()
+            message(FATAL "OpenJPEG version not found")
+        endif()
+    else()
+        if(OPENJPEG_INCLUDE_DIR MATCHES "openjpeg-2.0")
+            if(EXISTS "${OPENJPEG_INCLUDE_DIR}/opj_config.h")
+                file(READ "${OPENJPEG_INCLUDE_DIR}/opj_config.h" VERSION_H_CONTENTS)
+                string(REGEX MATCH "OPJ_PACKAGE_VERSION[ \t]+\"([0-9]+).([0-9]+).([0-9]+)\""
+                       OPJ_VERSION ${VERSION_H_CONTENTS})
+                string(REGEX MATCH "([0-9]+).([0-9]+).([0-9]+)"
+                       OPJ_VERSION ${OPJ_VERSION})
+                if(OPJ_VERSION)
+                    transform_version(OPENJPEG_VERSION_NUM ${CMAKE_MATCH_1} ${CMAKE_MATCH_2} ${CMAKE_MATCH_3})
+                else()
+                    message(FATAL "OpenJPEG 2.0 header version not found")
+                endif()
+            endif()
+        else()
+            set(MAJOR_VERSION 0)
+            set(MINOR_VERSION 0)
+            set(REV_VERSION 0)
+            if(EXISTS "${OPENJPEG_INCLUDE_DIR}/opj_config.h")
+                file(READ "${OPENJPEG_INCLUDE_DIR}/opj_config.h" VERSION_H_CONTENTS)
+                string(REGEX MATCH "OPJ_VERSION_MAJOR[ \t]+([0-9]+)"
+                  MAJOR_VERSION ${VERSION_H_CONTENTS})
+                string (REGEX MATCH "([0-9]+)" MAJOR_VERSION ${MAJOR_VERSION})
+                string(REGEX MATCH "OPJ_VERSION_MINOR[ \t]+([0-9]+)"
+                  MINOR_VERSION ${VERSION_H_CONTENTS})
+                string (REGEX MATCH "([0-9]+)"
+                  MINOR_VERSION ${MINOR_VERSION})
+                string(REGEX MATCH "OPJ_VERSION_BUILD[ \t]+([0-9]+)"
+                  REV_VERSION ${VERSION_H_CONTENTS})
+                string (REGEX MATCH "([0-9]+)"
+                  REV_VERSION ${REV_VERSION})
+                unset(VERSION_H_CONTENTS)
+            endif()
+            set(OpenJPEG_VERSION_STRING "${MAJOR_VERSION}.${MINOR_VERSION}.${REV_VERSION}")
+            TRANSFORM_VERSION(OPENJPEG_VERSION_NUM ${MAJOR_VERSION} ${MINOR_VERSION} ${REV_VERSION})
+            unset(MAJOR_VERSION)
+            unset(MINOR_VERSION)
+            unset(REV_VERSION)
+        endif()
+   endif()
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(OpenJPEG
+                                  FOUND_VAR OPENJPEG_FOUND
+                                  REQUIRED_VARS OPENJPEG_LIBRARY OPENJPEG_INCLUDE_DIR
+                                  VERSION_VAR OpenJPEG_VERSION_STRING)
+if(OPENJPEG_FOUND)
+  set(OPENJPEG_LIBRARIES "${OPENJPEG_LIBRARY}")
+  set(OPENJPEG_INCLUDE_DIRS "${OPENJPEG_INCLUDE_DIR}")
+
+  if(NOT TARGET OPENJPEG::OpenJPEG)
+    add_library(OPENJPEG::OpenJPEG UNKNOWN IMPORTED)
+    set_target_properties(OPENJPEG::OpenJPEG PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${OPENJPEG_INCLUDE_DIR}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                          IMPORTED_LOCATION "${OPENJPEG_LIBRARY}")
+  endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindOracle.cmake

@@ -0,0 +1,226 @@
+#.rst:
+# FindOracle
+# ----------
+#
+# Configure Oracle libraries
+#
+# ORACLE_FOUND - system has Oracle OCI
+# ORACLE_INCLUDE_DIRS - where to find oci.h
+# ORACLE_LIBRARIES - the libraries to link against to use Oracle OCI
+#
+# Components: CLNTSH, CLNTST, OCCI, XML, OCIEI
+# CLNTSH is enabled by default
+# for example: FIND_PACKAGE(Oracle REQUIRED CLNTSH OCCI)
+#
+# This module will set the following variables in your project:
+#
+# ``ORACLE_FOUND``
+#   Oracle installation detected (InstantClient or "thick" client)
+# ``ORACLE_INCLUDE_DIRS``
+#   Oracle include directory (where oci.h resides)
+# ``ORACLE_CLNTSH_LIBRARY``
+#   Library libclntsh.so.*
+# ``ORACLE_CLNTST_LIBRARY``
+#   Library libclntst??.a (not present in InstantClient, must be generated by executing genclntst)
+# ``ORACLE_OCCI_LIBRARY``
+#   OCCI C++ client library
+# ``ORACLE_XML_LIBRARY``
+#   Oracle XMLTYPE library libxml?.a (usually static, only present in thick client)
+# ``ORACLE_LIBRARIES``
+#   All Oracle libraries detected libclntsh.so.*, libociei.so.8 libxml.a ....
+# ``ORACLE_OCI_VERSION``
+#   This is set to 8i, 9i, 10g, 11g, 12c
+
+# TOra Project: Configure Oracle libraries
+#
+# Copyright (c) 2007 Petr Vanek <petr@yarpen.cz>
+# Copyright (c) 2016 Ivan Brezina <ibre5041@ibrezina.net>
+# Redistribution and use is allowed according to the terms of the BSD license.
+#
+
+# Port to GDAL
+# Copyright (c) 2018 Hiroshi Miura
+#
+
+if(DEFINED Oracle_ROOT)
+    set(ORACLE_HOME "${Oracle_ROOT}")
+elseif(DEFINED ORACLE_ROOT)
+    set(ORACLE_HOME "${ORACLE_ROOT}")
+else()
+    file(TO_CMAKE_PATH "$ENV{ORACLE_HOME}" ORACLE_HOME)
+endif()
+get_filename_component(XE_HOME "[HKEY_LOCAL_MACHINE\\SOFTWARE\\ORACLE\\KEY_XE;ORACLE_HOME]" ABSOLUTE CACHE)
+mark_as_advanced(XE_HOME)
+
+set(ORACLE_INCLUDES_LOCATION
+        ${ORACLE_HOME}/rdbms/public
+        ${ORACLE_HOME}/include
+        # xdk
+        ${ORACLE_HOME}/xdk/include
+        # sdk
+        ${ORACLE_HOME}/sdk/include/
+        # xe on windows
+        ${ORACLE_HOME}/OCI/include/
+        # instant client from rpm
+        /usr/include/oracle/11.2/client${LIB_SUFFIX}/
+        /usr/include/oracle/12.1/client${LIB_SUFFIX}/
+        # instantclient on OS X from macports
+        /opt/local/lib/oracle/sdk/include/
+        # Oracle XE Windows
+        ${XE_HOME}/oci/include/
+   )
+
+find_path(Oracle_INCLUDE_DIR oci.h
+          PATHS ${ORACLE_INCLUDES_LOCATION}
+          HINTS ${ORACLE_PATH_LIB}
+          NO_DEFAULT_PATH NO_CMAKE_ENVIRONMENT_PATH NO_CMAKE_PATH NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH
+)
+
+# guess OCI version
+#   we need it before lib checking because of OS X bugs in instant client (see below)
+if (NOT DEFINED ORACLE_OCI_VERSION AND ORACLE_INCLUDES)
+  try_run(OCIVER_TYPE OCIVER_COMPILED
+          ${PROJECT_BINARY_DIR}
+          ${PROJECT_SOURCE_DIR}/cmake/modules/OCIVersion.c
+          CMAKE_FLAGS "-DINCLUDE_DIRECTORIES:STRING=${ORACLE_INCLUDES}"
+          OUTPUT_VARIABLE OCIVER)
+
+  if(${OCIVER_TYPE} GREATER "120")
+    set(ORACLE_OCI_VERSION "12C")
+  elseif(${OCIVER_TYPE} GREATER "110")
+    set(ORACLE_OCI_VERSION "11G")
+  elseif(${OCIVER_TYPE} EQUAL "102")
+    set(ORACLE_OCI_VERSION "10G_R2")
+  elseif(${OCIVER_TYPE} EQUAL "101")
+    set(ORACLE_OCI_VERSION "10G")
+  elseif(${OCIVER_TYPE} EQUAL "91")
+    set(ORACLE_OCI_VERSION "9")
+  elseif(${OCIVER_TYPE} EQUAL "92")
+    set(ORACLE_OCI_VERSION "9")
+  elseif(NOT ${OCIVER_TYPE} GREATER "90")
+    set(ORACLE_OCI_VERSION "8I")
+  else(${OCIVER_TYPE} GREATER "110")
+    set(ORACLE_OCI_VERSION "10G_R2")
+  endif ()
+
+  message(STATUS "Guessed ORACLE_OCI_VERSION value: ${ORACLE_OCI_VERSION} for ${OCIVER_TYPE}")
+
+  if(APPLE)
+    if(${OCIVER_TYPE} LESS 110)
+        list(FIND Oracle_FIND_COMPONENTS "OCIEI" _nextcomp)
+        if(_nextcomp EQUAL -1)
+            list(APPEND Oracle_FIND_COMPONENTS OCIEI)
+            message(STATUS "    APPLE requires libociei for instantclient < 11, enforcing ociei")
+        endif()
+    endif()
+  endif()
+endif()
+
+set(ORACLE_LIB_LOCATION
+        # TODO add 32/64bit version here (lib32/lib64 on some platforms)
+        ${ORACLE_HOME}/lib
+        # xe on windows
+        ${ORACLE_HOME}/OCI/lib/MSVC/
+        ${ORACLE_HOME}
+        # InstantClient on WinXP
+        ${ORACLE_HOME}/sdk/lib/msvc/
+        # Instant client from rpm
+        /usr/lib${LIB_SUFFIX}/
+        /usr/lib/oracle/11.2/client${LIB_SUFFIX}/lib/
+        /usr/lib/oracle/12.1/client${LIB_SUFFIX}/lib/
+        # instant client on OS X from macports
+        /opt/local/lib/oracle/
+        # Oracle XE Windows
+        ${XE_HOME}/oci/lib/MSVC/
+    )
+
+# The NO_DEFAULT_PATH is necessary here in the case there is Oracle DB
+# *and* instant client installed. The order is given in ORACLE_LIB_LOCATION.
+# See above.
+find_library(Oracle_LIBRARY
+             NAMES oci
+             PATHS ${ORACLE_LIB_LOCATION}
+             HINTS ${ORACLE_PATH_LIBS}
+             NO_DEFAULT_PATH
+             )
+
+# Oracle InstantClient 12.1 has no liboci. It seems we just need libclntsh
+# for the GDAL drivers.
+if( Oracle_CAN_USE_CLNTSH_AS_MAIN_LIBRARY AND "${Oracle_FIND_COMPONENTS}" STREQUAL "")
+    set(Oracle_FIND_COMPONENTS CLNTSH)
+endif()
+
+foreach(_comp IN LISTS Oracle_FIND_COMPONENTS)
+  set(Oracle_${_comp}_FOUND FALSE)
+endforeach()
+
+set(Oracle_known_components CLNTSH CLNTST OCCI XML OCIEI)
+
+set(Oracle_CLNTSH_lib libclntsh clntsh)
+set(Oracle_CLNTST_lib libclntst libclntst9 libclntst10 libclntst11 libclntst12 clntst clntst9 clntst10 clntst11 clntst12)
+set(Oracle_OCCI_lib libocci occi)
+set(Oracle_XML_lib
+    libxml xml libxml10 xml10 libxml11 xml11 oraxml10 oraxml11)
+set(Oracle_XML_header xml.h)
+set(Oracle_OCIEI_lib libociei ociei)
+
+foreach(_comp IN LISTS Oracle_known_components)
+    list(FIND Oracle_FIND_COMPONENTS "${_comp}" _nextcomp)
+    if(_nextcomp GREATER -1)
+        find_library(Oracle_${_comp}_LIBRARY
+                     NAMES ${Oracle_${_comp}_lib}
+                     PATHS ${ORACLE_LIB_LOCATION}
+                     NO_DEFAULT_PATH
+        )
+        mark_as_advanced(Oracle_${_comp}_LIBRARY)
+        if(Oracle_${_comp}_header)
+            find_path(Oracle_${_comp}_INCLUDE_DIR
+                      NAMES ${Oracle_${_comp}_header}
+                      PATHS ${ORACLE_INCLUDES_LOCATION}
+                      NO_DEFAULT_PATH)
+            mark_as_advanced(Oracle_${_comp}_INCLUDE_DIR)
+        endif()
+    endif()
+endforeach()
+
+if( NOT Oracle_LIBRARY AND Oracle_CAN_USE_CLNTSH_AS_MAIN_LIBRARY AND Oracle_CLNTSH_LIBRARY )
+    set(Oracle_LIBRARY "${Oracle_CLNTSH_LIBRARY}")
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Oracle
+                                  FOUND_VAR Oracle_FOUND
+                                  REQUIRED_VARS Oracle_LIBRARY Oracle_INCLUDE_DIR
+                                  VERSION_VAR ORACLE_OCI_VERSION
+                                  HANDLE_COMPONENTS)
+mark_as_advanced(Oracle_INCLUDE_DIR Oracle_LIBRARY)
+
+IF(Oracle_FOUND)
+    set(Oracle_INCLUDE_DIRS "${Oracle_INCLUDE_DIR}")
+    set(Oracle_LIBRARIES "${Oracle_LIBRARY}")
+    if(Oracle_XML_INCLUDE_DIR AND Oracle_XML_LIBRARY)
+        list(APPEND Oracle_INCLUDE_DIRS "${Oracle_XML_INCLUDE_DIR}")
+    endif()
+    if(NOT TARGET Oracle::OCI)
+        add_library(Oracle::OCI UNKNOWN IMPORTED)
+        set_target_properties(Oracle::OCI PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${Oracle_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${Oracle_LIBRARY}"
+                              )
+        foreach(tgt IN LISTS Oracle_known_components)
+            if(Oracle_${tgt}_FOUND)
+                add_library(Oracle::${tgt} UNKNOWN IMPORTED)
+                set_target_properties(Oracle::${tgt} PROPERTIES
+                                      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                                      IMPORTED_LOCATION "${Oracle_${tgt}_LIBRARY}")
+            endif()
+        endforeach()
+        if(Oracle_XML_INCLUDE_DIR)
+            if(TARGET Oracle::XML)
+                set_property(Oracle::XML APPEND PROPERTY
+                             INTERFACE_INCLUDE_DIRECTORIES "${Oracle_XML_INCLUDE_DIR}")
+            endif()
+        endif()
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindPCRE.cmake

@@ -0,0 +1,28 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# FindPCRE
+# ~~~~~~~~~
+# Copyright (C) 2017-2018, Hiroshi Miura
+#
+# Find the native PCRE headers and libraries.
+
+find_path(PCRE_INCLUDE_DIR NAMES pcre.h)
+find_library(PCRE_LIBRARY NAMES pcre)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PCRE
+                                  FOUND_VAR PCRE_FOUND
+                                  REQUIRED_VARS PCRE_LIBRARY PCRE_INCLUDE_DIR)
+mark_as_advanced(PCRE_INCLUDE_DIR PCRE_LIBRARY)
+if(PCRE_FOUND)
+    set(PCRE_LIBRARIES "${PCRE_LIBRARY}")
+    set(PCRE_INCLUDE_DIRS "${PCRE_INCLUDE_DIR}")
+    if(NOT TARGET PCRE::PCRE)
+        add_library(PCRE::PCRE UNKNOWN IMPORTED)
+        set_target_properties(PCRE::PCRE PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${PCRE_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${PCRE_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindPCRE2.cmake

@@ -0,0 +1,27 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# FindPCRE2
+# ~~~~~~~~~
+# Copyright (C) 2017-2018, Hiroshi Miura
+#
+# Find the native PCRE2 headers and libraries.
+
+find_path(PCRE2_INCLUDE_DIR NAMES pcre2.h)
+find_library(PCRE2-8_LIBRARY NAMES pcre2-8 pcre2-8d pcre2-8-static pcre2-8-staticd NAMES_PER_DIR)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PCRE2
+                                  REQUIRED_VARS PCRE2-8_LIBRARY PCRE2_INCLUDE_DIR)
+mark_as_advanced(PCRE2_INCLUDE_DIR PCRE2-8_LIBRARY)
+if(PCRE2_FOUND)
+    list(APPEND PCRE2_LIBRARIES "${PCRE2-8_LIBRARY}")
+    set(PCRE2_INCLUDE_DIRS "${PCRE2_INCLUDE_DIR}")
+    if(NOT TARGET PCRE2::PCRE2-8)
+        add_library(PCRE2::PCRE2-8 UNKNOWN IMPORTED)
+        set_target_properties(PCRE2::PCRE2-8 PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${PCRE2_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${PCRE2-8_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindPROJ.cmake

@@ -0,0 +1,91 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindPROJ
+---------
+
+CMake module to search for PROJ(PROJ.4 and PROJ) library
+
+On success, the macro sets the following variables:
+``PROJ_FOUND``
+  if the library found
+
+``PROJ_LIBRARIES``
+  full path to the library
+
+``PROJ_INCLUDE_DIRS``
+  where to find the library headers
+
+``PROJ_VERSION_STRING``
+  version string of PROJ
+
+Copyright (c) 2009 Mateusz Loskot <mateusz@loskot.net>
+Copyright (c) 2015 NextGIS <info@nextgis.com>
+Copyright (c) 2018 Hiroshi Miura
+
+#]=======================================================================]
+
+find_path(PROJ_INCLUDE_DIR proj.h
+          PATHS ${PROJ_ROOT}/include
+          DOC "Path to PROJ library include directory")
+
+set(PROJ_NAMES ${PROJ_NAMES} proj proj_i)
+set(PROJ_NAMES_DEBUG ${PROJ_NAMES_DEBUG} projd proj_d)
+
+if(NOT PROJ_LIBRARY)
+  find_library(PROJ_LIBRARY_RELEASE NAMES ${PROJ_NAMES})
+  find_library(PROJ_LIBRARY_DEBUG NAMES ${PROJ_NAMES_DEBUG})
+  include(SelectLibraryConfigurations)
+  select_library_configurations(PROJ)
+  mark_as_advanced(PROJ_LIBRARY_RELEASE PROJ_LIBRARY_DEBUG)
+endif()
+
+unset(PROJ_NAMES)
+unset(PROJ_NAMES_DEBUG)
+
+if(PROJ_INCLUDE_DIR)
+    file(READ "${PROJ_INCLUDE_DIR}/proj.h" PROJ_H_CONTENTS)
+    string(REGEX REPLACE "^.*PROJ_VERSION_MAJOR +([0-9]+).*$" "\\1" PROJ_VERSION_MAJOR "${PROJ_H_CONTENTS}")
+    string(REGEX REPLACE "^.*PROJ_VERSION_MINOR +([0-9]+).*$" "\\1" PROJ_VERSION_MINOR "${PROJ_H_CONTENTS}")
+    string(REGEX REPLACE "^.*PROJ_VERSION_PATCH +([0-9]+).*$" "\\1" PROJ_VERSION_PATCH "${PROJ_H_CONTENTS}")
+    unset(PROJ_H_CONTENTS)
+    set(PROJ_VERSION_STRING "${PROJ_VERSION_MAJOR}.${PROJ_VERSION_MINOR}.${PROJ_VERSION_PATCH}")
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PROJ
+                                  REQUIRED_VARS PROJ_LIBRARY PROJ_INCLUDE_DIR
+                                  VERSION_VAR PROJ_VERSION_STRING)
+mark_as_advanced(PROJ_INCLUDE_DIR PROJ_LIBRARY)
+
+if(PROJ_FOUND)
+  set(PROJ_LIBRARIES "${PROJ_LIBRARY}")
+  set(PROJ_INCLUDE_DIRS "${PROJ_INCLUDE_DIR}")
+  if(NOT TARGET PROJ::proj)
+    add_library(PROJ::proj UNKNOWN IMPORTED)
+    set_target_properties(PROJ::proj PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${PROJ_INCLUDE_DIR}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C")
+    if(EXISTS "${PROJ_LIBRARY}")
+      set_target_properties(PROJ::proj PROPERTIES
+        IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+        IMPORTED_LOCATION "${PROJ_LIBRARY}")
+    endif()
+    if(EXISTS "${PROJ_LIBRARY_RELEASE}")
+      set_property(TARGET PROJ::proj APPEND PROPERTY
+        IMPORTED_CONFIGURATIONS RELEASE)
+      set_target_properties(PROJ::proj PROPERTIES
+        IMPORTED_LINK_INTERFACE_LANGUAGES_RELEASE "C"
+        IMPORTED_LOCATION_RELEASE "${PROJ_LIBRARY_RELEASE}")
+    endif()
+    if(EXISTS "${PROJ_LIBRARY_DEBUG}")
+      set_property(TARGET PROJ::proj APPEND PROPERTY
+        IMPORTED_CONFIGURATIONS DEBUG)
+      set_target_properties(PROJ::proj PROPERTIES
+        IMPORTED_LINK_INTERFACE_LANGUAGES_DEBUG "C"
+        IMPORTED_LOCATION_DEBUG "${PROJ_LIBRARY_DEBUG}")
+    endif()
+  endif()
+endif()
+

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindPodofo.cmake

@@ -0,0 +1,93 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindPODOFO
+-----------
+
+Copyright (c) 2017, Hiroshi Miura <miurahr@linux.com>
+
+Find the PODOFO headers and libraries.
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``PODOFO::PODOFO``, if
+PODOFO has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``PODOFO_FOUND``
+  True if PODOFO found.
+
+``PODOFO_INCLUDE_DIRS``
+  where to find podofo/POFDoc.h, etc.
+
+``PODOFO_LIBRARIES``
+  List of podofo libraries to link.
+
+``PODOFO_VERSION_STRING``
+  Version of podofo library defined in podofo/base/podofo_config.h
+
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+  pkg_check_modules(PC_PODOFO QUIET podofo)
+endif()
+
+find_path(PODOFO_INCLUDE_DIR
+          NAMES podofo.h
+          HINTS ${PC_PODOFO_INCLUDE_DIRS}
+          PATH_SUFFIXES podofo)
+
+find_library(PODOFO_LIBRARY
+             NAMES podofo libpodofo
+             HINTS ${PC_PODOFO_LIBRARY_DIRS})
+
+mark_as_advanced(PODOFO_INCLUDE_DIR PODOFO_LIBRARY)
+
+if(PODOFO_INCLUDE_DIR)
+  set(version_hdr "${PODOFO_INCLUDE_DIR}/base/podofo_config.h")
+  if(NOT EXISTS ${version_hdr})
+    # PoDoFo >= 0.10
+    set(version_hdr "${PODOFO_INCLUDE_DIR}/auxiliary/podofo_config.h")
+  endif()
+  if(EXISTS ${version_hdr})
+    file(STRINGS ${version_hdr} _contents REGEX "^[ \t]*#define PODOFO_VERSION_.*")
+    if(_contents)
+        string(REGEX REPLACE ".*#define PODOFO_VERSION_MAJOR[ \t]+([0-9]+).*" "\\1" PODOFO_VERSION_MAJOR "${_contents}")
+        string(REGEX REPLACE ".*#define PODOFO_VERSION_MINOR[ \t]+([0-9]+).*" "\\1" PODOFO_VERSION_MINOR "${_contents}")
+        string(REGEX REPLACE ".*#define PODOFO_VERSION_PATCH[ \t]+([0-9]+).*" "\\1" PODOFO_VERSION_PATCH "${_contents}")
+    endif()
+    set(PODOFO_VERSION_STRING  ${PODOFO_VERSION_MAJOR}.${PODOFO_VERSION_MINOR}.${PODOFO_VERSION_PATCH})
+  endif()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Podofo
+                                  FOUND_VAR PODOFO_FOUND
+                                  REQUIRED_VARS PODOFO_LIBRARY PODOFO_INCLUDE_DIR
+                                  VERSION_VAR PODOFO_VERSION_STRING)
+
+if(PODOFO_FOUND)
+  get_filename_component(PODOFO_PARENT_INCLUDE_DIR ${PODOFO_INCLUDE_DIR} DIRECTORY)
+  set(PODOFO_INCLUDE_DIRS "${PODOFO_INCLUDE_DIR};${PODOFO_PARENT_INCLUDE_DIR}")
+  set(PODOFO_LIBRARIES "${PDOFO_LIBRARY}")
+  if(NOT TARGET PODOFO::Podofo)
+    add_library(PODOFO::Podofo UNKNOWN IMPORTED)
+    set_target_properties(PODOFO::Podofo PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${PODOFO_INCLUDE_DIRS}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                          IMPORTED_LOCATION "${PODOFO_LIBRARY}")
+  endif()
+endif()
+
+include(FeatureSummary)
+set_package_properties(PODOFO PROPERTIES
+                       DESCRIPTION "a free, portable C++ library which includes classes to parse PDF files and modify their contents into memory."
+                       URL "http://podofo.sourceforge.net/"
+)