@alteriom/painlessmesh 1.7.2 → 1.7.4

package/examples/alteriom/.pio/libdeps/esp32/TaskScheduler/examples/Scheduler_example10_Benchmark/Scheduler_example10_Benchmark.ino

@@ -0,0 +1,106 @@
+
+/**
+ * This is a test to benchmark TaskScheduler execution.
+ * 
+ * This test executes 1,000,000 cycles of a task with empty callback method
+ * Compiled with different options, you can assess the impact of each on the size of the Task object
+ * and the execution overhead of the main execution pass route.
+ *
+ * Sample execution times (in milliseconds per 1M iterations) are provided below.
+ * The test board is Arduino UNO 16MHz processor.
+ *
+ 
+TaskScheduler 2.1.0:
+No modifiers
+Duration=19869
+
+with SLEEP
+Duration=20058
+
+with status request:
+Duration=20058
+
+with time critical:
+Duration=27289
+
+
+TaskScheduler 1.9.0:
+No modifiers
+Duration=15656
+
+with SLEEP
+Duration=16285
+
+with status request:
+Duration=16600
+
+with rollover fix:
+Duration=18109
+
+
+TaskScheduler 1.8.5:
+Duration=15719
+
+with SLEEP
+Duration=16348
+
+with status request:
+Duration=18360
+
+with rollover fix:
+Duration=18423
+
+ */
+
+
+//#define _TASK_TIMECRITICAL     // Enable monitoring scheduling overruns
+//#define _TASK_STATUS_REQUEST     // Compile with support for StatusRequest functionality - triggering tasks on status change events in addition to time only
+//#define _TASK_WDT_IDS          // Compile with support for wdt control points and task ids
+//#define _TASK_LTS_POINTER      // Compile with support for local task storage pointer
+//#define _TASK_SLEEP_ON_IDLE_RUN
+//#define _TASK_MICRO_RES
+#include <TaskScheduler.h>
+
+Scheduler ts;
+
+// Callback methods prototypes
+bool tOn(); void tOff();
+void callback();
+
+// Tasks
+Task t(TASK_IMMEDIATE, 1000000, &callback, &ts, false, &tOn, &tOff);
+
+unsigned long c1, c2;
+
+bool tOn() {
+  c1 = millis();
+  c2 = 0;
+  
+  return true;
+}
+
+void tOff() {
+  c2 = millis();
+  Serial.println("done.");
+  Serial.print("Tstart =");Serial.println(c1);
+  Serial.print("Tfinish=");Serial.println(c2);
+  Serial.print("Duration=");Serial.println(c2-c1);
+}
+
+void setup() {
+  // put your setup code here, to run once:
+  Serial.begin(115200);
+  Serial.print("Start...");
+
+  t.enable();
+}
+
+void callback() {
+  
+}
+
+
+void loop() {
+  // put your main code here, to run repeatedly:
+  ts.execute();
+}

package/examples/alteriom/.pio/libdeps/esp32/TaskScheduler/examples/Scheduler_example11_Priority/Scheduler_example11_Priority.ino

@@ -0,0 +1,105 @@
+/**
+ * This is a test of TaskScheduler layered priority funtionality
+ * 
+ * Current test employs two priority layers:
+ * Base scheduler runs tasks t1, t2 and t3
+ * High priority scheduler runs tasks t4 and t5
+ * 
+ * Sequence of task scheduling (not execution!) is:
+ * 4, 5, 1, 4, 5, 2, 4, 5, 3 = one base scheduler pass
+ * 
+ * Scheduling overhead (at 20 micros per one pass) is: (B + B * H) * T = (3 + 3 * 2) * 18 = 162 micros
+ * where
+ *  B - number of tasks in the base scheduler's chain
+ *  H - number of tasks in the high priority scheduler's chain
+ *  T - scheduling overhead for 1 pass (~15-18 microseconds) 
+ *  
+ *  Actual task execution order:
+
+Scheduler Priority Test
+Task: 40:  0 Start delay = 0
+Task: 50: 10  Start delay = 10
+Task: 1:  21  Start delay = 21
+Task: 2:  31  Start delay = 31
+Task: 3:  41  Start delay = 41
+
+Task: 40: 500 Start delay = 0
+Task: 40: 1000  Start delay = 0
+Task: 50: 1010  Start delay = 10
+Task: 1:  1021  Start delay = 20
+Task: 40: 1500  Start delay = 0
+Task: 40: 2000  Start delay = 0
+Task: 50: 2011  Start delay = 11
+Task: 1:  2022  Start delay = 21
+Task: 2:  2032  Start delay = 32
+Task: 40: 2500  Start delay = 0
+Task: 40: 3000  Start delay = 0
+Task: 50: 3010  Start delay = 10
+Task: 1:  3021  Start delay = 20
+Task: 3:  3032  Start delay = 32
+
+Task: 40: 3500  Start delay = 0
+Task: 40: 4000  Start delay = 0
+Task: 50: 4011  Start delay = 11
+Task: 1:  4022  Start delay = 21
+Task: 2:  4032  Start delay = 32
+Task: 40: 4500  Start delay = 0
+Task: 40: 5000  Start delay = 0
+Task: 50: 5010  Start delay = 10
+Task: 1:  5021  Start delay = 20
+Task: 40: 5500  Start delay = 0
+Task: 40: 6000  Start delay = 0
+Task: 50: 6010  Start delay = 10
+Task: 1:  6022  Start delay = 21
+Task: 2:  6032  Start delay = 32
+Task: 3:  6043  Start delay = 42
+
+ */
+ 
+#define _TASK_SLEEP_ON_IDLE_RUN
+#define _TASK_PRIORITY
+#define _TASK_WDT_IDS
+#define _TASK_TIMECRITICAL
+#include <TaskScheduler.h>
+
+Scheduler r, hpr;
+
+// Callback methods prototypes
+void tCallback();
+
+// Tasks
+Task t1(1000, TASK_FOREVER, &tCallback, &r);  //adding task to the chain on creation
+Task t2(2000, TASK_FOREVER, &tCallback, &r);
+Task t3(3000, TASK_FOREVER, &tCallback, &r);
+
+Task t4(500, TASK_FOREVER, &tCallback, &hpr);  //adding task to the chain on creation
+Task t5(1000, TASK_FOREVER, &tCallback, &hpr);  //adding task to the chain on creation
+
+void tCallback() {
+  Scheduler &s = Scheduler::currentScheduler();
+  Task &t = s.currentTask();
+  
+  Serial.print("Task: "); Serial.print(t.getId());Serial.print(":\t");
+  Serial.print(millis()); Serial.print("\tStart delay = "); Serial.println(t.getStartDelay());
+  delay(10);
+
+  if (t.getId() == 3) Serial.println();
+}
+
+void setup () {
+  Serial.begin(115200);
+  Serial.println("Scheduler Priority Test");
+
+  t4.setId(40);
+  t5.setId(50);
+
+  r.setHighPriorityScheduler(&hpr); 
+  r.enableAll(true); // this will recursively enable the higher priority tasks as well
+}
+
+
+void loop () {
+  
+  r.execute();
+  
+}

package/examples/alteriom/.pio/libdeps/esp32/TaskScheduler/examples/Scheduler_example12_Priority/Scheduler_example12_Priority.ino

@@ -0,0 +1,136 @@
+/**
+ * This is a test of TaskScheduler layered priority funtionality
+ * 
+ * Current test employs three priority layers:
+ * Base scheduler runs tasks t1, t2 and t3
+ * High priority scheduler runs tasks t4 and t5
+ * Highest priority scheduler runs tasks t6 and t7
+ * 
+ * Sequence of task scheduling (not execution!) is:
+ * 6, 7, 4, 6, 7, 5, 1, 6, 7, 4, 6, 7, 5, 2, 6, 7, 4, 6, 7, 5, 3 = one base scheduler pass
+ * 
+ * Scheduling overhead (at 20 micros per one pass) is: (B + B * H + B * H * C) * T = (3 + 3 * 2 + 3 * 2 * 2) * 18 = 378 micros
+ * where
+ *  B - number of tasks in the base scheduler's chain
+ *  H - number of tasks in the high priority scheduler's chain
+ *  C - number of tasks in the critical priority scheduler's chain
+ *  T - scheduling overhead for 1 pass (~15-18 microseconds) 
+ *  
+ *  Actual task execution order:
+
+Scheduler Priority Test
+Task: 600:  0 Start delay = 0
+Task: 700:  10  Start delay = 10
+Task: 40: 21  Start delay = 21
+Task: 50: 31  Start delay = 31
+Task: 1:  43  Start delay = 41
+Task: 2:  53  Start delay = 53
+Task: 3:  63  Start delay = 63
+
+Task: 600:  500 Start delay = 0
+Task: 40: 510 Start delay = 10
+Task: 600:  1000  Start delay = 0
+Task: 700:  1010  Start delay = 10
+Task: 40: 1021  Start delay = 21
+Task: 50: 1032  Start delay = 32
+Task: 1:  1043  Start delay = 43
+Task: 600:  1500  Start delay = 0
+Task: 40: 1510  Start delay = 10
+Task: 600:  2000  Start delay = 0
+Task: 700:  2011  Start delay = 11
+Task: 40: 2022  Start delay = 22
+Task: 50: 2032  Start delay = 32
+Task: 1:  2043  Start delay = 43
+Task: 2:  2054  Start delay = 54
+Task: 600:  2500  Start delay = 0
+Task: 40: 2510  Start delay = 10
+Task: 600:  3000  Start delay = 0
+Task: 700:  3010  Start delay = 10
+Task: 40: 3021  Start delay = 21
+Task: 50: 3032  Start delay = 32
+Task: 1:  3043  Start delay = 43
+Task: 3:  3053  Start delay = 53
+
+Task: 600:  3500  Start delay = 0
+Task: 40: 3510  Start delay = 10
+Task: 600:  4000  Start delay = 0
+Task: 700:  4011  Start delay = 11
+Task: 40: 4022  Start delay = 22
+Task: 50: 4032  Start delay = 32
+Task: 1:  4043  Start delay = 43
+Task: 2:  4054  Start delay = 54
+Task: 600:  4500  Start delay = 0
+Task: 40: 4510  Start delay = 10
+Task: 600:  5000  Start delay = 0
+Task: 700:  5010  Start delay = 10
+Task: 40: 5021  Start delay = 21
+Task: 50: 5031  Start delay = 31
+Task: 1:  5043  Start delay = 43
+Task: 600:  5500  Start delay = 0
+Task: 40: 5511  Start delay = 11
+Task: 600:  6000  Start delay = 0
+Task: 700:  6010  Start delay = 10
+Task: 40: 6022  Start delay = 22
+Task: 50: 6032  Start delay = 32
+Task: 1:  6043  Start delay = 43
+Task: 2:  6053  Start delay = 53
+Task: 3:  6065  Start delay = 65
+
+ */
+ 
+#define _TASK_SLEEP_ON_IDLE_RUN
+#define _TASK_PRIORITY
+#define _TASK_WDT_IDS
+#define _TASK_TIMECRITICAL
+#include <TaskScheduler.h>
+
+Scheduler r;
+Scheduler hpr;
+Scheduler cpr;
+
+// Callback methods prototypes
+void tCallback();
+
+// Tasks
+Task t1(1000, TASK_FOREVER, &tCallback, &r);  //adding task to the chain on creation
+Task t2(2000, TASK_FOREVER, &tCallback, &r);
+Task t3(3000, TASK_FOREVER, &tCallback, &r);
+
+Task t4(500, TASK_FOREVER, &tCallback, &hpr);  //adding task to the chain on creation
+Task t5(1000, TASK_FOREVER, &tCallback, &hpr);  //adding task to the chain on creation
+
+Task t6(500, TASK_FOREVER, &tCallback, &cpr);  //adding task to the chain on creation
+Task t7(1000, TASK_FOREVER, &tCallback, &cpr);  //adding task to the chain on creation
+
+void tCallback() {
+  Scheduler &s = Scheduler::currentScheduler();
+  Task &t = s.currentTask();
+  
+  Serial.print("Task: "); Serial.print(t.getId());Serial.print(":\t");
+  Serial.print(millis()); Serial.print("\tStart delay = "); Serial.println(t.getStartDelay());
+  delay(10);
+
+  if (t.getId() == 3) Serial.println();
+}
+
+void setup () {
+  Serial.begin(115200);
+  Serial.println("Scheduler Priority Test");
+
+  t4.setId(40);
+  t5.setId(50);
+  
+  t6.setId(600);
+  t7.setId(700);
+
+  r.setHighPriorityScheduler(&hpr); 
+  hpr.setHighPriorityScheduler(&cpr); 
+  r.enableAll(true); // this will recursively enable the higher priority tasks as well
+}
+
+
+void loop () {
+  
+  r.execute();
+  
+}

package/examples/alteriom/.pio/libdeps/esp32/TaskScheduler/examples/Scheduler_example13_Micros/Scheduler_example13_Micros.ino

@@ -0,0 +1,71 @@
+/**
+ * TaskScheduler Test of microsecond scheduling resolution
+ *
+ * Task 1 runs starting with 211 microseconds intervals, doubling the interval on every iteration 
+ * until it wraps when interval reaches about 72 minutes mark
+ * 
+ * Task 2 provides heartbeat at a steady 5 seconds intervals
+ *
+ */
+ 
+#define _TASK_MICRO_RES
+#include <TaskScheduler.h>
+
+#define T1_INIT (211L)
+
+Scheduler runner;
+// Callback methods prototypes
+void t1Callback();
+void t1OnDisable();
+void t2Callback();
+
+
+unsigned long t1_interval = T1_INIT;
+
+// Tasks
+Task t1(t1_interval, 1, &t1Callback, &runner, true, NULL, &t1OnDisable);      //adding task to the chain on creation
+Task t2(5 * TASK_SECOND, TASK_FOREVER, &t2Callback, &runner, true);  //adding task to the chain on creation
+
+
+
+void t1Callback() {
+  unsigned long t = micros();
+  Serial.print("t1: ");
+  Serial.println(t);
+}
+
+void t1OnDisable() {
+  t1_interval += t1_interval; 
+  if (t1_interval < T1_INIT) t1_interval = T1_INIT;
+  t1.setInterval(t1_interval);
+  t1.restartDelayed();
+}
+
+void t2Callback() {
+  unsigned long t = micros();
+  Serial.print("t2: ");
+  Serial.print(t);
+  Serial.println(" heartbeat");
+}
+
+
+void setup () {
+  Serial.begin(115200);
+  Serial.println("Scheduler TEST Microsecond Resolution");
+  
+  Serial.println("5 seconds delay");
+  delay(5000);
+   
+  runner.startNow(); // This creates a new scheduling starting point for all ACTIVE tasks. 
+                      // PLEASE NOTE - THIS METHOD DOES NOT ACTIVATE TASKS, JUST RESETS THE START TIME
+  t1.delay();        // Tasks which need to start delayed, need to be delayed again after startNow();
+
+// Alternatively, tasks should be just enabled at the bottom of setup() method
+//  runner.enableAll();    
+//  t1.delay();
+}
+
+
+void loop () {
+  runner.execute();
+}