unageanu-jiji 0.1.0

data/swf/chart/fx/chart/ui/graph/GraphManager.as

@@ -0,0 +1,177 @@
+package fx.chart.ui.graph {
+
+  import fx.util.*;
+  import fx.chart.ui.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.external.*;
+  
+  /**
+   * グラフマネージャ
+   */
+  public class GraphManager extends AbstractDrawChartUI {
+
+     /**
+      * グラフ情報のマップ
+      */
+    private var infos:Object = {};
+
+    public function GraphManager( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+      
+      // 一覧UIを描く
+    }
+
+    /**
+     * グラフ一覧が更新された場合に呼び出される。
+     * swfの初期化時やpidが更新された場合に発生。
+     */
+    public function onGraphListChanged(ev:*):void {
+
+        // 既存のグラフは一旦破棄
+        for ( var i:* in infos ) {
+          for ( var j:* in infos[i] ) {
+            if ( infos[i][j].graph ) {
+              infos[i][j].graph.destroy();
+            }
+          }
+        }
+        infos = {};
+
+        // グラフ一覧を作成
+        for ( var graph:* in model.graphs ) {
+            infos[graph] = {};
+            var x:* = model.graphs[graph];
+            for ( var g:* in x ) {
+              infos[graph][g] = new GraphInfo( x[g], null,  model, ctrl, rc );
+            }
+        }
+
+        // グラフデータを取得して描画。
+        updateGraphs();
+    }
+
+    /**
+     * ローソク足データが更新された場合に呼び出される。
+     */
+    public function onCandleDataChanged(ev:Event):void {
+        // グラフデータを再取得&&更新
+        updateGraphs();
+    }
+
+    public function on( name:Array ):void {
+      // レイヤーを非表示。
+      if ( infos && infos[name[0]] && infos[name[0]][name[1]]  ) {
+        var target:GraphInfo = infos[name[0]][name[1]];
+        target.visible = true;
+        
+        // データが未取得であればとってくる。
+        if ( !target.datas ) {
+          ctrl.requestOutputDatas( [name], function( map:Object ):void {
+            target.datas = null;
+            if ( map[name[0]][name[1]] ) {
+              target.datas = map[name[0]][name[1]];
+              // グラフ表示
+              target.draw( );
+              target.graph.setVisible(true);
+            }
+          });
+        } else {
+          // 取得済みであればレイヤーを表示するだけ。
+          target.graph.setVisible(true);
+        }
+      }
+    }
+    public function off( name:Array ):void {
+      // レイヤーを非表示。
+      if ( infos && infos[name[0]] && infos[name[0]][name[1]]  ) {
+        var target:GraphInfo = infos[name[0]][name[1]];
+        target.visible = false;
+        target.graph.setVisible(false);
+      }
+    }
+    /**
+     * グラフの色を更新する
+     */
+    public function setGraphColors( name:Array, colors:Array ):void {
+        // レイヤーを非表示。
+        if ( infos && infos[name[0]] && infos[name[0]][name[1]]  ) {
+            var target:GraphInfo = infos[name[0]][name[1]];
+            target.setColors( colors ); 
+            target.draw(); // グラフを再描画
+        }
+      }
+    
+    /**
+     * グラフデータを再取得して更新する。
+     */
+    public function updateGraphs():void {
+        var names:Array = [];
+        for ( var i:* in infos ) {
+          for ( var j:* in infos[i] ) {
+              infos[i][j].datas = null;
+              if ( infos[i][j].visible ) {
+                names.push( [i,j] );
+              }
+          }
+        }
+        if ( names.length <= 0 ) { return; }
+        ctrl.requestOutputDatas( names, function( map:Object ):void {
+          names.forEach( function( item:*,i:int,arr:Array ):void {
+              if ( map[item[0]][item[1]] ) {
+                  infos[item[0]][item[1]].datas = map[item[0]][item[1]] ;
+                  // グラフ表示
+                  if ( infos[item[0]][item[1]].visible ) { 
+                    infos[item[0]][item[1]].draw( );
+                  }
+              }
+          } );
+        });
+    }
+  }
+}
+
+import fx.chart.ui.*;
+import fx.chart.model.*;
+import fx.chart.ctrl.*;
+import fx.chart.ui.graph.Graph;
+
+class GraphInfo {
+    
+  internal  var info:Object;
+  internal  var visible:Boolean;
+  internal  var datas:Array;
+  internal  var colors:Array;
+  internal  var graph:Graph;
+
+  function GraphInfo( info:Object, datas:Array,
+    model:Model, controller:Controller, rc:RenderingContext ) {
+    this.info = info;
+    this.visible = info["visible"] == false ? false : true;
+    this.datas = datas;
+    if ( info["colors"] && info["colors"] is Array ) {
+      setColors( info["colors"] ); 
+    }
+    this.graph = new Graph( model, controller, rc );
+  }
+  internal function draw():void {
+    graph.draw( {
+      "datas": datas,
+      "options": info
+    }, colors );
+  }
+  internal function setColors( colors:Array):void {
+      var self:GraphInfo = this;
+      self.colors = [];
+      colors.forEach( function(c:*,i:int,arr:Array):void {
+        if ( c is String && c.match(/\#([a-fA-F0-9]{6})/) ) {
+          self.colors.push( Number(c.replace(/^\#/, "0x")));
+        }
+      });
+  }
+}
+

data/swf/chart/fx/net/StubFactory.as

@@ -0,0 +1,113 @@
+package fx.net {
+  
+  import fx.util.*;
+    
+  /**
+   * スタブファクトリ
+   */
+  public class StubFactory  {
+    
+    /**
+     * エンドポイント
+     */
+    private var endPoint:String = "./json";
+
+    /**
+     * リスナ
+     */
+    public var listenerSupport:ListenerSupport = new ListenerSupport();
+    
+    /**
+     * コンストラクタ
+     */ 
+    public function StubFactory( endPoint:String ) {
+      this.endPoint = endPoint;
+    }
+    
+    /**
+     * スタブを生成する。
+     */
+    public function create( name:String ):* {
+      return new Stub( endPoint + "/" + name, this );
+    }
+    
+    
+  }
+}
+
+import flash.errors.*;
+import flash.events.*;
+import flash.net.URLLoader;
+import flash.net.URLRequest;
+import flash.net.URLRequestMethod;
+import flash.net.URLVariables;
+import flash.utils.Proxy;
+import flash.utils.flash_proxy;
+import com.adobe.serialization.json.JSON;
+import fx.net.*
+import fx.chart.ctrl.Event;
+
+// スタブ
+dynamic class Stub extends Proxy {
+  
+  /**現在進行中のリクエスト数*/
+  private static var requestCount:int = 0;
+  
+  private var endPoint:String;
+  private var sf:StubFactory;
+  
+  function Stub( endPoint:String, sf:StubFactory ) {
+    this.endPoint = endPoint;
+    this.sf = sf;
+  }
+  flash_proxy override function callProperty(name:*, ...rest):* {
+    var fail:Function = rest.pop();
+    var success:Function = rest.pop();
+    
+    // リクエストを生成
+    var request:URLRequest = new URLRequest();
+    request.url = endPoint;
+    var data:String = JSON.encode({
+        "method":name.toString(), "params":rest, "time":new Date().getTime()
+    });
+    log(data);
+    //request.method = URLRequestMethod.POST;
+    var variable:URLVariables = new URLVariables();
+    variable.request = data;
+    request.data = variable;
+    
+    // ローダーを生成し、イベントハンドラを設定
+    var loader:URLLoader = new URLLoader();
+    loader.addEventListener(flash.events.Event.COMPLETE, function( ev:flash.events.Event):void {
+       changeRequestCount(-1);
+       log(ev.target.data);
+       var result:Object = JSON.decode( ev.target.data)[0];
+       if ( result["error"] ) {
+          fail.apply(null, [result["error"]] );
+       } else {
+          success.apply(null, [result["result"]] );
+       }
+    });
+    loader.addEventListener(IOErrorEvent.IO_ERROR, function( ev:IOErrorEvent ):void {
+       changeRequestCount(-1);
+       fail.apply(null, [ev] );
+    });
+    loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, function( ev:SecurityErrorEvent ):void {
+       changeRequestCount(-1);
+       fail.apply(null, [ev] );
+    });
+    
+    try {
+        loader.load(request);
+        changeRequestCount(1);
+    } catch (error:*) {
+        fail.apply(null, [error] );
+    }
+  }
+  private function changeRequestCount( diff:int  ):void {
+      requestCount+= diff;
+      log( "request count : " + String(requestCount) );
+      sf.listenerSupport.fire( fx.chart.ctrl.Event.REQUEST_COUNT_CHANGED, 
+              {"requestCount":requestCount} );
+  }
+} 

data/swf/chart/fx/util/ListenerSupport.as

@@ -0,0 +1,55 @@
+package fx.util {
+  
+  /**
+   * リスナ
+   */
+  public class ListenerSupport  {
+
+    /**
+     * リスナ
+     */
+    private var listeners:Object = {};
+      
+    /**
+     * イベントリスナを追加する。
+     */
+    public function addEventListener( type:String,
+      listener:Function, self:*=null, priority:int=0 ):void {
+      var list:Array = listeners[type];
+      if ( !list ) {
+        list = [];
+        listeners[type] = list;
+      }
+      list.push( {listener:listener, priority:priority, self:self} );
+      list.sortOn( "priority", Array.NUMERIC);
+    }
+    
+    /**
+     * イベントリスナを削除する。
+     */
+    public function removeEventListener( type:String,
+      listener:Function ):void {
+      var list:Array = listeners[type];
+      if ( !list ) {
+        var tmp:Array = [];
+        list.forEach( function(item:*,i:int,arr:Array):void { 
+            if ( item.listener != listener ) tmp.add( item );
+        } );
+        listeners[type] = tmp;
+      }
+    }
+    
+    /**
+     * イベントをキックする
+     */
+    public function fire( type:String, ev:* ):void {
+      var list:Array = listeners[type];
+      if ( !list ) {
+        return;
+      }
+      for ( var i:int=0; i<list.length; i++ ) {
+        list[i].listener.apply( list[i].self, [ev] );
+      }
+    }
+  }
+}