unageanu-jiji 0.1.0

data/swf/chart/fx/chart/ui/TradeDetailWindow.as

@@ -0,0 +1,146 @@
+package fx.chart.ui {
+
+  import fx.chart.model.*;
+  import fx.chart.ctrl.Controller;
+  import fx.chart.*;
+  import fx.util.*;
+  import flash.events.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.filters.*;
+
+  public class TradeDetailWindow extends AbstractChartUI  {
+
+    private static const WIDTH:int = 230;
+    private static const HEIGHT:int = 100;
+
+    private var infoLayer:Sprite;
+    private var window:Window;
+
+    /**テキストフィールド*/
+    private var textFields:Object = new Object();
+
+    /**アイコン*/
+    private var sell:Bitmap;
+    private var buy:Bitmap;
+
+    public function TradeDetailWindow( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+
+      infoLayer = new Sprite();
+      infoLayer.name = "trade";
+      rc.layers.window.addChild( infoLayer );
+      window = new Window( model,controller,rc,
+          infoLayer, WIDTH, HEIGHT );
+
+      var stageWidth:int = rc.stage.width;
+      var stageHeight:int = rc.stage.height;
+
+      var g:Graphics = window.window.graphics;
+
+      g.lineStyle( 0, 0xE3E3E0, 1,
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      g.moveTo( 10, 35 );
+      g.lineTo( WIDTH-10, 35 );
+      g.moveTo( 10, 60 );
+      g.lineTo( WIDTH-10, 60 );
+
+      // 最初は非表示
+      infoLayer.visible = false;
+
+      textFields["result"] = createTextField( 10,5,220,24,Constants.TEXT_FORMAT_TINFO_PROFIT_UP );
+      textFields["info"] = createTextField( 40,40,180,15,Constants.TEXT_FORMAT_TINFO_INFO );
+
+      (["start","end"]).forEach( function( item:*,i:int,arr:Array ):void{
+        textFields[item] = createTextField( 40,63+i*15,190,15,Constants.TEXT_FORMAT_INFO_BASIC_L );
+      } );
+
+      sell = new Constants.ICON_SELL();
+      buy = new Constants.ICON_BUY();
+      ([sell,buy]).forEach( function( item:*,i:int,arr:Array ):void{
+        item.x = 10;
+        item.y = 40;
+        //item.alpha = 5;
+        window.window.addChild( item );
+        item.visible = false;
+      });
+
+      var start:Bitmap = new Constants.ICON_START_LABEL();
+      var end:Bitmap = new Constants.ICON_END_LABEL();
+      ([start,end]).forEach( function( item:*,i:int,arr:Array ):void{
+        item.x = 11;
+        item.y = 66+i*15;
+        window.window.addChild( item );
+      } );
+
+      // イベントをキャプチャ
+      infoLayer.stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
+    }
+
+    public function onMouseMove( ev:MouseEvent ):void {
+      var stageWidth:int = rc.stage.width;
+      var stageHeight:int = rc.stage.height;
+      if ( model.rateDatas &&
+          ev.stageX >= rc.stage.candle.left+1 &&
+          ev.stageX < rc.stage.candle.right &&
+          ev.stageY > rc.stage.candle.top &&
+          ev.stageY <= rc.stage.profit.bottom ) {
+        infoLayer.x = ev.stageX > rc.stage.candle.right - WIDTH -10 ? ev.stageX-15-WIDTH : ev.stageX+15;
+        infoLayer.y = ev.stageY > rc.stage.profit.bottom - HEIGHT -10 ? ev.stageY-15-HEIGHT : ev.stageY+15;
+      }
+    }
+
+    public function update( d:Object, ev:MouseEvent ):void {
+
+      onMouseMove( ev );
+
+      if ( d["profit_or_loss"] > 0 ) {
+        textFields["result"].text = "+" + d["profit_or_loss"];
+        textFields["result"].setTextFormat( Constants.TEXT_FORMAT_TINFO_PROFIT_UP );
+      } else {
+        textFields["result"].text = d["profit_or_loss"];
+        textFields["result"].setTextFormat( d["profit_or_loss"] == 0
+            ? Constants.TEXT_FORMAT_TINFO_PROFIT_DRAW
+            : Constants.TEXT_FORMAT_TINFO_PROFIT_DOWN);
+      }
+      if ( d["sell_or_buy"] == "sell" ) {
+        sell.visible = true;
+        buy.visible = false;
+      } else {
+        sell.visible = false;
+        buy.visible = true;
+      }
+      textFields["info"].text = " / " + d["pair"] + " / " + int( d["price"] / d["rate"])
+      textFields["start"].text = d["rate"] + " " + formatDate( d["date"] );
+      if ( d["fix_rate"] && d["fix_date"] ) {
+        textFields["end"].text = d["fix_rate"] + " " + formatDate( d["fix_date"] );
+      } else {
+        textFields["end"].text = "-";
+      }
+    }
+
+    private function formatDate( longtime:Number ):String {
+      var date:Date = new Date();
+      date.setTime( longtime*1000 );
+      return Util.formatDate( date );
+    }
+
+    private function createTextField( x:int, y:int,
+        width:int, height:int, format:TextFormat ):TextField {
+      var text:TextField = new TextField();
+      text.selectable = false;
+      text.width = width;
+      text.height = height;
+      text.defaultTextFormat = format;
+      text.y = y;
+      text.x = x;
+      text.text = "-";
+      window.window.addChild( text );
+      return text;
+    }
+
+  }
+
+}

data/swf/chart/fx/chart/ui/TradeResult.as

@@ -0,0 +1,334 @@
+package fx.chart.ui {
+
+  import fx.util.*;
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+
+  import flash.display.*;
+  import flash.events.MouseEvent;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.external.*;
+
+  /**
+   * 取引データ
+   */
+  public class TradeResult extends AbstractDrawChartUI {
+
+    /**詳細情報ウインドウ*/
+    private var detailWindow:TradeDetailWindow;
+
+    /**取引結果を描画するスプライト*/
+    private var graph:Sprite;
+    private var graphFixed:Sprite;
+    private var trades:Sprite;
+
+    public function TradeResult( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+
+      detailWindow = new TradeDetailWindow( model,controller,rc );
+
+      // スプライト
+      graphFixed = new Sprite();
+      rc.layers.lowAxisY.addChild( graphFixed );
+      graph = new Sprite();
+      rc.layers.main.addChild( graph );
+      trades = new Sprite();
+      rc.layers.axisY.addChild( trades );
+      
+    }
+    public function onTradeDataChanged( ev:Event ):void {
+      trades.x = 0;
+      Util.clear( trades );
+
+      var trade:Rectangle = rc.stage.trade;
+
+      var datas:Array = model.tradeDatas.getDatas();
+      if ( datas.length <= 0 ) { return; }
+
+      datas.sortOn( "date", Array.NUMERIC ); // 開始日時順にソート
+      var slotsUp:Array = [];
+      var slotsDown:Array = [];
+      for (var i:int=0;i<6;i++) {
+         slotsUp.push(new Slot(model.scaleTime));
+         slotsDown.push(new Slot(model.scaleTime));
+      }
+      datas.forEach( function(t:*,i:int,arr:Array):void{
+         var slots:Array = t.profit_or_loss >= 0 ? slotsUp : slotsDown 
+        for (var j:int=0;j<slots.length;j++) {
+          if ( !slots[j].conflict(t) ) {
+            slots[j].add(t);
+            return;
+          }
+        }
+        // 入りきらないモノは破棄。
+      });
+
+      // 描画
+      slotsUp.forEach( function(s:*,j:int,arr2:Array):void{
+        var y:int = trade.top + int(trade.height/2) - (j+1) * 6;
+        drawSlot( s, y );
+      });
+      slotsDown.forEach( function(s:*,j:int,arr2:Array):void{
+          var y:int = trade.top + int(trade.height/2) +2 +  j * 6;
+          drawSlot( s, y );
+      });
+    }
+    
+    private function drawSlot( s:Slot, y:int ):void {
+        
+        var trade:Rectangle = rc.stage.trade;
+        
+        s.data.forEach( function(d:*,i:int,arr:Array):void {
+    
+          var sprite:Sprite = new Sprite();
+          var g:Graphics =sprite.graphics;
+    
+          var start:int = model.positionManager.fromDate( Math.ceil(d.date / model.scaleTime) * model.scaleTime );
+          var end:Number = 0;
+          if ( d.fix_date ) {
+            end = model.positionManager.fromDate( Math.ceil(d.fix_date / model.scaleTime) * model.scaleTime );
+          }
+          var w:int = end - start + 4 < trade.width ? end - start + 4 : trade.width ;
+          var color:uint = getTradeColor(d);
+    
+          // 開始円
+          var img:Bitmap = null;
+          if ( start > 3 ) {
+            img = getTradeBitmap( d );
+            img.x = 0;
+            img.y = 0;
+            sprite.addChild(img);
+          }
+    
+          // 線
+          var abs:Number = Math.abs( d.profit_or_loss);
+          var left:int = NaN;
+          if ( d.fix_date && (end+trade.left < trade.right) ) {
+            if ( start > 0) {
+              left = w-2;
+            } else {
+              left = end;
+            }
+          } else {
+            if ( start > 0) {
+              left = trade.width - start;
+            } else {
+              left = trade.width-1;
+            }
+          }
+          g.lineStyle( 0, color, 1,
+              true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+          g.moveTo( start > 3 ? 2 : 0 , 2 );
+          g.lineTo( left, 2 );
+    
+          // 終了円
+          if ( d.fix_date && trade.left + end <= trade.right -3 ) {
+            img = getTradeBitmap( d );
+            img.x = start > 0 ? w-4 : end-3;
+            img.y = 0;
+            sprite.addChild(img);
+          }
+          
+          // あたり判定を行うためのスプライト
+          var overSpace:Sprite = new Sprite();
+          overSpace.alpha = 1;
+          overSpace.graphics.beginFill(0x000000);
+          overSpace.graphics.drawRect( 0, 0, left+5, 6 );
+          overSpace.graphics.endFill();
+          overSpace.x = start > 0 ? start+trade.left-2 : trade.left ;
+          overSpace.y = y ;
+          overSpace.visible = false;
+          sprite.hitArea = overSpace;
+          
+          sprite.x = start > 0 ? start+trade.left-2 : trade.left + 1;
+          sprite.y = y ;
+          sprite.addEventListener(MouseEvent.MOUSE_OVER, function(ev:flash.events.MouseEvent):void {
+            rc.layers.setWindowVisible({"trade":true});
+            detailWindow.update( d, ev );
+          });
+          sprite.addEventListener(MouseEvent.MOUSE_OUT,  function(ev:flash.events.MouseEvent):void {
+            rc.layers.setWindowVisible({"info":true});
+          });
+          trades.addChild( overSpace );
+          trades.addChild( sprite );
+        });
+    }
+    
+    private function getTradeBitmap(d:Object):Bitmap {
+      var sell:Boolean = d["sell_or_buy"] == "sell";
+      var img:Bitmap = null;
+      if (d.profit_or_loss > 0) {
+        img = sell ? new Constants.ICON_TRADE_UP_SELL()
+                   : new Constants.ICON_TRADE_UP_BUY();
+      } else if (d.profit_or_loss == 0) {
+          img = sell ? new Constants.ICON_TRADE_DRAW_SELL()
+          : new Constants.ICON_TRADE_DRAW_BUY();
+      } else {
+        img = sell ? new Constants.ICON_TRADE_DOWN_SELL()
+                   : new Constants.ICON_TRADE_DOWN_BUY();
+      }
+      var abs:Number = Math.abs( d.profit_or_loss);
+      return img;
+    }
+    private function getTradeColor(d:Object):uint {
+      var color:uint = 0;
+      if (d.profit_or_loss > 0) {
+        color = Constants.COLOR_UP;
+      } else  if (d.profit_or_loss == 0) {
+          color = Constants.COLOR_DRAW;
+      } else {
+        color = Constants.COLOR_DOWN;
+      }
+      return color;
+    }
+
+    public function onProfitDataChanged( ev:Event ):void {
+
+      // レイヤーを初期化
+      ([graph,graphFixed,axis,lowAxis]).forEach( function(l:*,i:*,arr:Array):void{
+          l.x = 0;
+          Util.clear( l );
+      } );
+
+      var pm:PositionManager = model.positionManager;
+      var profit:Rectangle = rc.stage.profit;
+      var middle:int = profit.top + profit.height/2;
+
+      // 0
+      var zero:TextField = new TextField();
+      zero.selectable = false;
+      zero.text = "0";
+      zero.width = profit.left-1;
+      zero.setTextFormat( Constants.TEXT_FORMAT_SCALE_Y );
+      zero.y = middle-7;
+      zero.x = 0;
+      axis.addChild(zero);
+
+      // 背景
+//      axis.graphics.lineStyle( 0, Constants.COLOR_AXIS_HI );
+//      axis.graphics.moveTo( profit.left+1, middle+1 );
+//      axis.graphics.lineTo( profit.right, middle+1 );
+      axis.graphics.lineStyle( 0, Constants.COLOR_CANDLE );
+      axis.graphics.moveTo( profit.left+1, middle );
+      axis.graphics.lineTo( profit.right, middle );
+//      var img:Bitmap = new Constants.BITMAP_STRIPE();
+//      g.beginBitmapFill(img.bitmapData);
+//      g.drawRect( Constants.LEFT+2, middle,
+//          stageWidth-Constants.LEFT-Constants.PADDING, 1 );
+//      g.endFill();
+
+      if ( model.profitDatas.getDatas().length <= 0 ) { return; }
+
+      // 軸
+      lowAxis.graphics.lineStyle( 0, Constants.COLOR_AXIS_RIGHT, 1, true,
+          LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+
+      var step:Number = Math.pow(10, int(pm.profitPerY == 0 ? 1 : Math.log(pm.profitPerY)*Math.LOG10E));
+      if ( pm.profitPerY > step * 5 ) {
+        step *= 5;
+      }
+      var start:Number = Math.ceil( -1*pm.profitPerY / step ) * step;
+      for( var tmp:Number=start; tmp<=pm.profitPerY; tmp+=step) {
+        if ( tmp == 0 ) { continue; }
+        var y:int = profit.bottom
+          - pm.fromProfit(tmp,profit.height); //int((max-tmp) * hp);
+        lowAxis.graphics.moveTo( rc.stage.candle.left+1, y );
+        lowAxis.graphics.lineTo( rc.stage.candle.right, y );
+
+        var scaleText:TextField = new TextField();
+        scaleText.selectable = false;
+        scaleText.text = tmp.toString();
+        scaleText.width = rc.stage.candle.left;
+        scaleText.setTextFormat( Constants.TEXT_FORMAT_SCALE_Y );
+        scaleText.y = y-7;
+        scaleText.x = 0;
+        axis.addChild(scaleText);
+      }
+
+
+      // データ
+      var datas:Array = model.profitDatas.getDatas();
+      graph.graphics.lineStyle( 0, Constants.COLOR_UNFIXED, 1,
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      var prevX:Array = [];
+      var prevY:Array = [];
+      var imgRed:Bitmap  = new Constants.BITMAP_STRIPE_RED();
+      var imgBlue:Bitmap = new Constants.BITMAP_STRIPE_BLUE();
+      datas.forEach( function(d:*,i:int,arr:Array):void {
+        var x:int = pm.fromDate( d[4] )+profit.left;
+        var y:int = profit.bottom - pm.fromProfit( d[0], profit.height );
+
+        // 現在の損益
+        if (i==0) {
+          graph.graphics.moveTo( x, y);
+        } else {
+          graph.graphics.lineTo( x, y );
+        }
+
+        // コミット済み損益
+        y = profit.bottom - pm.fromProfit( d[1], profit.height );//middle - d[1]*hp;
+        if ( i <= 0 || i >= datas.length-1 ) {
+          prevY.push(y);
+          prevX.push(x);
+          return;
+        }
+
+        if ( prevY[prevY.length-1] != y ) {
+          prevY.push(y);
+          prevX.push(x);
+          if ( prevY[prevY.length-2] >= middle ) {
+            if ( y < middle ) {
+              drawFixedPosition(graphFixed.graphics,imgBlue,prevX,prevY,middle);
+              prevX = [x];
+              prevY = [y];
+            }
+          } else {
+            if ( y >= middle ) {
+              drawFixedPosition(graphFixed.graphics,imgRed,prevX,prevY,middle);
+              prevX = [x];
+              prevY = [y];
+            }
+          }
+        }
+      });
+      drawFixedPosition(graphFixed.graphics,prevY[0]>=middle ? imgBlue : imgRed,prevX,prevY,middle);
+    }
+    private function drawFixedPosition(g:Graphics,
+        img:Bitmap,prevX:Array,prevY:Array,middle:int):void {
+      g.moveTo( prevX[0], middle );
+      g.beginBitmapFill(img.bitmapData);
+      prevY.forEach( function(d:*,i:int,arr:Array):void {
+        if (i>0) {
+          g.lineTo( prevX[i], prevY[i-1] );
+        }
+        g.lineTo( prevX[i], prevY[i] );
+      });
+      g.lineTo( prevX[prevX.length-1], middle );
+      g.endFill();
+    }
+  }
+}
+
+class Slot {
+
+  public var data:Array = [];
+  private var last:Number = -1;
+  private var scaleTime:Number = 0;
+
+  public function Slot( scaleTime:Number ) {
+    this.scaleTime = scaleTime;
+  }
+
+  public function conflict( trade:Object ):Boolean {
+    return last == 0 || trade.date <= last+scaleTime;
+  }
+  public function add( trade:Object ):void {
+    data.push( trade );
+    last = trade.fix_date;
+    log("last:" + String(last) )
+  }
+}
+